m4/amversion.in

   1 ##                                                          -*- Autoconf -*-
   2 ## @configure_input@
   3 # Copyright (C) 2002-2012 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # AM_AUTOMAKE_VERSION(VERSION)
  10 # ----------------------------
  11 # Automake X.Y traces this macro to ensure aclocal.m4 has been
  12 # generated from the m4 files accompanying Automake X.Y.
  13 # (This private macro should not be called outside this file.)
  14 AC_DEFUN([AM_AUTOMAKE_VERSION],
  15 [am__api_version='@APIVERSION@'
  16 dnl Some users find AM_AUTOMAKE_VERSION and mistake it for a way to
  17 dnl require some minimum version.  Point them to the right macro.
  18 m4_if([$1], [@VERSION@], [],
  19       [AC_FATAL([Do not call $0, use AM_INIT_AUTOMAKE([$1]).])])dnl
  20 ])
  21
  22 # _AM_AUTOCONF_VERSION(VERSION)
  23 # -----------------------------
  24 # aclocal traces this macro to find the Autoconf version.
  25 # This is a private macro too.  Using m4_define simplifies
  26 # the logic in aclocal, which can simply ignore this definition.
  27 m4_define([_AM_AUTOCONF_VERSION], [])
  28
  29 # AM_SET_CURRENT_AUTOMAKE_VERSION
  30 # -------------------------------
  31 # Call AM_AUTOMAKE_VERSION and AM_AUTOMAKE_VERSION so they can be traced.
  32 # This function is AC_REQUIREd by AM_INIT_AUTOMAKE.
  33 AC_DEFUN([AM_SET_CURRENT_AUTOMAKE_VERSION],
  34 [AM_AUTOMAKE_VERSION([@VERSION@])dnl
  35 m4_ifndef([AC_AUTOCONF_VERSION],
  36   [m4_copy([m4_PACKAGE_VERSION], [AC_AUTOCONF_VERSION])])dnl
  37 _AM_AUTOCONF_VERSION(m4_defn([AC_AUTOCONF_VERSION]))])