awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2 set(PROJECT_AWECLIENT_NAME awesome-client)
   3
   4 # If ${SOURCE_DIR} is a git repository VERSION is set to
   5 # `git describe` later.
   6 set(VERSION devel)
   7
   8 set(CODENAME "Accidental Babies")
   9
  10 project(${PROJECT_AWE_NAME} C)
  11
  12 set(CMAKE_BUILD_TYPE RELEASE)
  13
  14 set(CURSES_NEED_NCURSES true)
  15
  16 option(WITH_DBUS "build with D-BUS" ON)
  17 option(GENERATE_MANPAGES "generate manpages" ON)
  18 option(GENERATE_LUADOC "generate luadoc" ON)
  19
  20 link_directories(/usr/local/lib)
  21
  22 # {{{ CFLAGS
  23 add_definitions(-std=gnu99 -ggdb3 -fno-strict-aliasing -Wall -Wextra
  24     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  25     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  26     -Wpointer-arith -Wredundant-decls -Wformat-nonliteral
  27     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  28     -Wstrict-prototypes)
  29 # }}}
  30
  31 # {{{ Endianness
  32 include(TestBigEndian)
  33 TEST_BIG_ENDIAN(AWESOME_IS_BIG_ENDIAN)
  34 # }}}
  35
  36 # {{{ Find external utilities
  37 macro(a_find_program var prg req)
  38     set(required ${req})
  39     find_program(${var} ${prg})
  40     if(NOT ${var})
  41         message(STATUS "${prg} not found.")
  42         if(required)
  43             message(FATAL_ERROR "${prg} is required to build awesome")
  44         endif()
  45     else()
  46         message(STATUS "${prg} -> ${${var}}")
  47     endif()
  48 endmacro()
  49
  50 a_find_program(CAT_EXECUTABLE cat TRUE)
  51 a_find_program(LN_EXECUTABLE ln TRUE)
  52 a_find_program(GREP_EXECUTABLE grep TRUE)
  53 a_find_program(GIT_EXECUTABLE git FALSE)
  54 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  55 a_find_program(GPERF_EXECUTABLE gperf TRUE)
  56 # programs needed for man pages
  57 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  58 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  59 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  60 # lua documentation
  61 a_find_program(LUA_EXECUTABLE lua FALSE)
  62 a_find_program(LUADOC_EXECUTABLE luadoc FALSE)
  63 # doxygen
  64 include(FindDoxygen)
  65 # pkg-config
  66 include(FindPkgConfig)
  67 # ncurses
  68 include(FindCurses)
  69 # lua 5.1
  70 include(FindLua51) #Due to a cmake bug, you will see Lua50 on screen
  71 # }}}
  72
  73 # {{{ Check if documentation can be build
  74 if(GENERATE_MANPAGES)
  75     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR NOT GZIP_EXECUTABLE)
  76         if(NOT ASCIIDOC_EXECUTABLE)
  77             SET(missing "asciidoc")
  78         endif()
  79         if(NOT XMLTO_EXECUTABLE)
  80             SET(missing ${missing} " xmlto")
  81         endif()
  82         if(NOT GZIP_EXECUTABLE)
  83             SET(missing ${missing} " gzip")
  84         endif()
  85
  86         message(STATUS "Not generating manpages. Missing: " ${missing})
  87         set(GENERATE_MANPAGES OFF)
  88     endif()
  89 endif()
  90
  91 if(GENERATE_LUADOC)
  92     if(NOT LUADOC_EXECUTABLE)
  93         message(STATUS "Not generating luadoc. Missing: luadoc")
  94         set(GENERATE_LUADOC OFF)
  95     endif()
  96 endif()
  97 # }}}
  98
  99 # {{{ Version stamp
 100 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
 101     # get current version
 102     execute_process(
 103         COMMAND ${GIT_EXECUTABLE} describe
 104         WORKING_DIRECTORY ${SOURCE_DIR}
 105         OUTPUT_VARIABLE VERSION
 106         OUTPUT_STRIP_TRAILING_WHITESPACE)
 107     # file the git-version-stamp.sh script will look into
 108     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 109     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 110     # create a version_stamp target later
 111     set(BUILD_FROM_GIT TRUE)
 112 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 113     # get version from version stamp
 114     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 115 endif()
 116 # }}}
 117
 118 # {{{ Get hostname
 119 execute_process(
 120     COMMAND ${HOSTNAME_EXECUTABLE}
 121     WORKING_DIRECTORY ${SOURCE_DIR}
 122     OUTPUT_VARIABLE BUILDHOSTNAME
 123     OUTPUT_STRIP_TRAILING_WHITESPACE)
 124 # }}}
 125
 126 # {{{ Required libraries
 127 #
 128 # this sets up:
 129 # AWESOME_REQUIRED_LIBRARIES
 130 # AWESOME_REQUIRED_INCLUDE_DIRS
 131 # AWESOMECLIENT_LIBRARIES
 132
 133 # Use pkgconfig to get most of the libraries
 134 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 135     xcb>=1.1)
 136
 137 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 138     glib-2.0
 139     cairo
 140     x11
 141     pango>=1.19.3
 142     pangocairo>=1.19.3
 143     xcb-randr
 144     xcb-xtest
 145     xcb-xinerama
 146     xcb-event>=0.3.4
 147     xcb-aux>=0.3.0
 148     xcb-atom>=0.3.0
 149     xcb-keysyms>=0.3.4
 150     xcb-icccm>=0.3.3
 151     xcb-image>=0.3.0
 152     xcb-property>=0.3.0
 153     cairo-xcb
 154     libstartup-notification-1.0>=0.10
 155     xproto>=7.0.11
 156     imlib2
 157     libxdg-basedir>=1.0.0)
 158
 159 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 160     message(FATAL_ERROR)
 161 endif()
 162
 163 macro(a_find_library variable library)
 164     find_library(${variable} ${library})
 165     if(NOT ${variable})
 166         message(FATAL_ERROR ${library} " library not found.")
 167     endif()
 168 endmacro()
 169
 170 # Check for libev
 171 a_find_library(LIB_EV ev)
 172
 173 # Error check
 174 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 175     message(FATAL_ERROR "lua library not found")
 176 endif()
 177
 178 set(AWESOME_REQUIRED_LIBRARIES
 179     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 180     ${AWESOME_REQUIRED_LIBRARIES}
 181     ${LIB_EV}
 182     ${LUA_LIBRARIES})
 183
 184 set(AWESOME_REQUIRED_INCLUDE_DIRS
 185     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 186     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 187     ${LUA_INCLUDE_DIR})
 188
 189 set(AWESOMECLIENT_LIBRARIES
 190     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 191     ${LIB_READLINE}
 192     ${LIB_XCB}
 193     ${CURSES_LIBRARIES})
 194
 195 set(AWESOMECLIENT_REQUIRED_INCLUDE_DIRS
 196     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS})
 197 # }}}
 198
 199 # {{{ Optional libraries
 200 #
 201 # this sets up:
 202 # AWESOME_OPTIONAL_LIBRARIES
 203 # AWESOME_OPTIONAL_INCLUDE_DIRS
 204
 205 if(WITH_DBUS)
 206     pkg_check_modules(DBUS dbus-1)
 207     if(DBUS_FOUND)
 208         set(AWESOME_OPTIONAL_LIBRARIES ${AWESOME_OPTIONAL_LIBRARIES} ${DBUS_LIBRARIES})
 209         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 210     else()
 211         set(WITH_DBUS OFF)
 212         message(STATUS "DBUS not found. Disabled.")
 213     endif()
 214 endif()
 215 # }}}
 216
 217 # {{{ Install path and configuration variables
 218 if(DEFINED PREFIX)
 219     set(PREFIX ${PREFIX} CACHE PATH "install prefix")
 220     set(CMAKE_INSTALL_PREFIX ${PREFIX})
 221 else()
 222     set(PREFIX ${CMAKE_INSTALL_PREFIX} CACHE PATH "install prefix")
 223 endif()
 224
 225 #If a sysconfdir is specified, use it instead
 226 #of the default configuration dir.
 227 if(DEFINED SYSCONFDIR)
 228     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 229 else()
 230     set(SYSCONFDIR ${PREFIX}/etc CACHE PATH "config directory")
 231 endif()
 232
 233 #If an XDG Config Dir is specificed, use it instead
 234 #of the default XDG configuration dir.
 235 if(DEFINED XDG_CONFIG_DIR)
 236     set(XDG_CONFIG_DIR ${XDG_CONFIG_DIR} CACHE PATH "xdg config directory")
 237 else()
 238     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 239 endif()
 240
 241 # setting AWESOME_DOC_PATH
 242 if(DEFINED AWESOME_DOC_PATH)
 243     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 244 else()
 245     set(AWESOME_DOC_PATH ${PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 246 endif()
 247
 248 # setting AWESOME_XSESSION_PATH
 249 if(DEFINED AWESOME_XSESSION_PATH)
 250     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 251 else()
 252     set(AWESOME_XSESSION_PATH ${PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 253 endif()
 254
 255 # set man path
 256 if(DEFINED AWESOME_MAN_PATH)
 257    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 258 else()
 259    set(AWESOME_MAN_PATH ${PREFIX}/share/man CACHE PATH "awesome manpage directory")
 260 endif()
 261
 262 # Hide to avoid confusion
 263 mark_as_advanced(CMAKE_INSTALL_PREFIX)
 264
 265 set(AWESOME_VERSION          ${VERSION})
 266 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 267 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 268 set(AWESOME_COMPILE_BY       $ENV{USER})
 269 set(AWESOME_RELEASE          ${CODENAME})
 270 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 271 set(AWESOME_DATA_PATH        ${PREFIX}/share/${PROJECT_AWE_NAME})
 272 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 273 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 274 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 275 # }}}
 276
 277 # {{{ Configure files
 278 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in)
 279 set(AWESOME_CONFIGURE_FILES
 280     ${awesome_lua_configure_files}
 281     config.h.in
 282     awesomerc.lua.in
 283     themes/default/theme.in
 284     themes/sky/theme.in
 285     awesome-version-internal.h.in
 286     awesome.doxygen.in)
 287
 288 macro(a_configure_file file)
 289     string(REGEX REPLACE ".in\$" "" outfile ${file})
 290     message(STATUS "Configuring ${outfile}")
 291     configure_file(${SOURCE_DIR}/${file}
 292                    ${BUILD_DIR}/${outfile}
 293                    ESCAPE_QUOTE
 294                    @ONLY)
 295 endmacro()
 296
 297 foreach(file ${AWESOME_CONFIGURE_FILES})
 298     a_configure_file(${file})
 299 endforeach()
 300 #}}}
 301
 302 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80