CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  21     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  23
  24 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua)
  25
  26 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  27 set(AWE_CONF_FILE rc.lua)
  28
  29 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  30 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  31
  32 set(AWE_DOC_FILES
  33     ${SOURCE_DIR}/AUTHORS
  34     ${SOURCE_DIR}/BUGS
  35     ${SOURCE_DIR}/README
  36     ${SOURCE_DIR}/LICENSE)
  37
  38 set(AWE_SRCS
  39     ${SOURCE_DIR}/awesome.c
  40     ${SOURCE_DIR}/client.c
  41     ${SOURCE_DIR}/dbus.c
  42     ${SOURCE_DIR}/root.c
  43     ${SOURCE_DIR}/event.c
  44     ${SOURCE_DIR}/property.c
  45     ${SOURCE_DIR}/ewmh.c
  46     ${SOURCE_DIR}/key.c
  47     ${SOURCE_DIR}/keygrabber.c
  48     ${SOURCE_DIR}/mousegrabber.c
  49     ${SOURCE_DIR}/banning.c
  50     ${SOURCE_DIR}/luaa.c
  51     ${SOURCE_DIR}/spawn.c
  52     ${SOURCE_DIR}/hooks.c
  53     ${SOURCE_DIR}/mouse.c
  54     ${SOURCE_DIR}/button.c
  55     ${SOURCE_DIR}/screen.c
  56     ${SOURCE_DIR}/stack.c
  57     ${SOURCE_DIR}/selection.c
  58     ${SOURCE_DIR}/wibox.c
  59     ${SOURCE_DIR}/systray.c
  60     ${SOURCE_DIR}/tag.c
  61     ${SOURCE_DIR}/titlebar.c
  62     ${SOURCE_DIR}/widget.c
  63     ${SOURCE_DIR}/window.c
  64     ${SOURCE_DIR}/image.c
  65     ${SOURCE_DIR}/draw.c
  66     ${SOURCE_DIR}/color.c
  67     ${SOURCE_DIR}/timer.c
  68     ${SOURCE_DIR}/common/buffer.c
  69     ${SOURCE_DIR}/common/atoms.c
  70     ${SOURCE_DIR}/common/util.c
  71     ${SOURCE_DIR}/common/version.c
  72     ${SOURCE_DIR}/common/xembed.c
  73     ${SOURCE_DIR}/common/xutil.c
  74     ${SOURCE_DIR}/common/xcursor.c
  75     ${SOURCE_DIR}/common/backtrace.c
  76     ${SOURCE_DIR}/common/luaobject.c
  77     ${SOURCE_DIR}/common/luaclass.c
  78     ${SOURCE_DIR}/widgets/graph.c
  79     ${SOURCE_DIR}/widgets/progressbar.c
  80     ${SOURCE_DIR}/widgets/textbox.c
  81     ${SOURCE_DIR}/widgets/systray.c
  82     ${SOURCE_DIR}/widgets/imagebox.c)
  83
  84 set(AWE_MAN_SRCS
  85     ${SOURCE_DIR}/manpages/awesome.1.txt
  86     ${SOURCE_DIR}/manpages/awsetbg.1.txt
  87     ${SOURCE_DIR}/manpages/awesome-client.1.txt
  88     ${SOURCE_DIR}/manpages/awesomerc.5.txt)
  89
  90 add_executable(${PROJECT_AWE_NAME}
  91     ${AWE_SRCS}
  92     ${BUILD_DIR}/common/tokenize.c)
  93
  94 set_target_properties(${PROJECT_AWE_NAME}
  95     PROPERTIES
  96     LINK_FLAGS -export-dynamic)
  97
  98 target_link_libraries(${PROJECT_AWE_NAME}
  99     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 100     ${AWESOME_REQUIRED_LIBRARIES}
 101     ${AWESOME_OPTIONAL_LIBRARIES})
 102
 103 # atoms
 104 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 105 add_custom_command(
 106     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 107     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 108     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 109     WORKING_DIRECTORY ${SOURCE_DIR}
 110     DEPENDS ${SOURCE_DIR}/common/atoms.list
 111     COMMENT "Generating atoms-extern.h"
 112     VERBATIM)
 113
 114 add_custom_command(
 115     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 116     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 117     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 118     WORKING_DIRECTORY ${SOURCE_DIR}
 119     DEPENDS ${SOURCE_DIR}/common/atoms.list
 120     COMMENT "Generating atoms-intern.h"
 121     VERBATIM)
 122
 123 # gperf
 124 add_custom_command(
 125     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 126     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 127             ${BUILD_DIR}/common/tokenize.h
 128     OUTPUT  ${BUILD_DIR}/common/tokenize.h
 129     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 130             ${SOURCE_DIR}/build-utils/gperf.sh
 131     COMMENT "Generating common/tokenize.h")
 132
 133 add_custom_command(
 134     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 135     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 136             ${BUILD_DIR}/common/tokenize.c
 137     OUTPUT  ${BUILD_DIR}/common/tokenize.c
 138     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 139             ${SOURCE_DIR}/build-utils/gperf.sh
 140     COMMENT "Generating common/tokenize.c")
 141
 142 add_custom_target(generated_sources
 143     DEPENDS ${BUILD_DIR}/common/atoms-intern.h
 144             ${BUILD_DIR}/common/atoms-extern.h
 145             ${BUILD_DIR}/common/tokenize.c
 146             ${BUILD_DIR}/common/tokenize.h)
 147
 148 # Default theme directory
 149 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 150 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/sky)
 151 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 152 # }}}
 153
 154 # {{{ Version stamp
 155 if(BUILD_FROM_GIT)
 156     add_custom_target(version_stamp ALL
 157         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 158                 ${VERSION_STAMP_FILE}
 159                 ${BUILD_DIR}/awesome-version-internal.h
 160         WORKING_DIRECTORY ${SOURCE_DIR})
 161
 162     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 163 endif()
 164 # }}}
 165
 166 # {{{ Manpages
 167 if(GENERATE_MANPAGES)
 168     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 169         file(MAKE_DIRECTORY ${BUILD_DIR}/manpages)
 170     endif()
 171     foreach(txtfile ${AWE_MAN_SRCS})
 172         string(REGEX REPLACE ".txt\$" ".xml" xmlfile ${txtfile})
 173         string(REPLACE ${SOURCE_DIR}
 174                        ${BUILD_DIR} xmlfile ${xmlfile})
 175         string(REGEX REPLACE ".xml\$" ".gz" gzfile ${xmlfile})
 176         string(REGEX REPLACE ".gz\$" "" manfile ${gzfile})
 177
 178         add_custom_command(
 179             COMMAND ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} - < ${txtfile}
 180             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 181             OUTPUT  ${xmlfile}
 182             DEPENDS ${txtfile}
 183             VERBATIM)
 184         add_custom_command(
 185             COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 186             OUTPUT  ${manfile}
 187             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 188             DEPENDS ${xmlfile})
 189         add_custom_command(
 190             COMMAND ${GZIP_EXECUTABLE} < ${manfile} > ${gzfile}
 191             OUTPUT  ${gzfile}
 192             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 193             DEPENDS ${manfile}
 194             VERBATIM)
 195
 196         set(MAN_FILES ${MAN_FILES} ${gzfile})
 197
 198         # figure out in what section to install to from filename
 199         string(REGEX REPLACE "^.*\\.([0-9])\\.gz\$" "\\1" section ${gzfile})
 200         set(AWE_MAN${section}_FILES ${AWE_MAN${section}_FILES} ${gzfile})
 201     endforeach()
 202
 203     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 204 endif()
 205 # }}}
 206
 207 # {{{ Doxygen
 208 if(DOXYGEN_EXECUTABLE)
 209     add_custom_target(doc
 210         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 211         WORKING_DIRECTORY ${BUILD_DIR})
 212 endif()
 213 # }}}
 214
 215 # {{{ Lua API Documentation
 216 if(GENERATE_LUADOC)
 217
 218     set(capi_lua ${BUILD_DIR}/lib/capi.lua)
 219
 220     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 221         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 222     endif()
 223
 224     # {{{ setup a command for ${capi_lua}
 225     macro(a_file_match infile regex result_var)
 226         file(STRINGS ${infile} match REGEX ${regex} LIMIT_COUNT 1)
 227         if(match)
 228             set(${result_var} TRUE)
 229         else()
 230             set(${result_var} FALSE)
 231         endif()
 232     endmacro()
 233
 234     set(luadoc_c_srcs "")
 235
 236     # find .c files exporting lua functions
 237     foreach(cfile ${AWE_SRCS})
 238         a_file_match(${cfile} "const struct luaL_reg" result)
 239         if(result)
 240             set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 241         else()
 242             a_file_match(${cfile} "luaA_.*_index" result)
 243             if(result)
 244                 set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 245         endif()
 246         endif()
 247     endforeach()
 248
 249     # create fake lua source file to process by luadoc
 250     add_custom_command(
 251         COMMAND ${CAT_EXECUTABLE} ${luadoc_c_srcs}
 252                 | ${LUA_EXECUTABLE} ${SOURCE_DIR}/build-utils/fake-lua-src.lua
 253                 > ${capi_lua}
 254         OUTPUT  ${capi_lua}
 255         DEPENDS ${luadoc_c_srcs}
 256         COMMENT "Generating fake lua source."
 257         VERBATIM)
 258     # }}}
 259
 260     # Generate documentation of lib//0lua
 261     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua)
 262     foreach(filename ${lua_lib_files})
 263         file(RELATIVE_PATH filename ${BUILD_DIR}/lib ${filename})
 264         set(luadoc_srcs ${luadoc_srcs} ${filename})
 265     endforeach()
 266
 267     add_custom_target(luadoc ALL
 268         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc
 269         WORKING_DIRECTORY ${BUILD_DIR}/lib
 270         DEPENDS ${AWE_LUA_FILES} ${capi_lua})
 271 endif()
 272 # }}}
 273
 274 # {{{ Theme icons
 275 file(GLOB icon_sources ${SOURCE_DIR}/themes/*/titlebar/*.png)
 276 set(ALL_ICONS ${icon_sources})
 277
 278 macro(a_icon_convert match replacement input)
 279     string(REPLACE ${match} ${replacement} output ${input})
 280
 281     if(NOT ${input} STREQUAL ${output})
 282         if(NOT ${output} MATCHES ${BUILD_DIR})
 283             string(REPLACE ${SOURCE_DIR} ${BUILD_DIR} output ${output})
 284         endif()
 285
 286         set(ALL_ICONS ${ALL_ICONS} ${output})
 287
 288         get_filename_component(output_path ${output} PATH)
 289         file(MAKE_DIRECTORY ${output_path})
 290
 291         add_custom_command(
 292             COMMAND ${CONVERT_EXECUTABLE} ${input} ${ARGN} ${output}
 293             OUTPUT  ${output}
 294             DEPENDS ${input}
 295             VERBATIM)
 296     endif()
 297 endmacro()
 298
 299 foreach(icon ${ALL_ICONS})
 300     # Make unfocused icons translucent
 301     a_icon_convert("_focus" "_normal" ${icon}
 302         -gamma 0.6 -channel A -evaluate Multiply 0.4)
 303 endforeach()
 304
 305 foreach(icon ${ALL_ICONS})
 306     # Make inactive icons grayscale
 307     a_icon_convert("_active" "_inactive" ${icon}
 308         -colorspace Gray)
 309 endforeach()
 310
 311 add_custom_target(generated_icons ALL DEPENDS ${ALL_ICONS})
 312 # }}}
 313
 314 # {{{ Dist tarball
 315 if(BUILD_FROM_GIT)
 316     add_custom_target(dist
 317         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 318         WORKING_DIRECTORY ${SOURCE_DIR})
 319 endif()
 320 # }}}
 321
 322 # {{{ Installation
 323 install(TARGETS ${PROJECT_AWE_NAME} RUNTIME DESTINATION bin)
 324 install(FILES "utils/awsetbg" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 325 install(FILES "utils/awesome-client" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 326 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH})
 327 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 328         RENAME ${AWE_CONF_FILE})
 329 if(GENERATE_MANPAGES)
 330     install(FILES ${AWE_MAN1_FILES} DESTINATION ${AWESOME_MAN_PATH}/man1)
 331     install(FILES ${AWE_MAN5_FILES} DESTINATION ${AWESOME_MAN_PATH}/man5)
 332 endif()
 333 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 334 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH})
 335 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 336     PATTERN "*.in" EXCLUDE)
 337 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 338 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 339 if(GENERATE_LUADOC)
 340     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 341 endif()
 342 # }}}
 343
 344 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80