tests/tools.at

   1 #                                                       -*- Autotest -*-
   2
   3 AT_BANNER([Executables (autoheader, autoupdate...).])
   4
   5 # Copyright (C) 2000, 2001, 2003, 2004, 2006 Free Software Foundation, Inc.
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 ## ----------------------------- ##
  22 ## Syntax of the shell scripts.  ##
  23 ## ----------------------------- ##
  24
  25 # We use `/bin/sh -n script' to check that there are no syntax errors
  26 # in the scripts.  Although incredible, there are /bin/sh that go into
  27 # endless loops with `-n', e.g., SunOS's:
  28 #
  29 #   $ uname -a
  30 #   SunOS ondine 4.1.3 2 sun4m unknown
  31 #   $ cat endless.sh
  32 #   while false
  33 #   do
  34 #     :
  35 #   done
  36 #   exit 0
  37 #   $ time sh endless.sh
  38 #   sh endless.sh  0,02s user 0,03s system 78% cpu 0,064 total
  39 #   $ time sh -nx endless.sh
  40 #   ^Csh -nx endless.sh  3,67s user 0,03s system 63% cpu 5,868 total
  41 #
  42 # So before using `/bin/sh -n' to check our scripts, we first check
  43 # that `/bin/sh -n' is not broken to death.
  44
  45 AT_SETUP([Syntax of the shell scripts])
  46
  47 AT_CHECK([test "$ac_cv_sh_n_works" = yes || exit 77])
  48
  49 # Specify the absolute name of the tool, as some shells don't honor PATH when
  50 # running `sh PROG'.
  51
  52 AT_CHECK_SHELL_SYNTAX([$abs_top_builddir/bin/autoconf])
  53 AT_CHECK_SHELL_SYNTAX([$abs_top_builddir/tests/autoconf])
  54 AT_CHECK_SHELL_SYNTAX([$abs_top_builddir/tests/testsuite])
  55
  56 # These are not built, they are in the src tree.
  57 AT_CHECK_SHELL_SYNTAX([$abs_top_srcdir/build-aux/install-sh])
  58 AT_CHECK_SHELL_SYNTAX([$abs_top_srcdir/build-aux/missing])
  59
  60 AT_CLEANUP
  61
  62
  63
  64
  65 ## ---------------------------- ##
  66 ## Syntax of the Perl scripts.  ##
  67 ## ---------------------------- ##
  68
  69 AT_SETUP([Syntax of the Perl scripts])
  70
  71 AT_CHECK_PERL_SYNTAX([autoheader])
  72 AT_CHECK_PERL_SYNTAX([autom4te])
  73 AT_CHECK_PERL_SYNTAX([autoreconf])
  74 AT_CHECK_PERL_SYNTAX([autoscan])
  75 AT_CHECK_PERL_SYNTAX([autoupdate])
  76 AT_CHECK_PERL_SYNTAX([ifnames])
  77
  78 AT_CLEANUP
  79
  80
  81
  82
  83 ## ------------------ ##
  84 ## autom4te's cache.  ##
  85 ## ------------------ ##
  86
  87 AT_SETUP([autom4te cache])
  88
  89 AT_DATA_M4SUGAR([[script.4s]],
  90 [[m4_include([foo])
  91 ]])
  92
  93 # Everything is OK.
  94 touch foo
  95 AT_CHECK_M4SUGAR
  96
  97 # We moved a file: it should fail
  98 mkdir sub
  99 mv foo sub
 100 AT_CHECK_M4SUGAR([], [1], [],
 101 [m4:script.4s:1: cannot open `foo': No such file or directory
 102 autom4te: m4 failed with exit status: 1
 103 ])
 104
 105 # But if we change the main file, then we should no longer complain of
 106 # missing files.
 107 AT_DATA_M4SUGAR([[script.4s]],
 108 [[m4_include([sub/foo])
 109 ]])
 110 AT_CHECK_M4SUGAR
 111
 112 AT_CLEANUP
 113
 114
 115 # autom4te --force
 116 # ----------------
 117
 118 AT_SETUP([autom4te --force])
 119
 120 AT_DATA([file.m4],
 121 [[right
 122 ]])
 123 AT_CHECK_AUTOM4TE([-o file file.m4])
 124
 125 # Create a file whose time stamp is in the future.
 126 # (next year)-01-01 00:01 UTC should always be in the future,
 127 # even on slow machines.
 128 echo BAD >file
 129 this_year=`TZ=UTC0 date +%Y`
 130 TZ=UTC0 touch -t `expr $this_year + 1`01010001 file
 131
 132 AT_CHECK_AUTOM4TE([--force -o file file.m4])
 133 AT_CHECK([cat file], 0,
 134 [[right
 135 ]])
 136
 137 AT_CLEANUP
 138
 139
 140
 141
 142 ## ------------------ ##
 143 ## autoconf --trace.  ##
 144 ## ------------------ ##
 145
 146
 147 # autoconf --trace: user macros
 148 # -----------------------------
 149 AT_SETUP([autoconf --trace: user macros])
 150
 151 AT_DATA([configure.ac],
 152 [[m4_define([active], [ACTIVE])
 153 m4_define([TRACE1], [TRACE2(m4_shift($@))])
 154 m4_define([TRACE2], [[$2], $1])
 155
 156 # No arguments.
 157 TRACE1
 158 TRACE2
 159
 160 # With arguments, single line.
 161 TRACE1(foo, @bar, @baz)
 162 TRACE1(foo, TRACE1(bar, baz))
 163 TRACE1(foo, active, baz)
 164 TRACE1(foo, [active], TRACE1(active, [active]))
 165 ]])
 166
 167 # Several --traces.
 168 AT_CHECK_AUTOCONF([-t TRACE1 -t TRACE2], 0,
 169 [[configure.ac:6:TRACE1:
 170 configure.ac:6:TRACE2:
 171 configure.ac:7:TRACE2:
 172 configure.ac:10:TRACE1:foo:@bar:@baz
 173 configure.ac:10:TRACE2:@bar:@baz
 174 configure.ac:11:TRACE1:bar:baz
 175 configure.ac:11:TRACE2:baz
 176 configure.ac:11:TRACE1:foo::baz
 177 configure.ac:11:TRACE2::baz
 178 configure.ac:12:TRACE1:foo:ACTIVE:baz
 179 configure.ac:12:TRACE2:ACTIVE:baz
 180 configure.ac:13:TRACE1:ACTIVE:active
 181 configure.ac:13:TRACE2:active
 182 configure.ac:13:TRACE1:foo:active::ACTIVE
 183 configure.ac:13:TRACE2:active::ACTIVE
 184 ]])
 185
 186 # Several line requests.
 187 AT_CHECK_AUTOCONF([[-t TRACE1:'
 188 [$1], [$2], [$3].']], 0,
 189 [[
 190 [], [], [].
 191
 192 [foo], [@bar], [@baz].
 193
 194 [bar], [baz], [].
 195
 196 [foo], [], [baz].
 197
 198 [foo], [ACTIVE], [baz].
 199
 200 [ACTIVE], [active], [].
 201
 202 [foo], [active], [].
 203 ]])
 204
 205 # ${sep}@.
 206 AT_CHECK_AUTOCONF([-t TRACE2:'${)===(}@'], 0,
 207 [[[]
 208 []
 209 [@bar])===([@baz]
 210 [baz]
 211 [])===([baz]
 212 [ACTIVE])===([baz]
 213 [active]
 214 [active])===([])===([ACTIVE]
 215 ]])
 216
 217 # Arguments spanning multiple lines.
 218 AT_DATA([configure.ac],
 219 [[m4_define([TRACE], [])
 220 TRACE(foo
 221 bar,
 222 bar
 223 foo)
 224 ]])
 225
 226 AT_CHECK_AUTOCONF([-t TRACE:'$%'], 0,
 227 [[foo bar:bar foo
 228 ]])
 229
 230 AT_CLEANUP
 231
 232
 233 # autoconf --trace: builtins
 234 # --------------------------
 235 AT_SETUP([autoconf --trace: builtins])
 236
 237 AT_DATA([configure.ac],
 238 [[define([active], [ACTIVE])
 239 ]])
 240
 241 AT_CHECK_AUTOCONF([[-t define | sed -n '$p']],
 242          0,
 243 [[configure.ac:1:define:active:ACTIVE
 244 ]])
 245
 246 # FIXME: Without `$1' the following test dies.  Groumphf, once again to
 247 # dive into obscure feature interaction...
 248 # Note that using `-i' means we need the *.m4 files, not the *.m4f files,
 249 # hence we need srcdir, not builddir.
 250 AT_CHECK_AUTOCONF([[-t define:'$1' -i| sed -n '$p']],
 251          0,
 252 [[active
 253 ]])
 254
 255 AT_CLEANUP
 256
 257
 258
 259 ## ---------------------------- ##
 260 ## autoconf: forbidden tokens.  ##
 261 ## ---------------------------- ##
 262
 263
 264 # autoconf: forbidden tokens, basic
 265 # ---------------------------------
 266 AT_SETUP([autoconf: forbidden tokens, basic])
 267
 268 AT_DATA_M4SH([configure.ac],
 269 [[AS_INIT
 270 m4_foo
 271 _m4_bar
 272 AS_FOO
 273 _AS_BAR
 274 [dnl]
 275 ]])
 276
 277 AT_CHECK_AUTOCONF([], 1, [],
 278 [[configure.ac:2: error: possibly undefined macro: m4@&t@_foo
 279       If this token and others are legitimate, please use m4@&t@_pattern_allow.
 280       See the Autoconf documentation.
 281 configure.ac:3: error: possibly undefined macro: _m4@&t@_bar
 282 configure.ac:4: error: possibly undefined macro: AS@&t@_FOO
 283 configure.ac:5: error: possibly undefined macro: _AS@&t@_BAR
 284 configure.ac:6: error: possibly undefined macro: d@&t@nl
 285 ]])
 286 # Second run should succeed and yield no output.
 287 AT_CHECK([autoconf])
 288
 289 AT_CLEANUP
 290
 291
 292 # autoconf: forbidden tokens, exceptions
 293 # --------------------------------------
 294 AT_SETUP([autoconf: forbidden tokens, exceptions])
 295
 296 AT_DATA_M4SH([configure.ac],
 297 [[AS_INIT
 298
 299 # This is allowed in spite of the name.
 300 # It is on purpose that we check the case where there are several
 301 # tokens on the same line.
 302 m4_pattern_allow([^AS_ALLOWED$])
 303 NOT_AS_ALLOWED AS_ALLOWED AS_ALLOWED_NOT
 304
 305 # Test forbidding.
 306 m4_pattern_forbid([^FORBIDDEN$])
 307 NOT_FORBIDDEN FORBIDDEN FORBIDDEN_NOT
 308
 309 # Test Autoconf's patterns.
 310 AS_THIS_IS_INVALID and _AS_THIS_IS_INVALID_TOO
 311 BUT_AZ_THIS_IS_NOT ALTHOUGH_AS_THIS_IS
 312 # This is legal, although there is `AS_DEFINE' in there.
 313 BAS_DEFINE
 314 # AS_THIS_IS_A_COMMENT so just shut up.
 315 It would be very bad if Autoconf forgot to expand [AS_]INIT!
 316 ]])
 317
 318 AT_CHECK_AUTOCONF([], 1, [],
 319 [[configure.ac:1: error: possibly undefined macro: AS@&t@_INIT
 320       If this token and others are legitimate, please use m4@&t@_pattern_allow.
 321       See the Autoconf documentation.
 322 configure.ac:7: error: possibly undefined macro: AS@&t@_ALLOWED_NOT
 323 configure.ac:10: error: possibly undefined macro: FORBIDDEN
 324 configure.ac:14: error: possibly undefined macro: AS@&t@_THIS_IS_INVALID
 325 configure.ac:14: error: possibly undefined macro: _AS@&t@_THIS_IS_INVALID_TOO
 326 ]])
 327
 328 AT_CLEANUP
 329
 330
 331 # autoconf: automatically allowed tokens
 332 # --------------------------------------
 333 AT_SETUP([autoconf: automatically allowed tokens])
 334
 335 AT_DATA_M4SH([configure.ac],
 336 [[AC_INIT
 337 m4_pattern_forbid([^FB_])
 338 AC_DEFINE([FB_ONE])
 339 AC_SUBST([FB_TWO])
 340 AC_OUTPUT
 341 ]])
 342
 343 AT_CHECK_AUTOCONF
 344
 345 AT_CLEANUP
 346
 347
 348 # autoconf: do not forbid the empty token
 349 # ---------------------------------------
 350 AT_SETUP([autoconf: the empty token])
 351
 352 AT_DATA_M4SH([configure.ac],
 353 [[m4_pattern_allow([^foo$])
 354 m4_divert([0])dnl
 355  line that begins with a space
 356 ]])
 357
 358 AT_CHECK_AUTOCONF
 359
 360 AT_CLEANUP
 361
 362
 363 # autoconf: subdirectories
 364 # ------------------------
 365 AT_SETUP([autoconf: subdirectories])
 366
 367 AT_DATA([configure.ac],
 368 [[AC_INIT
 369 AC_PROG_MKDIR_P
 370 AC_CONFIG_FILES(sub/foo)
 371 AC_OUTPUT
 372 ]])
 373
 374 mkdir sub
 375
 376 AT_DATA([sub/foo.in],
 377 [[@MKDIR_P@
 378 ]])
 379
 380 AT_DATA([install-sh])
 381
 382 AT_CHECK_AUTOCONF
 383 AT_CHECK_CONFIGURE
 384 AT_CHECK([[grep '^[^/].*/mkdir -p' sub/foo]], 1)
 385
 386 AT_CLEANUP
 387
 388
 389 # autoconf: input from stdin
 390 # --------------------------
 391 AT_SETUP([autoconf: input from stdin])
 392
 393 # Past Autoconf versions failed to read from stdin when other, non-frozen input
 394 # files were present.
 395 AT_DATA([aclocal.m4])
 396
 397 AT_CHECK([echo 'AC_INIT(X, 1.0, bug-autoconf@gnu.org)' | autoconf -t AC_INIT -],
 398          0, [stdin:1:AC_INIT:X:1.0:bug-autoconf@gnu.org
 399 ])
 400 AT_CHECK([echo 'AC_INIT(X, 2.0, bug-autoconf@gnu.org)' | autoconf -t AC_INIT -],
 401          0, [stdin:1:AC_INIT:X:2.0:bug-autoconf@gnu.org
 402 ])
 403
 404 AT_CLEANUP
 405
 406
 407
 408
 409 ## --------- ##
 410 ## ifnames.  ##
 411 ## --------- ##
 412
 413 AT_SETUP([ifnames])
 414
 415 AT_DATA([iftest1.c],
 416 [[#ifdef DEF1
 417 #ifndef DEF2
 418 #if ! defined DEF3 && defined DEF4 /* but not defined DEF5 */
 419     # if SPACES
 420         #       if      TABS
 421 /* #if C_COMMENTS */
 422 // #if CXX_COMMENTS
 423 #if LINE1 = \
 424 LINE2
 425 #if (VAL1*VAL2)==VAL3+VAL4 /* Not VAL5 !!! */
 426 ]])
 427
 428 AT_DATA([iftest2.c],
 429 [[#ifdef IFTEST2
 430 #if VAL1
 431 ]])
 432
 433 AT_CHECK([ifnames iftest1.c iftest2.c], 0,
 434 [DEF1 iftest1.c
 435 DEF2 iftest1.c
 436 DEF3 iftest1.c
 437 DEF4 iftest1.c
 438 IFTEST2 iftest2.c
 439 LINE1 iftest1.c
 440 LINE2 iftest1.c
 441 SPACES iftest1.c
 442 TABS iftest1.c
 443 VAL1 iftest1.c iftest2.c
 444 VAL2 iftest1.c
 445 VAL3 iftest1.c
 446 VAL4 iftest1.c
 447 ], [])
 448
 449 AT_CLEANUP
 450
 451
 452
 453 ## ------------ ##
 454 ## autoheader.  ##
 455 ## ------------ ##
 456
 457 # autoheader is intensively used in its modern form throughout this
 458 # test suite.  But we also have to check that acconfig.h still works.
 459 # autoheader uses autoconf --trace, so traces first.
 460
 461 AT_SETUP([autoheader])
 462
 463 AT_DATA([acconfig.h],
 464 [[/* Define this to whatever you want. */
 465 #undef this
 466 ]])
 467
 468
 469 # 1. Check that `acconfig.h' is still honored.
 470 AT_DATA([configure.ac],
 471 [[AC_INIT
 472 AC_CONFIG_HEADERS(config.h:config.hin)
 473 AC_DEFINE(this, "whatever you want.")
 474 ]])
 475
 476 AT_CHECK_AUTOHEADER([], [], [], [ignore])
 477 AT_CHECK([cat config.hin], 0,
 478 [[/* config.hin.  Generated from configure.ac by autoheader.  */
 479 /* Define this to whatever you want. */
 480 #undef this
 481
 482 /* Define to the address where bug reports for this package should be sent. */
 483 #undef PACKAGE_BUGREPORT
 484
 485 /* Define to the full name of this package. */
 486 #undef PACKAGE_NAME
 487
 488 /* Define to the full name and version of this package. */
 489 #undef PACKAGE_STRING
 490
 491 /* Define to the one symbol short name of this package. */
 492 #undef PACKAGE_TARNAME
 493
 494 /* Define to the version of this package. */
 495 #undef PACKAGE_VERSION
 496 ]])
 497
 498
 499 # 2. Check that missing templates are a fatal error.
 500 AT_DATA([configure.ac],
 501 [[AC_INIT
 502 AC_CONFIG_HEADERS(config.h:config.hin)
 503 AC_DEFINE(that, "whatever you want.")
 504 ]])
 505
 506 # The test suite goes too fast for the cache time stamps...
 507 # Pass --force.
 508 AT_CHECK_AUTOHEADER([--force], [1], [], [ignore])
 509
 510
 511 # 3. Check TOP and BOTTOM.
 512 AT_DATA([acconfig.h],
 513 [[/* Top from acconfig.h. */
 514 @TOP@
 515 /* Middle from acconfig.h. */
 516 @BOTTOM@
 517 /* Bottom from acconfig.h. */
 518 ]])
 519
 520 AT_DATA([configure.ac],
 521 [[AC_INIT
 522 AC_CONFIG_HEADERS(config.h:config.hin)
 523 AH_TOP([Top1 from configure.ac.])
 524 AH_TOP([Top2 from configure.ac.])
 525 AH_TOP([The Cat in a h@t.])
 526 AH_VERBATIM([Middle], [Middle from configure.ac.])
 527 AH_VERBATIM([Mouse],  [The Mouse in a h@t.])
 528 AH_BOTTOM([Bottom1 from configure.ac.])
 529 AH_BOTTOM([Bottom2 from configure.ac.])
 530 AH_BOTTOM([The Dog in a h@t.])
 531
 532 AC_DEFINE([ANT], [@], [The Ant in a h@t.])
 533 ]])
 534
 535
 536 # Yes, that's right: the `middle' part of `acconfig.h' is still before
 537 # the AH_TOP part.  But so what, you're not supposed to use the two
 538 # together.
 539 # Ignore STDERR which is the longuish complaint against autoheader junk
 540 # files.
 541 AT_CHECK_AUTOHEADER([--force], [], [], [ignore])
 542 AT_CHECK([cat config.hin], 0,
 543 [[/* config.hin.  Generated from configure.ac by autoheader.  */
 544 /* Top from acconfig.h. */
 545 /* Middle from acconfig.h. */
 546
 547 Top1 from configure.ac.
 548
 549 Top2 from configure.ac.
 550
 551 The Cat in a h@t.
 552
 553 /* The Ant in a h@t. */
 554 #undef ANT
 555
 556 Middle from configure.ac.
 557
 558 The Mouse in a h@t.
 559
 560 /* Define to the address where bug reports for this package should be sent. */
 561 #undef PACKAGE_BUGREPORT
 562
 563 /* Define to the full name of this package. */
 564 #undef PACKAGE_NAME
 565
 566 /* Define to the full name and version of this package. */
 567 #undef PACKAGE_STRING
 568
 569 /* Define to the one symbol short name of this package. */
 570 #undef PACKAGE_TARNAME
 571
 572 /* Define to the version of this package. */
 573 #undef PACKAGE_VERSION
 574
 575 Bottom1 from configure.ac.
 576
 577 Bottom2 from configure.ac.
 578
 579 The Dog in a h@t.
 580 /* Bottom from acconfig.h. */
 581 ]])
 582
 583 AT_CLEANUP
 584
 585
 586
 587
 588 ## ------------ ##
 589 ## autoupdate.  ##
 590 ## ------------ ##
 591
 592 # Check that AC_CANONICAL_SYSTEM and AC_OUTPUT are properly updated.
 593 AT_SETUP([autoupdate])
 594
 595 AT_DATA([configure.ac],
 596 [[AC_INIT(Test, 1.0)
 597 AC_CANONICAL_SYSTEM
 598 # The doc says 27 is a valid fubar.
 599 fubar=27
 600 AC_OUTPUT(Makefile, echo $fubar, fubar=$fubar)
 601 ]])
 602
 603 AT_DATA([expout],
 604 [[AC_INIT([Test],[1.0])
 605 AC_CANONICAL_TARGET
 606 # The doc says 27 is a valid fubar.
 607 fubar=27
 608 AC_CONFIG_FILES([Makefile])
 609 AC_CONFIG_COMMANDS([default],[echo $fubar],[fubar=$fubar])
 610 AC_OUTPUT
 611 ]])
 612
 613 # Checking `autoupdate'.
 614 AT_CHECK_AUTOUPDATE
 615 AT_CHECK([cat configure.ac], 0, [expout])
 616 # Checking that `autoupdate' is idempotent
 617 AT_CHECK_AUTOUPDATE
 618 AT_CHECK([cat configure.ac], 0, [expout])
 619
 620 AT_CLEANUP
 621
 622
 623 # autoupdating AC_LINK_FILES
 624 # --------------------------
 625 AT_SETUP([autoupdating AC_LINK_FILES])
 626
 627 AT_DATA([configure.ac],
 628 [[AC_INIT
 629 AC_LINK_FILES(dst1 dst2, src1 src2)
 630 AC_OUTPUT
 631 ]])
 632
 633 AT_DATA([dst1], dst1
 634 )
 635 AT_DATA([dst2], dst2
 636 )
 637
 638 # Checking `autoupdate'.
 639 AT_CHECK_AUTOUPDATE([], 0, [], ignore)
 640 AT_CHECK_AUTOCONF
 641 AT_CHECK_CONFIGURE
 642 AT_CHECK([cat src1], 0, [dst1
 643 ])
 644 AT_CHECK([cat src2], 0, [dst2
 645 ])
 646
 647 AT_CLEANUP
 648
 649
 650 # autoupdating AC_PREREQ
 651 # ----------------------
 652 AT_SETUP([autoupdating AC_PREREQ])
 653
 654 # Produce `AC_PREREQ(<AUTOUPDATE VERSION>)'.
 655 AT_CHECK([autoupdate --version | sed 's/.*) //;q'], 0, [stdout])
 656 autoupdate_version=`cat stdout`
 657 echo "AC_PREREQ($autoupdate_version)" >expout
 658
 659 AT_CHECK([echo "AC_PREREQ(1.0)" | autoupdate -],
 660          0, [expout], [])
 661
 662 AT_CHECK([echo "AC_PREREQ($autoupdate_version)" | autoupdate -],
 663          0, [expout], [])
 664
 665 AT_CHECK([echo "AC_PREREQ(999.99)" | autoupdate -],
 666          63, [], [ignore])
 667
 668 AT_CLEANUP
 669
 670
 671 # autoupdating AU_ALIAS
 672 # ---------------------
 673 AT_SETUP([autoupdating AU_ALIAS])
 674
 675 AT_DATA([configure.ac],
 676 [[AC_INIT
 677 AC_DEFUN([FOO], [$#])
 678 AU_ALIAS([BAZ],[FOO])
 679 test "FOO:FOO():FOO(x) BAZ:BAZ():BAZ(x)" = "0:1:1 0:1:1" || exit 1
 680 AC_PROG_CC
 681 AC_STDC_HEADERS
 682 AC_OUTPUT
 683 ]])
 684
 685 # Checking `autoupdate'.
 686 AT_CHECK_AUTOUPDATE
 687 AT_CHECK_AUTOCONF
 688 AT_CHECK_CONFIGURE
 689 AT_CHECK([grep 'AC_HEADER_STDC(' configure.ac], 1, [ignore], [ignore])
 690 AT_CHECK([grep 'AC_HEADER_STDC' configure.ac], 0, [ignore], [ignore])
 691
 692 AT_CLEANUP
 693
 694
 695 # autoupdating OLD to NEW
 696 # -----------------------
 697
 698 # The example taken from the code comments.
 699 AT_SETUP([autoupdating OLD to NEW])
 700
 701 AT_DATA([aclocal.m4],
 702 [[AU_DEFUN([OLD], [NEW([$1, $2], m4@&t@_eval([$1 + $2]))])
 703 AC_DEFUN([NEW], [echo "sum($1) = $2"])
 704 ]])
 705
 706 AT_DATA([configure.ac],
 707 [[AC_INIT
 708 OLD(1, 2)
 709 NEW([0, 0], [0])
 710 ]])
 711
 712 # Checking `autoupdate'.
 713 AT_CHECK_AUTOUPDATE
 714 AT_CHECK_AUTOCONF
 715 AT_CHECK_CONFIGURE
 716 AT_CHECK([[grep 'NEW(\[1, 2], *\[3])' configure.ac]], 0, [ignore], [ignore])
 717 AT_CHECK([[grep 'NEW(\[0, 0], *\[0])' configure.ac]], 0, [ignore], [ignore])
 718
 719 AT_CLEANUP
 720
 721
 722 # autoupdating AC_HELP_STRING
 723 # ---------------------------
 724 AT_SETUP([autoupdating AC_HELP_STRING])
 725
 726 AT_DATA([configure.ac],
 727 [[AC_INIT
 728 AC_ARG_ENABLE([foo], [AC_HELP_STRING([--enable-foo], [foo bar])], [:], [:])
 729 ]])
 730
 731 # Checking `autoupdate'.
 732 AT_CHECK_AUTOUPDATE([], [], [], [ignore])
 733 AT_CHECK_AUTOCONF
 734 AT_CHECK_CONFIGURE([], [], [], [ignore])
 735 AT_CHECK([[grep '\[--enable-foo], *\[foo bar]' configure.ac]], 0, [ignore], [ignore])
 736
 737 AT_CLEANUP
 738
 739
 740 # autoupdating with m4sugar
 741 # -------------------------
 742 AT_SETUP([autoupdating with m4sugar])
 743
 744 AT_DATA([aclocal.m4],
 745 [[AU_DEFUN([OLD],
 746 [m4@&t@_pushdef([foo], [bar])dn@&t@l
 747 echo "foo $1 foo"
 748 m4@&t@_popdef([foo])dn@&t@l
 749 ])
 750 ]])
 751
 752 touch foo.in
 753
 754 AT_DATA([configure.ac],
 755 [[AC_PREREQ(2.54)
 756 m4_define([gnumeric_version_epoch], [1])
 757 AC_INIT
 758 OLD([ bla  bla ])
 759 AC_FOREACH([name], [n1 n2],
 760            [echo name
 761 ])
 762 AC_CHECKING([for feature])
 763 AC_MSG_RESULT_UNQUOTED([`echo done`])
 764
 765 AC_OUTPUT([foo])
 766 ]])
 767
 768 # Checking `autoupdate'.
 769 AT_CHECK_AUTOUPDATE([], [], [], [ignore])
 770 AT_CHECK_AUTOCONF
 771 AT_CHECK_CONFIGURE([], [], [], [ignore])
 772
 773 AT_CLEANUP
 774
 775
 776 # autoupdating AC_LANG_SAVE
 777 # -------------------------
 778 AT_SETUP([autoupdating AC_LANG_SAVE])
 779
 780 AT_DATA([configure.ac],
 781 [[AC_INIT
 782 AC_LANG_SAVE
 783 AC_LANG_RESTORE
 784 AC_LANG_SAVE
 785 AC_LANG_RESTORE
 786 ]])
 787
 788 # Checking `autoupdate'.
 789 AT_CHECK_AUTOUPDATE([], [], [], [ignore])
 790 AT_CHECK_AUTOCONF
 791 AT_CHECK_CONFIGURE([], [], [], [ignore])
 792
 793 AT_CLEANUP
 794
 795
 796 # autoupdating AC_FOREACH
 797 # -----------------------
 798 AT_SETUP([autoupdating AC_FOREACH])
 799
 800 AT_DATA([aclocal.m4],
 801 [[AU_DEFUN([OLD], [AC_FOREACH([myvar], [4 5 6], [' myvar'])])
 802 ]])
 803
 804 AT_DATA([configure.ac],
 805 [[AC_INIT
 806 echo AC_FOREACH([myvar], [1 2 3], [' myvar'])OLD
 807 ]])
 808
 809 # Checking `autoupdate'.
 810 AT_CHECK_AUTOUPDATE
 811 AT_CHECK([[grep 'echo 1 2 3 4 5 6' configure.ac]], 1, [ignore], [ignore])
 812 AT_CHECK([[grep 'm4@&t@_foreach_w' configure.ac]], 0, [ignore], [ignore])
 813 AT_CHECK_AUTOCONF
 814 AT_CHECK_CONFIGURE([], [0], [stdout])
 815 AT_CHECK([[grep ' 1 2 3 4 5 6' stdout]], 0, [ignore], [ignore])
 816
 817 AT_CLEANUP
 818
 819
 820 # autoupdating with aclocal and m4_include
 821 # ----------------------------------------
 822 AT_SETUP([autoupdating with aclocal and m4@&t@_include])
 823
 824 # We use aclocal.
 825 AT_CHECK([aclocal --version || exit 77], [], [ignore], [ignore])
 826
 827 mkdir m4 aclocal
 828 AT_DATA([configure.in],
 829 [[AC_INIT(x,0)
 830 AC_UNCHANGED_MACRO
 831 AC_OLD_MACRO
 832 AC_OUTPUT
 833 ]])
 834 AT_DATA([m4/stuff.m4],
 835 [[AU_ALIAS([AC_OLD_MACRO], [AC_NEW_MACRO])
 836 AC_DEFUN([AC_NEW_MACRO], [echo hi])
 837 AC_DEFUN([AC_UNCHANGED_MACRO], [echo one])
 838 ]])
 839 cp m4/stuff.m4 aclocal/stuff.m4
 840 AT_CHECK([aclocal -I aclocal], [0], [ignore], [ignore])
 841 # Checking `autoupdate'.
 842 AT_CHECK_AUTOUPDATE
 843 AT_CHECK([aclocal -I m4], [0], [ignore], [ignore])
 844 AT_CHECK_AUTOUPDATE
 845
 846 AT_CLEANUP
 847
 848
 849 # Keeping autom4te.cfg complete
 850 # -----------------------------
 851
 852 AT_SETUP([autom4te preselections])
 853 : ${sleep='sleep 1'}    # Command to force different time stamps.
 854 # If this test should run on FAT file systems and older w32,
 855 # then setting $sleep correctly needs to be revisited.
 856
 857 # We use aclocal and automake.
 858 AT_CHECK([automake --version || exit 77], [], [ignore], [ignore])
 859 AT_CHECK([test ! -f $HOME/.autom4te.cfg || exit 77], [], [ignore], [ignore])
 860
 861 AT_DATA([configure.in],
 862 [[AC_INIT(GNU foo, 1.0)
 863 AM_INIT_AUTOMAKE
 864 AC_CONFIG_FILES([Makefile])
 865 AC_OUTPUT
 866 ]])
 867
 868 AT_DATA([Makefile.am],
 869 [[AUTOMAKE_OPTIONS = foreign
 870 ]])
 871
 872 $sleep # `aclocal.m4' should be strictly younger than its inputs
 873
 874 # If Autoconf is too old, or the user has turned caching off, skip:
 875 AT_CHECK([aclocal || { ret=$?; test $ret -eq 63 && ret=77; exit $ret; }],
 876          [], [], [ignore])
 877 AT_CHECK([test -d autom4te.cache || exit 77])
 878 AT_CHECK([autoconf])
 879
 880 # If this test fails due to missing entries in lib/autom4te.in, then
 881 # comparing the old and new requests is a good place to start debugging:
 882 cp autom4te.cache/requests old-requests
 883 echo newer >newer
 884 $sleep # if `configure' is regenerated, we want it to be strictly newer,
 885        # to catch the error consistently.
 886 AT_CHECK([aclocal], [], [], [ignore])
 887 AT_CHECK([automake --no-force --add-missing], [], [], [ignore])
 888 AT_CHECK([autoconf])
 889 AT_CHECK([test "`find configure -newer newer`" = "" ||
 890           { diff old-requests autom4te.cache/requests; exit 1; }])
 891
 892 AT_CLEANUP