tests/semantics.at

   1 #                                                       -*- Autotest -*-
   2
   3 AT_BANNER([Semantics.])
   4
   5 # Copyright (C) 2000, 2001, 2002, 2004, 2005, 2006, 2007 Free Software
   6 # Foundation, Inc.
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 ## -------------------------------- ##
  23 ## Members of the AC_CHECK family.  ##
  24 ## -------------------------------- ##
  25
  26
  27 # AC_CHECK_LIB
  28 # ------------
  29 # Well, I can't imagine a system where `cos' is neither in libc, nor
  30 # in libm.  Nor can I imagine a lib more likely to exists than libm.
  31 # But there are systems without libm, on which we don't want to have
  32 # this test fail, so exit successfully if `cos' is in libc.
  33 AT_CHECK_MACRO([AC_CHECK_LIB],
  34 [AC_TRY_LINK_FUNC(cos,
  35                   [AC_MSG_ERROR([`cos' is in `libc'], 77)])
  36
  37 AC_CHECK_LIB(m, cos,,
  38              [AC_MSG_ERROR([cannot find `cos' in `libm'])])
  39
  40 # No kidding, using variables was broken in 2.50 :(
  41 ac_sin=sin
  42 AC_CHECK_LIB(m, $ac_sin,,
  43       [AC_MSG_ERROR([cannot find `\$ac_sin' (= `$ac_sin') in `libm'])])
  44
  45 ac_m=m
  46 AC_CHECK_LIB($ac_m, acos,,
  47       [AC_MSG_ERROR([cannot find `acos' in `\$ac_m' (= `$ac_m')])])
  48
  49 ac_asin=asin
  50 AC_CHECK_LIB($ac_m, $ac_asin,,
  51       [AC_MSG_ERROR([cannot find `\$ac_asin' (= `$ac_asin') in `\$ac_m' (= `$at_m')])])
  52
  53 # But if the bug is in the caching mechanism, then be sure we
  54 # correctly detect failures.
  55
  56 AC_CHECK_LIB(m, cossack,
  57              [AC_MSG_ERROR([found `cossack' in `libm'])])
  58
  59 # No kidding, using variables was broken in 2.50 :(
  60 ac_sinner=sinner
  61 AC_CHECK_LIB(m, $ac_sinner,
  62       [AC_MSG_ERROR([found `\$ac_sinner' (= `$ac_sinner') in `libm'])])
  63
  64 ac_m=m
  65 AC_CHECK_LIB($ac_m, acossack,
  66       [AC_MSG_ERROR([found `acossack' in `\$ac_m' (= `$ac_m')])])
  67
  68 ac_asinner=asinner
  69 AC_CHECK_LIB($ac_m, $ac_asinner,
  70       [AC_MSG_ERROR([found `\$ac_asinner' (= `$ac_asinner') in `\$ac_m' (= `$at_m')])])
  71
  72 ])
  73
  74
  75 # AC_SEARCH_LIBS
  76 # --------------
  77 AT_CHECK_MACRO([AC_SEARCH_LIBS],
  78 [
  79 AC_SEARCH_LIBS(cos, oser m ust,,
  80              [AC_MSG_ERROR([cannot find `cos'])])
  81
  82 case "$ac_cv_search_cos" in
  83   -loser|-lust) AC_MSG_ERROR([jeez, $ac_cv_search_cos must be a cool library!]) ;;
  84 esac
  85 ])
  86
  87
  88 # AC_SEARCH_LIBS (none needed)
  89 # ----------------------------
  90 AT_CHECK_MACRO([AC_SEARCH_LIBS (none needed)],
  91 [
  92 AC_SEARCH_LIBS(printf, oser c ust,,
  93              [AC_MSG_ERROR([cannot find `printf'])])
  94
  95 case "$ac_cv_search_printf" in
  96   -loser|-lust) AC_MSG_ERROR([jeez, $ac_cv_search_printf must be a cool library!]) ;;
  97   -lc) AC_MSG_ERROR([huh, you need to give -lc?])
  98 esac
  99 ])
 100
 101
 102 # AC_CHECK_DECLS
 103 # --------------
 104 # Check that it performs the correct actions:
 105 AT_CHECK_MACRO([AC_CHECK_DECLS],
 106 [[AC_CHECK_DECLS([yes, no, myenum, mystruct, myfunc, mymacro1, mymacro2],,,
 107                  [[int yes = 1;
 108                    enum { myenum };
 109                    struct { int x[20]; } mystruct;
 110                    extern int myfunc();
 111                    #define mymacro1(arg) arg
 112                    #define mymacro2]])]],
 113 [AT_CHECK_DEFINES(
 114 [#define HAVE_DECL_MYENUM 1
 115 #define HAVE_DECL_MYFUNC 1
 116 #define HAVE_DECL_MYMACRO1 1
 117 #define HAVE_DECL_MYMACRO2 1
 118 #define HAVE_DECL_MYSTRUCT 1
 119 #define HAVE_DECL_NO 0
 120 #define HAVE_DECL_YES 1
 121 ])])
 122
 123
 124 # AC_CHECK_FUNCS
 125 # --------------
 126 # Check that it performs the correct actions:
 127 # Must define HAVE_PRINTF, but not HAVE_AUTOCONF_FTNIRP
 128 AT_CHECK_MACRO([AC_CHECK_FUNCS],
 129 [AC_CHECK_FUNCS(printf autoconf_ftnirp)],
 130 [AT_CHECK_DEFINES(
 131 [/* #undef HAVE_AUTOCONF_FTNIRP */
 132 #define HAVE_PRINTF 1
 133 ])])
 134
 135
 136 # AC_REPLACE_FUNCS
 137 # ----------------
 138 # Check that it performs the correct actions: autoconf_ftnirp.c must
 139 # be compiled, and must define HAVE_PRINTF, but not HAVE_AUTOCONF_FTNIRP
 140 # FIXME: Maybe check the traces?
 141 AT_SETUP([AC_REPLACE_FUNCS])
 142
 143 AT_DATA([config.in],
 144 [@LIBOBJS@
 145 ])
 146
 147 AT_CONFIGURE_AC(
 148 [AC_CONFIG_FILES(config.libobjs:config.in)
 149 AC_REPLACE_FUNCS(printf autoconf_ftnirp)])
 150
 151 AT_CHECK_AUTOCONF([-W obsolete])
 152 AT_CHECK_AUTOHEADER
 153 AT_CHECK_CONFIGURE
 154 AT_CHECK_ENV
 155 AT_CHECK_DEFINES(
 156 [/* #undef HAVE_AUTOCONF_FTNIRP */
 157 #define HAVE_PRINTF 1
 158 ])
 159
 160 AT_CHECK([sed 's/  */ /g;s/^ //;s/ $//' config.libobjs], [],
 161          [${LIBOBJDIR}autoconf_ftnirp$U.o
 162 ])
 163
 164 AT_CLEANUP
 165
 166
 167 # AC_CHECK_HEADERS
 168 # ----------------
 169 # Check that it performs the correct actions:
 170 # Must define HAVE_STDIO_H, but not HAVE_AUTOCONF_IO_H.
 171 AT_CHECK_MACRO([AC_CHECK_HEADERS],
 172 [AC_CHECK_HEADERS(stdio.h autoconf_io.h)],
 173 [AT_CHECK_DEFINES(
 174 [/* #undef HAVE_AUTOCONF_IO_H */
 175 #define HAVE_STDIO_H 1
 176 ])])
 177
 178
 179 # AC_CHECK_HEADERS_OLD
 180 # --------------------
 181 # Check that it performs the correct actions:
 182 # Must not check prerequisites, hence define header2.h
 183 AT_SETUP([AC_CHECK_HEADERS_OLD])
 184
 185 AT_DATA([header1.h],
 186 [typedef int foo;
 187 ])
 188
 189 AT_DATA([header2.h],
 190 [typedef foo bar;
 191 ])
 192
 193 AT_CONFIGURE_AC([AC_CHECK_HEADERS(header2.h, [], [], -)])
 194
 195 AT_CHECK_AUTOCONF([-W obsolete])
 196 AT_CHECK_AUTOHEADER
 197 AT_CHECK_CONFIGURE([CPPFLAGS=-I.])
 198 AT_CHECK_ENV
 199 AT_CHECK_DEFINES(
 200 [#define HAVE_HEADER2_H 1
 201 ])
 202
 203 AT_CLEANUP
 204
 205
 206 # AC_CHECK_HEADERS_NEW
 207 # --------------------
 208 # Check that it performs the correct actions:
 209 # Must check prerequisites, hence define header2.h but not header3.h
 210 AT_SETUP([AC_CHECK_HEADERS_NEW])
 211
 212 AT_DATA([header1.h],
 213 [typedef int foo;
 214 ])
 215
 216 AT_DATA([header2.h],
 217 [typedef foo bar;
 218 ])
 219
 220 AT_DATA([header3.h],
 221 [typedef bar wow;
 222 ])
 223
 224 AT_CONFIGURE_AC(
 225 [AC_CHECK_HEADERS(header2.h header3.h, [], [], [[@%:@include "header1.h"]])])
 226
 227 AT_CHECK_AUTOCONF([-W obsolete])
 228 AT_CHECK_AUTOHEADER
 229 AT_CHECK_CONFIGURE([CPPFLAGS=-I.])
 230 AT_CHECK_ENV
 231 AT_CHECK_DEFINES(
 232 [#define HAVE_HEADER2_H 1
 233 /* #undef HAVE_HEADER3_H */
 234 ])
 235
 236 AT_CLEANUP
 237
 238
 239 # AC_CHECK_MEMBERS
 240 # ----------------
 241 # Check that it performs the correct actions.
 242 # Must define HAVE_STRUCT_YES_S_YES, but not HAVE_STRUCT_YES_S_NO.
 243 AT_CHECK_MACRO([AC_CHECK_MEMBERS],
 244 [[AC_CHECK_MEMBERS([struct yes_s.yes, struct yes_s.no, struct yes_s.substruct],,,
 245                    [struct sub { int x; };
 246                     struct yes_s { int yes; struct sub substruct; };])]],
 247 [AT_CHECK_DEFINES(
 248 [/* #undef HAVE_STRUCT_YES_S_NO */
 249 #define HAVE_STRUCT_YES_S_SUBSTRUCT 1
 250 #define HAVE_STRUCT_YES_S_YES 1
 251 ])])
 252
 253
 254 # AC_CHECK_ALIGNOF
 255 # ----------------
 256 AT_CHECK_MACRO_CROSS([AC_CHECK_ALIGNOF],
 257 [[AC_CHECK_ALIGNOF(char)
 258 AC_CHECK_ALIGNOF(charchar,
 259 [[#include <stddef.h>
 260 #include <stdio.h>
 261 typedef char charchar[2];]])
 262 AC_CHECK_ALIGNOF(charcharchar)
 263 ]],
 264 [AT_CHECK_DEFINES(
 265 [#define ALIGNOF_CHAR 1
 266 #define ALIGNOF_CHARCHAR 1
 267 #define ALIGNOF_CHARCHARCHAR 0
 268 ])])
 269
 270
 271 # AC_CHECK_ALIGNOF struct
 272 # -----------------------
 273 AT_CHECK_MACRO_CROSS([AC_CHECK_ALIGNOF struct],
 274 [[AC_CHECK_ALIGNOF([struct { char c; }])
 275 AC_CHECK_ALIGNOF([struct nosuchstruct])
 276 ]],
 277 [AT_CHECK([[grep "#define ALIGNOF_STRUCT___CHAR_C___ [^0]" config.h]],
 278          0, ignore)
 279 AT_CHECK([[grep "#define ALIGNOF_STRUCT_NOSUCHSTRUCT 0" config.h]],
 280          0, ignore)
 281 ])
 282
 283 # AC_CHECK_SIZEOF
 284 # ---------------
 285 AT_CHECK_MACRO_CROSS([AC_CHECK_SIZEOF],
 286 [[AC_CHECK_SIZEOF(char)
 287 AC_CHECK_SIZEOF(charchar,,
 288 [[#include <stdio.h>
 289 typedef char charchar[2];]])
 290 AC_CHECK_SIZEOF(charcharchar)
 291 ]],
 292 [AT_CHECK_DEFINES(
 293 [#define SIZEOF_CHAR 1
 294 #define SIZEOF_CHARCHAR 2
 295 #define SIZEOF_CHARCHARCHAR 0
 296 ])])
 297
 298
 299 # AC_CHECK_SIZEOF struct
 300 # ----------------------
 301 AT_CHECK_MACRO_CROSS([AC_CHECK_SIZEOF struct],
 302 [[AC_C_CONST
 303 AC_CHECK_SIZEOF([struct x], [], [struct x { char c; int x; };])
 304 AC_CHECK_SIZEOF([const struct x], [], [struct x { const char *p; int x; };])
 305 AC_CHECK_SIZEOF([struct nosuchstruct])
 306 ]],
 307 [AT_CHECK([[grep "#define SIZEOF_STRUCT_X [^0]" config.h]],
 308          0, ignore)
 309 AT_CHECK([[grep "#define SIZEOF_CONST_STRUCT_X [^0]" config.h]],
 310          0, ignore)
 311 AT_CHECK([[grep "#define SIZEOF_STRUCT_NOSUCHSTRUCT 0" config.h]],
 312          0, ignore)
 313 ])
 314
 315
 316 # AC_CHECK_TYPES
 317 # --------------
 318 # Check that it performs the correct actions.
 319 # Must define HAVE_STRUCT_YES_S, HAVE_INT, but not HAVE_STRUCT_NO_S.
 320 # `int' and `struct yes_s' are both checked to test both the compiler
 321 # builtin types, and defined types.
 322 AT_CHECK_MACRO([AC_CHECK_TYPES],
 323 [[AC_CHECK_TYPES([int, struct yes_s, struct no_s],,,
 324                  [struct yes_s { int yes ;} ;])]],
 325 [AT_CHECK_DEFINES(
 326 [#define HAVE_INT 1
 327 /* #undef HAVE_STRUCT_NO_S */
 328 #define HAVE_STRUCT_YES_S 1
 329 ])])
 330
 331
 332 # AC_CHECK_TYPES
 333 # --------------
 334 # Check that we properly dispatch properly to the old implementation
 335 # or to the new one.
 336 AT_SETUP([AC_CHECK_TYPES: backward compatibility])
 337
 338 AT_DATA([configure.ac],
 339 [[AC_INIT
 340 define([_AC_CHECK_TYPE_NEW], [NEW])
 341 define([_AC_CHECK_TYPE_OLD], [OLD])
 342 #(cut-from-here
 343 AC_CHECK_TYPE(ptrdiff_t)
 344 AC_CHECK_TYPE(ptrdiff_t, int)
 345 AC_CHECK_TYPE(quad, long long int)
 346 AC_CHECK_TYPE(table_42, [int[42]])
 347 # Nice machine!
 348 AC_CHECK_TYPE(uint8_t, uint65536_t)
 349 AC_CHECK_TYPE(a,b,c,d)
 350 #to-here)
 351 AC_OUTPUT
 352 ]])
 353
 354 AT_CHECK_AUTOCONF
 355 AT_CHECK([[sed -e '/^#(cut-from-here/,/^#to-here)/!d' -e '/^#/d' configure]],
 356          0,
 357          [NEW
 358 OLD
 359 OLD
 360 OLD
 361 OLD
 362 NEW
 363 ])
 364
 365 AT_CLEANUP
 366
 367
 368 # AC_CHECK_FILES
 369 # --------------
 370 # FIXME: To really test HAVE_AC_EXISTS2 and HAVE_AC_MISSING2 we need to
 371 # open AH_TEMPLATE to `configure.ac', which is not yet the case.
 372 AT_CHECK_MACRO([AC_CHECK_FILES],
 373 [touch at-exists1 at-exists2
 374 ac_exists2=at-exists2
 375 ac_missing2=at-missing2
 376 AC_CHECK_FILES(at-exists1 at-missing1 $ac_exists2 $ac_missing2)
 377 rm at-exists1 at-exists2],
 378 [AT_CHECK_DEFINES(
 379 [#define HAVE_AT_EXISTS1 1
 380 /* #undef HAVE_AT_MISSING1 */
 381 ])])
 382
 383
 384
 385 ## ------------------------------ ##
 386 ## AC_CHECK_PROG & AC_PATH_PROG.  ##
 387 ## ------------------------------ ##
 388
 389
 390 # AT_CHECK_PROGS_PREPARE
 391 # ----------------------
 392 # Create a sub directory `path' with 6 subdirs which all 7 contain
 393 # an executable `tool'. `6' contains a `better' tool.
 394 m4_define([AT_CHECK_PROGS_PREPARE],
 395 [mkdir path
 396
 397 cat >path/tool <<\EOF
 398 #! /bin/sh
 399 exit 0
 400 EOF
 401 chmod +x path/tool
 402
 403 for i in 1 2 3 4 5 6
 404 do
 405   mkdir path/$i
 406   cp path/tool path/$i
 407 done
 408 cp path/tool path/6/better])
 409
 410
 411 # -------------------------------- #
 412 # AC_CHECK_PROG & AC_CHECK_PROGS.  #
 413 # -------------------------------- #
 414
 415 AT_SETUP([AC_CHECK_PROG & AC_CHECK_PROGS])
 416
 417 AT_CHECK_PROGS_PREPARE
 418
 419 AT_DATA([configure.ac],
 420 [[AC_INIT
 421 pwd=`pwd`
 422 p="1${PATH_SEPARATOR}2${PATH_SEPARATOR}3${PATH_SEPARATOR}4${PATH_SEPARATOR}5${PATH_SEPARATOR}6"
 423 path=`echo $p | sed -e 's,\([[0-9]]\),'"$pwd"'/path/\1,g'`
 424 fail=false
 425
 426 AC_CHECK_PROG(TOOL1, tool, found, not-found, $path)
 427 test "$TOOL1" = found || fail=:
 428
 429 # Yes, the semantics of this macro is weird.
 430 AC_CHECK_PROG(TOOL2, tool,, not-found, $path)
 431 test "$TOOL2" = not-found || fail=:
 432
 433 AC_CHECK_PROG(TOOL3, tool, tool, not-found, $path, $pwd/path/1/tool)
 434 test "$TOOL3" = "$pwd/path/2/tool" || fail=:
 435
 436 AC_CHECK_PROG(TOOL4, better, better, not-found, $path, $pwd/path/1/tool)
 437 test "$TOOL4" = better || fail=:
 438
 439 # When a tool is not found, and no value is given for not-found,
 440 # the variable is left empty.
 441 AC_CHECK_PROGS(TOOL5, missing,, $path)
 442 test -z "$TOOL5" || fail=:
 443
 444 AC_CHECK_PROGS(TOOL6, missing tool better,, $path)
 445 test "$TOOL6" = tool || fail=:
 446
 447 # No AC-OUTPUT, we don't need config.status.
 448 $fail &&
 449   AC_MSG_ERROR([[CHECK_PROG failed]])
 450 AS_EXIT(0)
 451 ]])
 452
 453 AT_CHECK_AUTOCONF
 454 AT_CHECK_CONFIGURE
 455
 456 AT_CLEANUP
 457
 458
 459
 460 ## ---------------- ##
 461 ## AC_C_BIGENDIAN.  ##
 462 ## ---------------- ##
 463
 464 AT_SETUP([AC_C_BIGENDIAN])
 465 AT_KEYWORDS([cross])
 466
 467 # Make sure that AC_C_BIGENDIAN behave the same whether we are
 468 # cross-compiling or not.
 469
 470 _AT_CHECK_AC_MACRO(
 471   [[AC_C_BIGENDIAN(
 472       [ac_endian=big],
 473       [ac_endian=little],
 474       [ac_endian=unknown],
 475       [ac_endian=universal])
 476    echo $ac_endian > at-endian
 477 ]])
 478
 479 rm -f config.hin  # So that next run of autoheader is quiet.
 480 _AT_CHECK_AC_MACRO(
 481   [[# Force cross compiling.
 482    cross_compiling=yes
 483    ac_tool_warned=yes
 484    AC_C_BIGENDIAN(
 485      [ac_endian=big],
 486      [ac_endian=little],
 487      [ac_endian=unknown],
 488      [ac_endian=universal])
 489    ac_prevendian=`cat at-endian`
 490    # Check that we have found the same result as in the previous run
 491    # or unknown (because the cross-compiling check is allowed to fail;
 492    # although it might be interesting to suppress this comparison, just
 493    # to know on which system it fails if it ever does).
 494    if test $ac_endian != $ac_prevendian && test $ac_endian != unknown; then
 495      AC_MSG_ERROR([unexpected endianness: first run found '$ac_prevendian' but second run found '$ac_endian'])
 496    fi
 497 ]])
 498
 499 # Make sure AC_C_BIGENDIAN with no argument will create a config.h template
 500 # containing "WORDS_BIGENDIAN".
 501 AT_CONFIGURE_AC([[AC_C_BIGENDIAN]])
 502 # --force is necessary, the computer might be too fast.
 503 AT_CHECK_AUTOHEADER([--force])
 504 AT_CHECK([grep WORDS_BIGENDIAN config.hin], [], [ignore])
 505
 506 AT_CLEANUP
 507
 508
 509 # ------------------------------ #
 510 # AC_PATH_PROG & AC_PATH_PROGS.  #
 511 # ------------------------------ #
 512
 513 AT_SETUP([AC_PATH_PROG & AC_PATH_PROGS])
 514
 515 AT_CHECK_PROGS_PREPARE
 516
 517 AT_DATA([configure.ac],
 518 [[AC_INIT
 519 pwd=`pwd`
 520 p="1${PATH_SEPARATOR}2${PATH_SEPARATOR}3${PATH_SEPARATOR}4${PATH_SEPARATOR}5${PATH_SEPARATOR}6"
 521 path=`echo $p | sed -e 's,\([[0-9]]\),'"$pwd"'/path/\1,g'`
 522 fail=false
 523
 524 AC_PATH_PROG(TOOL1, tool, not-found, $path)
 525 test "$TOOL1" = "$pwd/path/1/tool" || fail=:
 526
 527 AC_PATH_PROG(TOOL2, better, not-found, $path)
 528 test "$TOOL2" = "$pwd/path/6/better" || fail=:
 529
 530 # When a tool is not found, and no value is given for not-found,
 531 # the variable is left empty.
 532 AC_PATH_PROGS(TOOL3, missing,, $path)
 533 test -z "$TOOL3" || fail=:
 534
 535 AC_PATH_PROGS(TOOL4, missing tool better,, $path)
 536 test "$TOOL4" = "$pwd/path/1/tool" || fail=:
 537
 538 # No AC-OUTPUT, we don't need config.status.
 539 $fail &&
 540   AC_MSG_ERROR([[PATH_PROG failed]])
 541 AS_EXIT(0)
 542 ]])
 543
 544 AT_CHECK_AUTOCONF
 545 AT_CHECK_CONFIGURE
 546
 547 AT_CLEANUP
 548
 549
 550
 551
 552 ## -------------- ##
 553 ## AC_PATH_XTRA.  ##
 554 ## -------------- ##
 555
 556
 557 AT_SETUP([AC_PATH_XTRA])
 558
 559 _AT_CHECK_AC_MACRO([AC_PATH_XTRA])
 560
 561 # Check X_DISPLAY_MISSING.
 562 AT_CHECK_CONFIGURE([--without-x])
 563 AT_CHECK_DEFINES(
 564 [#define X_DISPLAY_MISSING 1
 565 ])
 566
 567 AT_CLEANUP
 568
 569
 570 ## ------------------------------- ##
 571 ## Obsolete non-updatable macros.  ##
 572 ## ------------------------------- ##
 573
 574
 575 AT_CHECK_MACRO([AC_SYS_RESTARTABLE_SYSCALLS], , ,[-W no-obsolete])
 576 AT_CHECK_MACRO([AC_FUNC_SETVBUF_REVERSED], , ,[-W no-obsolete])
 577 AT_CHECK_MACRO([AC_FUNC_WAIT3], , ,[-W no-obsolete])