awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2 set(PROJECT_AWECLIENT_NAME awesome-client)
   3
   4 # If ${SOURCE_DIR} is a git repository VERSION is set to
   5 # `git describe` later.
   6 set(VERSION devel)
   7
   8 set(CODENAME "Hunting For Witches")
   9
  10 project(${PROJECT_AWE_NAME} C)
  11
  12 set(CMAKE_BUILD_TYPE RELEASE)
  13
  14 set(CURSES_NEED_NCURSES true)
  15
  16 option(WITH_DBUS "build with D-BUS" ON)
  17 option(GENERATE_MANPAGES "generate manpages" ON)
  18 option(GENERATE_LUADOC "generate luadoc" ON)
  19
  20 link_directories(/usr/local/lib)
  21
  22 # {{{ CFLAGS
  23 add_definitions(-std=gnu99 -ggdb3 -fno-strict-aliasing -Wall -Wextra
  24     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  25     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  26     -Wpointer-arith -Wredundant-decls -Wformat-nonliteral
  27     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  28     -Wstrict-prototypes)
  29 # }}}
  30
  31 # {{{ Find external utilities
  32 macro(a_find_program var prg req)
  33     set(required ${req})
  34     find_program(${var} ${prg})
  35     if(NOT ${var})
  36         message(STATUS "${prg} not found.")
  37         if(required)
  38             message(FATAL_ERROR "${prg} is required to build awesome")
  39         endif()
  40     else()
  41         message(STATUS "${prg} -> ${${var}}")
  42     endif()
  43 endmacro()
  44
  45 a_find_program(CAT_EXECUTABLE cat TRUE)
  46 a_find_program(LN_EXECUTABLE ln TRUE)
  47 a_find_program(GREP_EXECUTABLE grep TRUE)
  48 a_find_program(GIT_EXECUTABLE git FALSE)
  49 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  50 a_find_program(GPERF_EXECUTABLE gperf TRUE)
  51 # programs needed for man pages
  52 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  53 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  54 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  55 # lua documentation
  56 a_find_program(LUA_EXECUTABLE lua FALSE)
  57 a_find_program(LUADOC_EXECUTABLE luadoc FALSE)
  58 # doxygen
  59 include(FindDoxygen)
  60 # pkg-config
  61 include(FindPkgConfig)
  62 # ncurses
  63 include(FindCurses)
  64 # lua 5.1
  65 include(FindLua51) #Due to a cmake bug, you will see Lua50 on screen
  66 # }}}
  67
  68 # {{{ Check if documentation can be build
  69 if(GENERATE_MANPAGES)
  70     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR NOT GZIP_EXECUTABLE)
  71         if(NOT ASCIIDOC_EXECUTABLE)
  72             SET(missing "asciidoc")
  73         endif()
  74         if(NOT XMLTO_EXECUTABLE)
  75             SET(missing ${missing} " xmlto")
  76         endif()
  77         if(NOT GZIP_EXECUTABLE)
  78             SET(missing ${missing} " gzip")
  79         endif()
  80
  81         message(STATUS "Not generating manpages. Missing: " ${missing})
  82         set(GENERATE_MANPAGES OFF)
  83     endif()
  84 endif()
  85
  86 if(GENERATE_LUADOC)
  87     if(NOT LUADOC_EXECUTABLE)
  88         message(STATUS "Not generating luadoc. Missing: luadoc")
  89         set(GENERATE_LUADOC OFF)
  90     endif()
  91 endif()
  92 # }}}
  93
  94 # {{{ Version stamp
  95 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
  96     # get current version
  97     execute_process(
  98         COMMAND ${GIT_EXECUTABLE} describe
  99         WORKING_DIRECTORY ${SOURCE_DIR}
 100         OUTPUT_VARIABLE VERSION
 101         OUTPUT_STRIP_TRAILING_WHITESPACE)
 102     # file the git-version-stamp.sh script will look into
 103     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 104     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 105     # create a version_stamp target later
 106     set(BUILD_FROM_GIT TRUE)
 107 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 108     # get version from version stamp
 109     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 110 endif()
 111 # }}}
 112
 113 # {{{ Get hostname
 114 execute_process(
 115     COMMAND ${HOSTNAME_EXECUTABLE}
 116     WORKING_DIRECTORY ${SOURCE_DIR}
 117     OUTPUT_VARIABLE BUILDHOSTNAME
 118     OUTPUT_STRIP_TRAILING_WHITESPACE)
 119 # }}}
 120
 121 # {{{ Required libraries
 122 #
 123 # this sets up:
 124 # AWESOME_REQUIRED_LIBRARIES
 125 # AWESOME_REQUIRED_INCLUDE_DIRS
 126 # AWESOMECLIENT_LIBRARIES
 127
 128 # Use pkgconfig to get most of the libraries
 129 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 130     xcb>=1.1)
 131
 132 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 133     glib-2.0
 134     cairo
 135     pango>=1.19.3
 136     pangocairo>=1.19.3
 137     xcb-randr
 138     xcb-xtest
 139     xcb-xinerama
 140     xcb-event>=0.3.0
 141     xcb-aux>=0.3.0
 142     xcb-atom>=0.3.0
 143     xcb-keysyms>=0.3.0
 144     xcb-icccm>=0.3.3
 145     xcb-image>=0.3.0
 146     xcb-property>=0.3.0
 147     cairo-xcb
 148     xproto>=7.0.11
 149     imlib2)
 150
 151 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 152     message(FATAL_ERROR)
 153 endif()
 154
 155 macro(a_find_library variable library)
 156     find_library(${variable} ${library})
 157     if(NOT ${variable})
 158         message(FATAL_ERROR ${library} " library not found.")
 159     endif()
 160 endmacro()
 161
 162 # Check for readline, ncurse and libev
 163 a_find_library(LIB_READLINE readline)
 164 a_find_library(LIB_EV ev)
 165
 166 # Error check
 167 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 168     message(FATAL_ERROR "lua library not found")
 169 endif()
 170
 171 set(AWESOME_REQUIRED_LIBRARIES
 172     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 173     ${AWESOME_REQUIRED_LIBRARIES}
 174     ${LIB_EV}
 175     ${LUA_LIBRARIES})
 176
 177 set(AWESOME_REQUIRED_INCLUDE_DIRS
 178     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 179     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 180     ${LUA_INCLUDE_DIR})
 181
 182 set(AWESOMECLIENT_LIBRARIES
 183     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 184     ${LIB_READLINE}
 185     ${LIB_XCB}
 186     ${CURSES_LIBRARIES})
 187
 188 set(AWESOMECLIENT_REQUIRED_INCLUDE_DIRS
 189     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS})
 190 # }}}
 191
 192 # {{{ Optional libraries
 193 #
 194 # this sets up:
 195 # AWESOME_OPTIONAL_LIBRARIES
 196 # AWESOME_OPTIONAL_INCLUDE_DIRS
 197
 198 if(WITH_DBUS)
 199     pkg_check_modules(DBUS dbus-1)
 200     if(DBUS_FOUND)
 201         set(AWESOME_OPTIONAL_LIBRARIES ${AWESOME_OPTIONAL_LIBRARIES} ${DBUS_LIBRARIES})
 202         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 203     else()
 204         set(WITH_DBUS OFF)
 205         message(STATUS "DBUS not found. Disabled.")
 206     endif()
 207 endif()
 208 # }}}
 209
 210 # {{{ Install path and configuration variables
 211 if(DEFINED PREFIX)
 212     set(PREFIX ${PREFIX} CACHE PATH "install prefix")
 213     set(CMAKE_INSTALL_PREFIX ${PREFIX})
 214 else()
 215     set(PREFIX ${CMAKE_INSTALL_PREFIX} CACHE PATH "install prefix")
 216 endif()
 217
 218 #If a sysconfdir is specified, use it instead
 219 #of the default configuration dir.
 220 if(DEFINED SYSCONFDIR)
 221     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 222 else()
 223     set(SYSCONFDIR /etc CACHE PATH "config directory")
 224 endif()
 225
 226 #If an XDG Config Dir is specificed, use it instead
 227 #of the default XDG configuration dir.
 228 if(DEFINED XDG_CONFIG_DIR)
 229     set(XDG_CONFIG_DIR ${XDG_CONFIG_SYS} CACHE PATH "xdg config directory")
 230 else()
 231     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 232 endif()
 233
 234 # setting AWESOME_DOC_PATH
 235 if(DEFINED AWESOME_DOC_PATH)
 236     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 237 else()
 238     set(AWESOME_DOC_PATH ${PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 239 endif()
 240
 241 # setting AWESOME_XSESSION_PATH
 242 if(DEFINED AWESOME_XSESSION_PATH)
 243     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 244 else()
 245     set(AWESOME_XSESSION_PATH ${PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 246 endif()
 247
 248 # set man path
 249 if(DEFINED AWESOME_MAN_PATH)
 250    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 251 else()
 252    set(AWESOME_MAN_PATH ${PREFIX}/share/man CACHE PATH "awesome manpage directory")
 253 endif()
 254
 255 # Hide to avoid confusion
 256 mark_as_advanced(CMAKE_INSTALL_PREFIX)
 257
 258 set(AWESOME_VERSION          ${VERSION})
 259 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 260 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 261 set(AWESOME_COMPILE_BY       $ENV{USER})
 262 set(AWESOME_RELEASE          ${CODENAME})
 263 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 264 set(AWESOME_DATA_PATH        ${PREFIX}/share/${PROJECT_AWE_NAME})
 265 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 266 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 267 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 268 # }}}
 269
 270 # {{{ Configure files
 271 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in)
 272 set(AWESOME_CONFIGURE_FILES
 273     ${awesome_lua_configure_files}
 274     config.h.in
 275     awesomerc.lua.in
 276     themes/default/theme.in
 277     themes/sky/theme.in
 278     awesome-version-internal.h.in
 279     awesome.doxygen.in)
 280
 281 macro(a_configure_file file)
 282     string(REGEX REPLACE ".in\$" "" outfile ${file})
 283     message(STATUS "Configuring ${outfile}")
 284     configure_file(${SOURCE_DIR}/${file}
 285                    ${BUILD_DIR}/${outfile}
 286                    ESCAPE_QUOTE
 287                    @ONLY)
 288 endmacro()
 289
 290 foreach(file ${AWESOME_CONFIGURE_FILES})
 291     a_configure_file(${file})
 292 endforeach()
 293 #}}}
 294
 295 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80