m4/minuso.m4

   1 ##                                                          -*- Autoconf -*-
   2 # Copyright (C) 1999, 2000, 2001, 2003, 2004, 2005
   3 # Free Software Foundation, Inc.
   4 #
   5 # This file is free software; the Free Software Foundation
   6 # gives unlimited permission to copy and/or distribute it,
   7 # with or without modifications, as long as this notice is preserved.
   8
   9 # serial 5
  10
  11 # AM_PROG_CC_C_O
  12 # --------------
  13 # Like AC_PROG_CC_C_O, but changed for automake.
  14 AC_DEFUN([AM_PROG_CC_C_O],
  15 [AC_REQUIRE([AC_PROG_CC_C_O])dnl
  16 AC_REQUIRE([AM_AUX_DIR_EXPAND])dnl
  17 AC_REQUIRE_AUX_FILE([compile])dnl
  18 # FIXME: we rely on the cache variable name because
  19 # there is no other way.
  20 set dummy $CC
  21 ac_cc=`echo $[2] | sed ['s/[^a-zA-Z0-9_]/_/g;s/^[0-9]/_/']`
  22 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" != yes"; then
  23    # Losing compiler, so override with the script.
  24    # FIXME: It is wrong to rewrite CC.
  25    # But if we don't then we get into trouble of one sort or another.
  26    # A longer-term fix would be to have automake use am__CC in this case,
  27    # and then we could set am__CC="\$(top_srcdir)/compile \$(CC)"
  28    CC="$am_aux_dir/compile $CC"
  29 fi
  30 dnl Make sure AC_PROG_CC is never called again, or it will override our
  31 dnl setting of CC.
  32 m4_define([AC_PROG_CC],
  33           [m4_fatal([AC_PROG_CC cannot be called after AM_PROG_CC_C_O])])
  34 ])