CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${BUILD_DIR}/common
  21     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  23     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  24
  25 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua)
  26
  27 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  28 set(AWE_CONF_FILE rc.lua)
  29
  30 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  31 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  32
  33 set(AWE_DOC_FILES
  34     ${SOURCE_DIR}/AUTHORS
  35     ${SOURCE_DIR}/BUGS
  36     ${SOURCE_DIR}/README
  37     ${SOURCE_DIR}/LICENSE)
  38
  39 set(AWE_SRCS
  40     ${SOURCE_DIR}/awesome.c
  41     ${SOURCE_DIR}/client.c
  42     ${SOURCE_DIR}/cnode.c
  43     ${SOURCE_DIR}/dbus.c
  44     ${SOURCE_DIR}/event.c
  45     ${SOURCE_DIR}/property.c
  46     ${SOURCE_DIR}/ewmh.c
  47     ${SOURCE_DIR}/key.c
  48     ${SOURCE_DIR}/keygrabber.c
  49     ${SOURCE_DIR}/mousegrabber.c
  50     ${SOURCE_DIR}/layout.c
  51     ${SOURCE_DIR}/luaa.c
  52     ${SOURCE_DIR}/spawn.c
  53     ${SOURCE_DIR}/hooks.c
  54     ${SOURCE_DIR}/mouse.c
  55     ${SOURCE_DIR}/screen.c
  56     ${SOURCE_DIR}/stack.c
  57     ${SOURCE_DIR}/selection.c
  58     ${SOURCE_DIR}/wibox.c
  59     ${SOURCE_DIR}/systray.c
  60     ${SOURCE_DIR}/tag.c
  61     ${SOURCE_DIR}/titlebar.c
  62     ${SOURCE_DIR}/widget.c
  63     ${SOURCE_DIR}/window.c
  64     ${SOURCE_DIR}/image.c
  65     ${SOURCE_DIR}/draw.c
  66     ${SOURCE_DIR}/swindow.c
  67     ${SOURCE_DIR}/common/buffer.c
  68     ${SOURCE_DIR}/common/atoms.c
  69     ${SOURCE_DIR}/common/util.c
  70     ${SOURCE_DIR}/common/version.c
  71     ${SOURCE_DIR}/common/xembed.c
  72     ${SOURCE_DIR}/common/xutil.c
  73     ${SOURCE_DIR}/common/xcursor.c
  74     ${SOURCE_DIR}/widgets/graph.c
  75     ${SOURCE_DIR}/widgets/progressbar.c
  76     ${SOURCE_DIR}/widgets/textbox.c
  77     ${SOURCE_DIR}/widgets/systray.c
  78     ${SOURCE_DIR}/widgets/imagebox.c)
  79
  80 set(AWE_MAN_SRCS
  81     ${SOURCE_DIR}/awesome.1.txt
  82     ${SOURCE_DIR}/awsetbg.1.txt
  83     ${SOURCE_DIR}/awesome-client.1.txt
  84     ${SOURCE_DIR}/awesomerc.5.txt)
  85
  86 add_executable(${PROJECT_AWE_NAME}
  87     ${AWE_SRCS}
  88     ${BUILD_DIR}/common/tokenize.c)
  89
  90 set_target_properties(${PROJECT_AWE_NAME}
  91     PROPERTIES
  92     LINK_FLAGS -export-dynamic)
  93
  94 target_link_libraries(${PROJECT_AWE_NAME}
  95     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
  96     ${AWESOME_REQUIRED_LIBRARIES}
  97     ${AWESOME_OPTIONAL_LIBRARIES})
  98
  99 # {{{ Generated sources
 100 add_custom_command(
 101     COMMAND ${SOURCE_DIR}/build-utils/widgetgen.sh
 102     ARGS    > ${BUILD_DIR}/widgetgen.h
 103     OUTPUT  ${BUILD_DIR}/widgetgen.h
 104     WORKING_DIRECTORY ${SOURCE_DIR}
 105     DEPENDS ${SOURCE_DIR}/widget.h
 106     COMMENT "Generating widgetgen.h"
 107     VERBATIM)
 108
 109 # atoms
 110 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 111 add_custom_command(
 112     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 113     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 114     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 115     WORKING_DIRECTORY ${SOURCE_DIR}
 116     DEPENDS ${SOURCE_DIR}/common/atoms.list
 117     COMMENT "Generating atoms-extern.h"
 118     VERBATIM)
 119
 120 add_custom_command(
 121     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 122     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 123     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 124     WORKING_DIRECTORY ${SOURCE_DIR}
 125     DEPENDS ${SOURCE_DIR}/common/atoms.list
 126     COMMENT "Generating atoms-intern.h"
 127     VERBATIM)
 128
 129 # gperf
 130 add_custom_command(
 131     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 132     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 133             ${BUILD_DIR}/common/tokenize.h
 134     OUTPUT  ${BUILD_DIR}/common/tokenize.h
 135     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 136             ${SOURCE_DIR}/build-utils/gperf.sh
 137     COMMENT "Generating common/tokenize.h")
 138
 139 add_custom_command(
 140     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 141     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 142             ${BUILD_DIR}/common/tokenize.c
 143     OUTPUT  ${BUILD_DIR}/common/tokenize.c
 144     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 145             ${SOURCE_DIR}/build-utils/gperf.sh
 146     COMMENT "Generating common/tokenize.c")
 147
 148 add_custom_target(generated_sources
 149     DEPENDS ${BUILD_DIR}/widgetgen.h
 150             ${BUILD_DIR}/common/atoms-intern.h
 151             ${BUILD_DIR}/common/atoms-extern.h
 152             ${BUILD_DIR}/common/tokenize.c
 153             ${BUILD_DIR}/common/tokenize.h)
 154
 155 # Default theme directory
 156 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 157 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/sky)
 158 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 159 # }}}
 160
 161 # {{{ Version stamp
 162 if(BUILD_FROM_GIT)
 163     add_custom_target(version_stamp ALL
 164         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 165                 ${VERSION_STAMP_FILE}
 166                 ${BUILD_DIR}/awesome-version-internal.h
 167         WORKING_DIRECTORY ${SOURCE_DIR})
 168
 169     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 170 endif()
 171 # }}}
 172
 173 # {{{ Manpages
 174 if(GENERATE_MANPAGES)
 175     foreach(txtfile ${AWE_MAN_SRCS})
 176         string(REGEX REPLACE ".txt\$" ".xml" xmlfile ${txtfile})
 177         string(REPLACE ${SOURCE_DIR}
 178                        ${BUILD_DIR} xmlfile ${xmlfile})
 179         string(REGEX REPLACE ".xml\$" ".gz" gzfile ${xmlfile})
 180         string(REGEX REPLACE ".gz\$" "" manfile ${gzfile})
 181
 182         add_custom_command(
 183             COMMAND ${CAT_EXECUTABLE} ${txtfile}
 184                     | ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} -
 185             WORKING_DIRECTORY ${BUILD_DIR}
 186             OUTPUT  ${xmlfile}
 187             DEPENDS ${txtfile}
 188             VERBATIM)
 189         add_custom_command(
 190             COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 191             OUTPUT  ${manfile}
 192             DEPENDS ${xmlfile})
 193         add_custom_command(
 194             COMMAND ${CAT_EXECUTABLE} ${manfile}
 195                     | ${GZIP_EXECUTABLE}
 196                     > ${gzfile}
 197             OUTPUT  ${gzfile}
 198             DEPENDS ${manfile}
 199             VERBATIM)
 200
 201         set(MAN_FILES ${MAN_FILES} ${gzfile})
 202
 203         # figure out in what section to install to from filename
 204         string(REGEX REPLACE "^.*\\.([0-9])\\.gz\$" "\\1" section ${gzfile})
 205         set(AWE_MAN${section}_FILES ${AWE_MAN${section}_FILES} ${gzfile})
 206     endforeach()
 207
 208     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 209 endif()
 210 # }}}
 211
 212 # {{{ Doxygen
 213 if(DOXYGEN_EXECUTABLE)
 214     add_custom_target(doc
 215         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 216         WORKING_DIRECTORY ${BUILD_DIR})
 217 endif()
 218 # }}}
 219
 220 # {{{ Lua API Documentation
 221 if(GENERATE_LUADOC)
 222
 223     set(capi_lua ${BUILD_DIR}/lib/capi.lua)
 224
 225     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 226         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 227     endif()
 228
 229     # {{{ setup a command for ${capi_lua}
 230     macro(a_file_match infile regex result_var)
 231         file(STRINGS ${infile} match REGEX ${regex} LIMIT_COUNT 1)
 232         if(match)
 233             set(${result_var} TRUE)
 234         else()
 235             set(${result_var} FALSE)
 236         endif()
 237     endmacro()
 238
 239     set(luadoc_c_srcs "")
 240
 241     # find .c files exporting lua functions
 242     foreach(cfile ${AWE_SRCS})
 243         a_file_match(${cfile} "const struct luaL_reg" result)
 244         if(result)
 245             set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 246         else()
 247             a_file_match(${cfile} "luaA_.*_index" result)
 248             if(result)
 249                 set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 250         endif()
 251         endif()
 252     endforeach()
 253
 254     # create fake lua source file to process by luadoc
 255     add_custom_command(
 256         COMMAND ${CAT_EXECUTABLE} ${luadoc_c_srcs}
 257                 | ${LUA_EXECUTABLE} ${SOURCE_DIR}/build-utils/fake-lua-src.lua
 258                 > ${capi_lua}
 259         OUTPUT  ${capi_lua}
 260         DEPENDS ${luadoc_c_srcs}
 261         COMMENT "Generating fake lua source."
 262         VERBATIM)
 263     # }}}
 264
 265     # Generate documentation of lib//0lua
 266     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua)
 267     foreach(filename ${lua_lib_files})
 268         file(RELATIVE_PATH filename ${BUILD_DIR}/lib ${filename})
 269         set(luadoc_srcs ${luadoc_srcs} ${filename})
 270     endforeach()
 271
 272     add_custom_target(luadoc ALL
 273         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc
 274         WORKING_DIRECTORY ${BUILD_DIR}/lib
 275         DEPENDS ${AWE_LUA_FILES} ${capi_lua})
 276 endif()
 277 # }}}
 278
 279 # {{{ Dist tarball
 280 if(BUILD_FROM_GIT)
 281     add_custom_target(dist
 282         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 283         WORKING_DIRECTORY ${SOURCE_DIR})
 284 endif()
 285 # }}}
 286
 287 # {{{ Installation
 288 install(TARGETS ${PROJECT_AWE_NAME} RUNTIME DESTINATION bin)
 289 install(FILES "utils/awsetbg" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 290 install(FILES "utils/awesome-client" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 291 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH})
 292 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 293         RENAME ${AWE_CONF_FILE})
 294 if(GENERATE_MANPAGES)
 295     install(FILES ${AWE_MAN1_FILES} DESTINATION ${AWESOME_MAN_PATH}/man1)
 296     install(FILES ${AWE_MAN5_FILES} DESTINATION ${AWESOME_MAN_PATH}/man5)
 297 endif()
 298 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 299 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH})
 300 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 301     PATTERN "*.in" EXCLUDE)
 302 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 303 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 304 if(GENERATE_LUADOC)
 305     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 306 endif()
 307 # }}}
 308
 309 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80