CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  21     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  23
  24 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua ${BUILD_DIR}/luadoc/*.lua)
  25
  26 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  27 set(AWE_CONF_FILE rc.lua)
  28
  29 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  30 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  31
  32 set(AWE_DOC_FILES
  33     ${SOURCE_DIR}/AUTHORS
  34     ${SOURCE_DIR}/BUGS
  35     ${SOURCE_DIR}/README
  36     ${SOURCE_DIR}/LICENSE)
  37
  38 set(AWE_SRCS
  39     ${SOURCE_DIR}/awesome.c
  40     ${SOURCE_DIR}/banning.c
  41     ${SOURCE_DIR}/color.c
  42     ${SOURCE_DIR}/dbus.c
  43     ${SOURCE_DIR}/draw.c
  44     ${SOURCE_DIR}/event.c
  45     ${SOURCE_DIR}/ewmh.c
  46     ${SOURCE_DIR}/keygrabber.c
  47     ${SOURCE_DIR}/keyresolv.c
  48     ${SOURCE_DIR}/luaa.c
  49     ${SOURCE_DIR}/mouse.c
  50     ${SOURCE_DIR}/mousegrabber.c
  51     ${SOURCE_DIR}/property.c
  52     ${SOURCE_DIR}/root.c
  53     ${SOURCE_DIR}/screen.c
  54     ${SOURCE_DIR}/selection.c
  55     ${SOURCE_DIR}/spawn.c
  56     ${SOURCE_DIR}/stack.c
  57     ${SOURCE_DIR}/strut.c
  58     ${SOURCE_DIR}/systray.c
  59     ${SOURCE_DIR}/xwindow.c
  60     ${SOURCE_DIR}/common/atoms.c
  61     ${SOURCE_DIR}/common/backtrace.c
  62     ${SOURCE_DIR}/common/buffer.c
  63     ${SOURCE_DIR}/common/luaclass.c
  64     ${SOURCE_DIR}/common/lualib.c
  65     ${SOURCE_DIR}/common/luaobject.c
  66     ${SOURCE_DIR}/common/util.c
  67     ${SOURCE_DIR}/common/version.c
  68     ${SOURCE_DIR}/common/xcursor.c
  69     ${SOURCE_DIR}/common/xembed.c
  70     ${SOURCE_DIR}/common/xutil.c
  71     ${SOURCE_DIR}/objects/button.c
  72     ${SOURCE_DIR}/objects/client.c
  73     ${SOURCE_DIR}/objects/drawin.c
  74     ${SOURCE_DIR}/objects/key.c
  75     ${SOURCE_DIR}/objects/tag.c
  76     ${SOURCE_DIR}/objects/timer.c
  77     ${SOURCE_DIR}/objects/window.c)
  78
  79 set(AWE_MAN_SRCS
  80     ${SOURCE_DIR}/manpages/awesome.1.txt
  81     ${SOURCE_DIR}/manpages/awsetbg.1.txt
  82     ${SOURCE_DIR}/manpages/awesome-client.1.txt
  83     ${SOURCE_DIR}/manpages/awesomerc.5.txt)
  84 set(AWE_MAN_LANGS it es fr de ru)
  85
  86 add_executable(${PROJECT_AWE_NAME}
  87     ${AWE_SRCS})
  88
  89 set_target_properties(${PROJECT_AWE_NAME}
  90     PROPERTIES
  91     LINK_FLAGS -export-dynamic)
  92
  93 target_link_libraries(${PROJECT_AWE_NAME}
  94     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
  95     ${AWESOME_REQUIRED_LDFLAGS}
  96     ${AWESOME_OPTIONAL_LDFLAGS})
  97
  98 # atoms
  99 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 100 add_custom_command(
 101     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 102     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 103     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 104     WORKING_DIRECTORY ${SOURCE_DIR}
 105     DEPENDS ${SOURCE_DIR}/common/atoms.list
 106     COMMENT "Generating atoms-extern.h"
 107     VERBATIM)
 108
 109 add_custom_command(
 110     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 111     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 112     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 113     WORKING_DIRECTORY ${SOURCE_DIR}
 114     DEPENDS ${SOURCE_DIR}/common/atoms.list
 115     COMMENT "Generating atoms-intern.h"
 116     VERBATIM)
 117
 118 add_custom_target(generated_sources
 119     DEPENDS ${BUILD_DIR}/common/atoms-intern.h
 120             ${BUILD_DIR}/common/atoms-extern.h)
 121
 122 # Default theme directory
 123 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 124 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/sky)
 125 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/zenburn)
 126 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 127 # }}}
 128
 129 # {{{ Version stamp
 130 if(BUILD_FROM_GIT)
 131     add_custom_target(version_stamp ALL
 132         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 133                 ${VERSION_STAMP_FILE}
 134                 ${BUILD_DIR}/awesome-version-internal.h
 135         WORKING_DIRECTORY ${SOURCE_DIR})
 136
 137     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 138 endif()
 139 # }}}
 140
 141 # {{{ Manpages
 142 if(GENERATE_MANPAGES)
 143     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 144         file(MAKE_DIRECTORY ${BUILD_DIR}/manpages)
 145     endif()
 146
 147     # add the default translation to the list of languages
 148     set(AWE_MAN_LANGS default ${AWE_MAN_LANGS})
 149
 150     foreach(lang ${AWE_MAN_LANGS})
 151
 152         foreach(txtfile ${AWE_MAN_SRCS})
 153             # figure the base name of the file (ie "awesome.1")
 154             GET_FILENAME_COMPONENT(tmpname ${txtfile} NAME)
 155             string(REGEX REPLACE ".txt\$" "" basename ${tmpname})
 156
 157             # figure the relative path of the file
 158             GET_FILENAME_COMPONENT(tmppath ${txtfile} PATH)
 159             string(REPLACE ${SOURCE_DIR}/ "" relpath ${tmppath})
 160
 161             # figure the manpage section to install to from filename
 162             string(REGEX REPLACE "^.*\\.([0-9])$" "\\1" section ${basename})
 163
 164             # construct the language specific versions of the basename and path
 165             if (lang STREQUAL default)
 166                 set(basename2 ${basename})
 167                 set(relpath2 ${relpath}/man${section})
 168             else()
 169                 set(basename2 ${basename}.${lang})
 170                 set(relpath2 ${relpath}/${lang}/man${section})
 171             endif()
 172
 173             # create the build directory (if it does not exist)
 174             file(MAKE_DIRECTORY ${BUILD_DIR}/${relpath2})
 175
 176             # set the final filenames
 177             set(txtfile ${SOURCE_DIR}/${relpath}/${basename2}.txt)
 178             set(xmlfile ${BUILD_DIR}/${relpath2}/${basename}.xml)
 179             set(gzfile  ${BUILD_DIR}/${relpath2}/${basename}.gz)
 180             set(manfile ${BUILD_DIR}/${relpath2}/${basename})
 181
 182             add_custom_command(
 183                 COMMAND ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} - < ${txtfile}
 184                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 185                 OUTPUT  ${xmlfile}
 186                 DEPENDS ${txtfile}
 187                 VERBATIM)
 188             add_custom_command(
 189                 COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 190                 OUTPUT  ${manfile}
 191                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 192                 DEPENDS ${xmlfile})
 193
 194             if(COMPRESS_MANPAGES)
 195                 add_custom_command(
 196                     COMMAND ${GZIP_EXECUTABLE} < ${manfile} > ${gzfile}
 197                     OUTPUT  ${gzfile}
 198                     WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 199                     DEPENDS ${manfile}
 200                     VERBATIM)
 201
 202                 set(MAN_FILES ${MAN_FILES} ${gzfile})
 203             else()
 204                 set(MAN_FILES ${MAN_FILES} ${manfile})
 205             endif()
 206         endforeach()
 207
 208     endforeach()
 209
 210     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 211 endif()
 212 # }}}
 213
 214 # {{{ Doxygen
 215 if(DOXYGEN_EXECUTABLE)
 216     add_custom_target(doc
 217         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 218         WORKING_DIRECTORY ${BUILD_DIR})
 219 endif()
 220 # }}}
 221
 222 # {{{ Lua API Documentation
 223 if(GENERATE_LUADOC)
 224
 225     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 226         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 227     endif()
 228
 229     set(luadoc_c_srcs "")
 230
 231     # Generate documentation of lib//0lua
 232     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua
 233         ${SOURCE_DIR}/luadoc/*.lua)
 234     foreach(filename ${lua_lib_files})
 235         file(RELATIVE_PATH filename ${BUILD_DIR} ${filename})
 236         set(luadoc_srcs ${luadoc_srcs} ${filename})
 237     endforeach()
 238
 239     add_custom_target(luadoc ALL
 240         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc --nofiles
 241         WORKING_DIRECTORY ${BUILD_DIR}
 242         DEPENDS ${AWE_LUA_FILES})
 243 endif()
 244 # }}}
 245
 246 # {{{ Theme icons
 247 file(GLOB icon_sources RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/themes/*/titlebar/*.png)
 248
 249 foreach(icon ${icon_sources})
 250     # Copy all icons to the build dir to simplify the following code.
 251     # Source paths are interpreted relative to ${SOURCE_DIR}, target paths
 252     # relative to ${BUILD_DIR}.
 253     get_filename_component(icon_path ${icon} PATH)
 254     get_filename_component(icon_name ${icon} NAME)
 255     file(COPY ${icon} DESTINATION ${icon_path})
 256     set(ALL_ICONS ${ALL_ICONS} "${icon_path}/${icon_name}")
 257 endforeach()
 258
 259 macro(a_icon_convert match replacement input)
 260     string(REPLACE ${match} ${replacement} output ${input})
 261
 262     if(NOT ${input} STREQUAL ${output})
 263         set(ALL_ICONS ${ALL_ICONS} ${output})
 264
 265         add_custom_command(
 266             COMMAND ${CONVERT_EXECUTABLE} ${input} ${ARGN} ${output}
 267             OUTPUT  ${output}
 268             DEPENDS ${input}
 269             VERBATIM)
 270     endif()
 271 endmacro()
 272
 273 foreach(icon ${ALL_ICONS})
 274     # Make unfocused icons translucent
 275     a_icon_convert("_focus" "_normal" ${icon}
 276         -gamma 0.6 -channel A -evaluate Multiply 0.4)
 277 endforeach()
 278
 279 foreach(icon ${ALL_ICONS})
 280     # Make inactive icons grayscale
 281     a_icon_convert("_active" "_inactive" ${icon}
 282         -colorspace Gray)
 283 endforeach()
 284
 285 add_custom_target(generated_icons ALL DEPENDS ${ALL_ICONS})
 286 # }}}
 287
 288 # {{{ Dist tarball
 289 if(BUILD_FROM_GIT)
 290     add_custom_target(dist
 291         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 292         WORKING_DIRECTORY ${SOURCE_DIR})
 293 endif()
 294 # }}}
 295
 296 # {{{ Installation
 297 install(TARGETS ${PROJECT_AWE_NAME} RUNTIME DESTINATION bin)
 298 install(FILES "utils/awsetbg" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 299 install(FILES "utils/awesome-client" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 300 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH}
 301     PATTERN "*.in" EXCLUDE)
 302 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 303         RENAME ${AWE_CONF_FILE})
 304 if(GENERATE_MANPAGES)
 305     if(COMPRESS_MANPAGES)
 306         set(regex "\\.(xml|txt|[0-9])$")
 307     else()
 308         set(regex "\\.(xml|txt|gz)$")
 309     endif()
 310     install(DIRECTORY ${BUILD_DIR}/${relpath}/ DESTINATION ${AWESOME_MAN_PATH}
 311             REGEX ${regex} EXCLUDE )
 312 endif()
 313 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 314 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 315     PATTERN "*.in" EXCLUDE)
 316 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 317     PATTERN "*.in" EXCLUDE)
 318 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 319 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 320 if(GENERATE_LUADOC)
 321     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 322 endif()
 323 # }}}
 324
 325 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80