awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2
   3 # If ${SOURCE_DIR} is a git repository VERSION is set to
   4 # `git describe` later.
   5 set(VERSION devel)
   6
   7 set(CODENAME "Closing In")
   8
   9 project(${PROJECT_AWE_NAME} C)
  10
  11 set(CMAKE_BUILD_TYPE RELEASE)
  12
  13 option(WITH_DBUS "build with D-BUS" ON)
  14 option(GENERATE_MANPAGES "generate manpages" ON)
  15 option(COMPRESS_MANPAGES "compress manpages" ON)
  16 option(GENERATE_LUADOC "generate luadoc" ON)
  17
  18 # {{{ CFLAGS
  19 add_definitions(-std=gnu99 -ggdb3 -rdynamic -fno-strict-aliasing -Wall -Wextra
  20     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  21     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  22     -Wpointer-arith -Wredundant-decls -Wformat-nonliteral
  23     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  24     -Wstrict-prototypes)
  25 # }}}
  26
  27 # {{{ Endianness
  28 include(TestBigEndian)
  29 TEST_BIG_ENDIAN(AWESOME_IS_BIG_ENDIAN)
  30 # }}}
  31
  32 # {{{ Find external utilities
  33 macro(a_find_program var prg req)
  34     set(required ${req})
  35     find_program(${var} ${prg})
  36     if(NOT ${var})
  37         message(STATUS "${prg} not found.")
  38         if(required)
  39             message(FATAL_ERROR "${prg} is required to build awesome")
  40         endif()
  41     else()
  42         message(STATUS "${prg} -> ${${var}}")
  43     endif()
  44 endmacro()
  45
  46 a_find_program(CAT_EXECUTABLE cat TRUE)
  47 a_find_program(LN_EXECUTABLE ln TRUE)
  48 a_find_program(GREP_EXECUTABLE grep TRUE)
  49 a_find_program(GIT_EXECUTABLE git FALSE)
  50 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  51 # programs needed for man pages
  52 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  53 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  54 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  55 # lua documentation
  56 a_find_program(LUA_EXECUTABLE lua FALSE)
  57 a_find_program(LUADOC_EXECUTABLE luadoc FALSE)
  58 # theme graphics
  59 a_find_program(CONVERT_EXECUTABLE convert TRUE)
  60 # doxygen
  61 include(FindDoxygen)
  62 # pkg-config
  63 include(FindPkgConfig)
  64 # lua 5.1
  65 include(FindLua51) #Due to a cmake bug, you will see Lua50 on screen
  66 # }}}
  67
  68 # {{{ Check if documentation can be build
  69 if(GENERATE_MANPAGES)
  70     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR (COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE))
  71         if(NOT ASCIIDOC_EXECUTABLE)
  72             SET(missing "asciidoc")
  73         endif()
  74         if(NOT XMLTO_EXECUTABLE)
  75             SET(missing ${missing} " xmlto")
  76         endif()
  77         if(COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE)
  78             SET(missing ${missing} " gzip")
  79         endif()
  80
  81         message(STATUS "Not generating manpages. Missing: " ${missing})
  82         set(GENERATE_MANPAGES OFF)
  83     endif()
  84 endif()
  85
  86 if(GENERATE_LUADOC)
  87     if(NOT LUADOC_EXECUTABLE)
  88         message(STATUS "Not generating luadoc. Missing: luadoc")
  89         set(GENERATE_LUADOC OFF)
  90     endif()
  91 endif()
  92 # }}}
  93
  94 # {{{ Version stamp
  95 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
  96     # get current version
  97     execute_process(
  98         COMMAND ${GIT_EXECUTABLE} describe
  99         WORKING_DIRECTORY ${SOURCE_DIR}
 100         OUTPUT_VARIABLE VERSION
 101         OUTPUT_STRIP_TRAILING_WHITESPACE)
 102     # file the git-version-stamp.sh script will look into
 103     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 104     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 105     # create a version_stamp target later
 106     set(BUILD_FROM_GIT TRUE)
 107 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 108     # get version from version stamp
 109     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 110 endif()
 111 # }}}
 112
 113 # {{{ Get hostname
 114 execute_process(
 115     COMMAND ${HOSTNAME_EXECUTABLE}
 116     WORKING_DIRECTORY ${SOURCE_DIR}
 117     OUTPUT_VARIABLE BUILDHOSTNAME
 118     OUTPUT_STRIP_TRAILING_WHITESPACE)
 119 # }}}
 120
 121 # {{{ Required libraries
 122 #
 123 # this sets up:
 124 # AWESOME_REQUIRED_LDFLAGS
 125 # AWESOME_REQUIRED_INCLUDE_DIRS
 126
 127 # Use pkgconfig to get most of the libraries
 128 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 129     xcb>=1.6)
 130
 131 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 132     glib-2.0
 133     cairo
 134     x11
 135     oocairo
 136     oopango
 137     xcb-randr
 138     xcb-xtest
 139     xcb-xinerama
 140     xcb-util>=0.3.8
 141     xcb-keysyms>=0.3.4
 142     xcb-icccm>=0.3.8
 143     xcb-image>=0.3.0
 144     cairo-xcb
 145     libstartup-notification-1.0>=0.10
 146     xproto>=7.0.15
 147     libxdg-basedir>=1.0.0)
 148
 149 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 150     message(FATAL_ERROR)
 151 endif()
 152
 153 macro(a_find_library variable library)
 154     find_library(${variable} ${library})
 155     if(NOT ${variable})
 156         message(FATAL_ERROR ${library} " library not found.")
 157     endif()
 158 endmacro()
 159
 160 # Check for libev
 161 a_find_library(LIB_EV ev)
 162
 163 # Check for backtrace_symbols()
 164 include(CheckFunctionExists)
 165 check_function_exists(backtrace_symbols HAS_EXECINFO)
 166 if(NOT HAS_EXECINFO)
 167     find_library(LIB_EXECINFO execinfo)
 168     if(LIB_EXECINFO)
 169         set(HAS_EXECINFO 1)
 170         set(AWESOME_REQUIRED_LDFLAGS
 171             ${AWESOME_REQUIRED_LDFLAGS}
 172             ${LIB_EXECINFO})
 173     endif()
 174 endif()
 175 if(HAS_EXECINFO)
 176     message(STATUS "checking for execinfo -- found")
 177 else()
 178     message(STATUS "checking for execinfo -- not found")
 179 endif()
 180
 181 # __builtin_clz is available since gcc 3.4
 182 try_compile(HAS___BUILTIN_CLZ
 183     ${CMAKE_BINARY_DIR}
 184     ${CMAKE_SOURCE_DIR}/build-tests/__builtin_clz.c)
 185 if(HAS___BUILTIN_CLZ)
 186     message(STATUS "checking for __builtin_clz -- yes")
 187 else()
 188     message(STATUS "checking for __builtin_clz -- no")
 189 endif()
 190
 191 # Error check
 192 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 193     message(FATAL_ERROR "lua library not found")
 194 endif()
 195
 196 set(AWESOME_REQUIRED_LDFLAGS
 197     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 198     ${AWESOME_REQUIRED_LDFLAGS}
 199     ${LIB_EV}
 200     ${LUA_LIBRARIES})
 201
 202 set(AWESOME_REQUIRED_INCLUDE_DIRS
 203     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 204     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 205     ${LUA_INCLUDE_DIR})
 206 # }}}
 207
 208 # {{{ Optional libraries
 209 #
 210 # this sets up:
 211 # AWESOME_OPTIONAL_LDFLAGS
 212 # AWESOME_OPTIONAL_INCLUDE_DIRS
 213
 214 if(WITH_DBUS)
 215     pkg_check_modules(DBUS dbus-1)
 216     if(DBUS_FOUND)
 217         set(AWESOME_OPTIONAL_LDFLAGS ${AWESOME_OPTIONAL_LDFLAGS} ${DBUS_LDFLAGS})
 218         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 219     else()
 220         set(WITH_DBUS OFF)
 221         message(STATUS "DBUS not found. Disabled.")
 222     endif()
 223 endif()
 224 # }}}
 225
 226 # {{{ Install path and configuration variables
 227 if(DEFINED PREFIX)
 228     set(PREFIX ${PREFIX} CACHE PATH "install prefix")
 229     set(CMAKE_INSTALL_PREFIX ${PREFIX})
 230 else()
 231     set(PREFIX ${CMAKE_INSTALL_PREFIX} CACHE PATH "install prefix")
 232 endif()
 233
 234 #If a sysconfdir is specified, use it instead
 235 #of the default configuration dir.
 236 if(DEFINED SYSCONFDIR)
 237     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 238 else()
 239     set(SYSCONFDIR ${PREFIX}/etc CACHE PATH "config directory")
 240 endif()
 241
 242 #If an XDG Config Dir is specificed, use it instead
 243 #of the default XDG configuration dir.
 244 if(DEFINED XDG_CONFIG_DIR)
 245     set(XDG_CONFIG_DIR ${XDG_CONFIG_DIR} CACHE PATH "xdg config directory")
 246 else()
 247     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 248 endif()
 249
 250 # setting AWESOME_DOC_PATH
 251 if(DEFINED AWESOME_DOC_PATH)
 252     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 253 else()
 254     set(AWESOME_DOC_PATH ${PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 255 endif()
 256
 257 # setting AWESOME_XSESSION_PATH
 258 if(DEFINED AWESOME_XSESSION_PATH)
 259     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 260 else()
 261     set(AWESOME_XSESSION_PATH ${PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 262 endif()
 263
 264 # set man path
 265 if(DEFINED AWESOME_MAN_PATH)
 266    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 267 else()
 268    set(AWESOME_MAN_PATH ${PREFIX}/share/man CACHE PATH "awesome manpage directory")
 269 endif()
 270
 271 # Hide to avoid confusion
 272 mark_as_advanced(CMAKE_INSTALL_PREFIX)
 273
 274 set(AWESOME_VERSION          ${VERSION})
 275 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 276 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 277 set(AWESOME_COMPILE_BY       $ENV{USER})
 278 set(AWESOME_RELEASE          ${CODENAME})
 279 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 280 set(AWESOME_DATA_PATH        ${PREFIX}/share/${PROJECT_AWE_NAME})
 281 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 282 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 283 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 284 # }}}
 285
 286 # {{{ Configure files
 287 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in ${SOURCE_DIR}/themes/*/*.lua.in)
 288 set(AWESOME_CONFIGURE_FILES
 289     ${awesome_lua_configure_files}
 290     config.h.in
 291     awesomerc.lua.in
 292     awesome-version-internal.h.in
 293     awesome.doxygen.in)
 294
 295 macro(a_configure_file file)
 296     string(REGEX REPLACE ".in\$" "" outfile ${file})
 297     message(STATUS "Configuring ${outfile}")
 298     configure_file(${SOURCE_DIR}/${file}
 299                    ${BUILD_DIR}/${outfile}
 300                    ESCAPE_QUOTE
 301                    @ONLY)
 302 endmacro()
 303
 304 foreach(file ${AWESOME_CONFIGURE_FILES})
 305     a_configure_file(${file})
 306 endforeach()
 307 #}}}
 308
 309 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80