m4/multi.m4

   1 ##                                                          -*- Autoconf -*-
   2 # Copyright (C) 1998, 1999, 2000, 2001, 2003, 2004, 2005
   3 # Free Software Foundation, Inc.
   4 #
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # serial 5
  10
  11 # AM_ENABLE_MULTILIB([MAKEFILE], [REL-TO-TOP-SRCDIR])
  12 # ---------------------------------------------------
  13 # Add --enable-multilib to configure.
  14 AC_DEFUN([AM_ENABLE_MULTILIB],
  15 [# Default to --enable-multilib
  16 AC_ARG_ENABLE(multilib,
  17 [  --enable-multilib       build many library versions (default)],
  18 [case "$enableval" in
  19   yes) multilib=yes ;;
  20   no)  multilib=no ;;
  21   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
  22  esac],
  23               [multilib=yes])
  24
  25 # We may get other options which we leave undocumented:
  26 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  27 # See config-ml.in if you want the gory details.
  28
  29 if test "$srcdir" = "."; then
  30   if test "$with_target_subdir" != "."; then
  31     multi_basedir="$srcdir/$with_multisrctop../$2"
  32   else
  33     multi_basedir="$srcdir/$with_multisrctop$2"
  34   fi
  35 else
  36   multi_basedir="$srcdir/$2"
  37 fi
  38 AC_SUBST(multi_basedir)
  39
  40 AC_OUTPUT_COMMANDS([
  41 # Only add multilib support code if we just rebuilt the top-level
  42 # Makefile.
  43 case " $CONFIG_FILES " in
  44  *" ]m4_default([$1],Makefile)[ "*)
  45    ac_file=]m4_default([$1],Makefile)[ . ${multi_basedir}/config-ml.in
  46    ;;
  47 esac],
  48                    [
  49 srcdir="$srcdir"
  50 host="$host"
  51 target="$target"
  52 with_multisubdir="$with_multisubdir"
  53 with_multisrctop="$with_multisrctop"
  54 with_target_subdir="$with_target_subdir"
  55 ac_configure_args="${multilib_arg} ${ac_configure_args}"
  56 multi_basedir="$multi_basedir"
  57 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
  58 CC="$CC"])])dnl