CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  21     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  23
  24 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua)
  25
  26 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  27 set(AWE_CONF_FILE rc.lua)
  28
  29 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  30 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  31
  32 set(AWE_DOC_FILES
  33     ${SOURCE_DIR}/AUTHORS
  34     ${SOURCE_DIR}/BUGS
  35     ${SOURCE_DIR}/README
  36     ${SOURCE_DIR}/LICENSE)
  37
  38 set(AWE_SRCS
  39     ${SOURCE_DIR}/awesome.c
  40     ${SOURCE_DIR}/client.c
  41     ${SOURCE_DIR}/dbus.c
  42     ${SOURCE_DIR}/root.c
  43     ${SOURCE_DIR}/event.c
  44     ${SOURCE_DIR}/property.c
  45     ${SOURCE_DIR}/ewmh.c
  46     ${SOURCE_DIR}/key.c
  47     ${SOURCE_DIR}/keygrabber.c
  48     ${SOURCE_DIR}/mousegrabber.c
  49     ${SOURCE_DIR}/banning.c
  50     ${SOURCE_DIR}/luaa.c
  51     ${SOURCE_DIR}/spawn.c
  52     ${SOURCE_DIR}/hooks.c
  53     ${SOURCE_DIR}/mouse.c
  54     ${SOURCE_DIR}/button.c
  55     ${SOURCE_DIR}/screen.c
  56     ${SOURCE_DIR}/stack.c
  57     ${SOURCE_DIR}/selection.c
  58     ${SOURCE_DIR}/wibox.c
  59     ${SOURCE_DIR}/systray.c
  60     ${SOURCE_DIR}/tag.c
  61     ${SOURCE_DIR}/titlebar.c
  62     ${SOURCE_DIR}/widget.c
  63     ${SOURCE_DIR}/window.c
  64     ${SOURCE_DIR}/image.c
  65     ${SOURCE_DIR}/draw.c
  66     ${SOURCE_DIR}/color.c
  67     ${SOURCE_DIR}/common/buffer.c
  68     ${SOURCE_DIR}/common/atoms.c
  69     ${SOURCE_DIR}/common/util.c
  70     ${SOURCE_DIR}/common/version.c
  71     ${SOURCE_DIR}/common/xembed.c
  72     ${SOURCE_DIR}/common/xutil.c
  73     ${SOURCE_DIR}/common/xcursor.c
  74     ${SOURCE_DIR}/common/backtrace.c
  75     ${SOURCE_DIR}/common/luaobject.c
  76     ${SOURCE_DIR}/common/luaclass.c
  77     ${SOURCE_DIR}/widgets/graph.c
  78     ${SOURCE_DIR}/widgets/progressbar.c
  79     ${SOURCE_DIR}/widgets/textbox.c
  80     ${SOURCE_DIR}/widgets/systray.c
  81     ${SOURCE_DIR}/widgets/imagebox.c)
  82
  83 set(AWE_MAN_SRCS
  84     ${SOURCE_DIR}/manpages/awesome.1.txt
  85     ${SOURCE_DIR}/manpages/awsetbg.1.txt
  86     ${SOURCE_DIR}/manpages/awesome-client.1.txt
  87     ${SOURCE_DIR}/manpages/awesomerc.5.txt)
  88
  89 add_executable(${PROJECT_AWE_NAME}
  90     ${AWE_SRCS}
  91     ${BUILD_DIR}/common/tokenize.c)
  92
  93 set_target_properties(${PROJECT_AWE_NAME}
  94     PROPERTIES
  95     LINK_FLAGS -export-dynamic)
  96
  97 target_link_libraries(${PROJECT_AWE_NAME}
  98     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
  99     ${AWESOME_REQUIRED_LIBRARIES}
 100     ${AWESOME_OPTIONAL_LIBRARIES})
 101
 102 # atoms
 103 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 104 add_custom_command(
 105     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 106     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 107     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 108     WORKING_DIRECTORY ${SOURCE_DIR}
 109     DEPENDS ${SOURCE_DIR}/common/atoms.list
 110     COMMENT "Generating atoms-extern.h"
 111     VERBATIM)
 112
 113 add_custom_command(
 114     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 115     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 116     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 117     WORKING_DIRECTORY ${SOURCE_DIR}
 118     DEPENDS ${SOURCE_DIR}/common/atoms.list
 119     COMMENT "Generating atoms-intern.h"
 120     VERBATIM)
 121
 122 # gperf
 123 add_custom_command(
 124     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 125     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 126             ${BUILD_DIR}/common/tokenize.h
 127     OUTPUT  ${BUILD_DIR}/common/tokenize.h
 128     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 129             ${SOURCE_DIR}/build-utils/gperf.sh
 130     COMMENT "Generating common/tokenize.h")
 131
 132 add_custom_command(
 133     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 134     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 135             ${BUILD_DIR}/common/tokenize.c
 136     OUTPUT  ${BUILD_DIR}/common/tokenize.c
 137     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 138             ${SOURCE_DIR}/build-utils/gperf.sh
 139     COMMENT "Generating common/tokenize.c")
 140
 141 add_custom_target(generated_sources
 142     DEPENDS ${BUILD_DIR}/common/atoms-intern.h
 143             ${BUILD_DIR}/common/atoms-extern.h
 144             ${BUILD_DIR}/common/tokenize.c
 145             ${BUILD_DIR}/common/tokenize.h)
 146
 147 # Default theme directory
 148 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 149 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/sky)
 150 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 151 # }}}
 152
 153 # {{{ Version stamp
 154 if(BUILD_FROM_GIT)
 155     add_custom_target(version_stamp ALL
 156         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 157                 ${VERSION_STAMP_FILE}
 158                 ${BUILD_DIR}/awesome-version-internal.h
 159         WORKING_DIRECTORY ${SOURCE_DIR})
 160
 161     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 162 endif()
 163 # }}}
 164
 165 # {{{ Manpages
 166 if(GENERATE_MANPAGES)
 167     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 168         file(MAKE_DIRECTORY ${BUILD_DIR}/manpages)
 169     endif()
 170     foreach(txtfile ${AWE_MAN_SRCS})
 171         string(REGEX REPLACE ".txt\$" ".xml" xmlfile ${txtfile})
 172         string(REPLACE ${SOURCE_DIR}
 173                        ${BUILD_DIR} xmlfile ${xmlfile})
 174         string(REGEX REPLACE ".xml\$" ".gz" gzfile ${xmlfile})
 175         string(REGEX REPLACE ".gz\$" "" manfile ${gzfile})
 176
 177         add_custom_command(
 178             COMMAND ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} - < ${txtfile}
 179             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 180             OUTPUT  ${xmlfile}
 181             DEPENDS ${txtfile}
 182             VERBATIM)
 183         add_custom_command(
 184             COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 185             OUTPUT  ${manfile}
 186             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 187             DEPENDS ${xmlfile})
 188         add_custom_command(
 189             COMMAND ${GZIP_EXECUTABLE} < ${manfile} > ${gzfile}
 190             OUTPUT  ${gzfile}
 191             WORKING_DIRECTORY ${BUILD_DIR}/manpages
 192             DEPENDS ${manfile}
 193             VERBATIM)
 194
 195         set(MAN_FILES ${MAN_FILES} ${gzfile})
 196
 197         # figure out in what section to install to from filename
 198         string(REGEX REPLACE "^.*\\.([0-9])\\.gz\$" "\\1" section ${gzfile})
 199         set(AWE_MAN${section}_FILES ${AWE_MAN${section}_FILES} ${gzfile})
 200     endforeach()
 201
 202     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 203 endif()
 204 # }}}
 205
 206 # {{{ Doxygen
 207 if(DOXYGEN_EXECUTABLE)
 208     add_custom_target(doc
 209         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 210         WORKING_DIRECTORY ${BUILD_DIR})
 211 endif()
 212 # }}}
 213
 214 # {{{ Lua API Documentation
 215 if(GENERATE_LUADOC)
 216
 217     set(capi_lua ${BUILD_DIR}/lib/capi.lua)
 218
 219     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 220         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 221     endif()
 222
 223     # {{{ setup a command for ${capi_lua}
 224     macro(a_file_match infile regex result_var)
 225         file(STRINGS ${infile} match REGEX ${regex} LIMIT_COUNT 1)
 226         if(match)
 227             set(${result_var} TRUE)
 228         else()
 229             set(${result_var} FALSE)
 230         endif()
 231     endmacro()
 232
 233     set(luadoc_c_srcs "")
 234
 235     # find .c files exporting lua functions
 236     foreach(cfile ${AWE_SRCS})
 237         a_file_match(${cfile} "const struct luaL_reg" result)
 238         if(result)
 239             set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 240         else()
 241             a_file_match(${cfile} "luaA_.*_index" result)
 242             if(result)
 243                 set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 244         endif()
 245         endif()
 246     endforeach()
 247
 248     # create fake lua source file to process by luadoc
 249     add_custom_command(
 250         COMMAND ${CAT_EXECUTABLE} ${luadoc_c_srcs}
 251                 | ${LUA_EXECUTABLE} ${SOURCE_DIR}/build-utils/fake-lua-src.lua
 252                 > ${capi_lua}
 253         OUTPUT  ${capi_lua}
 254         DEPENDS ${luadoc_c_srcs}
 255         COMMENT "Generating fake lua source."
 256         VERBATIM)
 257     # }}}
 258
 259     # Generate documentation of lib//0lua
 260     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua)
 261     foreach(filename ${lua_lib_files})
 262         file(RELATIVE_PATH filename ${BUILD_DIR}/lib ${filename})
 263         set(luadoc_srcs ${luadoc_srcs} ${filename})
 264     endforeach()
 265
 266     add_custom_target(luadoc ALL
 267         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc
 268         WORKING_DIRECTORY ${BUILD_DIR}/lib
 269         DEPENDS ${AWE_LUA_FILES} ${capi_lua})
 270 endif()
 271 # }}}
 272
 273 # {{{ Theme icons
 274 file(GLOB icon_sources ${SOURCE_DIR}/themes/*/titlebar/*.png)
 275 set(ALL_ICONS ${icon_sources})
 276
 277 macro(a_icon_convert match replacement input)
 278     string(REPLACE ${match} ${replacement} output ${input})
 279
 280     if(NOT ${input} STREQUAL ${output})
 281         if(NOT ${output} MATCHES ${BUILD_DIR})
 282             string(REPLACE ${SOURCE_DIR} ${BUILD_DIR} output ${output})
 283         endif()
 284
 285         set(ALL_ICONS ${ALL_ICONS} ${output})
 286
 287         get_filename_component(output_path ${output} PATH)
 288         file(MAKE_DIRECTORY ${output_path})
 289
 290         add_custom_command(
 291             COMMAND ${CONVERT_EXECUTABLE} ${input} ${ARGN} ${output}
 292             OUTPUT  ${output}
 293             DEPENDS ${input}
 294             VERBATIM)
 295     endif()
 296 endmacro()
 297
 298 foreach(icon ${ALL_ICONS})
 299     # Make unfocused icons translucent
 300     a_icon_convert("_focus" "_normal" ${icon}
 301         -gamma 0.6 -channel A -evaluate Multiply 0.4)
 302 endforeach()
 303
 304 foreach(icon ${ALL_ICONS})
 305     # Make inactive icons grayscale
 306     a_icon_convert("_active" "_inactive" ${icon}
 307         -colorspace Gray)
 308 endforeach()
 309
 310 add_custom_target(generated_icons ALL DEPENDS ${ALL_ICONS})
 311 # }}}
 312
 313 # {{{ Dist tarball
 314 if(BUILD_FROM_GIT)
 315     add_custom_target(dist
 316         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 317         WORKING_DIRECTORY ${SOURCE_DIR})
 318 endif()
 319 # }}}
 320
 321 # {{{ Installation
 322 install(TARGETS ${PROJECT_AWE_NAME} RUNTIME DESTINATION bin)
 323 install(FILES "utils/awsetbg" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 324 install(FILES "utils/awesome-client" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 325 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH})
 326 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 327         RENAME ${AWE_CONF_FILE})
 328 if(GENERATE_MANPAGES)
 329     install(FILES ${AWE_MAN1_FILES} DESTINATION ${AWESOME_MAN_PATH}/man1)
 330     install(FILES ${AWE_MAN5_FILES} DESTINATION ${AWESOME_MAN_PATH}/man5)
 331 endif()
 332 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 333 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH})
 334 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 335     PATTERN "*.in" EXCLUDE)
 336 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 337 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 338 if(GENERATE_LUADOC)
 339     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 340 endif()
 341 # }}}
 342
 343 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80