CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.6.0)
   2 set(CMAKE_ALLOW_LOOSE_LOOP_CONSTRUCTS  TRUE)
   3
   4 if(COMMAND cmake_policy)
   5     cmake_policy(VERSION 2.6)
   6 endif()
   7
   8 set(SOURCE_DIR ${CMAKE_CURRENT_SOURCE_DIR})
   9 set(BUILD_DIR ${CMAKE_CURRENT_BINARY_DIR})
  10
  11 if(NOT EXISTS ${SOURCE_DIR}/awesomeConfig.cmake)
  12     message(FATAL_ERROR "Please provide awesomeConfig.cmake")
  13 endif()
  14
  15 include(awesomeConfig.cmake)
  16
  17 include_directories(
  18     ${SOURCE_DIR}
  19     ${BUILD_DIR}
  20     ${BUILD_DIR}/common
  21     ${AWESOME_COMMON_REQUIRED_INCLUDE_DIRS}
  22     ${AWESOME_REQUIRED_INCLUDE_DIRS}
  23     ${AWESOME_OPTIONAL_INCLUDE_DIRS})
  24
  25 file(GLOB_RECURSE AWE_LUA_FILES ${BUILD_DIR}/lib/*.lua)
  26
  27 set(AWE_CONF_FILE_DEFAULT ${BUILD_DIR}/awesomerc.lua)
  28 set(AWE_CONF_FILE rc.lua)
  29
  30 set(AWE_ICON_DIR ${SOURCE_DIR}/icons)
  31 set(AWE_THEMES_DIR ${SOURCE_DIR}/themes)
  32
  33 set(AWE_DOC_FILES
  34     ${SOURCE_DIR}/AUTHORS
  35     ${SOURCE_DIR}/BUGS
  36     ${SOURCE_DIR}/README
  37     ${SOURCE_DIR}/LICENSE)
  38
  39 set(AWE_SRCS
  40     ${SOURCE_DIR}/awesome.c
  41     ${SOURCE_DIR}/client.c
  42     ${SOURCE_DIR}/cnode.c
  43     ${SOURCE_DIR}/dbus.c
  44     ${SOURCE_DIR}/event.c
  45     ${SOURCE_DIR}/property.c
  46     ${SOURCE_DIR}/ewmh.c
  47     ${SOURCE_DIR}/keybinding.c
  48     ${SOURCE_DIR}/keygrabber.c
  49     ${SOURCE_DIR}/layout.c
  50     ${SOURCE_DIR}/luaa.c
  51     ${SOURCE_DIR}/mouse.c
  52     ${SOURCE_DIR}/screen.c
  53     ${SOURCE_DIR}/stack.c
  54     ${SOURCE_DIR}/statusbar.c
  55     ${SOURCE_DIR}/wibox.c
  56     ${SOURCE_DIR}/systray.c
  57     ${SOURCE_DIR}/tag.c
  58     ${SOURCE_DIR}/titlebar.c
  59     ${SOURCE_DIR}/widget.c
  60     ${SOURCE_DIR}/window.c
  61     ${SOURCE_DIR}/image.c
  62     ${SOURCE_DIR}/draw.c
  63     ${SOURCE_DIR}/swindow.c
  64     ${SOURCE_DIR}/common/buffer.c
  65     ${SOURCE_DIR}/common/atoms.c
  66     ${SOURCE_DIR}/common/markup.c
  67     ${SOURCE_DIR}/common/socket.c
  68     ${SOURCE_DIR}/common/util.c
  69     ${SOURCE_DIR}/common/version.c
  70     ${SOURCE_DIR}/common/xembed.c
  71     ${SOURCE_DIR}/common/xutil.c
  72     ${SOURCE_DIR}/layouts/fibonacci.c
  73     ${SOURCE_DIR}/layouts/floating.c
  74     ${SOURCE_DIR}/layouts/magnifier.c
  75     ${SOURCE_DIR}/layouts/fair.c
  76     ${SOURCE_DIR}/layouts/max.c
  77     ${SOURCE_DIR}/layouts/tile.c
  78     ${SOURCE_DIR}/widgets/graph.c
  79     ${SOURCE_DIR}/widgets/progressbar.c
  80     ${SOURCE_DIR}/widgets/taglist.c
  81     ${SOURCE_DIR}/widgets/tasklist.c
  82     ${SOURCE_DIR}/widgets/textbox.c
  83     ${SOURCE_DIR}/widgets/systray.c
  84     ${SOURCE_DIR}/widgets/imagebox.c)
  85
  86 set(AWE_CLIENT_SRCS
  87     ${SOURCE_DIR}/awesome-client.c
  88     ${SOURCE_DIR}/common/socket.c
  89     ${SOURCE_DIR}/common/util.c
  90     ${SOURCE_DIR}/common/version.c)
  91
  92 set(AWE_MAN_SRCS
  93     ${SOURCE_DIR}/awesome.1.txt
  94     ${SOURCE_DIR}/awesome-client.1.txt
  95     ${SOURCE_DIR}/awesomerc.5.txt)
  96
  97 add_executable(${PROJECT_AWE_NAME}
  98     ${AWE_SRCS}
  99     ${BUILD_DIR}/common/tokenize.c)
 100
 101 add_executable(${PROJECT_AWECLIENT_NAME}
 102     ${AWE_CLIENT_SRCS}
 103     ${BUILD_DIR}/common/tokenize.c)
 104
 105 set_target_properties(${PROJECT_AWE_NAME}
 106     PROPERTIES
 107     LINK_FLAGS -export-dynamic)
 108
 109 target_link_libraries(${PROJECT_AWE_NAME}
 110     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 111     ${AWESOME_REQUIRED_LIBRARIES}
 112     ${AWESOME_OPTIONAL_LIBRARIES})
 113
 114 target_link_libraries(${PROJECT_AWECLIENT_NAME}
 115     ${AWESOME_COMMON_REQUIRED_LIBRARIES}
 116     ${AWESOMECLIENT_LIBRARIES})
 117
 118 # {{{ Generated sources
 119 file(GLOB LAYOUTGEN_DEPS ${SOURCE_DIR}/layouts/*.h)
 120 add_custom_command(
 121     COMMAND ${SOURCE_DIR}/build-utils/layoutgen.sh
 122     ARGS    > ${BUILD_DIR}/layoutgen.h
 123     OUTPUT  ${BUILD_DIR}/layoutgen.h
 124     WORKING_DIRECTORY ${SOURCE_DIR}
 125     DEPENDS ${LAYOUTGEN_DEPS}
 126     COMMENT "Generating layoutgen.h"
 127     VERBATIM)
 128
 129 add_custom_command(
 130     COMMAND ${SOURCE_DIR}/build-utils/widgetgen.sh
 131     ARGS    > ${BUILD_DIR}/widgetgen.h
 132     OUTPUT  ${BUILD_DIR}/widgetgen.h
 133     WORKING_DIRECTORY ${SOURCE_DIR}
 134     DEPENDS ${SOURCE_DIR}/widget.h
 135     COMMENT "Generating widgetgen.h"
 136     VERBATIM)
 137
 138 # atoms
 139 file(MAKE_DIRECTORY ${BUILD_DIR}/common)
 140 add_custom_command(
 141     COMMAND ${SOURCE_DIR}/build-utils/atoms-ext.sh ${SOURCE_DIR}/common/atoms.list
 142     ARGS    > ${BUILD_DIR}/common/atoms-extern.h
 143     OUTPUT  ${BUILD_DIR}/common/atoms-extern.h
 144     WORKING_DIRECTORY ${SOURCE_DIR}
 145     DEPENDS ${SOURCE_DIR}/common/atoms.list
 146     COMMENT "Generating atoms-extern.h"
 147     VERBATIM)
 148
 149 add_custom_command(
 150     COMMAND ${SOURCE_DIR}/build-utils/atoms-int.sh ${SOURCE_DIR}/common/atoms.list
 151     ARGS    > ${BUILD_DIR}/common/atoms-intern.h
 152     OUTPUT  ${BUILD_DIR}/common/atoms-intern.h
 153     WORKING_DIRECTORY ${SOURCE_DIR}
 154     DEPENDS ${SOURCE_DIR}/common/atoms.list
 155     COMMENT "Generating atoms-intern.h"
 156     VERBATIM)
 157
 158 # gperf
 159 add_custom_command(
 160     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 161     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 162             ${BUILD_DIR}/common/tokenize.h
 163     OUTPUT  ${BUILD_DIR}/common/tokenize.h
 164     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 165             ${SOURCE_DIR}/build-utils/gperf.sh
 166     COMMENT "Generating common/tokenize.h")
 167
 168 add_custom_command(
 169     COMMAND ${SOURCE_DIR}/build-utils/gperf.sh
 170     ARGS    ${SOURCE_DIR}/common/tokenize.gperf
 171             ${BUILD_DIR}/common/tokenize.c
 172     OUTPUT  ${BUILD_DIR}/common/tokenize.c
 173     DEPENDS ${SOURCE_DIR}/common/tokenize.gperf
 174             ${SOURCE_DIR}/build-utils/gperf.sh
 175     COMMENT "Generating common/tokenize.c")
 176
 177 add_custom_target(generated_sources
 178     DEPENDS ${BUILD_DIR}/widgetgen.h
 179             ${BUILD_DIR}/layoutgen.h
 180             ${BUILD_DIR}/common/atoms-intern.h
 181             ${BUILD_DIR}/common/atoms-extern.h
 182             ${BUILD_DIR}/common/tokenize.c
 183             ${BUILD_DIR}/common/tokenize.h)
 184
 185 add_dependencies(${PROJECT_AWE_NAME} generated_sources)
 186 add_dependencies(${PROJECT_AWECLIENT_NAME} generated_sources)
 187 # }}}
 188
 189 # {{{ Version stamp
 190 if(BUILD_FROM_GIT)
 191     add_custom_target(version_stamp ALL
 192         COMMAND ${SOURCE_DIR}/build-utils/git-version-stamp.sh
 193                 ${VERSION_STAMP_FILE}
 194                 ${BUILD_DIR}/awesome-version-internal.h
 195         WORKING_DIRECTORY ${SOURCE_DIR})
 196
 197     add_dependencies(${PROJECT_AWE_NAME} version_stamp)
 198     add_dependencies(${PROJECT_AWECLIENT_NAME} version_stamp)
 199 endif()
 200 # }}}
 201
 202 # {{{ Manpages
 203 if(GENERATE_MANPAGES)
 204     foreach(txtfile ${AWE_MAN_SRCS})
 205         string(REGEX REPLACE ".txt\$" ".xml" xmlfile ${txtfile})
 206         string(REPLACE ${SOURCE_DIR}
 207                        ${BUILD_DIR} xmlfile ${xmlfile})
 208         string(REGEX REPLACE ".xml\$" ".gz" gzfile ${xmlfile})
 209         string(REGEX REPLACE ".gz\$" "" manfile ${gzfile})
 210
 211         add_custom_command(
 212             COMMAND ${CAT_EXECUTABLE} ${txtfile}
 213                     | ${ASCIIDOC_EXECUTABLE} -d manpage -b docbook -o ${xmlfile} -
 214             WORKING_DIRECTORY ${BUILD_DIR}
 215             OUTPUT  ${xmlfile}
 216             DEPENDS ${txtfile}
 217             VERBATIM)
 218         add_custom_command(
 219             COMMAND ${XMLTO_EXECUTABLE} man ${xmlfile}
 220             OUTPUT  ${manfile}
 221             DEPENDS ${xmlfile})
 222         add_custom_command(
 223             COMMAND ${CAT_EXECUTABLE} ${manfile}
 224                     | ${GZIP_EXECUTABLE}
 225                     > ${gzfile}
 226             OUTPUT  ${gzfile}
 227             DEPENDS ${manfile}
 228             VERBATIM)
 229
 230         set(MAN_FILES ${MAN_FILES} ${gzfile})
 231
 232         # figure out in what section to install to from filename
 233         string(REGEX REPLACE "^.*\\.([0-9])\\.gz\$" "\\1" section ${gzfile})
 234         set(AWE_MAN${section}_FILES ${AWE_MAN${section}_FILES} ${gzfile})
 235     endforeach()
 236
 237     add_custom_target(man ALL DEPENDS ${MAN_FILES})
 238 endif()
 239 # }}}
 240
 241 # {{{ Doxygen
 242 if(DOXYGEN_EXECUTABLE)
 243     add_custom_target(doc
 244         COMMAND ${DOXYGEN_EXECUTABLE} awesome.doxygen
 245         WORKING_DIRECTORY ${BUILD_DIR})
 246 endif()
 247 # }}}
 248
 249 # {{{ Lua API Documentation
 250 if(GENERATE_LUADOC)
 251
 252     set(capi_lua ${BUILD_DIR}/lib/capi.lua)
 253
 254     if(NOT BUILD_DIR STREQUAL SOURCE_DIR)
 255         file(MAKE_DIRECTORY ${BUILD_DIR}/lib)
 256     endif()
 257
 258     # {{{ setup a command for ${capi_lua}
 259     macro(a_file_match infile regex result_var)
 260         file(STRINGS ${infile} match REGEX ${regex} LIMIT_COUNT 1)
 261         if(match)
 262             set(${result_var} TRUE)
 263         else()
 264             set(${result_var} FALSE)
 265         endif()
 266     endmacro()
 267
 268     set(luadoc_c_srcs "")
 269
 270     # find .c files exporting lua functions
 271     foreach(cfile ${AWE_SRCS})
 272         a_file_match(${cfile} "const struct luaL_reg" result)
 273         if(result)
 274             set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 275         else()
 276             a_file_match(${cfile} "luaA_.*_index" result)
 277             if(result)
 278                 set(luadoc_c_srcs ${luadoc_c_srcs} ${cfile})
 279         endif()
 280         endif()
 281     endforeach()
 282
 283     # create fake lua source file to process by luadoc
 284     add_custom_command(
 285         COMMAND ${CAT_EXECUTABLE} ${luadoc_c_srcs}
 286                 | ${LUA_EXECUTABLE} ${SOURCE_DIR}/build-utils/fake-lua-src.lua
 287                 > ${capi_lua}
 288         OUTPUT  ${capi_lua}
 289         DEPENDS ${luadoc_c_srcs}
 290         COMMENT "Generating fake lua source."
 291         VERBATIM)
 292     # }}}
 293
 294     # Generate documentation of lib//0lua
 295     file(GLOB_RECURSE lua_lib_files ${BUILD_DIR}/lib/*.lua)
 296     foreach(filename ${lua_lib_files})
 297         file(RELATIVE_PATH filename ${BUILD_DIR}/lib ${filename})
 298         set(luadoc_srcs ${luadoc_srcs} ${filename})
 299     endforeach()
 300
 301     add_custom_target(luadoc ALL
 302         COMMAND ${LUADOC_EXECUTABLE} ${luadoc_srcs} -d ${BUILD_DIR}/luadoc
 303         WORKING_DIRECTORY ${BUILD_DIR}/lib
 304         DEPENDS ${AWE_LUA_FILES} ${capi_lua})
 305 endif()
 306 # }}}
 307
 308 # {{{ Dist tarball
 309 if(BUILD_FROM_GIT)
 310     add_custom_target(dist
 311         COMMAND ${SOURCE_DIR}/build-utils/dist.sh ${VERSION}
 312         WORKING_DIRECTORY ${SOURCE_DIR})
 313 endif()
 314 # }}}
 315
 316 # {{{ Installation
 317 install(TARGETS ${PROJECT_AWE_NAME} ${PROJECT_AWECLIENT_NAME} RUNTIME DESTINATION bin)
 318 install(FILES "utils/awsetbg" DESTINATION bin PERMISSIONS OWNER_READ OWNER_WRITE OWNER_EXECUTE GROUP_READ GROUP_EXECUTE WORLD_READ WORLD_EXECUTE)
 319 install(DIRECTORY ${BUILD_DIR}/lib DESTINATION ${AWESOME_DATA_PATH})
 320 install(FILES ${AWE_CONF_FILE_DEFAULT} DESTINATION ${AWESOME_SYSCONFDIR}
 321         RENAME ${AWE_CONF_FILE})
 322 if(GENERATE_MANPAGES)
 323     install(FILES ${AWE_MAN1_FILES} DESTINATION ${AWESOME_MAN_PATH}/man1)
 324     install(FILES ${AWE_MAN5_FILES} DESTINATION ${AWESOME_MAN_PATH}/man5)
 325 endif()
 326 install(DIRECTORY ${AWE_ICON_DIR} DESTINATION ${AWESOME_DATA_PATH})
 327 install(FILES ${AWE_THEMES_DIR}/default-background.png ${BUILD_DIR}/themes/default DESTINATION ${AWESOME_THEMES_PATH})
 328 install(FILES ${AWE_DOC_FILES} DESTINATION ${AWESOME_DOC_PATH})
 329 install(FILES "awesome.desktop" DESTINATION ${AWESOME_XSESSION_PATH})
 330 if(GENERATE_LUADOC)
 331     install(DIRECTORY ${BUILD_DIR}/luadoc DESTINATION ${AWESOME_DOC_PATH})
 332 endif()
 333 # }}}
 334
 335 # vim: filetype=cmake:expandtab:shiftwidth=4:tabstop=8:softtabstop=4:encoding=utf-8:textwidth=80