awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2
   3 # If ${SOURCE_DIR} is a git repository VERSION is set to
   4 # `git describe` later.
   5 set(VERSION devel)
   6
   7 set(CODENAME "Closing In")
   8
   9 project(${PROJECT_AWE_NAME} C)
  10
  11 set(CMAKE_BUILD_TYPE RELEASE)
  12
  13 option(WITH_DBUS "build with D-BUS" ON)
  14 option(GENERATE_MANPAGES "generate manpages" ON)
  15 option(COMPRESS_MANPAGES "compress manpages" ON)
  16 option(GENERATE_LUADOC "generate luadoc" ON)
  17
  18 link_directories(/usr/local/lib)
  19
  20 # {{{ CFLAGS
  21 add_definitions(-std=gnu99 -ggdb3 -rdynamic -fno-strict-aliasing -Wall -Wextra
  22     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  23     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  24     -Wpointer-arith -Wredundant-decls -Wformat-nonliteral
  25     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  26     -Wstrict-prototypes)
  27 # }}}
  28
  29 # {{{ Endianness
  30 include(TestBigEndian)
  31 TEST_BIG_ENDIAN(AWESOME_IS_BIG_ENDIAN)
  32 # }}}
  33
  34 # {{{ Find external utilities
  35 macro(a_find_program var prg req)
  36     set(required ${req})
  37     find_program(${var} ${prg})
  38     if(NOT ${var})
  39         message(STATUS "${prg} not found.")
  40         if(required)
  41             message(FATAL_ERROR "${prg} is required to build awesome")
  42         endif()
  43     else()
  44         message(STATUS "${prg} -> ${${var}}")
  45     endif()
  46 endmacro()
  47
  48 a_find_program(CAT_EXECUTABLE cat TRUE)
  49 a_find_program(LN_EXECUTABLE ln TRUE)
  50 a_find_program(GREP_EXECUTABLE grep TRUE)
  51 a_find_program(GIT_EXECUTABLE git FALSE)
  52 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  53 # programs needed for man pages
  54 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  55 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  56 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  57 # lua documentation
  58 a_find_program(LUA_EXECUTABLE lua FALSE)
  59 a_find_program(LUADOC_EXECUTABLE luadoc FALSE)
  60 # theme graphics
  61 a_find_program(CONVERT_EXECUTABLE convert TRUE)
  62 # doxygen
  63 include(FindDoxygen)
  64 # pkg-config
  65 include(FindPkgConfig)
  66 # lua 5.1
  67 include(FindLua51) #Due to a cmake bug, you will see Lua50 on screen
  68 # }}}
  69
  70 # {{{ Check if documentation can be build
  71 if(GENERATE_MANPAGES)
  72     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR (COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE))
  73         if(NOT ASCIIDOC_EXECUTABLE)
  74             SET(missing "asciidoc")
  75         endif()
  76         if(NOT XMLTO_EXECUTABLE)
  77             SET(missing ${missing} " xmlto")
  78         endif()
  79         if(COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE)
  80             SET(missing ${missing} " gzip")
  81         endif()
  82
  83         message(STATUS "Not generating manpages. Missing: " ${missing})
  84         set(GENERATE_MANPAGES OFF)
  85     endif()
  86 endif()
  87
  88 if(GENERATE_LUADOC)
  89     if(NOT LUADOC_EXECUTABLE)
  90         message(STATUS "Not generating luadoc. Missing: luadoc")
  91         set(GENERATE_LUADOC OFF)
  92     endif()
  93 endif()
  94 # }}}
  95
  96 # {{{ Version stamp
  97 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
  98     # get current version
  99     execute_process(
 100         COMMAND ${GIT_EXECUTABLE} describe
 101         WORKING_DIRECTORY ${SOURCE_DIR}
 102         OUTPUT_VARIABLE VERSION
 103         OUTPUT_STRIP_TRAILING_WHITESPACE)
 104     # file the git-version-stamp.sh script will look into
 105     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 106     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 107     # create a version_stamp target later
 108     set(BUILD_FROM_GIT TRUE)
 109 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 110     # get version from version stamp
 111     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 112 endif()
 113 # }}}
 114
 115 # {{{ Get hostname
 116 execute_process(
 117     COMMAND ${HOSTNAME_EXECUTABLE}
 118     WORKING_DIRECTORY ${SOURCE_DIR}
 119     OUTPUT_VARIABLE BUILDHOSTNAME
 120     OUTPUT_STRIP_TRAILING_WHITESPACE)
 121 # }}}
 122
 123 # {{{ Required libraries
 124 #
 125 # this sets up:
 126 # AWESOME_REQUIRED_LDFLAGS
 127 # AWESOME_REQUIRED_INCLUDE_DIRS
 128
 129 # Use pkgconfig to get most of the libraries
 130 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 131     xcb>=1.4)
 132
 133 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 134     glib-2.0
 135     cairo
 136     x11
 137     pango>=1.19.3
 138     pangocairo>=1.19.3
 139     oocairo
 140     oopango
 141     xcb-randr
 142     xcb-xtest
 143     xcb-xinerama
 144     xcb-aux>=0.3.0
 145     xcb-atom>=0.3.0
 146     xcb-keysyms>=0.3.4
 147     xcb-icccm>=0.3.6
 148     xcb-image>=0.3.0
 149     cairo-xcb
 150     libstartup-notification-1.0>=0.10
 151     xproto>=7.0.15
 152     libxdg-basedir>=1.0.0)
 153
 154 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 155     message(FATAL_ERROR)
 156 endif()
 157
 158 macro(a_find_library variable library)
 159     find_library(${variable} ${library})
 160     if(NOT ${variable})
 161         message(FATAL_ERROR ${library} " library not found.")
 162     endif()
 163 endmacro()
 164
 165 # Check for libev
 166 a_find_library(LIB_EV ev)
 167 # GNU libc has <execinfo.h> and backtrace() stuff. If this is not available, we
 168 # need libexecinfo.
 169 message(STATUS "checking for execinfo")
 170 try_compile(HAS_EXECINFO
 171     ${CMAKE_BINARY_DIR}
 172     ${CMAKE_SOURCE_DIR}/build-tests/execinfo.c)
 173 if(NOT HAS_EXECINFO)
 174     find_library(LIB_EXECINFO execinfo)
 175     if(LIB_EXECINFO)
 176         set(HAS_EXECINFO 1)
 177         set(AWESOME_REQUIRED_LDFLAGS
 178             ${AWESOME_REQUIRED_LDFLAGS}
 179             ${LIB_EXECINFO})
 180     endif()
 181 endif()
 182 if(HAS_EXECINFO)
 183     message(STATUS "checking for execinfo -- found")
 184 else()
 185     message(STATUS "checking for execinfo -- not found")
 186 endif()
 187
 188 # Error check
 189 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 190     message(FATAL_ERROR "lua library not found")
 191 endif()
 192
 193 set(AWESOME_REQUIRED_LDFLAGS
 194     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 195     ${AWESOME_REQUIRED_LDFLAGS}
 196     ${LIB_EV}
 197     ${LUA_LIBRARIES})
 198
 199 set(AWESOME_REQUIRED_INCLUDE_DIRS
 200     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 201     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 202     ${LUA_INCLUDE_DIR})
 203 # }}}
 204
 205 # {{{ Optional libraries
 206 #
 207 # this sets up:
 208 # AWESOME_OPTIONAL_LDFLAGS
 209 # AWESOME_OPTIONAL_INCLUDE_DIRS
 210
 211 if(WITH_DBUS)
 212     pkg_check_modules(DBUS dbus-1)
 213     if(DBUS_FOUND)
 214         set(AWESOME_OPTIONAL_LDFLAGS ${AWESOME_OPTIONAL_LDFLAGS} ${DBUS_LDFLAGS})
 215         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 216     else()
 217         set(WITH_DBUS OFF)
 218         message(STATUS "DBUS not found. Disabled.")
 219     endif()
 220 endif()
 221 # }}}
 222
 223 # {{{ Install path and configuration variables
 224 if(DEFINED PREFIX)
 225     set(PREFIX ${PREFIX} CACHE PATH "install prefix")
 226     set(CMAKE_INSTALL_PREFIX ${PREFIX})
 227 else()
 228     set(PREFIX ${CMAKE_INSTALL_PREFIX} CACHE PATH "install prefix")
 229 endif()
 230
 231 #If a sysconfdir is specified, use it instead
 232 #of the default configuration dir.
 233 if(DEFINED SYSCONFDIR)
 234     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 235 else()
 236     set(SYSCONFDIR ${PREFIX}/etc CACHE PATH "config directory")
 237 endif()
 238
 239 #If an XDG Config Dir is specificed, use it instead
 240 #of the default XDG configuration dir.
 241 if(DEFINED XDG_CONFIG_DIR)
 242     set(XDG_CONFIG_DIR ${XDG_CONFIG_DIR} CACHE PATH "xdg config directory")
 243 else()
 244     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 245 endif()
 246
 247 # setting AWESOME_DOC_PATH
 248 if(DEFINED AWESOME_DOC_PATH)
 249     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 250 else()
 251     set(AWESOME_DOC_PATH ${PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 252 endif()
 253
 254 # setting AWESOME_XSESSION_PATH
 255 if(DEFINED AWESOME_XSESSION_PATH)
 256     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 257 else()
 258     set(AWESOME_XSESSION_PATH ${PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 259 endif()
 260
 261 # set man path
 262 if(DEFINED AWESOME_MAN_PATH)
 263    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 264 else()
 265    set(AWESOME_MAN_PATH ${PREFIX}/share/man CACHE PATH "awesome manpage directory")
 266 endif()
 267
 268 # Hide to avoid confusion
 269 mark_as_advanced(CMAKE_INSTALL_PREFIX)
 270
 271 set(AWESOME_VERSION          ${VERSION})
 272 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 273 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 274 set(AWESOME_COMPILE_BY       $ENV{USER})
 275 set(AWESOME_RELEASE          ${CODENAME})
 276 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 277 set(AWESOME_DATA_PATH        ${PREFIX}/share/${PROJECT_AWE_NAME})
 278 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 279 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 280 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 281 # }}}
 282
 283 # {{{ Configure files
 284 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in ${SOURCE_DIR}/themes/*/*.lua.in)
 285 set(AWESOME_CONFIGURE_FILES
 286     ${awesome_lua_configure_files}
 287     config.h.in
 288     awesomerc.lua.in
 289     awesome-version-internal.h.in
 290     awesome.doxygen.in)
 291
 292 macro(a_configure_file file)
 293     string(REGEX REPLACE ".in\$" "" outfile ${file})
 294     message(STATUS "Configuring ${outfile}")
 295     configure_file(${SOURCE_DIR}/${file}
 296                    ${BUILD_DIR}/${outfile}
 297                    ESCAPE_QUOTE
 298                    @ONLY)
 299 endmacro()
 300
 301 foreach(file ${AWESOME_CONFIGURE_FILES})
 302     a_configure_file(${file})
 303 endforeach()
 304 #}}}
 305
 306 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80