awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2 set(PROJECT_AWECLIENT_NAME awesome-client)
   3
   4 # If ${SOURCE_DIR} is a git repository VERSION is set to
   5 # `git describe` later.
   6 set(VERSION devel)
   7
   8 set(CODENAME "Bad Boyfriend")
   9
  10 project(${PROJECT_AWE_NAME} C)
  11
  12 set(CMAKE_BUILD_TYPE RELEASE)
  13
  14 set(CURSES_NEED_NCURSES true)
  15
  16 option(WITH_DBUS "build with D-BUS" ON)
  17 option(GENERATE_MANPAGES "generate manpages" ON)
  18 option(GENERATE_LUADOC "generate luadoc" ON)
  19
  20 link_directories(/usr/local/lib)
  21
  22 # {{{ CFLAGS
  23 add_definitions(-std=gnu99 -ggdb3 -fno-strict-aliasing -Wall -Wextra
  24     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  25     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  26     -Wpointer-arith -Wredundant-decls -Wformat-nonliteral
  27     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  28     -Wstrict-prototypes)
  29 # }}}
  30
  31 # {{{ Endianness
  32 include(TestBigEndian)
  33 TEST_BIG_ENDIAN(AWESOME_IS_BIG_ENDIAN)
  34 # }}}
  35
  36 # {{{ Find external utilities
  37 macro(a_find_program var prg req)
  38     set(required ${req})
  39     find_program(${var} ${prg})
  40     if(NOT ${var})
  41         message(STATUS "${prg} not found.")
  42         if(required)
  43             message(FATAL_ERROR "${prg} is required to build awesome")
  44         endif()
  45     else()
  46         message(STATUS "${prg} -> ${${var}}")
  47     endif()
  48 endmacro()
  49
  50 a_find_program(CAT_EXECUTABLE cat TRUE)
  51 a_find_program(LN_EXECUTABLE ln TRUE)
  52 a_find_program(GREP_EXECUTABLE grep TRUE)
  53 a_find_program(GIT_EXECUTABLE git FALSE)
  54 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  55 a_find_program(GPERF_EXECUTABLE gperf TRUE)
  56 # programs needed for man pages
  57 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  58 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  59 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  60 # lua documentation
  61 a_find_program(LUA_EXECUTABLE lua FALSE)
  62 a_find_program(LUADOC_EXECUTABLE luadoc FALSE)
  63 # doxygen
  64 include(FindDoxygen)
  65 # pkg-config
  66 include(FindPkgConfig)
  67 # ncurses
  68 include(FindCurses)
  69 # lua 5.1
  70 include(FindLua51) #Due to a cmake bug, you will see Lua50 on screen
  71 # }}}
  72
  73 # {{{ Check if documentation can be build
  74 if(GENERATE_MANPAGES)
  75     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR NOT GZIP_EXECUTABLE)
  76         if(NOT ASCIIDOC_EXECUTABLE)
  77             SET(missing "asciidoc")
  78         endif()
  79         if(NOT XMLTO_EXECUTABLE)
  80             SET(missing ${missing} " xmlto")
  81         endif()
  82         if(NOT GZIP_EXECUTABLE)
  83             SET(missing ${missing} " gzip")
  84         endif()
  85
  86         message(STATUS "Not generating manpages. Missing: " ${missing})
  87         set(GENERATE_MANPAGES OFF)
  88     endif()
  89 endif()
  90
  91 if(GENERATE_LUADOC)
  92     if(NOT LUADOC_EXECUTABLE)
  93         message(STATUS "Not generating luadoc. Missing: luadoc")
  94         set(GENERATE_LUADOC OFF)
  95     endif()
  96 endif()
  97 # }}}
  98
  99 # {{{ Version stamp
 100 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
 101     # get current version
 102     execute_process(
 103         COMMAND ${GIT_EXECUTABLE} describe
 104         WORKING_DIRECTORY ${SOURCE_DIR}
 105         OUTPUT_VARIABLE VERSION
 106         OUTPUT_STRIP_TRAILING_WHITESPACE)
 107     # file the git-version-stamp.sh script will look into
 108     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 109     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 110     # create a version_stamp target later
 111     set(BUILD_FROM_GIT TRUE)
 112 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 113     # get version from version stamp
 114     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 115 endif()
 116 # }}}
 117
 118 # {{{ Get hostname
 119 execute_process(
 120     COMMAND ${HOSTNAME_EXECUTABLE}
 121     WORKING_DIRECTORY ${SOURCE_DIR}
 122     OUTPUT_VARIABLE BUILDHOSTNAME
 123     OUTPUT_STRIP_TRAILING_WHITESPACE)
 124 # }}}
 125
 126 # {{{ Required libraries
 127 #
 128 # this sets up:
 129 # AWESOME_REQUIRED_LIBRARIES
 130 # AWESOME_REQUIRED_INCLUDE_DIRS
 131
 132 # Use pkgconfig to get most of the libraries
 133 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 134     xcb>=1.1)
 135
 136 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 137     glib-2.0
 138     cairo
 139     x11
 140     pango>=1.19.3
 141     pangocairo>=1.19.3
 142     xcb-randr
 143     xcb-xtest
 144     xcb-xinerama
 145     xcb-event>=0.3.4
 146     xcb-aux>=0.3.0
 147     xcb-atom>=0.3.0
 148     xcb-keysyms>=0.3.4
 149     xcb-icccm>=0.3.3
 150     xcb-image>=0.3.0
 151     xcb-property>=0.3.0
 152     cairo-xcb
 153     libstartup-notification-1.0>=0.10
 154     xproto>=7.0.15
 155     imlib2
 156     libxdg-basedir>=1.0.0)
 157
 158 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 159     message(FATAL_ERROR)
 160 endif()
 161
 162 macro(a_find_library variable library)
 163     find_library(${variable} ${library})
 164     if(NOT ${variable})
 165         message(FATAL_ERROR ${library} " library not found.")
 166     endif()
 167 endmacro()
 168
 169 # Check for libev
 170 a_find_library(LIB_EV ev)
 171
 172 # Error check
 173 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 174     message(FATAL_ERROR "lua library not found")
 175 endif()
 176
 177 set(AWESOME_REQUIRED_LIBRARIES
 178     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 179     ${AWESOME_REQUIRED_LIBRARIES}
 180     ${LIB_EV}
 181     ${LUA_LIBRARIES})
 182
 183 set(AWESOME_REQUIRED_INCLUDE_DIRS
 184     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 185     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 186     ${LUA_INCLUDE_DIR})
 187 # }}}
 188
 189 # {{{ Optional libraries
 190 #
 191 # this sets up:
 192 # AWESOME_OPTIONAL_LIBRARIES
 193 # AWESOME_OPTIONAL_INCLUDE_DIRS
 194
 195 if(WITH_DBUS)
 196     pkg_check_modules(DBUS dbus-1)
 197     if(DBUS_FOUND)
 198         set(AWESOME_OPTIONAL_LIBRARIES ${AWESOME_OPTIONAL_LIBRARIES} ${DBUS_LIBRARIES})
 199         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 200     else()
 201         set(WITH_DBUS OFF)
 202         message(STATUS "DBUS not found. Disabled.")
 203     endif()
 204 endif()
 205 # }}}
 206
 207 # {{{ Install path and configuration variables
 208 if(DEFINED PREFIX)
 209     set(PREFIX ${PREFIX} CACHE PATH "install prefix")
 210     set(CMAKE_INSTALL_PREFIX ${PREFIX})
 211 else()
 212     set(PREFIX ${CMAKE_INSTALL_PREFIX} CACHE PATH "install prefix")
 213 endif()
 214
 215 #If a sysconfdir is specified, use it instead
 216 #of the default configuration dir.
 217 if(DEFINED SYSCONFDIR)
 218     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 219 else()
 220     set(SYSCONFDIR ${PREFIX}/etc CACHE PATH "config directory")
 221 endif()
 222
 223 #If an XDG Config Dir is specificed, use it instead
 224 #of the default XDG configuration dir.
 225 if(DEFINED XDG_CONFIG_DIR)
 226     set(XDG_CONFIG_DIR ${XDG_CONFIG_DIR} CACHE PATH "xdg config directory")
 227 else()
 228     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 229 endif()
 230
 231 # setting AWESOME_DOC_PATH
 232 if(DEFINED AWESOME_DOC_PATH)
 233     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 234 else()
 235     set(AWESOME_DOC_PATH ${PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 236 endif()
 237
 238 # setting AWESOME_XSESSION_PATH
 239 if(DEFINED AWESOME_XSESSION_PATH)
 240     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 241 else()
 242     set(AWESOME_XSESSION_PATH ${PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 243 endif()
 244
 245 # set man path
 246 if(DEFINED AWESOME_MAN_PATH)
 247    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 248 else()
 249    set(AWESOME_MAN_PATH ${PREFIX}/share/man CACHE PATH "awesome manpage directory")
 250 endif()
 251
 252 # Hide to avoid confusion
 253 mark_as_advanced(CMAKE_INSTALL_PREFIX)
 254
 255 set(AWESOME_VERSION          ${VERSION})
 256 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 257 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 258 set(AWESOME_COMPILE_BY       $ENV{USER})
 259 set(AWESOME_RELEASE          ${CODENAME})
 260 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 261 set(AWESOME_DATA_PATH        ${PREFIX}/share/${PROJECT_AWE_NAME})
 262 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 263 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 264 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 265 # }}}
 266
 267 # {{{ Configure files
 268 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in ${SOURCE_DIR}/themes/*/*.lua.in)
 269 set(AWESOME_CONFIGURE_FILES
 270     ${awesome_lua_configure_files}
 271     config.h.in
 272     awesomerc.lua.in
 273     awesome-version-internal.h.in
 274     awesome.doxygen.in)
 275
 276 macro(a_configure_file file)
 277     string(REGEX REPLACE ".in\$" "" outfile ${file})
 278     message(STATUS "Configuring ${outfile}")
 279     configure_file(${SOURCE_DIR}/${file}
 280                    ${BUILD_DIR}/${outfile}
 281                    ESCAPE_QUOTE
 282                    @ONLY)
 283 endmacro()
 284
 285 foreach(file ${AWESOME_CONFIGURE_FILES})
 286     a_configure_file(${file})
 287 endforeach()
 288 #}}}
 289
 290 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80