CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  21     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  23
  24 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua ${BUILD_DIR}/luadoc/*.lua)
  25
  26 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  27 set(AWE_CONF_FILE rc.lua)
  28
  29 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  30 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  31
  32 set(AWE_DOC_FILES
  33     ${SOURCE_DIR}/AUTHORS
  34     ${SOURCE_DIR}/BUGS
  35     ${SOURCE_DIR}/README
  36     ${SOURCE_DIR}/LICENSE)
  37
  38 set(AWE_SRCS
  39     ${SOURCE_DIR}/awesome.c
  40     ${SOURCE_DIR}/client.c
  41     ${SOURCE_DIR}/strut.c
  42     ${SOURCE_DIR}/dbus.c
  43     ${SOURCE_DIR}/root.c
  44     ${SOURCE_DIR}/event.c
  45     ${SOURCE_DIR}/property.c
  46     ${SOURCE_DIR}/ewmh.c
  47     ${SOURCE_DIR}/key.c
  48     ${SOURCE_DIR}/keygrabber.c
  49     ${SOURCE_DIR}/mousegrabber.c
  50     ${SOURCE_DIR}/banning.c
  51     ${SOURCE_DIR}/luaa.c
  52     ${SOURCE_DIR}/spawn.c
  53     ${SOURCE_DIR}/hooks.c
  54     ${SOURCE_DIR}/mouse.c
  55     ${SOURCE_DIR}/button.c
  56     ${SOURCE_DIR}/screen.c
  57     ${SOURCE_DIR}/stack.c
  58     ${SOURCE_DIR}/selection.c
  59     ${SOURCE_DIR}/wibox.c
  60     ${SOURCE_DIR}/systray.c
  61     ${SOURCE_DIR}/tag.c
  62     ${SOURCE_DIR}/titlebar.c
  63     ${SOURCE_DIR}/widget.c
  64     ${SOURCE_DIR}/window.c
  65     ${SOURCE_DIR}/image.c
  66     ${SOURCE_DIR}/draw.c
  67     ${SOURCE_DIR}/font.c
  68     ${SOURCE_DIR}/color.c
  69     ${SOURCE_DIR}/timer.c
  70     ${SOURCE_DIR}/common/buffer.c
  71     ${SOURCE_DIR}/common/atoms.c
  72     ${SOURCE_DIR}/common/util.c
  73     ${SOURCE_DIR}/common/version.c
  74     ${SOURCE_DIR}/common/xembed.c
  75     ${SOURCE_DIR}/common/xutil.c
  76     ${SOURCE_DIR}/common/xcursor.c
  77     ${SOURCE_DIR}/common/backtrace.c
  78     ${SOURCE_DIR}/common/luaobject.c
  79     ${SOURCE_DIR}/common/luaclass.c
  80     ${SOURCE_DIR}/widgets/graph.c
  81     ${SOURCE_DIR}/widgets/progressbar.c
  82     ${SOURCE_DIR}/widgets/textbox.c
  83     ${SOURCE_DIR}/widgets/systray.c
  84     ${SOURCE_DIR}/widgets/imagebox.c)
  85
  86 set(AWE_MAN_SRCS
  87     ${SOURCE_DIR}/manpages/awesome.1.txt
  88     ${SOURCE_DIR}/manpages/awsetbg.1.txt
  89     ${SOURCE_DIR}/manpages/awesome-client.1.txt
  90     ${SOURCE_DIR}/manpages/awesomerc.5.txt)
  91
  92 add_executable(${PROJECT_AWE_NAME}
  93     ${AWE_SRCS}
  94     ${BUILD_DIR}/common/tokenize.c)
  95
  96 set_target_properties(${PROJECT_AWE_NAME}
  97     PROPERTIES
  98     LINK_FLAGS -export-dynamic)
  99
 100 target_link_libraries(${PROJECT_AWE_NAME}
 101     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 102     ${AWESOME_REQUIRED_LIBRARIES}
 103     ${AWESOME_OPTIONAL_LIBRARIES})
 104
 105 # atoms
 106 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 107 add_custom_command(
 108     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 109     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 110     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 111     WORKING_DIRECTORY ${SOURCE_DIR}
 112     DEPENDS ${SOURCE_DIR}/common/atoms.list
 113     COMMENT "Generating atoms-extern.h"
 114     VERBATIM)
 115
 116 add_custom_command(
 117     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 118     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 119     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 120     WORKING_DIRECTORY ${SOURCE_DIR}
 121     DEPENDS ${SOURCE_DIR}/common/atoms.list
 122     COMMENT "Generating atoms-intern.h"
 123     VERBATIM)
 124
 125 # gperf
 126 add_custom_command(
 127     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 128     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 129             ${BUILD_DIR}/common/tokenize.h
 130     OUTPUT  ${BUILD_DIR}/common/tokenize.h
 131     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 132             ${SOURCE_DIR}/build-utils/gperf.sh
 133     COMMENT "Generating common/tokenize.h")
 134
 135 add_custom_command(
 136     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 137     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 138             ${BUILD_DIR}/common/tokenize.c
 139     OUTPUT  ${BUILD_DIR}/common/tokenize.c
 140     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 141             ${SOURCE_DIR}/build-utils/gperf.sh
 142     COMMENT "Generating common/tokenize.c")
 143
 144 add_custom_target(generated_sources
 145     DEPENDS ${BUILD_DIR}/common/atoms-intern.h
 146             ${BUILD_DIR}/common/atoms-extern.h
 147             ${BUILD_DIR}/common/tokenize.c
 148             ${BUILD_DIR}/common/tokenize.h)
 149
 150 # Default theme directory
 151 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 152 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/sky)
 153 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/zenburn)
 154 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 155 # }}}
 156
 157 # {{{ Version stamp
 158 if(BUILD_FROM_GIT)
 159     add_custom_target(version_stamp ALL
 160         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 161                 ${VERSION_STAMP_FILE}
 162                 ${BUILD_DIR}/awesome-version-internal.h
 163         WORKING_DIRECTORY ${SOURCE_DIR})
 164
 165     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 166 endif()
 167 # }}}
 168
 169 # {{{ Manpages
 170 if(GENERATE_MANPAGES)
 171     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 172         file(MAKE_DIRECTORY ${BUILD_DIR}/manpages)
 173     endif()
 174     foreach(txtfile ${AWE_MAN_SRCS})
 175         string(REGEX REPLACE ".txt\$" ".xml" xmlfile ${txtfile})
 176         string(REPLACE ${SOURCE_DIR}
 177                        ${BUILD_DIR} xmlfile ${xmlfile})
 178         string(REGEX REPLACE ".xml\$" ".gz" gzfile ${xmlfile})
 179         string(REGEX REPLACE ".gz\$" "" manfile ${gzfile})
 180
 181         add_custom_command(
 182             COMMAND ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} - < ${txtfile}
 183             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 184             OUTPUT  ${xmlfile}
 185             DEPENDS ${txtfile}
 186             VERBATIM)
 187         add_custom_command(
 188             COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 189             OUTPUT  ${manfile}
 190             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 191             DEPENDS ${xmlfile})
 192         add_custom_command(
 193             COMMAND ${GZIP_EXECUTABLE} < ${manfile} > ${gzfile}
 194             OUTPUT  ${gzfile}
 195             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 196             DEPENDS ${manfile}
 197             VERBATIM)
 198
 199         set(MAN_FILES ${MAN_FILES} ${gzfile})
 200
 201         # figure out in what section to install to from filename
 202         string(REGEX REPLACE "^.*\\.([0-9])\\.gz\$" "\\1" section ${gzfile})
 203         set(AWE_MAN${section}_FILES ${AWE_MAN${section}_FILES} ${gzfile})
 204     endforeach()
 205
 206     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 207 endif()
 208 # }}}
 209
 210 # {{{ Doxygen
 211 if(DOXYGEN_EXECUTABLE)
 212     add_custom_target(doc
 213         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 214         WORKING_DIRECTORY ${BUILD_DIR})
 215 endif()
 216 # }}}
 217
 218 # {{{ Lua API Documentation
 219 if(GENERATE_LUADOC)
 220
 221     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 222         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 223     endif()
 224
 225     set(luadoc_c_srcs "")
 226
 227     # Generate documentation of lib//0lua
 228     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua
 229         ${SOURCE_DIR}/luadoc/*.lua)
 230     foreach(filename ${lua_lib_files})
 231         file(RELATIVE_PATH filename ${BUILD_DIR} ${filename})
 232         set(luadoc_srcs ${luadoc_srcs} ${filename})
 233     endforeach()
 234
 235     add_custom_target(luadoc ALL
 236         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc --nofiles
 237         WORKING_DIRECTORY ${BUILD_DIR}
 238         DEPENDS ${AWE_LUA_FILES})
 239 endif()
 240 # }}}
 241
 242 # {{{ Theme icons
 243 file(GLOB icon_sources ${SOURCE_DIR}/themes/*/titlebar/*.png)
 244 set(ALL_ICONS ${icon_sources})
 245
 246 macro(a_icon_convert match replacement input)
 247     string(REPLACE ${match} ${replacement} output ${input})
 248
 249     if(NOT ${input} STREQUAL ${output})
 250         if(NOT ${output} MATCHES ${BUILD_DIR})
 251             string(REPLACE ${SOURCE_DIR} ${BUILD_DIR} output ${output})
 252         endif()
 253
 254         set(ALL_ICONS ${ALL_ICONS} ${output})
 255
 256         get_filename_component(output_path ${output} PATH)
 257         file(MAKE_DIRECTORY ${output_path})
 258
 259         add_custom_command(
 260             COMMAND ${CONVERT_EXECUTABLE} ${input} ${ARGN} ${output}
 261             OUTPUT  ${output}
 262             DEPENDS ${input}
 263             VERBATIM)
 264     endif()
 265 endmacro()
 266
 267 foreach(icon ${ALL_ICONS})
 268     # Make unfocused icons translucent
 269     a_icon_convert("_focus" "_normal" ${icon}
 270         -gamma 0.6 -channel A -evaluate Multiply 0.4)
 271 endforeach()
 272
 273 foreach(icon ${ALL_ICONS})
 274     # Make inactive icons grayscale
 275     a_icon_convert("_active" "_inactive" ${icon}
 276         -colorspace Gray)
 277 endforeach()
 278
 279 add_custom_target(generated_icons ALL DEPENDS ${ALL_ICONS})
 280 # }}}
 281
 282 # {{{ Dist tarball
 283 if(BUILD_FROM_GIT)
 284     add_custom_target(dist
 285         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 286         WORKING_DIRECTORY ${SOURCE_DIR})
 287 endif()
 288 # }}}
 289
 290 # {{{ Installation
 291 install(TARGETS ${PROJECT_AWE_NAME} RUNTIME DESTINATION bin)
 292 install(FILES "utils/awsetbg" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 293 install(FILES "utils/awesome-client" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 294 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH})
 295 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 296         RENAME ${AWE_CONF_FILE})
 297 if(GENERATE_MANPAGES)
 298     install(FILES ${AWE_MAN1_FILES} DESTINATION ${AWESOME_MAN_PATH}/man1)
 299     install(FILES ${AWE_MAN5_FILES} DESTINATION ${AWESOME_MAN_PATH}/man5)
 300 endif()
 301 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 302 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH})
 303 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 304     PATTERN "*.in" EXCLUDE)
 305 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 306 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 307 if(GENERATE_LUADOC)
 308     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 309 endif()
 310 # }}}
 311
 312 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80