CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${BUILD_DIR}/common
  21     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  23     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  24
  25 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua)
  26
  27 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  28 set(AWE_CONF_FILE rc.lua)
  29
  30 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  31 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  32
  33 set(AWE_DOC_FILES
  34     ${SOURCE_DIR}/AUTHORS
  35     ${SOURCE_DIR}/BUGS
  36     ${SOURCE_DIR}/README
  37     ${SOURCE_DIR}/LICENSE)
  38
  39 set(AWE_SRCS
  40     ${SOURCE_DIR}/awesome.c
  41     ${SOURCE_DIR}/client.c
  42     ${SOURCE_DIR}/cnode.c
  43     ${SOURCE_DIR}/dbus.c
  44     ${SOURCE_DIR}/event.c
  45     ${SOURCE_DIR}/property.c
  46     ${SOURCE_DIR}/ewmh.c
  47     ${SOURCE_DIR}/keybinding.c
  48     ${SOURCE_DIR}/keygrabber.c
  49     ${SOURCE_DIR}/layout.c
  50     ${SOURCE_DIR}/luaa.c
  51     ${SOURCE_DIR}/hooks.c
  52     ${SOURCE_DIR}/mouse.c
  53     ${SOURCE_DIR}/screen.c
  54     ${SOURCE_DIR}/stack.c
  55     ${SOURCE_DIR}/statusbar.c
  56     ${SOURCE_DIR}/wibox.c
  57     ${SOURCE_DIR}/systray.c
  58     ${SOURCE_DIR}/tag.c
  59     ${SOURCE_DIR}/titlebar.c
  60     ${SOURCE_DIR}/widget.c
  61     ${SOURCE_DIR}/window.c
  62     ${SOURCE_DIR}/image.c
  63     ${SOURCE_DIR}/draw.c
  64     ${SOURCE_DIR}/swindow.c
  65     ${SOURCE_DIR}/common/buffer.c
  66     ${SOURCE_DIR}/common/atoms.c
  67     ${SOURCE_DIR}/common/markup.c
  68     ${SOURCE_DIR}/common/socket.c
  69     ${SOURCE_DIR}/common/util.c
  70     ${SOURCE_DIR}/common/version.c
  71     ${SOURCE_DIR}/common/xembed.c
  72     ${SOURCE_DIR}/common/xutil.c
  73     ${SOURCE_DIR}/layouts/fibonacci.c
  74     ${SOURCE_DIR}/layouts/floating.c
  75     ${SOURCE_DIR}/layouts/magnifier.c
  76     ${SOURCE_DIR}/layouts/fair.c
  77     ${SOURCE_DIR}/layouts/max.c
  78     ${SOURCE_DIR}/layouts/tile.c
  79     ${SOURCE_DIR}/widgets/graph.c
  80     ${SOURCE_DIR}/widgets/progressbar.c
  81     ${SOURCE_DIR}/widgets/textbox.c
  82     ${SOURCE_DIR}/widgets/systray.c
  83     ${SOURCE_DIR}/widgets/imagebox.c)
  84
  85 set(AWE_CLIENT_SRCS
  86     ${SOURCE_DIR}/awesome-client.c
  87     ${SOURCE_DIR}/common/socket.c
  88     ${SOURCE_DIR}/common/util.c
  89     ${SOURCE_DIR}/common/version.c)
  90
  91 set(AWE_MAN_SRCS
  92     ${SOURCE_DIR}/awesome.1.txt
  93     ${SOURCE_DIR}/awesome-client.1.txt
  94     ${SOURCE_DIR}/awesomerc.5.txt)
  95
  96 add_executable(${PROJECT_AWE_NAME}
  97     ${AWE_SRCS}
  98     ${BUILD_DIR}/common/tokenize.c)
  99
 100 add_executable(${PROJECT_AWECLIENT_NAME}
 101     ${AWE_CLIENT_SRCS}
 102     ${BUILD_DIR}/common/tokenize.c)
 103
 104 set_target_properties(${PROJECT_AWE_NAME}
 105     PROPERTIES
 106     LINK_FLAGS -export-dynamic)
 107
 108 target_link_libraries(${PROJECT_AWE_NAME}
 109     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 110     ${AWESOME_REQUIRED_LIBRARIES}
 111     ${AWESOME_OPTIONAL_LIBRARIES})
 112
 113 target_link_libraries(${PROJECT_AWECLIENT_NAME}
 114     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 115     ${AWESOMECLIENT_LIBRARIES})
 116
 117 # {{{ Generated sources
 118 file(GLOB LAYOUTGEN_DEPS ${SOURCE_DIR}/layouts/*.h)
 119 add_custom_command(
 120     COMMAND ${SOURCE_DIR}/build-utils/layoutgen.sh
 121     ARGS    > ${BUILD_DIR}/layoutgen.h
 122     OUTPUT  ${BUILD_DIR}/layoutgen.h
 123     WORKING_DIRECTORY ${SOURCE_DIR}
 124     DEPENDS ${LAYOUTGEN_DEPS}
 125     COMMENT "Generating layoutgen.h"
 126     VERBATIM)
 127
 128 add_custom_command(
 129     COMMAND ${SOURCE_DIR}/build-utils/widgetgen.sh
 130     ARGS    > ${BUILD_DIR}/widgetgen.h
 131     OUTPUT  ${BUILD_DIR}/widgetgen.h
 132     WORKING_DIRECTORY ${SOURCE_DIR}
 133     DEPENDS ${SOURCE_DIR}/widget.h
 134     COMMENT "Generating widgetgen.h"
 135     VERBATIM)
 136
 137 # atoms
 138 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 139 add_custom_command(
 140     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 141     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 142     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 143     WORKING_DIRECTORY ${SOURCE_DIR}
 144     DEPENDS ${SOURCE_DIR}/common/atoms.list
 145     COMMENT "Generating atoms-extern.h"
 146     VERBATIM)
 147
 148 add_custom_command(
 149     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 150     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 151     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 152     WORKING_DIRECTORY ${SOURCE_DIR}
 153     DEPENDS ${SOURCE_DIR}/common/atoms.list
 154     COMMENT "Generating atoms-intern.h"
 155     VERBATIM)
 156
 157 # gperf
 158 add_custom_command(
 159     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 160     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 161             ${BUILD_DIR}/common/tokenize.h
 162     OUTPUT  ${BUILD_DIR}/common/tokenize.h
 163     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 164             ${SOURCE_DIR}/build-utils/gperf.sh
 165     COMMENT "Generating common/tokenize.h")
 166
 167 add_custom_command(
 168     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 169     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 170             ${BUILD_DIR}/common/tokenize.c
 171     OUTPUT  ${BUILD_DIR}/common/tokenize.c
 172     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 173             ${SOURCE_DIR}/build-utils/gperf.sh
 174     COMMENT "Generating common/tokenize.c")
 175
 176 add_custom_target(generated_sources
 177     DEPENDS ${BUILD_DIR}/widgetgen.h
 178             ${BUILD_DIR}/layoutgen.h
 179             ${BUILD_DIR}/common/atoms-intern.h
 180             ${BUILD_DIR}/common/atoms-extern.h
 181             ${BUILD_DIR}/common/tokenize.c
 182             ${BUILD_DIR}/common/tokenize.h)
 183
 184 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 185 add_dependencies(${PROJECT_AWECLIENT_NAME} generated_sources)
 186 # }}}
 187
 188 # {{{ Version stamp
 189 if(BUILD_FROM_GIT)
 190     add_custom_target(version_stamp ALL
 191         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 192                 ${VERSION_STAMP_FILE}
 193                 ${BUILD_DIR}/awesome-version-internal.h
 194         WORKING_DIRECTORY ${SOURCE_DIR})
 195
 196     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 197     add_dependencies(${PROJECT_AWECLIENT_NAME} version_stamp)
 198 endif()
 199 # }}}
 200
 201 # {{{ Manpages
 202 if(GENERATE_MANPAGES)
 203     foreach(txtfile ${AWE_MAN_SRCS})
 204         string(REGEX REPLACE ".txt\$" ".xml" xmlfile ${txtfile})
 205         string(REPLACE ${SOURCE_DIR}
 206                        ${BUILD_DIR} xmlfile ${xmlfile})
 207         string(REGEX REPLACE ".xml\$" ".gz" gzfile ${xmlfile})
 208         string(REGEX REPLACE ".gz\$" "" manfile ${gzfile})
 209
 210         add_custom_command(
 211             COMMAND ${CAT_EXECUTABLE} ${txtfile}
 212                     | ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} -
 213             WORKING_DIRECTORY ${BUILD_DIR}
 214             OUTPUT  ${xmlfile}
 215             DEPENDS ${txtfile}
 216             VERBATIM)
 217         add_custom_command(
 218             COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 219             OUTPUT  ${manfile}
 220             DEPENDS ${xmlfile})
 221         add_custom_command(
 222             COMMAND ${CAT_EXECUTABLE} ${manfile}
 223                     | ${GZIP_EXECUTABLE}
 224                     > ${gzfile}
 225             OUTPUT  ${gzfile}
 226             DEPENDS ${manfile}
 227             VERBATIM)
 228
 229         set(MAN_FILES ${MAN_FILES} ${gzfile})
 230
 231         # figure out in what section to install to from filename
 232         string(REGEX REPLACE "^.*\\.([0-9])\\.gz\$" "\\1" section ${gzfile})
 233         set(AWE_MAN${section}_FILES ${AWE_MAN${section}_FILES} ${gzfile})
 234     endforeach()
 235
 236     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 237 endif()
 238 # }}}
 239
 240 # {{{ Doxygen
 241 if(DOXYGEN_EXECUTABLE)
 242     add_custom_target(doc
 243         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 244         WORKING_DIRECTORY ${BUILD_DIR})
 245 endif()
 246 # }}}
 247
 248 # {{{ Lua API Documentation
 249 if(GENERATE_LUADOC)
 250
 251     set(capi_lua ${BUILD_DIR}/lib/capi.lua)
 252
 253     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 254         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 255     endif()
 256
 257     # {{{ setup a command for ${capi_lua}
 258     macro(a_file_match infile regex result_var)
 259         file(STRINGS ${infile} match REGEX ${regex} LIMIT_COUNT 1)
 260         if(match)
 261             set(${result_var} TRUE)
 262         else()
 263             set(${result_var} FALSE)
 264         endif()
 265     endmacro()
 266
 267     set(luadoc_c_srcs "")
 268
 269     # find .c files exporting lua functions
 270     foreach(cfile ${AWE_SRCS})
 271         a_file_match(${cfile} "const struct luaL_reg" result)
 272         if(result)
 273             set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 274         else()
 275             a_file_match(${cfile} "luaA_.*_index" result)
 276             if(result)
 277                 set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 278         endif()
 279         endif()
 280     endforeach()
 281
 282     # create fake lua source file to process by luadoc
 283     add_custom_command(
 284         COMMAND ${CAT_EXECUTABLE} ${luadoc_c_srcs}
 285                 | ${LUA_EXECUTABLE} ${SOURCE_DIR}/build-utils/fake-lua-src.lua
 286                 > ${capi_lua}
 287         OUTPUT  ${capi_lua}
 288         DEPENDS ${luadoc_c_srcs}
 289         COMMENT "Generating fake lua source."
 290         VERBATIM)
 291     # }}}
 292
 293     # Generate documentation of lib//0lua
 294     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua)
 295     foreach(filename ${lua_lib_files})
 296         file(RELATIVE_PATH filename ${BUILD_DIR}/lib ${filename})
 297         set(luadoc_srcs ${luadoc_srcs} ${filename})
 298     endforeach()
 299
 300     add_custom_target(luadoc ALL
 301         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc
 302         WORKING_DIRECTORY ${BUILD_DIR}/lib
 303         DEPENDS ${AWE_LUA_FILES} ${capi_lua})
 304 endif()
 305 # }}}
 306
 307 # {{{ Dist tarball
 308 if(BUILD_FROM_GIT)
 309     add_custom_target(dist
 310         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 311         WORKING_DIRECTORY ${SOURCE_DIR})
 312 endif()
 313 # }}}
 314
 315 # {{{ Installation
 316 install(TARGETS ${PROJECT_AWE_NAME} ${PROJECT_AWECLIENT_NAME} RUNTIME DESTINATION bin)
 317 install(FILES "utils/awsetbg" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 318 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH})
 319 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 320         RENAME ${AWE_CONF_FILE})
 321 if(GENERATE_MANPAGES)
 322     install(FILES ${AWE_MAN1_FILES} DESTINATION ${AWESOME_MAN_PATH}/man1)
 323     install(FILES ${AWE_MAN5_FILES} DESTINATION ${AWESOME_MAN_PATH}/man5)
 324 endif()
 325 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 326 install(FILES ${AWE_THEMES_DIR}/default-background.png ${BUILD_DIR}/themes/default DESTINATION ${AWESOME_THEMES_PATH})
 327 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 328 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 329 if(GENERATE_LUADOC)
 330     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 331 endif()
 332 # }}}
 333
 334 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80