CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${BUILD_DIR}/common
  21     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  23     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  24
  25 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua)
  26
  27 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  28 set(AWE_CONF_FILE rc.lua)
  29
  30 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  31 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  32
  33 set(AWE_DOC_FILES
  34     ${SOURCE_DIR}/AUTHORS
  35     ${SOURCE_DIR}/BUGS
  36     ${SOURCE_DIR}/README
  37     ${SOURCE_DIR}/LICENSE)
  38
  39 set(AWE_SRCS
  40     ${SOURCE_DIR}/awesome.c
  41     ${SOURCE_DIR}/client.c
  42     ${SOURCE_DIR}/dbus.c
  43     ${SOURCE_DIR}/root.c
  44     ${SOURCE_DIR}/event.c
  45     ${SOURCE_DIR}/property.c
  46     ${SOURCE_DIR}/ewmh.c
  47     ${SOURCE_DIR}/key.c
  48     ${SOURCE_DIR}/keygrabber.c
  49     ${SOURCE_DIR}/mousegrabber.c
  50     ${SOURCE_DIR}/layout.c
  51     ${SOURCE_DIR}/luaa.c
  52     ${SOURCE_DIR}/spawn.c
  53     ${SOURCE_DIR}/hooks.c
  54     ${SOURCE_DIR}/mouse.c
  55     ${SOURCE_DIR}/button.c
  56     ${SOURCE_DIR}/screen.c
  57     ${SOURCE_DIR}/stack.c
  58     ${SOURCE_DIR}/selection.c
  59     ${SOURCE_DIR}/wibox.c
  60     ${SOURCE_DIR}/systray.c
  61     ${SOURCE_DIR}/tag.c
  62     ${SOURCE_DIR}/titlebar.c
  63     ${SOURCE_DIR}/widget.c
  64     ${SOURCE_DIR}/window.c
  65     ${SOURCE_DIR}/image.c
  66     ${SOURCE_DIR}/draw.c
  67     ${SOURCE_DIR}/color.c
  68     ${SOURCE_DIR}/swindow.c
  69     ${SOURCE_DIR}/common/buffer.c
  70     ${SOURCE_DIR}/common/atoms.c
  71     ${SOURCE_DIR}/common/util.c
  72     ${SOURCE_DIR}/common/version.c
  73     ${SOURCE_DIR}/common/xembed.c
  74     ${SOURCE_DIR}/common/xutil.c
  75     ${SOURCE_DIR}/common/xcursor.c
  76     ${SOURCE_DIR}/widgets/graph.c
  77     ${SOURCE_DIR}/widgets/progressbar.c
  78     ${SOURCE_DIR}/widgets/textbox.c
  79     ${SOURCE_DIR}/widgets/systray.c
  80     ${SOURCE_DIR}/widgets/imagebox.c)
  81
  82 set(AWE_MAN_SRCS
  83     ${SOURCE_DIR}/manpages/awesome.1.txt
  84     ${SOURCE_DIR}/manpages/awsetbg.1.txt
  85     ${SOURCE_DIR}/manpages/awesome-client.1.txt
  86     ${SOURCE_DIR}/manpages/awesomerc.5.txt)
  87
  88 add_executable(${PROJECT_AWE_NAME}
  89     ${AWE_SRCS}
  90     ${BUILD_DIR}/common/tokenize.c)
  91
  92 set_target_properties(${PROJECT_AWE_NAME}
  93     PROPERTIES
  94     LINK_FLAGS -export-dynamic)
  95
  96 target_link_libraries(${PROJECT_AWE_NAME}
  97     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
  98     ${AWESOME_REQUIRED_LIBRARIES}
  99     ${AWESOME_OPTIONAL_LIBRARIES})
 100
 101 # {{{ Generated sources
 102 add_custom_command(
 103     COMMAND ${SOURCE_DIR}/build-utils/widgetgen.sh
 104     ARGS    > ${BUILD_DIR}/widgetgen.h
 105     OUTPUT  ${BUILD_DIR}/widgetgen.h
 106     WORKING_DIRECTORY ${SOURCE_DIR}
 107     DEPENDS ${SOURCE_DIR}/widget.h
 108     COMMENT "Generating widgetgen.h"
 109     VERBATIM)
 110
 111 # atoms
 112 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 113 add_custom_command(
 114     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 115     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 116     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 117     WORKING_DIRECTORY ${SOURCE_DIR}
 118     DEPENDS ${SOURCE_DIR}/common/atoms.list
 119     COMMENT "Generating atoms-extern.h"
 120     VERBATIM)
 121
 122 add_custom_command(
 123     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 124     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 125     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 126     WORKING_DIRECTORY ${SOURCE_DIR}
 127     DEPENDS ${SOURCE_DIR}/common/atoms.list
 128     COMMENT "Generating atoms-intern.h"
 129     VERBATIM)
 130
 131 # gperf
 132 add_custom_command(
 133     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 134     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 135             ${BUILD_DIR}/common/tokenize.h
 136     OUTPUT  ${BUILD_DIR}/common/tokenize.h
 137     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 138             ${SOURCE_DIR}/build-utils/gperf.sh
 139     COMMENT "Generating common/tokenize.h")
 140
 141 add_custom_command(
 142     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 143     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 144             ${BUILD_DIR}/common/tokenize.c
 145     OUTPUT  ${BUILD_DIR}/common/tokenize.c
 146     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 147             ${SOURCE_DIR}/build-utils/gperf.sh
 148     COMMENT "Generating common/tokenize.c")
 149
 150 add_custom_target(generated_sources
 151     DEPENDS ${BUILD_DIR}/widgetgen.h
 152             ${BUILD_DIR}/common/atoms-intern.h
 153             ${BUILD_DIR}/common/atoms-extern.h
 154             ${BUILD_DIR}/common/tokenize.c
 155             ${BUILD_DIR}/common/tokenize.h)
 156
 157 # Default theme directory
 158 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 159 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/sky)
 160 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 161 # }}}
 162
 163 # {{{ Version stamp
 164 if(BUILD_FROM_GIT)
 165     add_custom_target(version_stamp ALL
 166         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 167                 ${VERSION_STAMP_FILE}
 168                 ${BUILD_DIR}/awesome-version-internal.h
 169         WORKING_DIRECTORY ${SOURCE_DIR})
 170
 171     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 172 endif()
 173 # }}}
 174
 175 # {{{ Manpages
 176 if(GENERATE_MANPAGES)
 177     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 178         file(MAKE_DIRECTORY ${BUILD_DIR}/manpages)
 179     endif()
 180     foreach(txtfile ${AWE_MAN_SRCS})
 181         string(REGEX REPLACE ".txt\$" ".xml" xmlfile ${txtfile})
 182         string(REPLACE ${SOURCE_DIR}
 183                        ${BUILD_DIR} xmlfile ${xmlfile})
 184         string(REGEX REPLACE ".xml\$" ".gz" gzfile ${xmlfile})
 185         string(REGEX REPLACE ".gz\$" "" manfile ${gzfile})
 186
 187         add_custom_command(
 188             COMMAND ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} - < ${txtfile}
 189             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 190             OUTPUT  ${xmlfile}
 191             DEPENDS ${txtfile}
 192             VERBATIM)
 193         add_custom_command(
 194             COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 195             OUTPUT  ${manfile}
 196             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 197             DEPENDS ${xmlfile})
 198         add_custom_command(
 199             COMMAND ${GZIP_EXECUTABLE} < ${manfile} > ${gzfile}
 200             OUTPUT  ${gzfile}
 201             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 202             DEPENDS ${manfile}
 203             VERBATIM)
 204
 205         set(MAN_FILES ${MAN_FILES} ${gzfile})
 206
 207         # figure out in what section to install to from filename
 208         string(REGEX REPLACE "^.*\\.([0-9])\\.gz\$" "\\1" section ${gzfile})
 209         set(AWE_MAN${section}_FILES ${AWE_MAN${section}_FILES} ${gzfile})
 210     endforeach()
 211
 212     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 213 endif()
 214 # }}}
 215
 216 # {{{ Doxygen
 217 if(DOXYGEN_EXECUTABLE)
 218     add_custom_target(doc
 219         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 220         WORKING_DIRECTORY ${BUILD_DIR})
 221 endif()
 222 # }}}
 223
 224 # {{{ Lua API Documentation
 225 if(GENERATE_LUADOC)
 226
 227     set(capi_lua ${BUILD_DIR}/lib/capi.lua)
 228
 229     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 230         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 231     endif()
 232
 233     # {{{ setup a command for ${capi_lua}
 234     macro(a_file_match infile regex result_var)
 235         file(STRINGS ${infile} match REGEX ${regex} LIMIT_COUNT 1)
 236         if(match)
 237             set(${result_var} TRUE)
 238         else()
 239             set(${result_var} FALSE)
 240         endif()
 241     endmacro()
 242
 243     set(luadoc_c_srcs "")
 244
 245     # find .c files exporting lua functions
 246     foreach(cfile ${AWE_SRCS})
 247         a_file_match(${cfile} "const struct luaL_reg" result)
 248         if(result)
 249             set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 250         else()
 251             a_file_match(${cfile} "luaA_.*_index" result)
 252             if(result)
 253                 set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 254         endif()
 255         endif()
 256     endforeach()
 257
 258     # create fake lua source file to process by luadoc
 259     add_custom_command(
 260         COMMAND ${CAT_EXECUTABLE} ${luadoc_c_srcs}
 261                 | ${LUA_EXECUTABLE} ${SOURCE_DIR}/build-utils/fake-lua-src.lua
 262                 > ${capi_lua}
 263         OUTPUT  ${capi_lua}
 264         DEPENDS ${luadoc_c_srcs}
 265         COMMENT "Generating fake lua source."
 266         VERBATIM)
 267     # }}}
 268
 269     # Generate documentation of lib//0lua
 270     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua)
 271     foreach(filename ${lua_lib_files})
 272         file(RELATIVE_PATH filename ${BUILD_DIR}/lib ${filename})
 273         set(luadoc_srcs ${luadoc_srcs} ${filename})
 274     endforeach()
 275
 276     add_custom_target(luadoc ALL
 277         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc
 278         WORKING_DIRECTORY ${BUILD_DIR}/lib
 279         DEPENDS ${AWE_LUA_FILES} ${capi_lua})
 280 endif()
 281 # }}}
 282
 283 # {{{ Theme icons
 284 file(GLOB icon_sources ${SOURCE_DIR}/themes/*/titlebar/*.png)
 285 set(ALL_ICONS ${icon_sources})
 286
 287 macro(a_icon_convert match replacement input)
 288     string(REPLACE ${match} ${replacement} output ${input})
 289
 290     if(NOT ${input} STREQUAL ${output})
 291         if(NOT ${output} MATCHES ${BUILD_DIR})
 292             string(REPLACE ${SOURCE_DIR} ${BUILD_DIR} output ${output})
 293         endif()
 294
 295         set(ALL_ICONS ${ALL_ICONS} ${output})
 296
 297         get_filename_component(output_path ${output} PATH)
 298         file(MAKE_DIRECTORY ${output_path})
 299
 300         add_custom_command(
 301             COMMAND ${CONVERT_EXECUTABLE} ${input} ${ARGN} ${output}
 302             OUTPUT  ${output}
 303             DEPENDS ${input}
 304             VERBATIM)
 305     endif()
 306 endmacro()
 307
 308 foreach(icon ${ALL_ICONS})
 309     # Make unfocused icons translucent
 310     a_icon_convert("_focus" "_normal" ${icon}
 311         -gamma 0.6 -channel A -evaluate Multiply 0.4)
 312 endforeach()
 313
 314 foreach(icon ${ALL_ICONS})
 315     # Make inactive icons grayscale
 316     a_icon_convert("_active" "_inactive" ${icon}
 317         -colorspace Gray)
 318 endforeach()
 319
 320 add_custom_target(generated_icons ALL DEPENDS ${ALL_ICONS})
 321 # }}}
 322
 323 # {{{ Dist tarball
 324 if(BUILD_FROM_GIT)
 325     add_custom_target(dist
 326         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 327         WORKING_DIRECTORY ${SOURCE_DIR})
 328 endif()
 329 # }}}
 330
 331 # {{{ Installation
 332 install(TARGETS ${PROJECT_AWE_NAME} RUNTIME DESTINATION bin)
 333 install(FILES "utils/awsetbg" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 334 install(FILES "utils/awesome-client" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 335 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH})
 336 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 337         RENAME ${AWE_CONF_FILE})
 338 if(GENERATE_MANPAGES)
 339     install(FILES ${AWE_MAN1_FILES} DESTINATION ${AWESOME_MAN_PATH}/man1)
 340     install(FILES ${AWE_MAN5_FILES} DESTINATION ${AWESOME_MAN_PATH}/man5)
 341 endif()
 342 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 343 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH})
 344 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 345     PATTERN "*.in" EXCLUDE)
 346 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 347 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 348 if(GENERATE_LUADOC)
 349     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 350 endif()
 351 # }}}
 352
 353 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80