CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  21     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  23
  24 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua ${BUILD_DIR}/luadoc/*.lua)
  25
  26 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  27 set(AWE_CONF_FILE rc.lua)
  28
  29 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  30 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  31
  32 set(AWE_DOC_FILES
  33     ${SOURCE_DIR}/AUTHORS
  34     ${SOURCE_DIR}/BUGS
  35     ${SOURCE_DIR}/README
  36     ${SOURCE_DIR}/LICENSE)
  37
  38 set(AWE_SRCS
  39     ${SOURCE_DIR}/awesome.c
  40     ${SOURCE_DIR}/banning.c
  41     ${SOURCE_DIR}/color.c
  42     ${SOURCE_DIR}/dbus.c
  43     ${SOURCE_DIR}/draw.c
  44     ${SOURCE_DIR}/event.c
  45     ${SOURCE_DIR}/ewmh.c
  46     ${SOURCE_DIR}/keygrabber.c
  47     ${SOURCE_DIR}/keyresolv.c
  48     ${SOURCE_DIR}/luaa.c
  49     ${SOURCE_DIR}/mouse.c
  50     ${SOURCE_DIR}/mousegrabber.c
  51     ${SOURCE_DIR}/property.c
  52     ${SOURCE_DIR}/root.c
  53     ${SOURCE_DIR}/screen.c
  54     ${SOURCE_DIR}/selection.c
  55     ${SOURCE_DIR}/spawn.c
  56     ${SOURCE_DIR}/stack.c
  57     ${SOURCE_DIR}/strut.c
  58     ${SOURCE_DIR}/systray.c
  59     ${SOURCE_DIR}/xwindow.c
  60     ${SOURCE_DIR}/common/atoms.c
  61     ${SOURCE_DIR}/common/backtrace.c
  62     ${SOURCE_DIR}/common/buffer.c
  63     ${SOURCE_DIR}/common/luaclass.c
  64     ${SOURCE_DIR}/common/lualib.c
  65     ${SOURCE_DIR}/common/luaobject.c
  66     ${SOURCE_DIR}/common/util.c
  67     ${SOURCE_DIR}/common/version.c
  68     ${SOURCE_DIR}/common/xcursor.c
  69     ${SOURCE_DIR}/common/xembed.c
  70     ${SOURCE_DIR}/common/xutil.c
  71     ${SOURCE_DIR}/objects/button.c
  72     ${SOURCE_DIR}/objects/client.c
  73     ${SOURCE_DIR}/objects/drawin.c
  74     ${SOURCE_DIR}/objects/key.c
  75     ${SOURCE_DIR}/objects/tag.c
  76     ${SOURCE_DIR}/objects/timer.c
  77     ${SOURCE_DIR}/objects/window.c)
  78
  79 set(AWE_MAN_SRCS
  80     ${SOURCE_DIR}/manpages/awesome.1.txt
  81     ${SOURCE_DIR}/manpages/awesome-client.1.txt
  82     ${SOURCE_DIR}/manpages/awesomerc.5.txt)
  83 set(AWE_MAN_LANGS it es fr de ru)
  84
  85 # Don't strip RPATH if compiling on Solaris
  86 if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  87     set(CMAKE_SKIP_BUILD_RPATH FALSE)
  88     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  89     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  90 endif()
  91
  92 add_executable(${PROJECT_AWE_NAME}
  93     ${AWE_SRCS})
  94
  95 # FreeBSD requires dynamic linking
  96 if(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
  97     set_target_properties(${PROJECT_AWE_NAME}
  98         PROPERTIES
  99         LINK_FLAGS -export-dynamic)
 100 endif()
 101
 102 target_link_libraries(${PROJECT_AWE_NAME}
 103     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 104     ${AWESOME_REQUIRED_LDFLAGS}
 105     ${AWESOME_OPTIONAL_LDFLAGS})
 106
 107 # atoms
 108 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 109 add_custom_command(
 110     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 111     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 112     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 113     WORKING_DIRECTORY ${SOURCE_DIR}
 114     DEPENDS ${SOURCE_DIR}/common/atoms.list
 115     COMMENT "Generating atoms-extern.h"
 116     VERBATIM)
 117
 118 add_custom_command(
 119     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 120     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 121     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 122     WORKING_DIRECTORY ${SOURCE_DIR}
 123     DEPENDS ${SOURCE_DIR}/common/atoms.list
 124     COMMENT "Generating atoms-intern.h"
 125     VERBATIM)
 126
 127 add_custom_target(generated_sources
 128     DEPENDS ${BUILD_DIR}/common/atoms-intern.h
 129             ${BUILD_DIR}/common/atoms-extern.h)
 130
 131 # Default theme directory
 132 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 133 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/sky)
 134 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/zenburn)
 135 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 136 # }}}
 137
 138 # {{{ Version stamp
 139 if(BUILD_FROM_GIT)
 140     add_custom_target(version_stamp ALL
 141         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 142                 ${VERSION_STAMP_FILE}
 143                 ${BUILD_DIR}/awesome-version-internal.h
 144         WORKING_DIRECTORY ${SOURCE_DIR})
 145
 146     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 147 endif()
 148 # }}}
 149
 150 # {{{ Manpages
 151 if(GENERATE_MANPAGES)
 152     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 153         file(MAKE_DIRECTORY ${BUILD_DIR}/manpages)
 154     endif()
 155
 156     # add the default translation to the list of languages
 157     set(AWE_MAN_LANGS default ${AWE_MAN_LANGS})
 158
 159     foreach(lang ${AWE_MAN_LANGS})
 160
 161         foreach(txtfile ${AWE_MAN_SRCS})
 162             # figure the base name of the file (ie "awesome.1")
 163             GET_FILENAME_COMPONENT(tmpname ${txtfile} NAME)
 164             string(REGEX REPLACE ".txt\$" "" basename ${tmpname})
 165
 166             # figure the relative path of the file
 167             GET_FILENAME_COMPONENT(tmppath ${txtfile} PATH)
 168             string(REPLACE ${SOURCE_DIR}/ "" relpath ${tmppath})
 169
 170             # figure the manpage section to install to from filename
 171             string(REGEX REPLACE "^.*\\.([0-9])$" "\\1" section ${basename})
 172
 173             # construct the language specific versions of the basename and path
 174             if (lang STREQUAL default)
 175                 set(basename2 ${basename})
 176                 set(relpath2 ${relpath}/man${section})
 177             else()
 178                 set(basename2 ${basename}.${lang})
 179                 set(relpath2 ${relpath}/${lang}/man${section})
 180             endif()
 181
 182             # create the build directory (if it does not exist)
 183             file(MAKE_DIRECTORY ${BUILD_DIR}/${relpath2})
 184
 185             # set the final filenames
 186             set(txtfile ${SOURCE_DIR}/${relpath}/${basename2}.txt)
 187             set(xmlfile ${BUILD_DIR}/${relpath2}/${basename}.xml)
 188             set(gzfile  ${BUILD_DIR}/${relpath2}/${basename}.gz)
 189             set(manfile ${BUILD_DIR}/${relpath2}/${basename})
 190
 191             add_custom_command(
 192                 COMMAND ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} - < ${txtfile}
 193                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 194                 OUTPUT  ${xmlfile}
 195                 DEPENDS ${txtfile}
 196                 VERBATIM)
 197             add_custom_command(
 198                 COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 199                 OUTPUT  ${manfile}
 200                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 201                 DEPENDS ${xmlfile})
 202
 203             if(COMPRESS_MANPAGES)
 204                 add_custom_command(
 205                     COMMAND ${GZIP_EXECUTABLE} < ${manfile} > ${gzfile}
 206                     OUTPUT  ${gzfile}
 207                     WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 208                     DEPENDS ${manfile}
 209                     VERBATIM)
 210
 211                 set(MAN_FILES ${MAN_FILES} ${gzfile})
 212             else()
 213                 set(MAN_FILES ${MAN_FILES} ${manfile})
 214             endif()
 215         endforeach()
 216
 217     endforeach()
 218
 219     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 220 endif()
 221 # }}}
 222
 223 # {{{ Doxygen
 224 if(DOXYGEN_EXECUTABLE)
 225     add_custom_target(doc
 226         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 227         WORKING_DIRECTORY ${BUILD_DIR})
 228 endif()
 229 # }}}
 230
 231 # {{{ Lua API Documentation
 232 if(GENERATE_LUADOC)
 233
 234     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 235         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 236     endif()
 237
 238     set(luadoc_c_srcs "")
 239
 240     # Generate documentation of lib//0lua
 241     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua
 242         ${SOURCE_DIR}/luadoc/*.lua)
 243     foreach(filename ${lua_lib_files})
 244         file(RELATIVE_PATH filename ${BUILD_DIR} ${filename})
 245         set(luadoc_srcs ${luadoc_srcs} ${filename})
 246     endforeach()
 247
 248     add_custom_target(luadoc ALL
 249         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc --nofiles
 250         WORKING_DIRECTORY ${BUILD_DIR}
 251         DEPENDS ${AWE_LUA_FILES})
 252 endif()
 253 # }}}
 254
 255 # {{{ Theme icons
 256 file(GLOB icon_sources RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/themes/*/titlebar/*.png)
 257
 258 foreach(icon ${icon_sources})
 259     # Copy all icons to the build dir to simplify the following code.
 260     # Source paths are interpreted relative to ${SOURCE_DIR}, target paths
 261     # relative to ${BUILD_DIR}.
 262     get_filename_component(icon_path ${icon} PATH)
 263     get_filename_component(icon_name ${icon} NAME)
 264     file(COPY ${icon} DESTINATION ${icon_path})
 265     set(ALL_ICONS ${ALL_ICONS} "${icon_path}/${icon_name}")
 266 endforeach()
 267
 268 macro(a_icon_convert match replacement input)
 269     string(REPLACE ${match} ${replacement} output ${input})
 270
 271     if(NOT ${input} STREQUAL ${output})
 272         set(ALL_ICONS ${ALL_ICONS} ${output})
 273
 274         add_custom_command(
 275             COMMAND ${CONVERT_EXECUTABLE} ${input} ${ARGN} ${output}
 276             OUTPUT  ${output}
 277             DEPENDS ${input}
 278             VERBATIM)
 279     endif()
 280 endmacro()
 281
 282 foreach(icon ${ALL_ICONS})
 283     # Make unfocused icons translucent
 284     a_icon_convert("_focus" "_normal" ${icon}
 285         -gamma 0.6 -channel A -evaluate Multiply 0.4)
 286 endforeach()
 287
 288 foreach(icon ${ALL_ICONS})
 289     # Make inactive icons grayscale
 290     a_icon_convert("_active" "_inactive" ${icon}
 291         -colorspace Gray)
 292 endforeach()
 293
 294 add_custom_target(generated_icons ALL DEPENDS ${ALL_ICONS})
 295 # }}}
 296
 297 # {{{ Dist tarball
 298 if(BUILD_FROM_GIT)
 299     add_custom_target(dist
 300         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 301         WORKING_DIRECTORY ${SOURCE_DIR})
 302 endif()
 303 # }}}
 304
 305 # {{{ Installation
 306 install(TARGETS ${PROJECT_AWE_NAME} RUNTIME DESTINATION bin)
 307 install(FILES "utils/awesome-client" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 308 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH}
 309     PATTERN "*.in" EXCLUDE)
 310 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 311         RENAME ${AWE_CONF_FILE})
 312 if(GENERATE_MANPAGES)
 313     if(COMPRESS_MANPAGES)
 314         set(regex "\\.(xml|txt|[0-9])$")
 315     else()
 316         set(regex "\\.(xml|txt|gz)$")
 317     endif()
 318     install(DIRECTORY ${BUILD_DIR}/${relpath}/ DESTINATION ${AWESOME_MAN_PATH}
 319             REGEX ${regex} EXCLUDE )
 320 endif()
 321 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 322 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 323     PATTERN "*.in" EXCLUDE)
 324 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 325     PATTERN "*.in" EXCLUDE)
 326 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 327 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 328 if(GENERATE_LUADOC)
 329     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 330 endif()
 331 # }}}
 332
 333 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80