configure.ac

   1 #                                                       -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1992, 1993, 1994, 1995, 1999, 2000, 2001, 2002, 2003,
   5 # 2004, 2005, 2006 Free Software Foundation, Inc.
   6
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20 # 02110-1301, USA.
  21
  22 # We need AC_CONFIG_TESTDIR.
  23 AC_PREREQ([2.59])
  24
  25 AC_INIT([GNU Autoconf], [2.59d], [bug-autoconf@gnu.org])
  26 AC_SUBST([PACKAGE_NAME])dnl
  27 AC_CONFIG_SRCDIR([ChangeLog])
  28
  29 AC_CONFIG_AUX_DIR([config])
  30 AC_CONFIG_FILES([config/Makefile])
  31
  32 AM_INIT_AUTOMAKE([check-news 1.7.9 dist-bzip2 readme-alpha])
  33
  34 # We use `/bin/sh -n script' to check that there are no syntax errors
  35 # in the scripts.  Although incredible, there are /bin/sh that go into
  36 # endless loops with `-n', e.g., SunOS's:
  37 #
  38 #   $ uname -a
  39 #   SunOS ondine 4.1.3 2 sun4m unknown
  40 #   $ cat endless.sh
  41 #   while false
  42 #   do
  43 #     :
  44 #   done
  45 #   exit 0
  46 #   $ time sh endless.sh
  47 #   sh endless.sh  0,02s user 0,03s system 78% cpu 0,064 total
  48 #   $ time sh -nx endless.sh
  49 #   ^Csh -nx endless.sh  3,67s user 0,03s system 63% cpu 5,868 total
  50 #
  51 # Also, some implementations of /bin/sh (e.g., Solaris 8) are soooo slow
  52 # that they are unusable on large scripts like our testsuite.
  53
  54 # So before using `/bin/sh -n' to check our scripts, we first check
  55 # that `/bin/sh -n' is known to not have these problems.
  56
  57 AC_CACHE_CHECK([whether /bin/sh -n is known to work], ac_cv_sh_n_works,
  58 [if (
  59     unset BASH_VERSION ZSH_VERSION
  60     /bin/sh -c '
  61       test -n "${BASH_VERSION+set}" || # Bash
  62       test -n "${KSH_VERSION+set}" || # pdksh
  63       test -n "${ZSH_VERSION+set}" || # zsh
  64       test -n "${.sh.version}" # ksh93; put this last since its syntax is dodgy
  65     '
  66   ) 2>/dev/null
  67 then ac_cv_sh_n_works=yes
  68 else ac_cv_sh_n_works=no
  69 fi
  70 ])
  71 AC_SUBST(ac_cv_sh_n_works)
  72
  73 # Initialize the test suite.
  74 AC_CONFIG_TESTDIR([tests])
  75 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
  76 AC_PATH_PROG([EXPR], [expr])
  77
  78
  79 ## ---- ##
  80 ## M4.  ##
  81 ## ---- ##
  82
  83 # We use an absolute name for GNU m4 so even if users have another m4 first in
  84 # their path, the installer can configure with a path that has GNU m4
  85 # first and get that path embedded in the installed autoconf and
  86 # autoheader scripts.
  87 AC_PROG_GNU_M4
  88 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  89   AC_MSG_ERROR([GNU M4 1.4 is required])
  90 fi
  91
  92 ## ----------- ##
  93 ## Man pages.  ##
  94 ## ----------- ##
  95
  96 AC_CONFIG_FILES(man/Makefile)
  97 AM_MISSING_PROG(HELP2MAN, help2man)
  98
  99
 100 ## ------ ##
 101 ## Perl.  ##
 102 ## ------ ##
 103
 104 # We use an absolute name for perl so the #! line in autoscan will work.
 105 AC_PATH_PROG([PERL], perl, no)
 106 AC_SUBST([PERL])dnl
 107 if test "$PERL" = no; then
 108   AC_MSG_ERROR([perl is not found])
 109 fi
 110 $PERL -e 'require 5.005_03;' || {
 111    AC_MSG_ERROR([Perl 5.005_03 or better is required])
 112 }
 113
 114
 115 ## ------- ##
 116 ## Emacs.  ##
 117 ## ------- ##
 118
 119 AC_CONFIG_FILES([lib/emacs/Makefile])
 120 TEST_EMACS=$EMACS
 121 test x"$TEST_EMACS" = xt && TEST_EMACS=
 122 AC_CHECK_PROGS([TEST_EMACS], [emacs xemacs], [no])
 123
 124 # autoconf-mode.el and autotest-mode.el do not work with older version of
 125 # Emacs (i.e. 18.x.x).  During byte-compilation, Emacs complains:
 126 # "Variable (broken nil) seen on pass 2 of byte compiler but not pass 1"
 127 # We detect this problem here.
 128 AS_IF([test "$TEST_EMACS" != no],
 129   [AC_CACHE_CHECK([whether $TEST_EMACS is sufficiently recent],
 130     [ac_cv_prog_emacs_ok],
 131     [# Note: The quoted "EOF" is intentional.  It protects the ` in the text.
 132     cat >conftest.el << "EOF"
 133       (defvar broken)
 134       (defun broken-mode () (setq broken-defaults `(broken nil)))
 135 EOF
 136     AS_IF([AC_RUN_LOG(
 137       [$TEST_EMACS -batch -q -f batch-byte-compile conftest.el 1>&2])],
 138       [ac_cv_prog_emacs_ok=yes], [ac_cv_prog_emacs_ok=no])
 139     rm -f conftest.el conftest.elc])
 140   AS_IF([test $ac_cv_prog_emacs_ok = no], [TEST_EMACS=no])])
 141
 142 AC_SUBST([EMACS], [$TEST_EMACS])
 143
 144 AM_PATH_LISPDIR
 145
 146
 147 ## ------------ ##
 148 ## Grep & sed.  ##
 149 ## ------------ ##
 150 AC_PROG_GREP
 151 AC_PROG_EGREP
 152 AC_PROG_SED
 153
 154
 155 ## ------------ ##
 156 ## Conclusion.  ##
 157 ## ------------ ##
 158
 159 AC_CONFIG_FILES([Makefile doc/Makefile
 160                  lib/Makefile lib/Autom4te/Makefile lib/autoscan/Makefile
 161                  lib/m4sugar/Makefile
 162                  lib/autoconf/Makefile lib/autotest/Makefile
 163                  bin/Makefile])
 164
 165 AC_OUTPUT
 166 # Report the state of this version of Autoconf if this is a beta.
 167 m4_bmatch(m4_defn([AC_PACKAGE_VERSION]),  [[a-z]],
 168 [    cat <<EOF
 169
 170 You are about to use an experimental version of Autoconf.  Be sure to
 171 read the relevant mailing lists, most importantly <autoconf@gnu.org>.
 172
 173 Below you will find information on the status of this version of Autoconf.
 174
 175
 176 EOF
 177     sed -n '/^\* Status/,$p' $srcdir/BUGS
 178 ])