CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${BUILD_DIR}/common
  21     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  23     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  24
  25 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua)
  26
  27 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  28 set(AWE_CONF_FILE rc.lua)
  29
  30 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  31 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  32
  33 set(AWE_DOC_FILES
  34     ${SOURCE_DIR}/AUTHORS
  35     ${SOURCE_DIR}/BUGS
  36     ${SOURCE_DIR}/README
  37     ${SOURCE_DIR}/LICENSE)
  38
  39 set(AWE_SRCS
  40     ${SOURCE_DIR}/awesome.c
  41     ${SOURCE_DIR}/client.c
  42     ${SOURCE_DIR}/cnode.c
  43     ${SOURCE_DIR}/dbus.c
  44     ${SOURCE_DIR}/event.c
  45     ${SOURCE_DIR}/property.c
  46     ${SOURCE_DIR}/ewmh.c
  47     ${SOURCE_DIR}/keybinding.c
  48     ${SOURCE_DIR}/keygrabber.c
  49     ${SOURCE_DIR}/layout.c
  50     ${SOURCE_DIR}/luaa.c
  51     ${SOURCE_DIR}/hooks.c
  52     ${SOURCE_DIR}/mouse.c
  53     ${SOURCE_DIR}/screen.c
  54     ${SOURCE_DIR}/stack.c
  55     ${SOURCE_DIR}/statusbar.c
  56     ${SOURCE_DIR}/wibox.c
  57     ${SOURCE_DIR}/systray.c
  58     ${SOURCE_DIR}/tag.c
  59     ${SOURCE_DIR}/titlebar.c
  60     ${SOURCE_DIR}/widget.c
  61     ${SOURCE_DIR}/window.c
  62     ${SOURCE_DIR}/image.c
  63     ${SOURCE_DIR}/draw.c
  64     ${SOURCE_DIR}/swindow.c
  65     ${SOURCE_DIR}/common/buffer.c
  66     ${SOURCE_DIR}/common/atoms.c
  67     ${SOURCE_DIR}/common/markup.c
  68     ${SOURCE_DIR}/common/socket.c
  69     ${SOURCE_DIR}/common/util.c
  70     ${SOURCE_DIR}/common/version.c
  71     ${SOURCE_DIR}/common/xembed.c
  72     ${SOURCE_DIR}/common/xutil.c
  73     ${SOURCE_DIR}/layouts/fibonacci.c
  74     ${SOURCE_DIR}/layouts/floating.c
  75     ${SOURCE_DIR}/layouts/magnifier.c
  76     ${SOURCE_DIR}/layouts/fair.c
  77     ${SOURCE_DIR}/layouts/max.c
  78     ${SOURCE_DIR}/layouts/tile.c
  79     ${SOURCE_DIR}/widgets/graph.c
  80     ${SOURCE_DIR}/widgets/progressbar.c
  81     ${SOURCE_DIR}/widgets/textbox.c
  82     ${SOURCE_DIR}/widgets/systray.c
  83     ${SOURCE_DIR}/widgets/imagebox.c)
  84
  85 set(AWE_CLIENT_SRCS
  86     ${SOURCE_DIR}/awesome-client.c
  87     ${SOURCE_DIR}/common/socket.c
  88     ${SOURCE_DIR}/common/util.c
  89     ${SOURCE_DIR}/common/version.c)
  90
  91 set(AWE_MAN_SRCS
  92     ${SOURCE_DIR}/awesome.1.txt
  93     ${SOURCE_DIR}/awesome-client.1.txt
  94     ${SOURCE_DIR}/awesomerc.5.txt)
  95
  96 add_executable(${PROJECT_AWE_NAME}
  97     ${AWE_SRCS}
  98     ${BUILD_DIR}/common/tokenize.c)
  99
 100 add_executable(${PROJECT_AWECLIENT_NAME}
 101     ${AWE_CLIENT_SRCS}
 102     ${BUILD_DIR}/common/tokenize.c)
 103
 104 set_target_properties(${PROJECT_AWE_NAME}
 105     PROPERTIES
 106     LINK_FLAGS -export-dynamic)
 107
 108 target_link_libraries(${PROJECT_AWE_NAME}
 109     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 110     ${AWESOME_REQUIRED_LIBRARIES}
 111     ${AWESOME_OPTIONAL_LIBRARIES})
 112
 113 target_link_libraries(${PROJECT_AWECLIENT_NAME}
 114     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 115     ${AWESOMECLIENT_LIBRARIES})
 116
 117 # {{{ Generated sources
 118 file(GLOB LAYOUTGEN_DEPS ${SOURCE_DIR}/layouts/*.h)
 119 add_custom_command(
 120     COMMAND ${SOURCE_DIR}/build-utils/layoutgen.sh
 121     ARGS    > ${BUILD_DIR}/layoutgen.h
 122     OUTPUT  ${BUILD_DIR}/layoutgen.h
 123     WORKING_DIRECTORY ${SOURCE_DIR}
 124     DEPENDS ${LAYOUTGEN_DEPS}
 125     COMMENT "Generating layoutgen.h"
 126     VERBATIM)
 127
 128 add_custom_command(
 129     COMMAND ${SOURCE_DIR}/build-utils/widgetgen.sh
 130     ARGS    > ${BUILD_DIR}/widgetgen.h
 131     OUTPUT  ${BUILD_DIR}/widgetgen.h
 132     WORKING_DIRECTORY ${SOURCE_DIR}
 133     DEPENDS ${SOURCE_DIR}/widget.h
 134     COMMENT "Generating widgetgen.h"
 135     VERBATIM)
 136
 137 # atoms
 138 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 139 add_custom_command(
 140     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 141     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 142     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 143     WORKING_DIRECTORY ${SOURCE_DIR}
 144     DEPENDS ${SOURCE_DIR}/common/atoms.list
 145     COMMENT "Generating atoms-extern.h"
 146     VERBATIM)
 147
 148 add_custom_command(
 149     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 150     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 151     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 152     WORKING_DIRECTORY ${SOURCE_DIR}
 153     DEPENDS ${SOURCE_DIR}/common/atoms.list
 154     COMMENT "Generating atoms-intern.h"
 155     VERBATIM)
 156
 157 # gperf
 158 add_custom_command(
 159     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 160     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 161             ${BUILD_DIR}/common/tokenize.h
 162     OUTPUT  ${BUILD_DIR}/common/tokenize.h
 163     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 164             ${SOURCE_DIR}/build-utils/gperf.sh
 165     COMMENT "Generating common/tokenize.h")
 166
 167 add_custom_command(
 168     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 169     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 170             ${BUILD_DIR}/common/tokenize.c
 171     OUTPUT  ${BUILD_DIR}/common/tokenize.c
 172     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 173             ${SOURCE_DIR}/build-utils/gperf.sh
 174     COMMENT "Generating common/tokenize.c")
 175
 176 add_custom_target(generated_sources
 177     DEPENDS ${BUILD_DIR}/widgetgen.h
 178             ${BUILD_DIR}/layoutgen.h
 179             ${BUILD_DIR}/common/atoms-intern.h
 180             ${BUILD_DIR}/common/atoms-extern.h
 181             ${BUILD_DIR}/common/tokenize.c
 182             ${BUILD_DIR}/common/tokenize.h)
 183
 184 # Default theme directory
 185 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 186 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 187 add_dependencies(${PROJECT_AWECLIENT_NAME} generated_sources)
 188 # }}}
 189
 190 # {{{ Version stamp
 191 if(BUILD_FROM_GIT)
 192     add_custom_target(version_stamp ALL
 193         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 194                 ${VERSION_STAMP_FILE}
 195                 ${BUILD_DIR}/awesome-version-internal.h
 196         WORKING_DIRECTORY ${SOURCE_DIR})
 197
 198     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 199     add_dependencies(${PROJECT_AWECLIENT_NAME} version_stamp)
 200 endif()
 201 # }}}
 202
 203 # {{{ Manpages
 204 if(GENERATE_MANPAGES)
 205     foreach(txtfile ${AWE_MAN_SRCS})
 206         string(REGEX REPLACE ".txt\$" ".xml" xmlfile ${txtfile})
 207         string(REPLACE ${SOURCE_DIR}
 208                        ${BUILD_DIR} xmlfile ${xmlfile})
 209         string(REGEX REPLACE ".xml\$" ".gz" gzfile ${xmlfile})
 210         string(REGEX REPLACE ".gz\$" "" manfile ${gzfile})
 211
 212         add_custom_command(
 213             COMMAND ${CAT_EXECUTABLE} ${txtfile}
 214                     | ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} -
 215             WORKING_DIRECTORY ${BUILD_DIR}
 216             OUTPUT  ${xmlfile}
 217             DEPENDS ${txtfile}
 218             VERBATIM)
 219         add_custom_command(
 220             COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 221             OUTPUT  ${manfile}
 222             DEPENDS ${xmlfile})
 223         add_custom_command(
 224             COMMAND ${CAT_EXECUTABLE} ${manfile}
 225                     | ${GZIP_EXECUTABLE}
 226                     > ${gzfile}
 227             OUTPUT  ${gzfile}
 228             DEPENDS ${manfile}
 229             VERBATIM)
 230
 231         set(MAN_FILES ${MAN_FILES} ${gzfile})
 232
 233         # figure out in what section to install to from filename
 234         string(REGEX REPLACE "^.*\\.([0-9])\\.gz\$" "\\1" section ${gzfile})
 235         set(AWE_MAN${section}_FILES ${AWE_MAN${section}_FILES} ${gzfile})
 236     endforeach()
 237
 238     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 239 endif()
 240 # }}}
 241
 242 # {{{ Doxygen
 243 if(DOXYGEN_EXECUTABLE)
 244     add_custom_target(doc
 245         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 246         WORKING_DIRECTORY ${BUILD_DIR})
 247 endif()
 248 # }}}
 249
 250 # {{{ Lua API Documentation
 251 if(GENERATE_LUADOC)
 252
 253     set(capi_lua ${BUILD_DIR}/lib/capi.lua)
 254
 255     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 256         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 257     endif()
 258
 259     # {{{ setup a command for ${capi_lua}
 260     macro(a_file_match infile regex result_var)
 261         file(STRINGS ${infile} match REGEX ${regex} LIMIT_COUNT 1)
 262         if(match)
 263             set(${result_var} TRUE)
 264         else()
 265             set(${result_var} FALSE)
 266         endif()
 267     endmacro()
 268
 269     set(luadoc_c_srcs "")
 270
 271     # find .c files exporting lua functions
 272     foreach(cfile ${AWE_SRCS})
 273         a_file_match(${cfile} "const struct luaL_reg" result)
 274         if(result)
 275             set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 276         else()
 277             a_file_match(${cfile} "luaA_.*_index" result)
 278             if(result)
 279                 set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 280         endif()
 281         endif()
 282     endforeach()
 283
 284     # create fake lua source file to process by luadoc
 285     add_custom_command(
 286         COMMAND ${CAT_EXECUTABLE} ${luadoc_c_srcs}
 287                 | ${LUA_EXECUTABLE} ${SOURCE_DIR}/build-utils/fake-lua-src.lua
 288                 > ${capi_lua}
 289         OUTPUT  ${capi_lua}
 290         DEPENDS ${luadoc_c_srcs}
 291         COMMENT "Generating fake lua source."
 292         VERBATIM)
 293     # }}}
 294
 295     # Generate documentation of lib//0lua
 296     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua)
 297     foreach(filename ${lua_lib_files})
 298         file(RELATIVE_PATH filename ${BUILD_DIR}/lib ${filename})
 299         set(luadoc_srcs ${luadoc_srcs} ${filename})
 300     endforeach()
 301
 302     add_custom_target(luadoc ALL
 303         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc
 304         WORKING_DIRECTORY ${BUILD_DIR}/lib
 305         DEPENDS ${AWE_LUA_FILES} ${capi_lua})
 306 endif()
 307 # }}}
 308
 309 # {{{ Dist tarball
 310 if(BUILD_FROM_GIT)
 311     add_custom_target(dist
 312         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 313         WORKING_DIRECTORY ${SOURCE_DIR})
 314 endif()
 315 # }}}
 316
 317 # {{{ Installation
 318 install(TARGETS ${PROJECT_AWE_NAME} ${PROJECT_AWECLIENT_NAME} RUNTIME DESTINATION bin)
 319 install(FILES "utils/awsetbg" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 320 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH})
 321 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 322         RENAME ${AWE_CONF_FILE})
 323 if(GENERATE_MANPAGES)
 324     install(FILES ${AWE_MAN1_FILES} DESTINATION ${AWESOME_MAN_PATH}/man1)
 325     install(FILES ${AWE_MAN5_FILES} DESTINATION ${AWESOME_MAN_PATH}/man5)
 326 endif()
 327 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 328 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH})
 329 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 330     PATTERN "*.in" EXCLUDE)
 331 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 332 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 333 if(GENERATE_LUADOC)
 334     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 335 endif()
 336 # }}}
 337
 338 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80