CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${BUILD_DIR}/common
  21     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  23     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  24
  25 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua)
  26
  27 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  28 set(AWE_CONF_FILE rc.lua)
  29
  30 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  31 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  32
  33 set(AWE_DOC_FILES
  34     ${SOURCE_DIR}/AUTHORS
  35     ${SOURCE_DIR}/BUGS
  36     ${SOURCE_DIR}/README
  37     ${SOURCE_DIR}/LICENSE)
  38
  39 set(AWE_SRCS
  40     ${SOURCE_DIR}/awesome.c
  41     ${SOURCE_DIR}/client.c
  42     ${SOURCE_DIR}/cnode.c
  43     ${SOURCE_DIR}/dbus.c
  44     ${SOURCE_DIR}/event.c
  45     ${SOURCE_DIR}/property.c
  46     ${SOURCE_DIR}/ewmh.c
  47     ${SOURCE_DIR}/keybinding.c
  48     ${SOURCE_DIR}/keygrabber.c
  49     ${SOURCE_DIR}/layout.c
  50     ${SOURCE_DIR}/luaa.c
  51     ${SOURCE_DIR}/mouse.c
  52     ${SOURCE_DIR}/screen.c
  53     ${SOURCE_DIR}/stack.c
  54     ${SOURCE_DIR}/statusbar.c
  55     ${SOURCE_DIR}/wibox.c
  56     ${SOURCE_DIR}/systray.c
  57     ${SOURCE_DIR}/tag.c
  58     ${SOURCE_DIR}/titlebar.c
  59     ${SOURCE_DIR}/widget.c
  60     ${SOURCE_DIR}/window.c
  61     ${SOURCE_DIR}/image.c
  62     ${SOURCE_DIR}/draw.c
  63     ${SOURCE_DIR}/swindow.c
  64     ${SOURCE_DIR}/common/buffer.c
  65     ${SOURCE_DIR}/common/atoms.c
  66     ${SOURCE_DIR}/common/markup.c
  67     ${SOURCE_DIR}/common/socket.c
  68     ${SOURCE_DIR}/common/util.c
  69     ${SOURCE_DIR}/common/version.c
  70     ${SOURCE_DIR}/common/xembed.c
  71     ${SOURCE_DIR}/common/xutil.c
  72     ${SOURCE_DIR}/layouts/fibonacci.c
  73     ${SOURCE_DIR}/layouts/floating.c
  74     ${SOURCE_DIR}/layouts/magnifier.c
  75     ${SOURCE_DIR}/layouts/fair.c
  76     ${SOURCE_DIR}/layouts/max.c
  77     ${SOURCE_DIR}/layouts/tile.c
  78     ${SOURCE_DIR}/widgets/graph.c
  79     ${SOURCE_DIR}/widgets/progressbar.c
  80     ${SOURCE_DIR}/widgets/textbox.c
  81     ${SOURCE_DIR}/widgets/systray.c
  82     ${SOURCE_DIR}/widgets/imagebox.c)
  83
  84 set(AWE_CLIENT_SRCS
  85     ${SOURCE_DIR}/awesome-client.c
  86     ${SOURCE_DIR}/common/socket.c
  87     ${SOURCE_DIR}/common/util.c
  88     ${SOURCE_DIR}/common/version.c)
  89
  90 set(AWE_MAN_SRCS
  91     ${SOURCE_DIR}/awesome.1.txt
  92     ${SOURCE_DIR}/awesome-client.1.txt
  93     ${SOURCE_DIR}/awesomerc.5.txt)
  94
  95 add_executable(${PROJECT_AWE_NAME}
  96     ${AWE_SRCS}
  97     ${BUILD_DIR}/common/tokenize.c)
  98
  99 add_executable(${PROJECT_AWECLIENT_NAME}
 100     ${AWE_CLIENT_SRCS}
 101     ${BUILD_DIR}/common/tokenize.c)
 102
 103 set_target_properties(${PROJECT_AWE_NAME}
 104     PROPERTIES
 105     LINK_FLAGS -export-dynamic)
 106
 107 target_link_libraries(${PROJECT_AWE_NAME}
 108     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 109     ${AWESOME_REQUIRED_LIBRARIES}
 110     ${AWESOME_OPTIONAL_LIBRARIES})
 111
 112 target_link_libraries(${PROJECT_AWECLIENT_NAME}
 113     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 114     ${AWESOMECLIENT_LIBRARIES})
 115
 116 # {{{ Generated sources
 117 file(GLOB LAYOUTGEN_DEPS ${SOURCE_DIR}/layouts/*.h)
 118 add_custom_command(
 119     COMMAND ${SOURCE_DIR}/build-utils/layoutgen.sh
 120     ARGS    > ${BUILD_DIR}/layoutgen.h
 121     OUTPUT  ${BUILD_DIR}/layoutgen.h
 122     WORKING_DIRECTORY ${SOURCE_DIR}
 123     DEPENDS ${LAYOUTGEN_DEPS}
 124     COMMENT "Generating layoutgen.h"
 125     VERBATIM)
 126
 127 add_custom_command(
 128     COMMAND ${SOURCE_DIR}/build-utils/widgetgen.sh
 129     ARGS    > ${BUILD_DIR}/widgetgen.h
 130     OUTPUT  ${BUILD_DIR}/widgetgen.h
 131     WORKING_DIRECTORY ${SOURCE_DIR}
 132     DEPENDS ${SOURCE_DIR}/widget.h
 133     COMMENT "Generating widgetgen.h"
 134     VERBATIM)
 135
 136 # atoms
 137 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 138 add_custom_command(
 139     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 140     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 141     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 142     WORKING_DIRECTORY ${SOURCE_DIR}
 143     DEPENDS ${SOURCE_DIR}/common/atoms.list
 144     COMMENT "Generating atoms-extern.h"
 145     VERBATIM)
 146
 147 add_custom_command(
 148     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 149     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 150     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 151     WORKING_DIRECTORY ${SOURCE_DIR}
 152     DEPENDS ${SOURCE_DIR}/common/atoms.list
 153     COMMENT "Generating atoms-intern.h"
 154     VERBATIM)
 155
 156 # gperf
 157 add_custom_command(
 158     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 159     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 160             ${BUILD_DIR}/common/tokenize.h
 161     OUTPUT  ${BUILD_DIR}/common/tokenize.h
 162     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 163             ${SOURCE_DIR}/build-utils/gperf.sh
 164     COMMENT "Generating common/tokenize.h")
 165
 166 add_custom_command(
 167     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 168     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 169             ${BUILD_DIR}/common/tokenize.c
 170     OUTPUT  ${BUILD_DIR}/common/tokenize.c
 171     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 172             ${SOURCE_DIR}/build-utils/gperf.sh
 173     COMMENT "Generating common/tokenize.c")
 174
 175 add_custom_target(generated_sources
 176     DEPENDS ${BUILD_DIR}/widgetgen.h
 177             ${BUILD_DIR}/layoutgen.h
 178             ${BUILD_DIR}/common/atoms-intern.h
 179             ${BUILD_DIR}/common/atoms-extern.h
 180             ${BUILD_DIR}/common/tokenize.c
 181             ${BUILD_DIR}/common/tokenize.h)
 182
 183 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 184 add_dependencies(${PROJECT_AWECLIENT_NAME} generated_sources)
 185 # }}}
 186
 187 # {{{ Version stamp
 188 if(BUILD_FROM_GIT)
 189     add_custom_target(version_stamp ALL
 190         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 191                 ${VERSION_STAMP_FILE}
 192                 ${BUILD_DIR}/awesome-version-internal.h
 193         WORKING_DIRECTORY ${SOURCE_DIR})
 194
 195     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 196     add_dependencies(${PROJECT_AWECLIENT_NAME} version_stamp)
 197 endif()
 198 # }}}
 199
 200 # {{{ Manpages
 201 if(GENERATE_MANPAGES)
 202     foreach(txtfile ${AWE_MAN_SRCS})
 203         string(REGEX REPLACE ".txt\$" ".xml" xmlfile ${txtfile})
 204         string(REPLACE ${SOURCE_DIR}
 205                        ${BUILD_DIR} xmlfile ${xmlfile})
 206         string(REGEX REPLACE ".xml\$" ".gz" gzfile ${xmlfile})
 207         string(REGEX REPLACE ".gz\$" "" manfile ${gzfile})
 208
 209         add_custom_command(
 210             COMMAND ${CAT_EXECUTABLE} ${txtfile}
 211                     | ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} -
 212             WORKING_DIRECTORY ${BUILD_DIR}
 213             OUTPUT  ${xmlfile}
 214             DEPENDS ${txtfile}
 215             VERBATIM)
 216         add_custom_command(
 217             COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 218             OUTPUT  ${manfile}
 219             DEPENDS ${xmlfile})
 220         add_custom_command(
 221             COMMAND ${CAT_EXECUTABLE} ${manfile}
 222                     | ${GZIP_EXECUTABLE}
 223                     > ${gzfile}
 224             OUTPUT  ${gzfile}
 225             DEPENDS ${manfile}
 226             VERBATIM)
 227
 228         set(MAN_FILES ${MAN_FILES} ${gzfile})
 229
 230         # figure out in what section to install to from filename
 231         string(REGEX REPLACE "^.*\\.([0-9])\\.gz\$" "\\1" section ${gzfile})
 232         set(AWE_MAN${section}_FILES ${AWE_MAN${section}_FILES} ${gzfile})
 233     endforeach()
 234
 235     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 236 endif()
 237 # }}}
 238
 239 # {{{ Doxygen
 240 if(DOXYGEN_EXECUTABLE)
 241     add_custom_target(doc
 242         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 243         WORKING_DIRECTORY ${BUILD_DIR})
 244 endif()
 245 # }}}
 246
 247 # {{{ Lua API Documentation
 248 if(GENERATE_LUADOC)
 249
 250     set(capi_lua ${BUILD_DIR}/lib/capi.lua)
 251
 252     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 253         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 254     endif()
 255
 256     # {{{ setup a command for ${capi_lua}
 257     macro(a_file_match infile regex result_var)
 258         file(STRINGS ${infile} match REGEX ${regex} LIMIT_COUNT 1)
 259         if(match)
 260             set(${result_var} TRUE)
 261         else()
 262             set(${result_var} FALSE)
 263         endif()
 264     endmacro()
 265
 266     set(luadoc_c_srcs "")
 267
 268     # find .c files exporting lua functions
 269     foreach(cfile ${AWE_SRCS})
 270         a_file_match(${cfile} "const struct luaL_reg" result)
 271         if(result)
 272             set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 273         else()
 274             a_file_match(${cfile} "luaA_.*_index" result)
 275             if(result)
 276                 set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 277         endif()
 278         endif()
 279     endforeach()
 280
 281     # create fake lua source file to process by luadoc
 282     add_custom_command(
 283         COMMAND ${CAT_EXECUTABLE} ${luadoc_c_srcs}
 284                 | ${LUA_EXECUTABLE} ${SOURCE_DIR}/build-utils/fake-lua-src.lua
 285                 > ${capi_lua}
 286         OUTPUT  ${capi_lua}
 287         DEPENDS ${luadoc_c_srcs}
 288         COMMENT "Generating fake lua source."
 289         VERBATIM)
 290     # }}}
 291
 292     # Generate documentation of lib//0lua
 293     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua)
 294     foreach(filename ${lua_lib_files})
 295         file(RELATIVE_PATH filename ${BUILD_DIR}/lib ${filename})
 296         set(luadoc_srcs ${luadoc_srcs} ${filename})
 297     endforeach()
 298
 299     add_custom_target(luadoc ALL
 300         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc
 301         WORKING_DIRECTORY ${BUILD_DIR}/lib
 302         DEPENDS ${AWE_LUA_FILES} ${capi_lua})
 303 endif()
 304 # }}}
 305
 306 # {{{ Dist tarball
 307 if(BUILD_FROM_GIT)
 308     add_custom_target(dist
 309         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 310         WORKING_DIRECTORY ${SOURCE_DIR})
 311 endif()
 312 # }}}
 313
 314 # {{{ Installation
 315 install(TARGETS ${PROJECT_AWE_NAME} ${PROJECT_AWECLIENT_NAME} RUNTIME DESTINATION bin)
 316 install(FILES "utils/awsetbg" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 317 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH})
 318 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 319         RENAME ${AWE_CONF_FILE})
 320 if(GENERATE_MANPAGES)
 321     install(FILES ${AWE_MAN1_FILES} DESTINATION ${AWESOME_MAN_PATH}/man1)
 322     install(FILES ${AWE_MAN5_FILES} DESTINATION ${AWESOME_MAN_PATH}/man5)
 323 endif()
 324 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 325 install(FILES ${AWE_THEMES_DIR}/default-background.png ${BUILD_DIR}/themes/default DESTINATION ${AWESOME_THEMES_PATH})
 326 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 327 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 328 if(GENERATE_LUADOC)
 329     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 330 endif()
 331 # }}}
 332
 333 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80