lib/Automake/XFile.pm

   1 # Copyright (C) 2001, 2003, 2004, 2006, 2008, 2009 Free Software Foundation,
   2 # Inc.
   3
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 2, or (at your option)
   7 # any later version.
   8
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16
  17 # Written by Akim Demaille <akim@freefriends.org>.
  18
  19 ###############################################################
  20 # The main copy of this file is in Automake's CVS repository. #
  21 # Updates should be sent to automake-patches@gnu.org.         #
  22 ###############################################################
  23
  24 package Automake::XFile;
  25
  26 =head1 NAME
  27
  28 Automake::XFile - supply object methods for filehandles with error handling
  29
  30 =head1 SYNOPSIS
  31
  32     use Automake::XFile;
  33
  34     $fh = new Automake::XFile;
  35     $fh->open ("< file");
  36     # No need to check $FH: we died if open failed.
  37     print <$fh>;
  38     $fh->close;
  39     # No need to check the return value of close: we died if it failed.
  40
  41     $fh = new Automake::XFile "> file";
  42     # No need to check $FH: we died if new failed.
  43     print $fh "bar\n";
  44     $fh->close;
  45
  46     $fh = new Automake::XFile "file", "r";
  47     # No need to check $FH: we died if new failed.
  48     defined $fh
  49     print <$fh>;
  50     undef $fh;   # automatically closes the file and checks for errors.
  51
  52     $fh = new Automake::XFile "file", O_WRONLY | O_APPEND;
  53     # No need to check $FH: we died if new failed.
  54     print $fh "corge\n";
  55
  56     $pos = $fh->getpos;
  57     $fh->setpos ($pos);
  58
  59     undef $fh;   # automatically closes the file and checks for errors.
  60
  61     autoflush STDOUT 1;
  62
  63 =head1 DESCRIPTION
  64
  65 C<Automake::XFile> inherits from C<IO::File>.  It provides the method
  66 C<name> returning the file name.  It provides dying versions of the
  67 methods C<close>, C<lock> (corresponding to C<flock>), C<new>,
  68 C<open>, C<seek>, and C<truncate>.  It also overrides the C<getline>
  69 and C<getlines> methods to translate C<\r\n> to C<\n>.
  70
  71 =head1 SEE ALSO
  72
  73 L<perlfunc>,
  74 L<perlop/"I/O Operators">,
  75 L<IO::File>
  76 L<IO::Handle>
  77 L<IO::Seekable>
  78
  79 =head1 HISTORY
  80
  81 Derived from IO::File.pm by Akim Demaille E<lt>F<akim@freefriends.org>E<gt>.
  82
  83 =cut
  84
  85 require 5.000;
  86 use strict;
  87 use vars qw($VERSION @EXPORT @EXPORT_OK $AUTOLOAD @ISA);
  88 use Carp;
  89 use Errno;
  90 use IO::File;
  91 use File::Basename;
  92 use Automake::ChannelDefs;
  93 use Automake::Channels qw(msg);
  94 use Automake::FileUtils;
  95
  96 require Exporter;
  97 require DynaLoader;
  98
  99 @ISA = qw(IO::File Exporter DynaLoader);
 100
 101 $VERSION = "1.2";
 102
 103 @EXPORT = @IO::File::EXPORT;
 104
 105 eval {
 106   # Make all Fcntl O_XXX and LOCK_XXX constants available for importing
 107   require Fcntl;
 108   my @O = grep /^(LOCK|O)_/, @Fcntl::EXPORT, @Fcntl::EXPORT_OK;
 109   Fcntl->import (@O);  # first we import what we want to export
 110   push (@EXPORT, @O);
 111 };
 112
 113 # Used in croak error messages.
 114 my $me = basename ($0);
 115
 116 ################################################
 117 ## Constructor
 118 ##
 119
 120 sub new
 121 {
 122   my $type = shift;
 123   my $class = ref $type || $type || "Automake::XFile";
 124   my $fh = $class->SUPER::new ();
 125   if (@_)
 126     {
 127       $fh->open (@_);
 128     }
 129   $fh;
 130 }
 131
 132 ################################################
 133 ## Open
 134 ##
 135
 136 sub open
 137 {
 138   my $fh = shift;
 139   my ($file) = @_;
 140
 141   # WARNING: Gross hack: $FH is a typeglob: use its hash slot to store
 142   # the `name' of the file we are opening.  See the example with
 143   # io_socket_timeout in IO::Socket for more, and read Graham's
 144   # comment in IO::Handle.
 145   ${*$fh}{'autom4te_xfile_file'} = "$file";
 146
 147   if (!$fh->SUPER::open (@_))
 148     {
 149       fatal "cannot open $file: $!";
 150     }
 151
 152   # In case we're running under MSWindows, don't write with CRLF.
 153   # (This circumvents a bug in at least Cygwin bash where the shell
 154   # parsing fails on lines ending with the continuation character '\'
 155   # and CRLF).
 156   binmode $fh if $file =~ /^\s*>/;
 157 }
 158
 159 ################################################
 160 ## Close
 161 ##
 162
 163 sub close
 164 {
 165   my $fh = shift;
 166   if (!$fh->SUPER::close (@_))
 167     {
 168       my $file = $fh->name;
 169       Automake::FileUtils::handle_exec_errors $file
 170         unless $!;
 171       fatal "cannot close $file: $!";
 172     }
 173 }
 174
 175 ################################################
 176 ## Getline
 177 ##
 178
 179 # Some Win32/perl installations fail to translate \r\n to \n on input
 180 # so we do that here.
 181 sub getline
 182 {
 183   local $_ = $_[0]->SUPER::getline;
 184   # Perform a _global_ replacement: $_ may can contains many lines
 185   # in slurp mode ($/ = undef).
 186   s/\015\012/\n/gs if defined $_;
 187   return $_;
 188 }
 189
 190 ################################################
 191 ## Getlines
 192 ##
 193
 194 sub getlines
 195 {
 196   my @res = ();
 197   my $line;
 198   push @res, $line while $line = $_[0]->getline;
 199   return @res;
 200 }
 201
 202 ################################################
 203 ## Name
 204 ##
 205
 206 sub name
 207 {
 208   my $fh = shift;
 209   return ${*$fh}{'autom4te_xfile_file'};
 210 }
 211
 212 ################################################
 213 ## Lock
 214 ##
 215
 216 sub lock
 217 {
 218   my ($fh, $mode) = @_;
 219   # Cannot use @_ here.
 220
 221   # Unless explicitly configured otherwise, Perl implements its `flock' with the
 222   # first of flock(2), fcntl(2), or lockf(3) that works.  These can fail on
 223   # NFS-backed files, with ENOLCK (GNU/Linux) or EOPNOTSUPP (FreeBSD); we
 224   # usually ignore these errors.  If $ENV{MAKEFLAGS} suggests that a parallel
 225   # invocation of `make' has invoked the tool we serve, report all locking
 226   # failures and abort.
 227   #
 228   # On Unicos, flock(2) and fcntl(2) over NFS hang indefinitely when `lockd' is
 229   # not running.  NetBSD NFS clients silently grant all locks.  We do not
 230   # attempt to defend against these dangers.
 231   #
 232   # -j is for parallel BSD make, -P is for parallel HP-UX make.
 233   if (!flock ($fh, $mode))
 234     {
 235       my $make_j = (exists $ENV{'MAKEFLAGS'}
 236                     && " -$ENV{'MAKEFLAGS'}" =~ / (-[BdeikrRsSw]*[jP]|--[jP]|---?jobs)/);
 237       my $note = "\nforgo `make -j' or use a file system that supports locks";
 238       my $file = $fh->name;
 239
 240       msg ($make_j ? 'fatal' : 'unsupported',
 241            "cannot lock $file with mode $mode: $!" . ($make_j ? $note : ""))
 242         if $make_j || !($!{ENOLCK} || $!{EOPNOTSUPP});
 243     }
 244 }
 245
 246 ################################################
 247 ## Seek
 248 ##
 249
 250 sub seek
 251 {
 252   my $fh = shift;
 253   # Cannot use @_ here.
 254   if (!seek ($fh, $_[0], $_[1]))
 255     {
 256       my $file = $fh->name;
 257       fatal "$me: cannot rewind $file with @_: $!";
 258     }
 259 }
 260
 261 ################################################
 262 ## Truncate
 263 ##
 264
 265 sub truncate
 266 {
 267   my ($fh, $len) = @_;
 268   if (!truncate ($fh, $len))
 269     {
 270       my $file = $fh->name;
 271       fatal "cannot truncate $file at $len: $!";
 272     }
 273 }
 274
 275 1;
 276
 277 ### Setup "GNU" style for perl-mode and cperl-mode.
 278 ## Local Variables:
 279 ## perl-indent-level: 2
 280 ## perl-continued-statement-offset: 2
 281 ## perl-continued-brace-offset: 0
 282 ## perl-brace-offset: 0
 283 ## perl-brace-imaginary-offset: 0
 284 ## perl-label-offset: -2
 285 ## cperl-indent-level: 2
 286 ## cperl-brace-offset: 0
 287 ## cperl-continued-brace-offset: 0
 288 ## cperl-label-offset: -2
 289 ## cperl-extra-newline-before-brace: t
 290 ## cperl-merge-trailing-else: nil
 291 ## cperl-continued-statement-offset: 2
 292 ## End: