awesomeConfig.cmake

   1 set(PROJECT_AWE_NAME awesome)
   2 set(PROJECT_AWECLIENT_NAME awesome-client)
   3
   4 # If ${SOURCE_DIR} is a git repository VERSION is set to
   5 # `git-describe` later.
   6 set(VERSION 3-devel)
   7
   8 set(VERSION_MAJOR ${VERSION})
   9 set(VERSION_MINOR 0)
  10 set(VERSION_PATCH 0)
  11
  12 set(CODENAME "Scared Of Girls")
  13
  14 project(${PROJECT_AWE_NAME} C)
  15
  16 set(CMAKE_BUILD_TYPE RELEASE)
  17
  18 set(CURSES_NEED_NCURSES true)
  19
  20 option(WITH_DBUS "build with D-BUS" ON)
  21 option(WITH_IMLIB2 "build with Imlib2" ON)
  22 option(GENERATE_MANPAGES "generate manpages" ON)
  23 option(GENERATE_LUADOC "generate luadoc" ON)
  24
  25 # {{{ CFLAGS
  26 add_definitions(-std=gnu99 -ggdb3 -fno-strict-aliasing -Wall -Wextra
  27     -Wchar-subscripts -Wundef -Wshadow -Wcast-align -Wwrite-strings
  28     -Wsign-compare -Wunused -Wno-unused-parameter -Wuninitialized -Winit-self
  29     -Wpointer-arith -Wredundant-decls -Wformat-nonliteral
  30     -Wno-format-zero-length -Wmissing-format-attribute -Wmissing-prototypes
  31     -Wstrict-prototypes)
  32 # }}}
  33
  34 # {{{ Find external utilities
  35 macro(a_find_program var prg req)
  36     set(required ${req})
  37     find_program(${var} ${prg})
  38     if(NOT ${var})
  39         message(STATUS "${prg} not found.")
  40         if(required)
  41             message(FATAL_ERROR "${prg} is required to build awesome")
  42         endif()
  43     else()
  44         message(STATUS "${prg} -> ${${var}}")
  45     endif()
  46 endmacro()
  47
  48 a_find_program(CAT_EXECUTABLE cat TRUE)
  49 a_find_program(LN_EXECUTABLE ln TRUE)
  50 a_find_program(GREP_EXECUTABLE grep TRUE)
  51 a_find_program(GIT_EXECUTABLE git FALSE)
  52 a_find_program(HOSTNAME_EXECUTABLE hostname FALSE)
  53 a_find_program(GPERF_EXECUTABLE gperf TRUE)
  54 a_find_program(LUAC_EXECUTABLE luac TRUE)
  55 # programs needed for man pages
  56 a_find_program(ASCIIDOC_EXECUTABLE asciidoc FALSE)
  57 a_find_program(XMLTO_EXECUTABLE xmlto FALSE)
  58 a_find_program(GZIP_EXECUTABLE gzip FALSE)
  59 # lua documentation
  60 a_find_program(LUA_EXECUTABLE lua FALSE)
  61 a_find_program(LUADOC_EXECUTABLE luadoc FALSE)
  62 # doxygen
  63 include(FindDoxygen)
  64 # pkg-config
  65 include(FindPkgConfig)
  66 # ncurses
  67 include(FindCurses)
  68 # lua 5.1
  69 include(FindLua51) #Due to a cmake bug, you will see Lua50 on screen
  70 # }}}
  71
  72 # {{{ Check if documentation can be build
  73 if(GENERATE_MANPAGES)
  74     if(NOT ASCIIDOC_EXECUTABLE OR NOT XMLTO_EXECUTABLE OR NOT GZIP_EXECUTABLE)
  75         if(NOT ASCIIDOC_EXECUTABLE)
  76             SET(missing "asciidoc")
  77         endif()
  78         if(NOT XMLTO_EXECUTABLE)
  79             SET(missing ${missing} " xmlto")
  80         endif()
  81         if(NOT GZIP_EXECUTABLE)
  82             SET(missing ${missing} " gzip")
  83         endif()
  84
  85         message(STATUS "Not generating manpages. Missing: " ${missing})
  86         set(GENERATE_MANPAGES OFF)
  87     endif()
  88 endif()
  89
  90 if(GENERATE_LUADOC)
  91     if(NOT LUADOC_EXECUTABLE)
  92         message(STATUS "Not generating luadoc. Missing: luadoc")
  93         set(GENERATE_LUADOC OFF)
  94     endif()
  95 endif()
  96 # }}}
  97
  98 # {{{ Version stamp
  99 if(EXISTS ${SOURCE_DIR}/.git/HEAD AND GIT_EXECUTABLE)
 100     # get current version
 101     execute_process(
 102         COMMAND ${GIT_EXECUTABLE} describe
 103         WORKING_DIRECTORY ${SOURCE_DIR}
 104         OUTPUT_VARIABLE VERSION
 105         OUTPUT_STRIP_TRAILING_WHITESPACE)
 106     # file the git-version-stamp.sh script will look into
 107     set(VERSION_STAMP_FILE ${BUILD_DIR}/.version_stamp)
 108     file(WRITE ${VERSION_STAMP_FILE} ${VERSION})
 109     # create a version_stamp target later
 110     set(BUILD_FROM_GIT TRUE)
 111 elseif( EXISTS ${SOURCE_DIR}/.version_stamp )
 112     # get version from version stamp
 113     file(READ ${SOURCE_DIR}/.version_stamp VERSION)
 114 endif()
 115 # }}}
 116
 117 # {{{ Get hostname
 118 execute_process(
 119     COMMAND ${HOSTNAME_EXECUTABLE}
 120     WORKING_DIRECTORY ${SOURCE_DIR}
 121     OUTPUT_VARIABLE BUILDHOSTNAME
 122     OUTPUT_STRIP_TRAILING_WHITESPACE)
 123 # }}}
 124
 125 # {{{ Required libraries
 126 #
 127 # this sets up:
 128 # AWESOME_REQUIRED_LIBRARIES
 129 # AWESOME_REQUIRED_INCLUDE_DIRS
 130 # AWESOMECLIENT_LIBRARIES
 131
 132 # Use pkgconfig to get most of the libraries
 133 pkg_check_modules(AWESOME_REQUIRED REQUIRED
 134     glib-2.0
 135     cairo
 136     pango
 137     pangocairo
 138     xcb
 139     xcb-event
 140     xcb-randr
 141     xcb-xinerama
 142     xcb-aux
 143     xcb-atom
 144     xcb-keysyms
 145     xcb-icccm
 146     cairo-xcb)
 147
 148 if(NOT AWESOME_REQUIRED_FOUND)
 149     message(FATAL_ERROR)
 150 endif()
 151
 152 macro(a_find_library variable library)
 153     find_library(${variable} ${library})
 154     if(NOT ${variable})
 155         message(FATAL_ERROR ${library} " library not found.")
 156     endif()
 157 endmacro()
 158
 159 # Check for readline, ncurse and libev
 160 a_find_library(LIB_READLINE readline)
 161 a_find_library(LIB_EV ev)
 162
 163 # Error check
 164 set( LUA_FOUND LUA51_FOUND OR LUA50_FOUND )# This is a workaround to a cmake bug
 165 if(NOT LUA_FOUND)
 166     message(FATAL_ERROR "lua library not found")
 167 endif()
 168
 169 set(AWESOME_REQUIRED_LIBRARIES ${AWESOME_REQUIRED_LIBRARIES}
 170     ${LIB_EV}
 171     ${LUA_LIBRARIES})
 172
 173 set(AWESOME_REQUIRED_INCLUDE_DIRS ${AWESOME_REQUIRED_INCLUDE_DIRS}
 174     ${LUA_INCLUDE_DIR})
 175
 176 set(AWESOMECLIENT_LIBRARIES
 177     ${LIB_READLINE}
 178     ${CURSES_LIBRARIES})
 179 # }}}
 180
 181 # {{{ Optional libraries
 182 #
 183 # this sets up:
 184 # AWESOME_OPTIONAL_LIBRARIES
 185 # AWESOME_OPTIONAL_INCLUDE_DIRS
 186
 187 if(WITH_DBUS)
 188     pkg_check_modules(DBUS dbus-1)
 189     if(DBUS_FOUND)
 190         set(AWESOME_OPTIONAL_LIBRARIES ${AWESOME_OPTIONAL_LIBRARIES} ${DBUS_LIBRARIES})
 191         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${DBUS_INCLUDE_DIRS})
 192     else()
 193         set(WITH_DBUS OFF)
 194         message(STATUS "DBUS not found. Disabled.")
 195     endif()
 196 endif()
 197
 198 if(WITH_IMLIB2)
 199     pkg_check_modules(IMLIB2 imlib2)
 200     if(IMLIB2_FOUND)
 201         set(AWESOME_OPTIONAL_LIBRARIES ${AWESOME_OPTIONAL_LIBRARIES} ${IMLIB2_LIBRARIES})
 202         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS} ${IMLIB2_INCLUDE_DIRS})
 203     else()
 204         set(WITH_IMLIB2 OFF)
 205         message(STATUS "Imlib2 not found. Disabled.")
 206     endif()
 207 endif()
 208
 209 if(NOT WITH_IMLIB2)
 210     pkg_check_modules(GDK_PIXBUF REQUIRED gdk-2.0>=2.2 gdk-pixbuf-2.0>=2.2)
 211     if(GDK_PIXBUF_FOUND)
 212         set(AWESOME_OPTIONAL_LIBRARIES ${AWESOME_OPTIONAL_LIBRARIES}
 213             ${GDK_PIXBUF_LIBRARIES})
 214         set(AWESOME_OPTIONAL_INCLUDE_DIRS ${AWESOME_OPTIONAL_INCLUDE_DIRS}
 215             ${GDK_PIXBUF_INCLUDE_DIRS})
 216     else()
 217         message(FATAL_ERROR "GdkPixBuf not found.")
 218     endif()
 219 endif()
 220 # }}}
 221
 222 # {{{ Install path and configuration variables
 223 if(DEFINED PREFIX)
 224     set(PREFIX ${PREFIX} CACHE PATH "install prefix")
 225     set(CMAKE_INSTALL_PREFIX ${PREFIX})
 226 else()
 227     set(PREFIX ${CMAKE_INSTALL_PREFIX} CACHE PATH "install prefix")
 228 endif()
 229
 230 #If a sysconfdir is specified, use it instead
 231 #of the default configuration dir.
 232 if(DEFINED SYSCONFDIR)
 233     set(SYSCONFDIR ${SYSCONFDIR} CACHE PATH "config directory")
 234 else()
 235     set(SYSCONFDIR /etc CACHE PATH "config directory")
 236 endif()
 237
 238 #If an XDG Config Dir is specificed, use it instead
 239 #of the default XDG configuration dir.
 240 if(DEFINED XDG_CONFIG_DIR)
 241     set(XDG_CONFIG_DIR ${XDG_CONFIG_SYS} CACHE PATH "xdg config directory")
 242 else()
 243     set(XDG_CONFIG_DIR ${SYSCONFDIR}/xdg CACHE PATH "xdg config directory")
 244 endif()
 245
 246 # setting AWESOME_DOC_PATH
 247 if(DEFINED AWESOME_DOC_PATH)
 248     set(AWESOME_DOC_PATH ${AWESOME_DOC_PATH} CACHE PATH "awesome docs directory")
 249 else()
 250     set(AWESOME_DOC_PATH ${PREFIX}/share/doc/${PROJECT_AWE_NAME} CACHE PATH "awesome docs directory")
 251 endif()
 252
 253 # setting AWESOME_XSESSION_PATH
 254 if(DEFINED AWESOME_XSESSION_PATH)
 255     set(AWESOME_XSESSION_PATH ${AWESOME_XSESSION_PATH} CACHE PATH "awesome xsessions directory")
 256 else()
 257     set(AWESOME_XSESSION_PATH ${PREFIX}/share/xsessions CACHE PATH "awesome xsessions directory")
 258 endif()
 259
 260 # set man path
 261 if(DEFINED AWESOME_MAN_PATH)
 262    set(AWESOME_MAN_PATH ${AWESOME_MAN_PATH} CACHE PATH "awesome manpage directory")
 263 else()
 264    set(AWESOME_MAN_PATH ${PREFIX}/share/man CACHE PATH "awesome manpage directory")
 265 endif()
 266
 267 # Hide to avoid confusion
 268 mark_as_advanced(CMAKE_INSTALL_PREFIX)
 269
 270 set(AWESOME_VERSION          ${VERSION})
 271 set(AWESOME_COMPILE_MACHINE  ${CMAKE_SYSTEM_PROCESSOR})
 272 set(AWESOME_COMPILE_HOSTNAME ${BUILDHOSTNAME})
 273 set(AWESOME_COMPILE_BY       $ENV{USER})
 274 set(AWESOME_RELEASE          ${CODENAME})
 275 set(AWESOME_SYSCONFDIR       ${XDG_CONFIG_DIR}/${PROJECT_AWE_NAME})
 276 set(AWESOME_DATA_PATH        ${PREFIX}/share/${PROJECT_AWE_NAME})
 277 set(AWESOME_LUA_LIB_PATH     ${AWESOME_DATA_PATH}/lib)
 278 set(AWESOME_ICON_PATH        ${AWESOME_DATA_PATH}/icons)
 279 set(AWESOME_THEMES_PATH      ${AWESOME_DATA_PATH}/themes)
 280 # }}}
 281
 282 # {{{ Configure files
 283 set(AWESOME_CONFIGURE_FILES
 284     config.h.in
 285     awesomerc.lua.in
 286     themes/default.in
 287     lib/awful.lua.in
 288     lib/beautiful.lua.in
 289     lib/tabulous.lua.in
 290     awesome-version-internal.h.in
 291     awesome.doxygen.in)
 292
 293 macro(a_configure_file file)
 294     string(REGEX REPLACE ".in\$" "" outfile ${file})
 295     message(STATUS "Configuring ${outfile}")
 296     configure_file(${SOURCE_DIR}/${file}
 297                    ${BUILD_DIR}/${outfile}
 298                    ESCAPE_QUOTE
 299                    @ONLY)
 300 endmacro()
 301
 302 foreach(file ${AWESOME_CONFIGURE_FILES})
 303     a_configure_file(${file})
 304 endforeach()
 305 #}}}
 306
 307 # {{{ CPack configuration
 308 SET(CPACK_SET_DESTDIR                  TRUE)
 309 set(CPACK_PACKAGE_NAME                 "${PROJECT_AWE_NAME}")
 310 set(CPACK_GENERATOR                    "TBZ2")
 311 set(CPACK_SOURCE_GENERATOR             "TBZ2")
 312 set(CPACK_SOURCE_IGNORE_FILES
 313     ".git;.*.swp$;.*~;.*patch;.gitignore;${BUILD_DIR}")
 314 set(CPACK_PACKAGE_DESCRIPTION_SUMMARY  "A dynamic floating and tiling window manager")
 315 set(CPACK_PACKAGE_VENDOR               "awesome development team")
 316 set(CPACK_PACKAGE_DESCRIPTION_FILE     "${SOURCE_DIR}/README")
 317 set(CPACK_RESOURCE_FILE_LICENSE        "${SOURCE_DIR}/LICENSE")
 318 set(CPACK_PACKAGE_VERSION_MAJOR        "${VERSION_MAJOR}")
 319 set(CPACK_PACKAGE_VERSION_MINOR        "${VERSION_MINOR}")
 320 set(CPACK_PACKAGE_VERSION_PATCH        "${VERSION_PATCH}")
 321
 322 include(CPack)
 323 #}}}
 324
 325 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80