CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  21     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  23
  24 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua ${BUILD_DIR}/luadoc/*.lua)
  25
  26 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  27 set(AWE_CONF_FILE rc.lua)
  28
  29 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  30 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  31
  32 set(AWE_DOC_FILES
  33     ${SOURCE_DIR}/AUTHORS
  34     ${SOURCE_DIR}/BUGS
  35     ${SOURCE_DIR}/README
  36     ${SOURCE_DIR}/LICENSE)
  37
  38 set(AWE_SRCS
  39     ${SOURCE_DIR}/awesome.c
  40     ${SOURCE_DIR}/banning.c
  41     ${SOURCE_DIR}/color.c
  42     ${SOURCE_DIR}/dbus.c
  43     ${SOURCE_DIR}/draw.c
  44     ${SOURCE_DIR}/event.c
  45     ${SOURCE_DIR}/ewmh.c
  46     ${SOURCE_DIR}/keygrabber.c
  47     ${SOURCE_DIR}/keyresolv.c
  48     ${SOURCE_DIR}/luaa.c
  49     ${SOURCE_DIR}/mouse.c
  50     ${SOURCE_DIR}/mousegrabber.c
  51     ${SOURCE_DIR}/property.c
  52     ${SOURCE_DIR}/root.c
  53     ${SOURCE_DIR}/screen.c
  54     ${SOURCE_DIR}/selection.c
  55     ${SOURCE_DIR}/spawn.c
  56     ${SOURCE_DIR}/stack.c
  57     ${SOURCE_DIR}/strut.c
  58     ${SOURCE_DIR}/systray.c
  59     ${SOURCE_DIR}/xwindow.c
  60     ${SOURCE_DIR}/common/atoms.c
  61     ${SOURCE_DIR}/common/backtrace.c
  62     ${SOURCE_DIR}/common/buffer.c
  63     ${SOURCE_DIR}/common/luaclass.c
  64     ${SOURCE_DIR}/common/lualib.c
  65     ${SOURCE_DIR}/common/luaobject.c
  66     ${SOURCE_DIR}/common/util.c
  67     ${SOURCE_DIR}/common/version.c
  68     ${SOURCE_DIR}/common/xcursor.c
  69     ${SOURCE_DIR}/common/xembed.c
  70     ${SOURCE_DIR}/common/xutil.c
  71     ${SOURCE_DIR}/objects/button.c
  72     ${SOURCE_DIR}/objects/client.c
  73     ${SOURCE_DIR}/objects/drawable.c
  74     ${SOURCE_DIR}/objects/drawin.c
  75     ${SOURCE_DIR}/objects/key.c
  76     ${SOURCE_DIR}/objects/tag.c
  77     ${SOURCE_DIR}/objects/timer.c
  78     ${SOURCE_DIR}/objects/window.c)
  79
  80 set(AWE_MAN_SRCS
  81     ${SOURCE_DIR}/manpages/awesome.1.txt
  82     ${SOURCE_DIR}/manpages/awesome-client.1.txt
  83     ${SOURCE_DIR}/manpages/awesomerc.5.txt)
  84 set(AWE_MAN_LANGS it es fr de ru)
  85
  86 # Don't strip RPATH if compiling on Solaris
  87 if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  88     set(CMAKE_SKIP_BUILD_RPATH FALSE)
  89     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  90     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  91 endif()
  92
  93 add_executable(${PROJECT_AWE_NAME}
  94     ${AWE_SRCS})
  95
  96 # FreeBSD requires dynamic linking
  97 if(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
  98     set_target_properties(${PROJECT_AWE_NAME}
  99         PROPERTIES
 100         LINK_FLAGS -export-dynamic)
 101 endif()
 102
 103 target_link_libraries(${PROJECT_AWE_NAME}
 104     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 105     ${AWESOME_REQUIRED_LDFLAGS}
 106     ${AWESOME_OPTIONAL_LDFLAGS})
 107
 108 # atoms
 109 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 110 add_custom_command(
 111     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 112     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 113     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 114     WORKING_DIRECTORY ${SOURCE_DIR}
 115     DEPENDS ${SOURCE_DIR}/common/atoms.list
 116     COMMENT "Generating atoms-extern.h"
 117     VERBATIM)
 118
 119 add_custom_command(
 120     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 121     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 122     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 123     WORKING_DIRECTORY ${SOURCE_DIR}
 124     DEPENDS ${SOURCE_DIR}/common/atoms.list
 125     COMMENT "Generating atoms-intern.h"
 126     VERBATIM)
 127
 128 add_custom_target(generated_sources
 129     DEPENDS ${BUILD_DIR}/common/atoms-intern.h
 130             ${BUILD_DIR}/common/atoms-extern.h)
 131
 132 # Default theme directory
 133 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 134 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/sky)
 135 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/zenburn)
 136 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 137 # }}}
 138
 139 # {{{ Version stamp
 140 if(BUILD_FROM_GIT)
 141     add_custom_target(version_stamp ALL
 142         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 143                 ${VERSION_STAMP_FILE}
 144                 ${BUILD_DIR}/awesome-version-internal.h
 145         WORKING_DIRECTORY ${SOURCE_DIR})
 146
 147     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 148 endif()
 149 # }}}
 150
 151 # {{{ Manpages
 152 if(GENERATE_MANPAGES)
 153     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 154         file(MAKE_DIRECTORY ${BUILD_DIR}/manpages)
 155     endif()
 156
 157     # add the default translation to the list of languages
 158     set(AWE_MAN_LANGS default ${AWE_MAN_LANGS})
 159
 160     foreach(lang ${AWE_MAN_LANGS})
 161
 162         foreach(txtfile ${AWE_MAN_SRCS})
 163             # figure the base name of the file (ie "awesome.1")
 164             GET_FILENAME_COMPONENT(tmpname ${txtfile} NAME)
 165             string(REGEX REPLACE ".txt\$" "" basename ${tmpname})
 166
 167             # figure the relative path of the file
 168             GET_FILENAME_COMPONENT(tmppath ${txtfile} PATH)
 169             string(REPLACE ${SOURCE_DIR}/ "" relpath ${tmppath})
 170
 171             # figure the manpage section to install to from filename
 172             string(REGEX REPLACE "^.*\\.([0-9])$" "\\1" section ${basename})
 173
 174             # construct the language specific versions of the basename and path
 175             if (lang STREQUAL default)
 176                 set(basename2 ${basename})
 177                 set(relpath2 ${relpath}/man${section})
 178             else()
 179                 set(basename2 ${basename}.${lang})
 180                 set(relpath2 ${relpath}/${lang}/man${section})
 181             endif()
 182
 183             # create the build directory (if it does not exist)
 184             file(MAKE_DIRECTORY ${BUILD_DIR}/${relpath2})
 185
 186             # set the final filenames
 187             set(txtfile ${SOURCE_DIR}/${relpath}/${basename2}.txt)
 188             set(xmlfile ${BUILD_DIR}/${relpath2}/${basename}.xml)
 189             set(gzfile  ${BUILD_DIR}/${relpath2}/${basename}.gz)
 190             set(manfile ${BUILD_DIR}/${relpath2}/${basename})
 191
 192             add_custom_command(
 193                 COMMAND ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} - < ${txtfile}
 194                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 195                 OUTPUT  ${xmlfile}
 196                 DEPENDS ${txtfile}
 197                 VERBATIM)
 198             add_custom_command(
 199                 COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 200                 OUTPUT  ${manfile}
 201                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 202                 DEPENDS ${xmlfile})
 203
 204             if(COMPRESS_MANPAGES)
 205                 add_custom_command(
 206                     COMMAND ${GZIP_EXECUTABLE} < ${manfile} > ${gzfile}
 207                     OUTPUT  ${gzfile}
 208                     WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 209                     DEPENDS ${manfile}
 210                     VERBATIM)
 211
 212                 set(MAN_FILES ${MAN_FILES} ${gzfile})
 213             else()
 214                 set(MAN_FILES ${MAN_FILES} ${manfile})
 215             endif()
 216         endforeach()
 217
 218     endforeach()
 219
 220     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 221 endif()
 222 # }}}
 223
 224 # {{{ Doxygen
 225 if(DOXYGEN_EXECUTABLE)
 226     add_custom_target(doc
 227         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 228         WORKING_DIRECTORY ${BUILD_DIR})
 229 endif()
 230 # }}}
 231
 232 # {{{ Lua API Documentation
 233 if(GENERATE_LUADOC)
 234
 235     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 236         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 237     endif()
 238
 239     set(luadoc_c_srcs "")
 240
 241     # Generate documentation of lib//0lua
 242     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua
 243         ${SOURCE_DIR}/luadoc/*.lua)
 244     foreach(filename ${lua_lib_files})
 245         file(RELATIVE_PATH filename ${BUILD_DIR} ${filename})
 246         set(luadoc_srcs ${luadoc_srcs} ${filename})
 247     endforeach()
 248
 249     add_custom_target(luadoc ALL
 250         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc --nofiles
 251         WORKING_DIRECTORY ${BUILD_DIR}
 252         DEPENDS ${AWE_LUA_FILES})
 253 endif()
 254 # }}}
 255
 256 # {{{ Theme icons
 257 file(GLOB icon_sources RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/themes/*/titlebar/*.png)
 258
 259 foreach(icon ${icon_sources})
 260     # Copy all icons to the build dir to simplify the following code.
 261     # Source paths are interpreted relative to ${SOURCE_DIR}, target paths
 262     # relative to ${BUILD_DIR}.
 263     get_filename_component(icon_path ${icon} PATH)
 264     get_filename_component(icon_name ${icon} NAME)
 265     file(COPY ${icon} DESTINATION ${icon_path})
 266     set(ALL_ICONS ${ALL_ICONS} "${icon_path}/${icon_name}")
 267 endforeach()
 268
 269 macro(a_icon_convert match replacement input)
 270     string(REPLACE ${match} ${replacement} output ${input})
 271
 272     if(NOT ${input} STREQUAL ${output})
 273         set(ALL_ICONS ${ALL_ICONS} ${output})
 274
 275         add_custom_command(
 276             COMMAND ${CONVERT_EXECUTABLE} ${input} ${ARGN} ${output}
 277             OUTPUT  ${output}
 278             DEPENDS ${input}
 279             VERBATIM)
 280     endif()
 281 endmacro()
 282
 283 foreach(icon ${ALL_ICONS})
 284     # Make unfocused icons translucent
 285     a_icon_convert("_focus" "_normal" ${icon}
 286         -gamma 0.6 -channel A -evaluate Multiply 0.4)
 287 endforeach()
 288
 289 foreach(icon ${ALL_ICONS})
 290     # Make inactive icons grayscale
 291     a_icon_convert("_active" "_inactive" ${icon}
 292         -colorspace Gray)
 293 endforeach()
 294
 295 add_custom_target(generated_icons ALL DEPENDS ${ALL_ICONS})
 296 # }}}
 297
 298 # {{{ Dist tarball
 299 if(BUILD_FROM_GIT)
 300     add_custom_target(dist
 301         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 302         WORKING_DIRECTORY ${SOURCE_DIR})
 303 endif()
 304 # }}}
 305
 306 # {{{ Installation
 307 install(TARGETS ${PROJECT_AWE_NAME} RUNTIME DESTINATION bin)
 308 install(FILES "utils/awesome-client" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 309 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH}
 310     PATTERN "*.in" EXCLUDE)
 311 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 312         RENAME ${AWE_CONF_FILE})
 313 if(GENERATE_MANPAGES)
 314     if(COMPRESS_MANPAGES)
 315         set(regex "\\.(xml|txt|[0-9])$")
 316     else()
 317         set(regex "\\.(xml|txt|gz)$")
 318     endif()
 319     install(DIRECTORY ${BUILD_DIR}/${relpath}/ DESTINATION ${AWESOME_MAN_PATH}
 320             REGEX ${regex} EXCLUDE )
 321 endif()
 322 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 323 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 324     PATTERN "*.in" EXCLUDE)
 325 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 326     PATTERN "*.in" EXCLUDE)
 327 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 328 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 329 if(GENERATE_LUADOC)
 330     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 331 endif()
 332 # }}}
 333
 334 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80