CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  21     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  23
  24 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  25 set(AWE_CONF_FILE rc.lua)
  26
  27 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  28 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  29
  30 set(AWE_DOC_FILES
  31     ${SOURCE_DIR}/AUTHORS
  32     ${SOURCE_DIR}/BUGS
  33     ${SOURCE_DIR}/README.md
  34     ${SOURCE_DIR}/LICENSE)
  35
  36 set(AWE_SRCS
  37     ${SOURCE_DIR}/awesome.c
  38     ${SOURCE_DIR}/banning.c
  39     ${SOURCE_DIR}/color.c
  40     ${SOURCE_DIR}/dbus.c
  41     ${SOURCE_DIR}/draw.c
  42     ${SOURCE_DIR}/event.c
  43     ${SOURCE_DIR}/ewmh.c
  44     ${SOURCE_DIR}/keygrabber.c
  45     ${SOURCE_DIR}/keyresolv.c
  46     ${SOURCE_DIR}/luaa.c
  47     ${SOURCE_DIR}/mouse.c
  48     ${SOURCE_DIR}/mousegrabber.c
  49     ${SOURCE_DIR}/property.c
  50     ${SOURCE_DIR}/root.c
  51     ${SOURCE_DIR}/selection.c
  52     ${SOURCE_DIR}/spawn.c
  53     ${SOURCE_DIR}/stack.c
  54     ${SOURCE_DIR}/strut.c
  55     ${SOURCE_DIR}/systray.c
  56     ${SOURCE_DIR}/xwindow.c
  57     ${SOURCE_DIR}/common/atoms.c
  58     ${SOURCE_DIR}/common/backtrace.c
  59     ${SOURCE_DIR}/common/buffer.c
  60     ${SOURCE_DIR}/common/luaclass.c
  61     ${SOURCE_DIR}/common/lualib.c
  62     ${SOURCE_DIR}/common/luaobject.c
  63     ${SOURCE_DIR}/common/util.c
  64     ${SOURCE_DIR}/common/version.c
  65     ${SOURCE_DIR}/common/xcursor.c
  66     ${SOURCE_DIR}/common/xembed.c
  67     ${SOURCE_DIR}/common/xutil.c
  68     ${SOURCE_DIR}/objects/button.c
  69     ${SOURCE_DIR}/objects/client.c
  70     ${SOURCE_DIR}/objects/drawable.c
  71     ${SOURCE_DIR}/objects/drawin.c
  72     ${SOURCE_DIR}/objects/key.c
  73     ${SOURCE_DIR}/objects/screen.c
  74     ${SOURCE_DIR}/objects/tag.c
  75     ${SOURCE_DIR}/objects/timer.c
  76     ${SOURCE_DIR}/objects/window.c)
  77
  78 set(AWE_MAN_SRCS
  79     ${SOURCE_DIR}/manpages/awesome.1.txt
  80     ${SOURCE_DIR}/manpages/awesome-client.1.txt
  81     ${SOURCE_DIR}/manpages/awesomerc.5.txt)
  82 set(AWE_MAN_LANGS it es fr de ru)
  83
  84 # Don't strip RPATH if compiling on Solaris
  85 if (${CMAKE_SYSTEM_NAME} MATCHES "SunOS")
  86     set(CMAKE_SKIP_BUILD_RPATH FALSE)
  87     set(CMAKE_BUILD_WITH_INSTALL_RPATH FALSE)
  88     set(CMAKE_INSTALL_RPATH_USE_LINK_PATH TRUE)
  89 endif()
  90
  91 add_executable(${PROJECT_AWE_NAME}
  92     ${AWE_SRCS})
  93
  94 # FreeBSD requires dynamic linking
  95 if(${CMAKE_SYSTEM_NAME} MATCHES "FreeBSD")
  96     set_target_properties(${PROJECT_AWE_NAME}
  97         PROPERTIES
  98         LINK_FLAGS -export-dynamic)
  99 endif()
 100
 101 target_link_libraries(${PROJECT_AWE_NAME}
 102     ${AWESOME_COMMON_REQUIRED_LDFLAGS}
 103     ${AWESOME_REQUIRED_LDFLAGS}
 104     ${AWESOME_OPTIONAL_LDFLAGS})
 105
 106 # check for lgi and the needed gobject introspection files
 107 add_custom_target(lgi-check ALL
 108     COMMAND ${SOURCE_DIR}/build-utils/lgi-check.sh)
 109
 110 # {{{ Generated sources
 111 # atoms
 112 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 113 add_custom_command(
 114     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 115     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 116     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 117     WORKING_DIRECTORY ${SOURCE_DIR}
 118     DEPENDS ${SOURCE_DIR}/common/atoms.list
 119     COMMENT "Generating atoms-extern.h"
 120     VERBATIM)
 121
 122 add_custom_command(
 123     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 124     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 125     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 126     WORKING_DIRECTORY ${SOURCE_DIR}
 127     DEPENDS ${SOURCE_DIR}/common/atoms.list
 128     COMMENT "Generating atoms-intern.h"
 129     VERBATIM)
 130
 131 add_custom_target(generated_sources
 132     DEPENDS ${BUILD_DIR}/common/atoms-intern.h
 133             ${BUILD_DIR}/common/atoms-extern.h)
 134
 135 # Default theme directory
 136 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/default)
 137 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/sky)
 138 file(MAKE_DIRECTORY ${BUILD_DIR}/themes/zenburn)
 139 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 140 # }}}
 141
 142 # {{{ Version stamp
 143 if(BUILD_FROM_GIT)
 144     add_custom_target(version_stamp ALL
 145         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 146                 ${VERSION_STAMP_FILE}
 147                 ${BUILD_DIR}/awesome-version-internal.h
 148         WORKING_DIRECTORY ${SOURCE_DIR})
 149
 150     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 151 endif()
 152 # }}}
 153
 154 # {{{ Manpages
 155 if(GENERATE_MANPAGES)
 156     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 157         file(MAKE_DIRECTORY ${BUILD_DIR}/manpages)
 158     endif()
 159
 160     # add the default translation to the list of languages
 161     set(AWE_MAN_LANGS default ${AWE_MAN_LANGS})
 162
 163     foreach(lang ${AWE_MAN_LANGS})
 164
 165         foreach(txtfile ${AWE_MAN_SRCS})
 166             # figure the base name of the file (ie "awesome.1")
 167             GET_FILENAME_COMPONENT(tmpname ${txtfile} NAME)
 168             string(REGEX REPLACE ".txt\$" "" basename ${tmpname})
 169
 170             # figure the relative path of the file
 171             GET_FILENAME_COMPONENT(tmppath ${txtfile} PATH)
 172             string(REPLACE ${SOURCE_DIR}/ "" relpath ${tmppath})
 173
 174             # figure the manpage section to install to from filename
 175             string(REGEX REPLACE "^.*\\.([0-9])$" "\\1" section ${basename})
 176
 177             # construct the language specific versions of the basename and path
 178             if (lang STREQUAL default)
 179                 set(basename2 ${basename})
 180                 set(relpath2 ${relpath}/man${section})
 181             else()
 182                 set(basename2 ${basename}.${lang})
 183                 set(relpath2 ${relpath}/${lang}/man${section})
 184             endif()
 185
 186             # create the build directory (if it does not exist)
 187             file(MAKE_DIRECTORY ${BUILD_DIR}/${relpath2})
 188
 189             # set the final filenames
 190             set(txtfile ${SOURCE_DIR}/${relpath}/${basename2}.txt)
 191             set(xmlfile ${BUILD_DIR}/${relpath2}/${basename}.xml)
 192             set(gzfile  ${BUILD_DIR}/${relpath2}/${basename}.gz)
 193             set(manfile ${BUILD_DIR}/${relpath2}/${basename})
 194
 195             add_custom_command(
 196                 COMMAND ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} - < ${txtfile}
 197                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 198                 OUTPUT  ${xmlfile}
 199                 DEPENDS ${txtfile}
 200                 VERBATIM)
 201             add_custom_command(
 202                 COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 203                 OUTPUT  ${manfile}
 204                 WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 205                 DEPENDS ${xmlfile})
 206
 207             if(COMPRESS_MANPAGES)
 208                 add_custom_command(
 209                     COMMAND ${GZIP_EXECUTABLE} < ${manfile} > ${gzfile}
 210                     OUTPUT  ${gzfile}
 211                     WORKING_DIRECTORY ${BUILD_DIR}/${relpath2}
 212                     DEPENDS ${manfile}
 213                     VERBATIM)
 214
 215                 set(MAN_FILES ${MAN_FILES} ${gzfile})
 216             else()
 217                 set(MAN_FILES ${MAN_FILES} ${manfile})
 218             endif()
 219         endforeach()
 220
 221     endforeach()
 222
 223     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 224 endif()
 225 # }}}
 226
 227 # {{{ Doxygen
 228 if(DOXYGEN_EXECUTABLE)
 229     add_custom_target(doc
 230         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 231         WORKING_DIRECTORY ${BUILD_DIR})
 232 endif()
 233 # }}}
 234
 235 # {{{ Lua API Documentation
 236 if(GENERATE_DOC)
 237     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 238         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 239     endif()
 240
 241     file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua ${BUILD_DIR}/luadoc/*.lua)
 242
 243     add_custom_target(ldoc ALL
 244         COMMAND ${LDOC_EXECUTABLE} .
 245         WORKING_DIRECTORY ${BUILD_DIR}
 246         DEPENDS ${AWE_LUA_FILES})
 247 endif()
 248 # }}}
 249
 250 # {{{ Theme icons
 251 file(GLOB icon_sources RELATIVE ${SOURCE_DIR} ${SOURCE_DIR}/themes/*/titlebar/*.png)
 252
 253 foreach(icon ${icon_sources})
 254     # Copy all icons to the build dir to simplify the following code.
 255     # Source paths are interpreted relative to ${SOURCE_DIR}, target paths
 256     # relative to ${BUILD_DIR}.
 257     get_filename_component(icon_path ${icon} PATH)
 258     get_filename_component(icon_name ${icon} NAME)
 259     file(COPY ${icon} DESTINATION ${icon_path})
 260     set(ALL_ICONS ${ALL_ICONS} "${icon_path}/${icon_name}")
 261 endforeach()
 262
 263 macro(a_icon_convert match replacement input)
 264     string(REPLACE ${match} ${replacement} output ${input})
 265
 266     if(NOT ${input} STREQUAL ${output})
 267         set(ALL_ICONS ${ALL_ICONS} ${output})
 268
 269         add_custom_command(
 270             COMMAND ${CONVERT_EXECUTABLE} ${input} ${ARGN} ${output}
 271             OUTPUT  ${output}
 272             DEPENDS ${input}
 273             VERBATIM)
 274     endif()
 275 endmacro()
 276
 277 foreach(icon ${ALL_ICONS})
 278     # Make unfocused icons translucent
 279     a_icon_convert("_focus" "_normal" ${icon}
 280         -colorspace rgb -gamma 0.6 -channel A -evaluate Multiply 0.4)
 281 endforeach()
 282
 283 foreach(icon ${ALL_ICONS})
 284     # Make inactive icons grayscale
 285     a_icon_convert("_active" "_inactive" ${icon}
 286         -colorspace Gray)
 287 endforeach()
 288
 289 add_custom_target(generated_icons ALL DEPENDS ${ALL_ICONS})
 290 # }}}
 291
 292 # {{{ Dist tarball
 293 if(BUILD_FROM_GIT)
 294     add_custom_target(dist
 295         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 296         WORKING_DIRECTORY ${SOURCE_DIR})
 297 endif()
 298 # }}}
 299
 300 # {{{ Installation
 301 install(TARGETS ${PROJECT_AWE_NAME} RUNTIME DESTINATION bin)
 302 install(FILES "utils/awesome-client" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 303 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH}
 304     PATTERN "*.in" EXCLUDE)
 305 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 306         RENAME ${AWE_CONF_FILE})
 307 if(GENERATE_MANPAGES)
 308     if(COMPRESS_MANPAGES)
 309         set(regex "\\.(xml|txt|[0-9])$")
 310     else()
 311         set(regex "\\.(xml|txt|gz)$")
 312     endif()
 313     install(DIRECTORY ${BUILD_DIR}/${relpath}/ DESTINATION ${AWESOME_MAN_PATH}
 314             REGEX ${regex} EXCLUDE )
 315 endif()
 316 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 317 install(DIRECTORY ${BUILD_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 318     PATTERN "*.in" EXCLUDE)
 319 install(DIRECTORY ${SOURCE_DIR}/themes DESTINATION ${AWESOME_DATA_PATH}
 320     PATTERN "*.in" EXCLUDE)
 321 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 322 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 323 if(GENERATE_DOC)
 324     install(DIRECTORY ${BUILD_DIR}/doc DESTINATION ${AWESOME_DOC_PATH})
 325 endif()
 326 # }}}
 327
 328 # {{{ Unit tests
 329 find_program(BUSTED_EXECUTABLE busted)
 330 if(BUSTED_EXECUTABLE)
 331     add_custom_target(check ALL
 332         ${BUSTED_EXECUTABLE} "--lpath=${CMAKE_BINARY_DIR}/lib/?.lua;${CMAKE_BINARY_DIR}/lib/?/init.lua;spec/?.lua"
 333         WORKING_DIRECTORY ${CMAKE_SOURCE_DIR}
 334         VERBATIM)
 335     add_custom_target(test DEPENDS check)
 336 endif()
 337 # }}}
 338
 339 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:textwidth=80