awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2
   3 # If ${SOURCE_DIR} is a git repository VERSION is set to
   4 # `git describe` later.
   5 set(VERSION devel)
   6
   7 set(CODENAME "The Fox")
   8
   9 project(${PROJECT_AWE_NAME} C)
  10
  11 set(CMAKE_BUILD_TYPE RELEASE)
  12
  13 option(WITH_DBUS "build with D-BUS" ON)
  14 option(GENERATE_MANPAGES "generate manpages" ON)
  15 option(COMPRESS_MANPAGES "compress manpages" ON)
  16 option(GENERATE_DOC "generate API documentation" ON)
  17
  18 # {{{ CFLAGS
  19 add_definitions(-O1 -std=gnu99 -ggdb3 -rdynamic -fno-strict-aliasing -Wall -Wextra
  20     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  21     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  22     -Wpointer-arith -Wformat-nonliteral
  23     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  24     -Wstrict-prototypes)
  25 # }}}
  26
  27 # {{{ Endianness
  28 include(TestBigEndian)
  29 TEST_BIG_ENDIAN(AWESOME_IS_BIG_ENDIAN)
  30 # }}}
  31
  32 # {{{ Find external utilities
  33 macro(a_find_program var prg req)
  34     set(required ${req})
  35     find_program(${var} ${prg})
  36     if(NOT ${var})
  37         message(STATUS "${prg} not found.")
  38         if(required)
  39             message(FATAL_ERROR "${prg} is required to build awesome")
  40         endif()
  41     else()
  42         message(STATUS "${prg} -> ${${var}}")
  43     endif()
  44 endmacro()
  45
  46 a_find_program(GIT_EXECUTABLE git FALSE)
  47 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  48 # programs needed for man pages
  49 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  50 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  51 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  52 # lua documentation
  53 a_find_program(LDOC_EXECUTABLE ldoc FALSE)
  54 if(NOT LDOC_EXECUTABLE)
  55     a_find_program(LDOC_EXECUTABLE ldoc.lua FALSE)
  56 endif()
  57 # theme graphics
  58 a_find_program(CONVERT_EXECUTABLE convert TRUE)
  59 # doxygen
  60 include(FindDoxygen)
  61 # pkg-config
  62 include(FindPkgConfig)
  63 # lua 5.1
  64 include(FindLua51)
  65 # }}}
  66
  67 # {{{ Check if documentation can be build
  68 if(GENERATE_MANPAGES)
  69     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR (COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE))
  70         if(NOT ASCIIDOC_EXECUTABLE)
  71             SET(missing "asciidoc")
  72         endif()
  73         if(NOT XMLTO_EXECUTABLE)
  74             SET(missing ${missing} " xmlto")
  75         endif()
  76         if(COMPRESS_MANPAGES AND NOT GZIP_EXECUTABLE)
  77             SET(missing ${missing} " gzip")
  78         endif()
  79
  80         message(STATUS "Not generating manpages. Missing: " ${missing})
  81         set(GENERATE_MANPAGES OFF)
  82     endif()
  83 endif()
  84
  85 if(GENERATE_DOC)
  86     if(NOT LDOC_EXECUTABLE)
  87         message(STATUS "Not generating API documentation. Missing: ldoc")
  88         set(GENERATE_DOC OFF)
  89     endif()
  90 endif()
  91 # }}}
  92
  93 # {{{ Version stamp
  94 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
  95     # get current version
  96     execute_process(
  97         COMMAND ${GIT_EXECUTABLE} describe
  98         WORKING_DIRECTORY ${SOURCE_DIR}
  99         OUTPUT_VARIABLE VERSION
 100         OUTPUT_STRIP_TRAILING_WHITESPACE)
 101     # file the git-version-stamp.sh script will look into
 102     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 103     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 104     # create a version_stamp target later
 105     set(BUILD_FROM_GIT TRUE)
 106 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 107     # get version from version stamp
 108     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 109 endif()
 110 # }}}
 111
 112 # {{{ Get hostname
 113 execute_process(
 114     COMMAND ${HOSTNAME_EXECUTABLE}
 115     WORKING_DIRECTORY ${SOURCE_DIR}
 116     OUTPUT_VARIABLE BUILDHOSTNAME
 117     OUTPUT_STRIP_TRAILING_WHITESPACE)
 118 # }}}
 119
 120 # {{{ Required libraries
 121 #
 122 # this sets up:
 123 # AWESOME_REQUIRED_LDFLAGS
 124 # AWESOME_REQUIRED_INCLUDE_DIRS
 125
 126 # Use pkgconfig to get most of the libraries
 127 pkg_check_modules(AWESOME_COMMON_REQUIRED REQUIRED
 128     xcb>=1.6)
 129
 130 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 131     glib-2.0
 132     gdk-pixbuf-2.0
 133     cairo
 134     x11
 135     xcb-cursor
 136     xcb-randr
 137     xcb-xtest
 138     xcb-xinerama
 139     xcb-shape
 140     xcb-util>=0.3.8
 141     xcb-keysyms>=0.3.4
 142     xcb-icccm>=0.3.8
 143     cairo-xcb
 144     libstartup-notification-1.0>=0.10
 145     xproto>=7.0.15
 146     libxdg-basedir>=1.0.0)
 147
 148 if(NOT AWESOME_REQUIRED_FOUND OR NOT AWESOME_COMMON_REQUIRED_FOUND)
 149     message(FATAL_ERROR)
 150 endif()
 151
 152 macro(a_find_library variable library)
 153     find_library(${variable} ${library})
 154     if(NOT ${variable})
 155         message(FATAL_ERROR ${library} " library not found.")
 156     endif()
 157 endmacro()
 158
 159 # Check for backtrace_symbols()
 160 include(CheckFunctionExists)
 161 check_function_exists(backtrace_symbols HAS_EXECINFO)
 162 if(NOT HAS_EXECINFO)
 163     find_library(LIB_EXECINFO execinfo)
 164     if(LIB_EXECINFO)
 165         set(HAS_EXECINFO 1)
 166         set(AWESOME_REQUIRED_LDFLAGS
 167             ${AWESOME_REQUIRED_LDFLAGS}
 168             ${LIB_EXECINFO})
 169     endif()
 170 endif()
 171 if(HAS_EXECINFO)
 172     message(STATUS "checking for execinfo -- found")
 173 else()
 174     message(STATUS "checking for execinfo -- not found")
 175 endif()
 176
 177 # __builtin_clz is available since gcc 3.4
 178 try_compile(HAS___BUILTIN_CLZ
 179     ${CMAKE_BINARY_DIR}
 180     ${CMAKE_SOURCE_DIR}/build-tests/__builtin_clz.c)
 181 if(HAS___BUILTIN_CLZ)
 182     message(STATUS "checking for __builtin_clz -- yes")
 183 else()
 184     message(STATUS "checking for __builtin_clz -- no")
 185 endif()
 186
 187 # Error check
 188 if(NOT LUA51_FOUND AND NOT LUA50_FOUND) # This is a workaround to a cmake bug
 189     message(FATAL_ERROR "lua library not found")
 190 endif()
 191
 192 set(AWESOME_REQUIRED_LDFLAGS
 193     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 194     ${AWESOME_REQUIRED_LDFLAGS}
 195     ${LUA_LIBRARIES})
 196
 197 set(AWESOME_REQUIRED_INCLUDE_DIRS
 198     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
 199     ${AWESOME_REQUIRED_INCLUDE_DIRS}
 200     ${LUA_INCLUDE_DIR})
 201 # }}}
 202
 203 # {{{ Optional libraries
 204 #
 205 # this sets up:
 206 # AWESOME_OPTIONAL_LDFLAGS
 207 # AWESOME_OPTIONAL_INCLUDE_DIRS
 208
 209 if(WITH_DBUS)
 210     pkg_check_modules(DBUS dbus-1)
 211     if(DBUS_FOUND)
 212         set(AWESOME_OPTIONAL_LDFLAGS ${AWESOME_OPTIONAL_LDFLAGS} ${DBUS_LDFLAGS})
 213         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 214     else()
 215         set(WITH_DBUS OFF)
 216         message(STATUS "DBUS not found. Disabled.")
 217     endif()
 218 endif()
 219 # }}}
 220
 221 # {{{ Install path and configuration variables
 222 #If a sysconfdir is specified, use it instead
 223 #of the default configuration dir.
 224 if(DEFINED SYSCONFDIR)
 225     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 226 else()
 227     set(SYSCONFDIR ${CMAKE_INSTALL_PREFIX}/etc CACHE PATH "config directory")
 228 endif()
 229
 230 #If an XDG Config Dir is specificed, use it instead
 231 #of the default XDG configuration dir.
 232 if(DEFINED XDG_CONFIG_DIR)
 233     set(XDG_CONFIG_DIR ${XDG_CONFIG_DIR} CACHE PATH "xdg config directory")
 234 else()
 235     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 236 endif()
 237
 238 # setting AWESOME_DOC_PATH
 239 if(DEFINED AWESOME_DOC_PATH)
 240     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 241 else()
 242     set(AWESOME_DOC_PATH ${CMAKE_INSTALL_PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 243 endif()
 244
 245 # setting AWESOME_XSESSION_PATH
 246 if(DEFINED AWESOME_XSESSION_PATH)
 247     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 248 else()
 249     set(AWESOME_XSESSION_PATH ${CMAKE_INSTALL_PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 250 endif()
 251
 252 # set man path
 253 if(DEFINED AWESOME_MAN_PATH)
 254    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 255 else()
 256    set(AWESOME_MAN_PATH ${CMAKE_INSTALL_PREFIX}/share/man CACHE PATH "awesome manpage directory")
 257 endif()
 258
 259 # Hide to avoid confusion
 260 mark_as_advanced(CMAKE_INSTALL_CMAKE_INSTALL_PREFIX)
 261
 262 set(AWESOME_VERSION          ${VERSION})
 263 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 264 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 265 set(AWESOME_COMPILE_BY       $ENV{USER})
 266 set(AWESOME_RELEASE          ${CODENAME})
 267 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 268 set(AWESOME_DATA_PATH        ${CMAKE_INSTALL_PREFIX}/share/${PROJECT_AWE_NAME})
 269 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 270 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 271 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 272 # }}}
 273
 274 # {{{ Configure files
 275 file(GLOB_RECURSE awesome_lua_configure_files RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/lib/*.lua.in ${SOURCE_DIR}/themes/*/*.lua.in)
 276 set(AWESOME_CONFIGURE_FILES
 277     ${awesome_lua_configure_files}
 278     config.h.in
 279     config.ld.in
 280     awesomerc.lua.in
 281     awesome-version-internal.h.in
 282     awesome.doxygen.in)
 283
 284 macro(a_configure_file file)
 285     string(REGEX REPLACE ".in\$" "" outfile ${file})
 286     message(STATUS "Configuring ${outfile}")
 287     configure_file(${SOURCE_DIR}/${file}
 288                    ${BUILD_DIR}/${outfile}
 289                    ESCAPE_QUOTE
 290                    @ONLY)
 291 endmacro()
 292
 293 foreach(file ${AWESOME_CONFIGURE_FILES})
 294     a_configure_file(${file})
 295 endforeach()
 296 #}}}
 297
 298 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80