m4/cond.m4

   1 # AM_CONDITIONAL                                              -*- Autoconf -*-
   2
   3 # Copyright (C) 1997, 2000, 2001, 2003, 2004 Free Software Foundation, Inc.
   4
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2, or (at your option)
   8 # any later version.
   9
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; if not, write to the Free Software
  17 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  18 # 02111-1307, USA.
  19
  20 # serial 6
  21
  22 # AM_CONDITIONAL(NAME, SHELL-CONDITION)
  23 # -------------------------------------
  24 # Define a conditional.
  25 AC_DEFUN([AM_CONDITIONAL],
  26 [AC_PREREQ(2.52)dnl
  27  ifelse([$1], [TRUE],  [AC_FATAL([$0: invalid condition: $1])],
  28         [$1], [FALSE], [AC_FATAL([$0: invalid condition: $1])])dnl
  29 AC_SUBST([$1_TRUE])
  30 AC_SUBST([$1_FALSE])
  31 if $2; then
  32   $1_TRUE=
  33   $1_FALSE='#'
  34 else
  35   $1_TRUE='#'
  36   $1_FALSE=
  37 fi
  38 AC_CONFIG_COMMANDS_PRE(
  39 [if test -z "${$1_TRUE}" && test -z "${$1_FALSE}"; then
  40   AC_MSG_ERROR([[conditional "$1" was never defined.
  41 Usually this means the macro was only invoked conditionally.]])
  42 fi])])