aclocal.in

   1 #!@PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
   6     if 0;
   7
   8 # aclocal - create aclocal.m4 by scanning configure.ac
   9
  10 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004, 2005
  11 #           Free Software Foundation, Inc.
  12
  13 # This program is free software; you can redistribute it and/or modify
  14 # it under the terms of the GNU General Public License as published by
  15 # the Free Software Foundation; either version 2, or (at your option)
  16 # any later version.
  17
  18 # This program is distributed in the hope that it will be useful,
  19 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 # GNU General Public License for more details.
  22
  23 # You should have received a copy of the GNU General Public License
  24 # along with this program; if not, write to the Free Software
  25 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  26 # 02111-1307, USA.
  27
  28 # Written by Tom Tromey <tromey@redhat.com>, and
  29 # Alexandre Duret-Lutz <adl@gnu.org>.
  30
  31 BEGIN
  32 {
  33   my $perllibdir = $ENV{'perllibdir'} || '@datadir@/@PACKAGE@-@APIVERSION@';
  34   unshift @INC, (split '@PATH_SEPARATOR@', $perllibdir);
  35 }
  36
  37 use strict;
  38
  39 use Automake::Config;
  40 use Automake::General;
  41 use Automake::Configure_ac;
  42 use Automake::Channels;
  43 use Automake::ChannelDefs;
  44 use Automake::XFile;
  45 use Automake::FileUtils;
  46 use File::Basename;
  47 use File::stat;
  48 use Cwd;
  49
  50 # Some globals.
  51
  52 # Include paths for searching macros.  We search macros in this order:
  53 # user-supplied directories first, then the directory containing the
  54 # automake macros, and finally the system-wide directories for
  55 # third-party macro.  @user_includes can be augmented with -I.
  56 # @system_includes can be augmented with the `dirlist' file.  Also
  57 # --acdir will reset both @automake_includes and @system_includes.
  58 my @user_includes = ();
  59 my @automake_includes = ("@datadir@/aclocal-$APIVERSION");
  60 my @system_includes = ('@datadir@/aclocal');
  61
  62 # Whether we should copy M4 file in $user_includes[0].
  63 my $install = 0;
  64
  65 # --diff
  66 my @diff_command;
  67
  68 # --dry-run
  69 my $dry_run = 0;
  70
  71 # configure.ac or configure.in.
  72 my $configure_ac;
  73
  74 # Output file name.
  75 my $output_file = 'aclocal.m4';
  76
  77 # Option --force.
  78 my $force_output = 0;
  79
  80 # Modification time of the youngest dependency.
  81 my $greatest_mtime = 0;
  82
  83 # Which macros have been seen.
  84 my %macro_seen = ();
  85
  86 # Remember the order into which we scanned the files.
  87 # It's important to output the contents of aclocal.m4 in the opposite order.
  88 # (Definitions in first files we have scanned should override those from
  89 # later files.  So they must appear last in the output.)
  90 my @file_order = ();
  91
  92 # Map macro names to file names.
  93 my %map = ();
  94
  95 # Ditto, but records the last definition of each macro as returned by --trace.
  96 my %map_traced_defs = ();
  97
  98 # Map basenames to macro names.
  99 my %invmap = ();
 100
 101 # Map file names to file contents.
 102 my %file_contents = ();
 103
 104 # Map file names to file types.
 105 my %file_type = ();
 106 use constant FT_USER => 1;
 107 use constant FT_AUTOMAKE => 2;
 108 use constant FT_SYSTEM => 3;
 109
 110 # Map file names to included files (transitively closed).
 111 my %file_includes = ();
 112
 113 # Files which have already been added.
 114 my %file_added = ();
 115
 116 # Files that have already been scanned.
 117 my %scanned_configure_dep = ();
 118
 119 # Serial numbers, for files that have one.
 120 # The key is the basename of the file,
 121 # the value is the serial number represented as a list.
 122 my %serial = ();
 123
 124 # Matches a macro definition.
 125 #   AC_DEFUN([macroname], ...)
 126 # or
 127 #   AC_DEFUN(macroname, ...)
 128 # When macroname is `['-quoted , we accept any character in the name,
 129 # except `]'.  Otherwise macroname stops on the first `]', `,', `)',
 130 # or `\n' encountered.
 131 my $ac_defun_rx =
 132   "(?:AU_ALIAS|A[CU]_DEFUN|AC_DEFUN_ONCE)\\((?:\\[([^]]+)\\]|([^],)\n]+))";
 133
 134 # Matches an AC_REQUIRE line.
 135 my $ac_require_rx = "AC_REQUIRE\\((?:\\[([^]]+)\\]|([^],)\n]+))\\)";
 136
 137 # Matches an m4_include line
 138 my $m4_include_rx = "(?:m4_)?(s?)include\\((?:\\[([^]]+)\\]|([^],)\n]+))\\)";
 139
 140 # Match a serial number
 141 my $serial_line_rx = '^#\s*serial\s+(\S*)';
 142 my $serial_number_rx = '^\d+(?:\.\d+)*$';
 143 \f
 144 ################################################################
 145
 146 # Check macros in acinclude.m4.  If one is not used, warn.
 147 sub check_acinclude ()
 148 {
 149   foreach my $key (keys %map)
 150     {
 151       # FIXME: should print line number of acinclude.m4.
 152       msg ('syntax', "warning: macro `$key' defined in "
 153            . "acinclude.m4 but never used")
 154         if $map{$key} eq 'acinclude.m4' && ! exists $macro_seen{$key};
 155     }
 156 }
 157
 158 sub reset_maps ()
 159 {
 160   $greatest_mtime = 0;
 161   %macro_seen = ();
 162   @file_order = ();
 163   %map = ();
 164   %map_traced_defs = ();
 165   %file_contents = ();
 166   %file_type = ();
 167   %file_includes = ();
 168   %file_added = ();
 169   %scanned_configure_dep = ();
 170   %invmap = ();
 171   %serial = ();
 172   undef &search;
 173 }
 174
 175 # install_file ($SRC, $DEST)
 176 sub install_file ($$)
 177 {
 178   my ($src, $dest) = @_;
 179   my $diff_dest = $dest;
 180
 181   if ($force_output
 182       || !exists $file_contents{$dest}
 183       || $file_contents{$src} ne $file_contents{$dest})
 184     {
 185       if (-e $dest)
 186         {
 187           msg 'note', "overwriting `$dest' with `$src'";
 188         }
 189       else
 190         {
 191           msg 'note', "installing `$dest' from `$src'";
 192           $diff_dest = '/dev/null';
 193         }
 194
 195       if (@diff_command)
 196         {
 197           my @cmd = (@diff_command, $diff_dest, $src);
 198           $! = 0;
 199           verb "running: @cmd";
 200           my $res = system (@cmd);
 201           Automake::FileUtils::handle_exec_errors "@cmd", 1
 202             if $res;
 203         }
 204       elsif (!$dry_run)
 205         {
 206           xsystem ('cp', $src, $dest);
 207         }
 208     }
 209 }
 210
 211 # Compare two lists of numbers.
 212 sub list_compare (\@\@)
 213 {
 214   my @l = @{$_[0]};
 215   my @r = @{$_[1]};
 216   while (1)
 217     {
 218       if (0 == @l)
 219         {
 220           return (0 == @r) ? 0 : -1;
 221         }
 222       elsif (0 == @r)
 223         {
 224           return 1;
 225         }
 226       elsif ($l[0] < $r[0])
 227         {
 228           return -1;
 229         }
 230       elsif ($l[0] > $r[0])
 231         {
 232           return 1;
 233         }
 234       shift @l;
 235       shift @r;
 236     }
 237 }
 238
 239 ################################################################
 240
 241 # scan_m4_dirs($TYPE, @DIRS)
 242 # --------------------------
 243 # Scan all M4 files installed in @DIRS for new macro definitions.
 244 # Register each file as of type $TYPE (one of the FT_* constants).
 245 sub scan_m4_dirs ($@)
 246 {
 247   my ($type, @dirlist) = @_;
 248
 249   foreach my $m4dir (@dirlist)
 250     {
 251       if (! opendir (DIR, $m4dir))
 252         {
 253           fatal "couldn't open directory `$m4dir': $!";
 254         }
 255
 256       # We reverse the directory contents so that foo2.m4 gets
 257       # used in preference to foo1.m4.
 258       foreach my $file (reverse sort grep (! /^\./, readdir (DIR)))
 259         {
 260           # Only examine .m4 files.
 261           next unless $file =~ /\.m4$/;
 262
 263           # Skip some files when running out of srcdir.
 264           next if $file eq 'aclocal.m4';
 265
 266           my $fullfile = File::Spec->canonpath ("$m4dir/$file");
 267             &scan_file ($type, $fullfile, 'aclocal');
 268         }
 269       closedir (DIR);
 270     }
 271 }
 272
 273 # Scan all the installed m4 files and construct a map.
 274 sub scan_m4_files ()
 275 {
 276   # First, scan configure.ac.  It may contain macro definitions,
 277   # or may include other files that define macros.
 278   &scan_file (FT_USER, $configure_ac, 'aclocal');
 279
 280   # Then, scan acinclude.m4 if it exists.
 281   if (-f 'acinclude.m4')
 282     {
 283       &scan_file (FT_USER, 'acinclude.m4', 'aclocal');
 284     }
 285
 286   # Finally, scan all files in our search paths.
 287   scan_m4_dirs (FT_USER, @user_includes);
 288   scan_m4_dirs (FT_AUTOMAKE, @automake_includes);
 289   scan_m4_dirs (FT_SYSTEM, @system_includes);
 290
 291   # Construct a new function that does the searching.  We use a
 292   # function (instead of just evaluating $search in the loop) so that
 293   # "die" is correctly and easily propagated if run.
 294   my $search = "sub search {\nmy \$found = 0;\n";
 295   foreach my $key (reverse sort keys %map)
 296     {
 297       $search .= ('if (/\b\Q' . $key . '\E(?!\w)/) { & add_macro ("' . $key
 298                   . '"); $found = 1; }' . "\n");
 299     }
 300   $search .= "return \$found;\n};\n";
 301   eval $search;
 302   prog_error "$@\n search is $search" if $@;
 303 }
 304
 305 ################################################################
 306
 307 # Add a macro to the output.
 308 sub add_macro ($)
 309 {
 310   my ($macro) = @_;
 311
 312   # Ignore unknown required macros.  Either they are not really
 313   # needed (e.g., a conditional AC_REQUIRE), in which case aclocal
 314   # should be quiet, or they are needed and Autoconf itself will
 315   # complain when we trace for macro usage later.
 316   return unless defined $map{$macro};
 317
 318   verb "saw macro $macro";
 319   $macro_seen{$macro} = 1;
 320   &add_file ($map{$macro});
 321 }
 322
 323 # scan_configure_dep ($file)
 324 # --------------------------
 325 # Scan a configure dependency (configure.ac, or separate m4 files)
 326 # for uses of know macros and AC_REQUIREs of possibly unknown macros.
 327 # Recursively scan m4_included files.
 328 sub scan_configure_dep ($)
 329 {
 330   my ($file) = @_;
 331   # Do not scan a file twice.
 332   return ()
 333     if exists $scanned_configure_dep{$file};
 334   $scanned_configure_dep{$file} = 1;
 335
 336   my $mtime = mtime $file;
 337   $greatest_mtime = $mtime if $greatest_mtime < $mtime;
 338
 339   my $contents = exists $file_contents{$file} ?
 340     $file_contents{$file} : contents $file;
 341
 342   my $line = 0;
 343   my @rlist = ();
 344   my @ilist = ();
 345   foreach (split ("\n", $contents))
 346     {
 347       ++$line;
 348       # Remove comments from current line.
 349       s/\bdnl\b.*$//;
 350       s/\#.*$//;
 351
 352       while (/$m4_include_rx/go)
 353         {
 354           my $ifile = $2 || $3;
 355           # Skip missing `sinclude'd files.
 356           next if $1 eq 's' && ! -f $ifile;
 357           push @ilist, $ifile;
 358         }
 359
 360       while (/$ac_require_rx/go)
 361         {
 362           push (@rlist, $1 || $2);
 363         }
 364
 365       # The search function is constructed dynamically by
 366       # scan_m4_files.  The last parenthetical match makes sure we
 367       # don't match things that look like macro assignments or
 368       # AC_SUBSTs.
 369       if (! &search && /(^|\s+)(AM_[A-Z0-9_]+)($|[^\]\)=A-Z0-9_])/)
 370         {
 371           # Macro not found, but AM_ prefix found.
 372           # Make this just a warning, because we do not know whether
 373           # the macro is actually used (it could be called conditionally).
 374           msg ('unsupported', "$file:$line",
 375                "warning: macro `$2' not found in library");
 376         }
 377     }
 378
 379   add_macro ($_) foreach (@rlist);
 380   my $dirname = dirname $file;
 381   &scan_configure_dep (File::Spec->rel2abs ($_, $dirname)) foreach (@ilist);
 382 }
 383
 384 # add_file ($FILE)
 385 # ----------------
 386 # Add $FILE to output.
 387 sub add_file ($)
 388 {
 389   my ($file) = @_;
 390
 391   # Only add a file once.
 392   return if ($file_added{$file});
 393   $file_added{$file} = 1;
 394
 395   scan_configure_dep $file;
 396 }
 397
 398 # Point to the documentation for underquoted AC_DEFUN only once.
 399 my $underquoted_manual_once = 0;
 400
 401 # scan_file ($TYPE, $FILE, $WHERE)
 402 # --------------------------------
 403 # Scan a single M4 file ($FILE), and all files it includes.
 404 # Return the list of included files.
 405 # $TYPE is one of FT_USER, FT_AUTOMAKE, or FT_SYSTEM, depending
 406 # on where the file comes from.
 407 # $WHERE is the location to use in the diagnostic if the file
 408 # does not exist.
 409 sub scan_file ($$$)
 410 {
 411   my ($type, $file, $where) = @_;
 412   my $dirname = dirname $file;
 413   my $basename = basename $file;
 414
 415   # Do not scan the same file twice.
 416   return @{$file_includes{$file}} if exists $file_includes{$file};
 417   # Prevent potential infinite recursion (if two files include each other).
 418   return () if exists $file_contents{$file};
 419
 420   unshift @file_order, $file;
 421
 422   $file_type{$file} = $type;
 423
 424   fatal "$where: file `$file' does not exist" if ! -e $file;
 425
 426   my $fh = new Automake::XFile $file;
 427   my $contents = '';
 428   my @inc_files = ();
 429   my %inc_lines = ();
 430
 431   my $defun_seen = 0;
 432   my $serial_seen = 0;
 433   my $serial_older = 0;
 434
 435   while ($_ = $fh->getline)
 436     {
 437       # Ignore `##' lines.
 438       next if /^##/;
 439
 440       $contents .= $_;
 441       my $line = $_;
 442
 443       if ($line =~ /$serial_line_rx/go)
 444         {
 445           my $number = $1;
 446           if ($number !~ /$serial_number_rx/go)
 447             {
 448               msg ('syntax', "$file:$.",
 449                    "warning: ill-formed serial number `$number', "
 450                    . "expecting a version string with only digits and dots");
 451             }
 452           elsif ($defun_seen)
 453             {
 454               # aclocal removes all definitions from M4 file with the
 455               # same basename if a greater serial number is found.
 456               # Encountering a serial after some macros will undefine
 457               # these macros...
 458               msg ('syntax', "$file:$.",
 459                    'the serial number must appear before any macro definition');
 460             }
 461           # We really care about serials only for non-automake macros
 462           # and when --install is used.  But the above diagnostics are
 463           # made regardless of this, because not using --install is
 464           # not a reason not the fix macro files.
 465           elsif ($install && $type != FT_AUTOMAKE)
 466             {
 467               $serial_seen = 1;
 468               my @new = split (/\./, $number);
 469
 470               verb "$file:$.: serial $number";
 471
 472               if (!exists $serial{$basename}
 473                   || list_compare (@new, @{$serial{$basename}}) > 0)
 474                 {
 475                   # Delete any definition we knew from the old macro.
 476                   foreach my $def (@{$invmap{$basename}})
 477                     {
 478                       verb "$file:$.: ignoring previous definition of $def";
 479                       delete $map{$def};
 480                     }
 481                   $invmap{$basename} = [];
 482                   $serial{$basename} = \@new;
 483                 }
 484               else
 485                 {
 486                   $serial_older = 1;
 487                 }
 488             }
 489         }
 490
 491       while ($line =~ /$ac_defun_rx/go)
 492         {
 493           $defun_seen = 1;
 494           if (! defined $1)
 495             {
 496               msg ('syntax', "$file:$.", "warning: underquoted definition of $2"
 497                    . "\n  run info '(automake)Extending aclocal'\n"
 498                    . "  or see http://sources.redhat.com/automake/"
 499                    . "automake.html#Extending-aclocal")
 500                 unless $underquoted_manual_once;
 501               $underquoted_manual_once = 1;
 502             }
 503
 504           # If this macro does not have a serial and we have already
 505           # seen a macro with the same basename earlier, we should
 506           # ignore the macro (don't exit immediately so we can still
 507           # diagnose later #serial numbers and underquoted macros).
 508           $serial_older ||= ($type != FT_AUTOMAKE
 509                              && !$serial_seen && exists $serial{$basename});
 510
 511           my $macro = $1 || $2;
 512           if (!$serial_older && !defined $map{$macro})
 513             {
 514               verb "found macro $macro in $file: $.";
 515               $map{$macro} = $file;
 516               push @{$invmap{$basename}}, $macro;
 517             }
 518           else
 519             {
 520               # Note: we used to give an error here if we saw a
 521               # duplicated macro.  However, this turns out to be
 522               # extremely unpopular.  It causes actual problems which
 523               # are hard to work around, especially when you must
 524               # mix-and-match tool versions.
 525               verb "ignoring macro $macro in $file: $.";
 526             }
 527         }
 528
 529       while ($line =~ /$m4_include_rx/go)
 530         {
 531           my $ifile = $2 || $3;
 532           # Skip missing `sinclude'd files.
 533           next if $1 eq 's' && ! -f $ifile;
 534           # m4_include is relative to the directory of the file which
 535           # perform the include, but we want paths relative to the
 536           # directory where aclocal is run.  Do not use
 537           # File::Spec->rel2abs, because we want to store relative
 538           # paths (they might be used later of aclocal outputs an
 539           # m4_include for this file, or if the user itself includes
 540           # this file).
 541           $ifile = "$dirname/$ifile"
 542             unless $dirname eq '.' || File::Spec->file_name_is_absolute ($ifile);
 543           push (@inc_files, $ifile);
 544           $inc_lines{$ifile} = $.;
 545         }
 546     }
 547
 548   # Ignore any file that has an old serial (or no serial if we know
 549   # another one with a serial).
 550   return ()
 551     if ($serial_older ||
 552         ($type != FT_AUTOMAKE && !$serial_seen && exists $serial{$basename}));
 553
 554   $file_contents{$file} = $contents;
 555
 556   # For some reason I don't understand, it does not work
 557   # to do `map { scan_file ($_, ...) } @inc_files' below.
 558   # With Perl 5.8.2 it undefines @inc_files.
 559   my @copy = @inc_files;
 560   my @all_inc_files = (@inc_files,
 561                        map { scan_file ($type, $_,
 562                                         "$file:$inc_lines{$_}") } @copy);
 563   $file_includes{$file} = \@all_inc_files;
 564   return @all_inc_files;
 565 }
 566
 567 # strip_redundant_includes (%FILES)
 568 # ---------------------------------
 569 # Each key in %FILES is a file that must be present in the output.
 570 # However some of these files might already include other files in %FILES,
 571 # so there is no point in including them another time.
 572 # This removes items of %FILES which are already included by another file.
 573 sub strip_redundant_includes (%)
 574 {
 575   my %files = @_;
 576
 577   # Always include acinclude.m4, even if it does not appear to be used.
 578   $files{'acinclude.m4'} = 1 if -f 'acinclude.m4';
 579   # File included by $configure_ac are redundant.
 580   $files{$configure_ac} = 1;
 581
 582   # Files at the end of @file_order should override those at the beginning,
 583   # so it is important to preserve these trailing files.  We can remove
 584   # a file A if it is going to be output before a file B that includes
 585   # file A, not the converse.
 586   foreach my $file (reverse @file_order)
 587     {
 588       next unless exists $files{$file};
 589       foreach my $ifile (@{$file_includes{$file}})
 590         {
 591           next unless exists $files{$ifile};
 592           delete $files{$ifile};
 593           verb "$ifile is already included by $file";
 594         }
 595     }
 596
 597   # configure.ac is implicitly included.
 598   delete $files{$configure_ac};
 599
 600   return %files;
 601 }
 602
 603 sub trace_used_macros ()
 604 {
 605   my %files = map { $map{$_} => 1 } keys %macro_seen;
 606   %files = strip_redundant_includes %files;
 607
 608   my $traces = ($ENV{AUTOM4TE} || 'autom4te');
 609   $traces .= " --language Autoconf-without-aclocal-m4 ";
 610   # All candidate files.
 611   $traces .= join (' ', grep { exists $files{$_} } @file_order) . " ";
 612   # All candidate macros.
 613   $traces .= join (' ',
 614                    (map { "--trace='$_:\$f::\$n::\$1'" } ('AC_DEFUN',
 615                                                           'AC_DEFUN_ONCE',
 616                                                           'AU_DEFUN')),
 617                    # Do not trace $1 for all other macros as we do
 618                    # not need it and it might contains harmful
 619                    # characters (like newlines).
 620                    (map { "--trace='$_:\$f::\$n'" } (keys %macro_seen)));
 621
 622   verb "running $traces $configure_ac";
 623
 624   my $tracefh = new Automake::XFile ("$traces $configure_ac |");
 625
 626   my %traced = ();
 627
 628   while ($_ = $tracefh->getline)
 629     {
 630       chomp;
 631       my ($file, $macro, $arg1) = split (/::/);
 632
 633       $traced{$macro} = 1 if exists $macro_seen{$macro};
 634
 635       $map_traced_defs{$arg1} = $file
 636         if ($macro eq 'AC_DEFUN'
 637             || $macro eq 'AC_DEFUN_ONCE'
 638             || $macro eq 'AU_DEFUN');
 639     }
 640
 641   $tracefh->close;
 642
 643   return %traced;
 644 }
 645
 646 sub scan_configure ()
 647 {
 648   # Make sure we include acinclude.m4 if it exists.
 649   if (-f 'acinclude.m4')
 650     {
 651       add_file ('acinclude.m4');
 652     }
 653   scan_configure_dep ($configure_ac);
 654 }
 655
 656 ################################################################
 657
 658 # Write output.
 659 # Return 0 iff some files were installed locally.
 660 sub write_aclocal ($@)
 661 {
 662   my ($output_file, @macros) = @_;
 663   my $output = '';
 664
 665   my %files = ();
 666   # Get the list of files containing definitions for the macros used.
 667   # (Filter out unused macro definitions with $map_traced_defs.  This
 668   # can happen when an Autoconf macro is conditionally defined:
 669   # aclocal sees the potential definition, but this definition is
 670   # actually never processed and the Autoconf implementation is used
 671   # instead.)
 672   for my $m (@macros)
 673     {
 674       $files{$map{$m}} = 1
 675         if (exists $map_traced_defs{$m}
 676             && $map{$m} eq $map_traced_defs{$m});
 677     }
 678   # Do not explicitly include a file that is already indirectly included.
 679   %files = strip_redundant_includes %files;
 680
 681   my $installed = 0;
 682
 683   for my $file (grep { exists $files{$_} } @file_order)
 684     {
 685       # Check the time stamp of this file, and of all files it includes.
 686       for my $ifile ($file, @{$file_includes{$file}})
 687         {
 688           my $mtime = mtime $ifile;
 689           $greatest_mtime = $mtime if $greatest_mtime < $mtime;
 690         }
 691
 692       # If the file to add looks like outside the project, copy it
 693       # to the output.  The regex catches filenames starting with
 694       # things like `/', `\', or `c:\'.
 695       if ($file_type{$file} != FT_USER
 696           || $file =~ m,^(?:\w:)?[\\/],)
 697         {
 698           if (!$install || $file_type{$file} != FT_SYSTEM)
 699             {
 700               # Copy the file into aclocal.m4.
 701               $output .= $file_contents{$file} . "\n";
 702             }
 703           else
 704             {
 705               # Install the file (and any file it includes).
 706               my $dest;
 707               for my $ifile (@{$file_includes{$file}}, $file)
 708                 {
 709                   $dest = "$user_includes[0]/" . basename $ifile;
 710                   verb "installing $ifile to $dest";
 711                   install_file ($ifile, $dest);
 712                 }
 713               $installed = 1;
 714             }
 715         }
 716       else
 717         {
 718           # Otherwise, simply include the file.
 719           $output .= "m4_include([$file])\n";
 720         }
 721     }
 722
 723   if ($installed)
 724     {
 725       verb "running aclocal anew, because some files were installed locally";
 726       return 0;
 727     }
 728
 729   # Nothing to output?!
 730   # FIXME: Shouldn't we diagnose this?
 731   return 1 if ! length ($output);
 732
 733   # We used to print `# $output_file generated automatically etc.'  But
 734   # this creates spurious differences when using autoreconf.  Autoreconf
 735   # creates aclocal.m4t and then rename it to aclocal.m4, but the
 736   # rebuild rules generated by Automake create aclocal.m4 directly --
 737   # this would gives two ways to get the same file, with a different
 738   # name in the header.
 739   $output = "# generated automatically by aclocal $VERSION -*- Autoconf -*-
 740
 741 # Copyright (C) 1996, 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004,
 742 # 2005  Free Software Foundation, Inc.
 743 # This file is free software; the Free Software Foundation
 744 # gives unlimited permission to copy and/or distribute it,
 745 # with or without modifications, as long as this notice is preserved.
 746
 747 # This program is distributed in the hope that it will be useful,
 748 # but WITHOUT ANY WARRANTY, to the extent permitted by law; without
 749 # even the implied warranty of MERCHANTABILITY or FITNESS FOR A
 750 # PARTICULAR PURPOSE.
 751
 752 $output";
 753
 754   # We try not to update $output_file unless necessary, because
 755   # doing so invalidate Autom4te's cache and therefore slows down
 756   # tools called after aclocal.
 757   #
 758   # We need to overwrite $output_file in the following situations.
 759   #   * The --force option is in use.
 760   #   * One of the dependencies is younger.
 761   #     (Not updating $output_file in this situation would cause
 762   #     make to call aclocal in loop.)
 763   #   * The contents of the current file are different from what
 764   #     we have computed.
 765   if (!$force_output
 766       && $greatest_mtime < mtime ($output_file)
 767       && $output eq contents ($output_file))
 768     {
 769       verb "$output_file unchanged";
 770       return 1;
 771     }
 772
 773   verb "writing $output_file";
 774
 775   if (!$dry_run)
 776     {
 777       my $out = new Automake::XFile "> $output_file";
 778       print $out $output;
 779     }
 780   return 1;
 781 }
 782
 783 ################################################################
 784
 785 # Print usage and exit.
 786 sub usage ($)
 787 {
 788   my ($status) = @_;
 789
 790   print "Usage: aclocal [OPTIONS] ...
 791
 792 Generate `aclocal.m4' by scanning `configure.ac' or `configure.in'
 793
 794 Options:
 795       --acdir=DIR           directory holding config files (for debugging)
 796       --diff[=COMMAND]      run COMMAND [diff -u] on M4 files that would be
 797                               changed (implies --install and --dry-run)
 798       --dry-run             pretend to, but do not actually update any file
 799       --force               always update output file
 800       --help                print this help, then exit
 801   -I DIR                    add directory to search list for .m4 files
 802       --install             copy third-party files to the first -I directory
 803       --output=FILE         put output in FILE (default aclocal.m4)
 804       --print-ac-dir        print name of directory holding m4 files, then exit
 805       --verbose             don't be silent
 806       --version             print version number, then exit
 807   -W, --warnings=CATEGORY   report the warnings falling in CATEGORY
 808
 809 Warning categories include:
 810   `syntax'        dubious syntactic constructs (default)
 811   `unsupported'   unknown macros (default)
 812   `all'           all the warnings (default)
 813   `no-CATEGORY'   turn off warnings in CATEGORY
 814   `none'          turn off all the warnings
 815   `error'         treat warnings as errors
 816
 817 Report bugs to <bug-automake\@gnu.org>.\n";
 818
 819   exit $status;
 820 }
 821
 822 # Print version and exit.
 823 sub version()
 824 {
 825   print <<EOF;
 826 aclocal (GNU $PACKAGE) $VERSION
 827 Written by Tom Tromey <tromey\@redhat.com>
 828        and Alexandre Duret-Lutz <adl\@gnu.org>.
 829
 830 Copyright (C) 2005 Free Software Foundation, Inc.
 831 This is free software; see the source for copying conditions.  There is NO
 832 warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
 833 EOF
 834   exit 0;
 835 }
 836
 837 # Parse command line.
 838 sub parse_arguments ()
 839 {
 840   my $print_and_exit = 0;
 841   my $diff_command;
 842
 843   my %cli_options =
 844     (
 845      'acdir=s'          => sub # Setting --acdir overrides both the
 846                              { # automake (versioned) directory and the
 847                                # public (unversioned) system directory.
 848                                @automake_includes = ();
 849                                @system_includes = ($_[1])
 850                              },
 851      'diff:s'           => \$diff_command,
 852      'dry-run'          => \$dry_run,
 853      'force'            => \$force_output,
 854      'I=s'              => \@user_includes,
 855      'install'          => \$install,
 856      'output=s'         => \$output_file,
 857      'print-ac-dir'     => \$print_and_exit,
 858      'verbose'          => sub { setup_channel 'verb', silent => 0; },
 859      'W|warnings=s'     => \&parse_warnings,
 860      );
 861   use Getopt::Long;
 862   Getopt::Long::config ("bundling", "pass_through");
 863
 864   # See if --version or --help is used.  We want to process these before
 865   # anything else because the GNU Coding Standards require us to
 866   # `exit 0' after processing these options, and we can't guarantee this
 867   # if we treat other options first.  (Handling other options first
 868   # could produce error diagnostics, and in this condition it is
 869   # confusing if aclocal does `exit 0'.)
 870   my %cli_options_1st_pass =
 871     (
 872      'version' => \&version,
 873      'help'    => sub { usage(0); },
 874      # Recognize all other options (and their arguments) but do nothing.
 875      map { $_ => sub {} } (keys %cli_options)
 876      );
 877   my @ARGV_backup = @ARGV;
 878   Getopt::Long::GetOptions %cli_options_1st_pass
 879     or exit 1;
 880   @ARGV = @ARGV_backup;
 881
 882   # Now *really* process the options.  This time we know that --help
 883   # and --version are not present, but we specify them nonetheless so
 884   # that ambiguous abbreviation are diagnosed.
 885   Getopt::Long::GetOptions %cli_options, 'version' => sub {}, 'help' => sub {}
 886     or exit 1;
 887
 888   if (@ARGV)
 889     {
 890       my %argopts;
 891       for my $k (keys %cli_options)
 892         {
 893           if ($k =~ /(.*)=s$/)
 894             {
 895               map { $argopts{(length ($_) == 1)
 896                              ? "-$_" : "--$_" } = 1; } (split (/\|/, $1));
 897             }
 898         }
 899       if (exists $argopts{$ARGV[0]})
 900         {
 901           fatal ("option `$ARGV[0]' requires an argument\n"
 902                  . "Try `$0 --help' for more information.");
 903         }
 904       else
 905         {
 906           fatal ("unrecognized option `$ARGV[0]'\n"
 907                  . "Try `$0 --help' for more information.");
 908         }
 909     }
 910
 911   if ($print_and_exit)
 912     {
 913       print "@system_includes\n";
 914       exit 0;
 915     }
 916
 917   if (defined $diff_command)
 918     {
 919       $diff_command = 'diff -u' if $diff_command eq '';
 920       @diff_command = split (' ', $diff_command);
 921       $install = 1;
 922       $dry_run = 1;
 923     }
 924
 925   if ($install && !@user_includes)
 926     {
 927       fatal ("--install should copy macros in the directory indicated by the"
 928              . "\nfirst -I option, but no -I was supplied.");
 929     }
 930
 931   if (! -d $system_includes[0])
 932     {
 933       # By default $(datadir)/aclocal doesn't exist.  We don't want to
 934       # get an error in the case where we are searching the default
 935       # directory and it hasn't been created.  (We know
 936       # @system_includes has its default value if @automake_includes
 937       # is not empty, because --acdir is the only way to change this.)
 938       @system_includes = () if @automake_includes;
 939     }
 940   else
 941     {
 942       # Finally, adds any directory listed in the `dirlist' file.
 943       if (open (DIRLIST, "$system_includes[0]/dirlist"))
 944         {
 945           while (<DIRLIST>)
 946             {
 947               # Ignore '#' lines.
 948               next if /^#/;
 949               # strip off newlines and end-of-line comments
 950               s/\s*\#.*$//;
 951               chomp;
 952               push (@system_includes, $_) if -d $_;
 953             }
 954           close (DIRLIST);
 955         }
 956     }
 957 }
 958
 959 ################################################################
 960
 961 parse_WARNINGS;             # Parse the WARNINGS environment variable.
 962 parse_arguments;
 963 $configure_ac = require_configure_ac;
 964
 965 # We may have to rerun aclocal if some file have been installed, but
 966 # it should not happen more than once.  The reason we must run again
 967 # is that once the file has been moved from /usr/share/aclocal/ to the
 968 # local m4/ directory it appears at a new place in the search path,
 969 # hence it should be output at a different position in aclocal.m4.  If
 970 # we did not rerun aclocal, the next run of aclocal would produce a
 971 # different aclocal.m4.
 972 my $loop = 0;
 973 while (1)
 974   {
 975     ++$loop;
 976     prog_error "Too many loops." if $loop > 2;
 977
 978     reset_maps;
 979     scan_m4_files;
 980     scan_configure;
 981     last if $exit_code;
 982     my %macro_traced = trace_used_macros;
 983     last if write_aclocal ($output_file, keys %macro_traced);
 984     last if $dry_run;
 985   }
 986 check_acinclude;
 987
 988 exit $exit_code;
 989
 990 ### Setup "GNU" style for perl-mode and cperl-mode.
 991 ## Local Variables:
 992 ## perl-indent-level: 2
 993 ## perl-continued-statement-offset: 2
 994 ## perl-continued-brace-offset: 0
 995 ## perl-brace-offset: 0
 996 ## perl-brace-imaginary-offset: 0
 997 ## perl-label-offset: -2
 998 ## cperl-indent-level: 2
 999 ## cperl-brace-offset: 0
1000 ## cperl-continued-brace-offset: 0
1001 ## cperl-label-offset: -2
1002 ## cperl-extra-newline-before-brace: t
1003 ## cperl-merge-trailing-else: nil
1004 ## cperl-continued-statement-offset: 2
1005 ## End: