configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoreconf to produce a configure script.
   3
   4 AC_PREREQ(2.61)
   5 dnl Each time you want an updated version number for your build, you need to
   6 dnl (re-)run autoreconf.
   7 AC_INIT([awesome window manager],
   8         [m4_esyscmd([./build-utils/package-version . version-stamp])],
   9         [http://awesome.naquadah.org/bugs/],
  10         [awesome])
  11 AC_CONFIG_AUX_DIR([auto-aux])
  12 AC_CONFIG_SRCDIR([awesome.c])
  13 dnl The AC_CONFIG_HEADER and awesome's own config.h are different beasts
  14 dnl AC_CONFIG_HEADER([config.h])
  15 dnl Other options:
  16 dnl    check-news   to check that NEWS has been adapted to current version
  17 AM_INIT_AUTOMAKE([
  18 -Wall -Werror
  19 1.10
  20 dist-bzip2
  21 filename-length-max=99
  22 foreign
  23 std-options
  24 subdir-objects
  25 ])
  26
  27 AC_DEFINE_UNQUOTED([AWESOME_RELEASE], ["Productivity Breaker"], [release code name])
  28
  29 AC_MSG_CHECKING([package version according to autoconf])
  30 AC_MSG_RESULT([${PACKAGE_VERSION}])
  31 AC_MSG_CHECKING([package version according to version script])
  32 version_script=`"${srcdir}/build-utils/package-version" "${srcdir}" version-stamp`
  33 AC_MSG_RESULT([${version_script}])
  34
  35 # Checks for programs.
  36 AC_PROG_SED
  37 AC_PROG_CC
  38 AM_PROG_CC_C_O
  39 AC_PROG_INSTALL
  40
  41 AC_ARG_VAR([ASCIIDOC], [asciidoc doc generation tool])
  42 AC_ARG_VAR([XMLTO], [xmlto converter from xml to other formats])
  43 AC_ARG_VAR([DOXYGEN], [doxygen source documentation system])
  44
  45 test "x$ASCIIDOC" = "x"  && AC_PATH_PROG([ASCIIDOC], [asciidoc], [:])
  46 test "x$XMLTO"    = "x"  && AC_PATH_PROG([XMLTO], [xmlto], [:])
  47 test "x$DOXYGEN"  = "x"  && AC_PATH_PROG([DOXYGEN], [doxygen], [:])
  48
  49 test "x$ASCIIDOC" = "x:" && AC_MSG_WARN([awesome requires asciidoc])
  50 test "x$XMLTO"    = "x:" && AC_MSG_WARN([awesome requires xmlto])
  51 test "x$DOXYGEN"  = "x:" && AC_MSG_WARN([awesome requires doxygen])
  52
  53 AM_CONDITIONAL([HAVE_ASCIIDOC], [test "x$ASCIIDOC" != "x:"])
  54 AM_CONDITIONAL([HAVE_XMLTO],    [test "x$XMLTO"    != "x:"])
  55 AM_CONDITIONAL([HAVE_DOXYGEN],  [test "x$DOXYGEN"  != "x:"])
  56
  57 AM_CONDITIONAL([USING_GCC], [test "x$GCC" = "xyes"])
  58
  59 AC_CANONICAL_HOST
  60 AC_DEFINE_UNQUOTED([AWESOME_COMPILE_MACHINE], ["$host"], [build for this machine])
  61
  62 AC_DEFINE_UNQUOTED([AWESOME_COMPILE_HOSTNAME], ["${ac_hostname}"], [build host])
  63
  64 AC_ARG_VAR([WHOAMI], [whoami(1) command])
  65 AC_PATH_PROG([WHOAMI], [whoami], [false])
  66 AS_IF([test "x$WHOAMI" = "xfalse"], [aw_whoami="???"], [aw_whoami=`$WHOAMI`])
  67 AC_DEFINE_UNQUOTED([AWESOME_COMPILE_BY], ["$aw_whoami"], [build user])
  68
  69 # Checks for libraries.
  70 AC_PATH_XTRA
  71 PKG_CHECK_MODULES([CAIRO], [cairo],,
  72    [AC_MSG_ERROR([awesome requires cairo.])])
  73 PKG_CHECK_MODULES([CONFUSE], [libconfuse >= 2.6],,
  74    [AC_MSG_ERROR([awesome requires libconfuse >= 2.6.])])
  75 PKG_CHECK_MODULES([XFT], [xft],,
  76    [AC_MSG_ERROR([awesome requires xft.])])
  77 PKG_CHECK_MODULES([XINERAMA], [xinerama],,
  78    [AC_MSG_ERROR([awesome requires Xinerama.])])
  79 PKG_CHECK_MODULES([XRANDR], [xrandr],,
  80    [AC_MSG_ERROR([awesome requires Xrandr.])])
  81
  82 # Checks for header files.
  83 AC_PATH_X
  84 AC_HEADER_STDC
  85 AC_HEADER_SYS_WAIT
  86 AC_CHECK_HEADERS([fcntl.h limits.h locale.h stdlib.h string.h sys/socket.h unistd.h])
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 AC_C_CONST
  90 AC_C_INLINE
  91 AC_TYPE_SIZE_T
  92 AC_TYPE_SSIZE_T
  93
  94 # Checks for library functions.
  95 AC_FUNC_FORK
  96 AC_FUNC_REALLOC
  97 AC_FUNC_SELECT_ARGTYPES
  98 AC_TYPE_SIGNAL
  99 AC_FUNC_VPRINTF
 100 AC_CHECK_FUNCS([memchr regcomp select setenv socket strchr strrchr strstr])
 101
 102 AC_CONFIG_FILES([Makefile])
 103 AC_CONFIG_FILES([awesome.doxygen])
 104 AC_OUTPUT