configure.in

   1 # Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.49f)
   3 AC_INIT(GNU Autoconf, 2.49f, bug-autoconf@gnu.org)
   4 AC_CONFIG_SRCDIR(acgeneral.m4)
   5 AM_INIT_AUTOMAKE(autoconf, 2.49f)
   6
   7 # Initialize the test suite.
   8 AT_CONFIG(..)
   9 AC_PATH_PROG(EXPR, expr)
  10
  11 # We use a path for GNU m4 so even if users have another m4 first in
  12 # their path, the installer can configure with a path that has GNU m4
  13 # first and get that path embedded in the installed autoconf and
  14 # autoheader scripts.
  15 AC_PROG_GNU_M4
  16 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  17   AC_MSG_ERROR([GNU m4 1.4 is required])
  18 fi
  19 # This is needed because Automake does not seem to realize there is
  20 # a AC-SUBST inside AC-PROG-GNU-M4.  Grmph!
  21 AC_SUBST(M4)
  22
  23 # `autoconf' and `ifnames' use AWK.
  24 AC_PROG_AWK
  25
  26 # Generating man pages.
  27 AM_MISSING_PROG(HELP2MAN, help2man, $missing_dir)
  28
  29 # We use a path for perl so the #! line in autoscan will work.
  30 AC_PATH_PROG(PERL, perl, no)
  31 AC_SUBST(PERL)dnl
  32 AC_SUBST(PERLSCRIPTS)dnl
  33 if test "$PERL" != no; then
  34   PERLSCRIPTS="autoscan autoupdate"
  35 else
  36   AC_MSG_WARN([autoscan and autoupdate will not be built since perl is not found])
  37 fi
  38
  39 AC_PROG_INSTALL
  40
  41 # Work with the GNU or Cygnus source tree layout.
  42 if test -f $srcdir/standards.texi; then
  43   AC_SUBST(standards_texi, standards.texi)dnl
  44 fi
  45
  46 # Automake can't see inner AC_SUBSTS (`aclocal' is bypassed), so we tag the
  47 # AC_SUBSTS here too.
  48 AC_SUBST(PACKAGE_NAME)
  49 AC_SUBST(PACKAGE)
  50 AC_SUBST(VERSION)
  51
  52 AC_OUTPUT(Makefile m4/Makefile man/Makefile doc/Makefile
  53           tests/Makefile tests/atconfig)
  54
  55 # Report the state of this version of Autoconf if this is a beta.
  56 case AC_PACKAGE_VERSION in
  57   *[[a-z]]*)
  58     cat <<EOF
  59
  60 You are about to use an experimental version of Autoconf.  Be sure to
  61 read the relevant mailing lists, most importantly <autoconf@gnu.org>.
  62
  63 Below you will find information on the status of this version of Autoconf.
  64
  65
  66 EOF
  67     sed -n '/^\* Status/,$p' $srcdir/BUGS;;
  68 esac