tests/torture.at

   1 #                                                       -*- Autotest -*-
   2
   3 # Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005, 2006 Free Software
   4 # Foundation, Inc.
   5 #
   6 # This program is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301, USA.
  20
  21
  22 AT_BANNER([[Testing config.status.]])
  23
  24
  25 ## ---------------------------------------- ##
  26 ## AC_CONFIG_COMMANDS with empty commands.  ##
  27 ## ---------------------------------------- ##
  28
  29 AT_CHECK_MACRO([AC_CONFIG_COMMANDS with empty commands],
  30 [[AC_CONFIG_COMMANDS([foo], [], [:])
  31 ]])
  32
  33
  34 ## -------------------------- ##
  35 ## Multiple AC_CONFIG_FILES.  ##
  36 ## -------------------------- ##
  37
  38 AT_SETUP([Multiple AC_CONFIG_FILES])
  39
  40 AT_CONFIGURE_AC([[AC_CONFIG_FILES([foo foo])]])
  41 AT_CHECK_AUTOCONF([], 1, [], [ignore])
  42
  43 AT_CLEANUP
  44
  45
  46
  47 ## ------------ ##
  48 ## AC_ARG_VAR.  ##
  49 ## ------------ ##
  50
  51 # AT_CHECK_AC_ARG_VAR(FIRST-VALUE, SECOND-VALUE)
  52 # ----------------------------------------------
  53 # Check that AC_ARG_VAR caches the latest values, diagnoses
  54 # inconsistencies, and arms config.status.
  55 m4_define([AT_CHECK_AC_ARG_VAR],
  56 [rm -f config.cache
  57
  58 # Initial value.
  59 m4_ifval([$1],
  60          [precious='m4_bpatsubst($1, [[']], ['\\''])'; export precious],
  61          [unset precious])
  62 AT_CHECK_CONFIGURE([--config-cache -q])
  63 AT_CHECK([cat file], [], [`$1'
  64 ])
  65
  66 # Testing --recheck: 1. have the environment `forget' about PRECIOUS.
  67 unset precious
  68 # 2. Rerun config.status to recreate `file'.
  69 AT_CHECK([./config.status --recheck], [], [ignore])
  70 AT_CHECK([./config.status], [], [ignore])
  71 # 3. Check that file contains the old value of PRECIOUS.
  72 AT_CHECK([cat file], [], [`$1'
  73 ])
  74
  75 # Second value: we should issue an error here: the value
  76 # has changed!
  77 m4_ifval([$2],
  78          [precious='$2'; export precious],
  79          [unset precious])
  80 AT_CHECK_CONFIGURE([--config-cache], [1], [], [ignore])
  81
  82 ])# AT_CHECK_AC_ARG_VAR
  83
  84
  85 AT_SETUP([AC_ARG_VAR])
  86
  87 # We don't want to run this test if this shell doesn't support
  88 # `unset'.
  89 AT_CHECK([
  90 if (FOO=FOO; unset FOO) >/dev/null 2>&1; then
  91   exit 0
  92 else
  93   exit 77
  94 fi
  95 ])
  96
  97 AT_DATA([configure.ac],
  98 [[AC_INIT
  99 AC_ARG_VAR([precious], [this variable costs a lot])
 100 echo "precious:$precious"
 101 AC_OUTPUT(file)
 102 ]])
 103
 104 AT_DATA([file.in],
 105 [[`@precious@'
 106 ]])
 107
 108 AT_CHECK_AUTOCONF
 109
 110 # Set a precious variable
 111 AT_CHECK_AC_ARG_VAR([], [apple of my eye])
 112
 113 # Unset a precious variable
 114 AT_CHECK_AC_ARG_VAR([apple of my eye], [])
 115
 116 # Change a precious variable
 117 AT_CHECK_AC_ARG_VAR([apple of my eye], [orange of my eye])
 118
 119 # Change a precious variable that contains braces
 120 AT_CHECK_AC_ARG_VAR([apple of my {eye}], [orange of my eye])
 121
 122 # Change a precious variable that contains all kinds of fun
 123 AT_CHECK_AC_ARG_VAR(['p  r      ec"iou$], [orange of my eye])
 124
 125 AT_CLEANUP
 126
 127
 128
 129
 130 ## ---------------------------------------------- ##
 131 ## AC_CONFIG_FILES, HEADERS, LINKS and COMMANDS.  ##
 132 ## ---------------------------------------------- ##
 133
 134 AT_SETUP([AC_CONFIG_FILES, HEADERS, LINKS and COMMANDS])
 135
 136 AT_DATA([configure.ac],
 137 [[AC_INIT
 138 rm -f -r header var-header file var-file link var-link command var-command
 139 echo 'OK' >input
 140
 141 # Be sure to also stress the associated INIT-CMDS.
 142 case $what_to_test in
 143  header)
 144    AC_CONFIG_HEADERS(header:input);;
 145  var-header)
 146    AC_CONFIG_HEADERS(var-header:$header_in, [], [header_in=input]);;
 147
 148  file)
 149    AC_CONFIG_FILES(file:input);;
 150  var-file)
 151    AC_CONFIG_FILES(var-file:$file_in, [], [file_in=input]);;
 152
 153  command)
 154    AC_CONFIG_COMMANDS(command,
 155                       [cp input command]);;
 156  var-command)
 157    AC_CONFIG_COMMANDS(var-command,
 158                       [cp $command_in var-command], [command_in=input]);;
 159
 160  link)
 161    AC_CONFIG_LINKS(link:input);;
 162  var-link)
 163    AC_CONFIG_LINKS(var-link:$link_in, [], [link_in=input]);;
 164 esac
 165 AC_OUTPUT
 166 ]])
 167
 168 AT_CHECK_AUTOCONF
 169
 170
 171 # AT_CHECK_CONFIG_CREATION(THING = (header | link | file | command))
 172 # ------------------------------------------------------------------
 173 # Check that THING and var-THING (which uses variables in AC_CONFIG_THING)
 174 # are properly created, with the right content.
 175 # Use `grep OK' instead of a simple `cat' to avoid banners such as in
 176 # AC_CONFIG_HEADERS.
 177 m4_define([AT_CHECK_CONFIG_CREATION],
 178 [AT_CHECK_CONFIGURE([what_to_test=$1])
 179 AT_CHECK([ls header var-header file var-file command var-command link var-link 2>/dev/null],
 180          [ignore], [$1
 181 ])
 182 AT_CHECK([grep OK $1], [], [OK
 183 ])
 184
 185 AT_CHECK_CONFIGURE([what_to_test=var-$1 --no-create])
 186 # config.status might be stupidly expecting data on stdin, if it's
 187 # really broken...
 188 AT_CHECK([./config.status var-$1 </dev/null], [], [ignore])
 189 AT_CHECK([ls header var-header file var-file command var-command link var-link 2>/dev/null],
 190          [ignore], [var-$1
 191 ])
 192 AT_CHECK([grep OK var-$1], [], [OK
 193 ])
 194 ])# AT_CHECK_CONFIG_CREATION
 195
 196
 197 # Create a file
 198 AT_CHECK_CONFIG_CREATION(file)
 199
 200 # Create a header
 201 AT_CHECK_CONFIG_CREATION(header)
 202
 203 # Execute a command
 204 AT_CHECK_CONFIG_CREATION(command)
 205
 206 # Create a link
 207 AT_CHECK_CONFIG_CREATION(link)
 208
 209 AT_CLEANUP
 210
 211
 212
 213 ## ---------------------------------------- ##
 214 ## Macro calls in AC_CONFIG_COMMANDS tags.  ##
 215 ## ---------------------------------------- ##
 216
 217 AT_SETUP([Macro calls in AC_CONFIG_COMMANDS tags])
 218
 219 AT_DATA_M4SUGAR([configure.ac],
 220 [[AC_INIT
 221 AC_CONFIG_COMMANDS([m4_if(1,1,mytag)])
 222 AC_OUTPUT
 223 ]])
 224
 225 AT_CHECK_AUTOCONF
 226 AT_CHECK_CONFIGURE
 227
 228 AT_CLEANUP
 229
 230
 231
 232 ## ------------------- ##
 233 ## Missing templates.  ##
 234 ## ------------------- ##
 235
 236 # Check that config.status detects missing input files
 237 AT_SETUP([Missing templates])
 238
 239 AT_DATA([configure.ac],
 240 [[AC_INIT
 241 AC_CONFIG_FILES([nonexistent])
 242 AC_OUTPUT
 243 ]])
 244
 245 AT_CHECK_AUTOCONF
 246 AT_CHECK_CONFIGURE([], [1], [],
 247 [[config.status: error: cannot find input file: nonexistent.in
 248 ]])
 249 # Make sure that the output file doesn't exist
 250 AT_CHECK([test -f nonexistent], 1)
 251
 252 AT_CLEANUP
 253
 254
 255
 256
 257 ## ---------------------- ##
 258 ## configure invocation.  ##
 259 ## ---------------------- ##
 260
 261 # Check that `configure' and `config.status' honor their interface.
 262 #
 263 # We run `./configure one=val1 --enable-two=val2 --with-three=val3'
 264 # and verify that (i) `configure' correctly receives the arguments,
 265 # (ii) correctly passes them to `config.status', which we check by
 266 # running `config.status --recheck', and (iii) correctly passes them
 267 # to sub-configure scripts.
 268
 269 AT_SETUP([configure invocation])
 270
 271 mkdir sub
 272
 273 AT_DATA([configure.ac],
 274 [[AC_INIT
 275 AC_CONFIG_SUBDIRS([sub])
 276 echo "result=$one$enable_two$with_three"
 277 AC_OUTPUT
 278 ]])
 279
 280 AT_DATA([sub/configure.ac],
 281 [[AC_INIT
 282 echo "result=$one$enable_two$with_three"
 283 AC_OUTPUT
 284 ]])
 285
 286 echo fake install-sh script >install-sh
 287
 288 AT_CHECK_AUTOCONF
 289 cd sub
 290 AT_CHECK_AUTOCONF
 291 cd ..
 292
 293 AT_CHECK_CONFIGURE([one=one --enable-two=two --with-three=three |
 294                      sed -n -e 's/^result=//p'], 0,
 295                    [m4_do([onetwothree
 296 ],                        [onetwothree
 297 ])])
 298 AT_CHECK([./config.status --recheck | sed -n 's/^result=//p'], 0,
 299          [onetwothree
 300 ])
 301
 302 AT_CHECK_CONFIGURE([one="\"'$ " --enable-two="\" '  $" --with-three="   \"'$"|
 303                       sed -n -e 's/^result=//p'], 0,
 304                    [m4_do(["'$ " '  $   "'$
 305 ],                        ["'$ " '  $   "'$
 306 ])])
 307 AT_CHECK([./config.status --recheck | sed -n 's/^result=//p'], 0,
 308          ["'$ " '  $    "'$
 309 ])
 310
 311 AT_CLEANUP
 312
 313
 314
 315 ## -------------------------------------------- ##
 316 ## Check that `#define' templates are honored.  ##
 317 ## -------------------------------------------- ##
 318
 319 # Use various forms of `#define' templates, and make sure there are no
 320 # problems when a symbol is prefix of another.
 321
 322 AT_SETUP([[#define header templates]])
 323
 324 AT_DATA([configure.ac],
 325 [[AC_INIT
 326 AC_CONFIG_HEADERS(config.h:config.hin)
 327
 328 # I18n of dummy variables: their French translations.
 329 AC_DEFINE(foo, toto)
 330 AC_DEFINE(bar, tata)
 331 AC_DEFINE(baz, titi)
 332 AC_DEFINE(fubar, tutu)
 333
 334 # Symbols which are prefixes of another.
 335 AC_DEFINE(a, A)
 336 AC_DEFINE(aaa, AAA)
 337 AC_DEFINE(aa, AA)
 338 AC_CONFIG_FILES(defs)
 339
 340 # Things included in confdefs.h, but which make no sense in
 341 # config.h, nor in $DEFS.
 342 cat <<\EOF >>confdefs.h
 343 /* Hi Mum! Look, I am doing C++! */
 344 #ifdef __cplusplus
 345 void exit (int status);
 346 #endif
 347 EOF
 348
 349 # In addition of config.h output a full DEFS
 350 AC_OUTPUT_MAKE_DEFS
 351 DEFS_SAVED=$DEFS
 352 AC_SUBST(DEFS_SAVED)
 353 AC_OUTPUT
 354 ]])
 355
 356 AT_DATA([defs.in],
 357 [[@DEFS_SAVED@
 358 ]])
 359
 360 AT_DATA([config.hin],
 361 [[#define foo   0
 362 #  define bar bar
 363 #  define baz   "Archimedes was sinking in his baz"
 364 #  define fubar                         tutu
 365 #define a B
 366 #define aa BB
 367 #define aaa BBB
 368 #undef a
 369 #undef aa
 370 #undef aaa
 371 ]])
 372
 373 AT_CHECK_AUTOCONF
 374 AT_CHECK_CONFIGURE
 375
 376 AT_DATA([expout],
 377 [[/* config.h.  Generated from config.hin by configure.  */
 378 #define foo toto
 379 #  define bar tata
 380 #  define baz titi
 381 #  define fubar tutu
 382 #define a A
 383 #define aa AA
 384 #define aaa AAA
 385 #define a A
 386 #define aa AA
 387 #define aaa AAA
 388 ]])
 389 AT_CHECK([cat config.h], 0, expout)
 390
 391 # Check the value of DEFS.
 392 AT_DATA([expout],
 393 [[-DPACKAGE_NAME=\"\" -DPACKAGE_TARNAME=\"\" -DPACKAGE_VERSION=\"\" -DPACKAGE_STRING=\"\" -DPACKAGE_BUGREPORT=\"\" -Dfoo=toto -Dbar=tata -Dbaz=titi -Dfubar=tutu -Da=A -Daaa=AAA -Daa=AA
 394 ]])
 395
 396 # Because we strip trailing spaces in `testsuite' we can't leave one in
 397 # expout, hence nuke the one left by AC_OUTPUT_MAKE_DEFS.
 398 AT_CHECK([sed -e 's/ $//' defs], 0, expout)
 399
 400 AT_CLEANUP
 401
 402
 403
 404 ## ------------------------- ##
 405 ## Torturing config.status.  ##
 406 ## ------------------------- ##
 407
 408 ## Require 100 AC_DEFINE and AC_SUBST and AC_SUBST_FILE with a significantly
 409 ## big value.  This is mostly to check that Autoconf produces portable sed
 410 ## scripts in config.status.  sed is used to skip the first two lines
 411 ## `Generated by...'.
 412
 413 # We use m4_for many times.
 414 m4_pattern_allow([^m4_for$])
 415
 416 AT_SETUP([Torturing config.status])
 417
 418 dnl The value used as a big value for AC_DEFINE.
 419 dnl Don't use sh active chars here, below it is also used in a sh
 420 dnl assignment.
 421 m4_define([AT_BIG_VALUE],
 422 [This value should be long enough to torture the various limits of sed and other tools used by Autoconf.])
 423
 424 m4_define([AT_DESCRIPTION],
 425 [Define to a long string if your `Autoconf' works properly.])
 426
 427
 428 # AT_DUMMY_VAR(NUMBER)
 429 # --------------------
 430 # Build a name used for AC_SUBST and AC_DEFINE.  Put ac_ in it
 431 # so that the check for user name space invasion does not complain
 432 # of the new variables defined.
 433 #
 434 # Note that you should not use the name ac_dummy, because it will be
 435 # turned into ac_uummy during the construction of config.status.  Yes,
 436 # this is admittedly a bug, but it would be too hard to fix this.
 437 # There is really no point in AC_DEFINE a var named ac_d.*.
 438 m4_pattern_allow([^m4_bpatsubst$])
 439 m4_define([AT_DUMMY_VAR],
 440 [ac_Dummy_[]m4_bpatsubst([000$1], [.*\(...\)$], [\1])])
 441
 442
 443
 444 AT_DATA([dummy.in],
 445 [m4_for([AT_Count], 1, 100, 1,
 446 [@AT_DUMMY_VAR(AT_Count)@
 447 @[f]AT_Count@
 448 ])])
 449
 450
 451 i=1
 452 while test $i != 101; do
 453   echo "content of file $i" > file_$i
 454   i=`expr $i + 1`
 455 done
 456
 457
 458 # ------------ #
 459 # configure.ac #
 460 # ------------ #
 461
 462 m4_pattern_allow([^m4_(define|defun)$])
 463 AT_DATA([configure.ac],
 464 dnl The following lines transfer AT_DUMMY_VAR, AT_DESCRIPTION, and
 465 dnl AT_BIG_VALUE into the configure.ac as AC_DUMMY_VAR etc.
 466 [[m4_define([AC_DUMMY_VAR],]
 467 m4_dquote(m4_defn([AT_DUMMY_VAR]))[)]]
 468
 469 [[m4_define([AC_DESCRIPTION],]
 470 m4_dquote(m4_defn([AT_DESCRIPTION]))[)]]
 471
 472 [[m4_define([AC_BIG_VALUE],]
 473 m4_dquote(m4_defn([AT_BIG_VALUE]))[)]]
 474
 475 [[# AC_DEFUBST(NAME)
 476 # ----------------
 477 # Related VALUE to NAME both with AC_SUBST and AC_DEFINE.  This is
 478 # used in the torture tests.
 479 m4_defun([AC_DEFUBST],
 480 [AC_DUMMY_VAR($1)="AC_BIG_VALUE"
 481 AC_DEFINE_UNQUOTED(AC_DUMMY_VAR($1), "$AC_DUMMY_VAR($1)",
 482                    AC_DESCRIPTION)
 483 AC_SUBST(AC_DUMMY_VAR($1))
 484 AC_SUBST_FILE([f]$1)
 485 f$1=file_$1
 486 ])
 487
 488 AC_INIT
 489 AC_CONFIG_HEADERS(config.h:config.hin)
 490 AC_CONFIG_FILES(dummy)
 491 m4_for(AC_Count, 1, 100, 1,
 492        [AC_DEFUBST(AC_Count)])
 493 AC_PROG_AWK
 494 AC_OUTPUT
 495 ]])# configure.ac
 496
 497 AT_CHECK_AUTOCONF
 498 AT_CHECK_AUTOHEADER
 499 # Check both awk and the result of AC_PROG_AWK
 500 for awk_arg in FOO= AWK=awk; do
 501   AT_CHECK_CONFIGURE([$awk_arg])
 502
 503   # Checking that AC_DEFINE worked properly.
 504   AT_DATA([expout],
 505 [/* Define to the address where bug reports for this package should be sent. */
 506 #define PACKAGE_BUGREPORT ""
 507
 508 /* Define to the full name of this package. */
 509 #define PACKAGE_NAME ""
 510
 511 /* Define to the full name and version of this package. */
 512 #define PACKAGE_STRING ""
 513
 514 /* Define to the one symbol short name of this package. */
 515 #define PACKAGE_TARNAME ""
 516
 517 /* Define to the version of this package. */
 518 #define PACKAGE_VERSION ""
 519 m4_for(AT_Count, 1, 100, 1,
 520 [
 521 /* AT_DESCRIPTION */
 522 [#define] AT_DUMMY_VAR(AT_Count) "AT_BIG_VALUE"
 523 ])])
 524
 525   AT_CHECK([sed -n '4,$ p' config.h], 0, expout)
 526
 527   # Checking that AC_SUBST worked properly.
 528   AT_DATA([expout],
 529 [m4_for(AT_Count, 1, 100, 1,
 530 [AT_BIG_VALUE
 531 content of file AT_Count
 532 ])])
 533
 534   AT_CHECK([cat dummy], 0, expout)
 535 done
 536
 537 AT_CLEANUP
 538
 539
 540 ## ------------------------------- ##
 541 ## Substitute a 2000-byte string.  ##
 542 ## ------------------------------- ##
 543
 544 # Solaris 9 /usr/ucb/sed that rejects commands longer than 4000 bytes.  HP/UX
 545 # sed dumps core around 8 KiB.  However, POSIX says that sed need not
 546 # handle lines longer than 2048 bytes (including the trailing newline).
 547 # So we'll just test a 2000-byte value, and for awk, we test a line with
 548 # almost 1000 words, and one variable with 5 lines of 2000 bytes each:
 549 # multi-line values should allow to get around the limitations.
 550
 551 AT_SETUP([Substitute a 2000-byte string])
 552
 553 AT_DATA([Foo.in], [@foo@
 554 ])
 555 AT_DATA([Bar.in], [@bar@
 556 ])
 557 AT_DATA([Baz.in], [@baz@
 558 ])
 559
 560 AT_DATA([configure.ac],
 561 [[AC_INIT
 562 AC_CONFIG_AUX_DIR($top_srcdir/build-aux)
 563 AC_SUBST([foo], ]m4_for([n], 1, 100,, ....................)[)
 564 AC_SUBST([bar], "]m4_for([n], 1, 100,, @ @ @ @ @ @ @ @ @ @@)[")
 565 AC_SUBST([baz], "]m4_for([n], 1, 5,, m4_for([m], 1, 100,, ... ... ... ... ....)
 566 )[")
 567 AC_PROG_AWK
 568 AC_CONFIG_FILES([Foo Bar Baz])
 569 AC_OUTPUT
 570 ]])
 571
 572 AT_CHECK_AUTOCONF
 573 # Check both awk and the result of AC_PROG_AWK
 574 for awk_arg in Foo= AWK=awk; do
 575   AT_CHECK_CONFIGURE([$awk_arg])
 576   AT_CHECK([cat Foo], 0, m4_for([n], 1, 100,, ....................)
 577 )
 578   AT_CHECK([cat Bar], 0, m4_for([n], 1, 100,, @ @ @ @ @ @ @ @ @ @@)
 579 )
 580   AT_CHECK([cat Baz], 0, m4_for([n], 1, 5,, m4_for([m], 1, 100,, ... ... ... ... ....)
 581 )
 582 )
 583 done
 584 AT_CLEANUP
 585
 586
 587 ## ------------------------------ ##
 588 ## Define to a 2000-byte string.  ##
 589 ## ------------------------------ ##
 590
 591 AT_SETUP([Define to a 2000-byte string])
 592
 593 AT_CONFIGURE_AC(
 594 [[
 595 AC_DEFINE([foo], ]m4_for([n], 1, 100,, ....................)[, [desc])
 596 ]])
 597
 598 AT_CHECK_AUTOCONF
 599 AT_CHECK_AUTOHEADER
 600 AT_CHECK_CONFIGURE
 601 AT_CHECK_DEFINES([@%:@define foo m4_for([n], 1, 100,, ....................)
 602 ])
 603 AT_CLEANUP
 604
 605
 606 ## ------------------------------------------ ##
 607 ## Substitute and define special characters.  ##
 608 ## ------------------------------------------ ##
 609
 610 # Use characters special to the shell, sed, awk, and M4.
 611
 612 AT_SETUP([Substitute and define special characters])
 613
 614 AT_DATA([Foo.in], [@foo@
 615 @bar@@notsubsted@@baz@ stray @ and more@@@baz@
 616 abc@bar@baz@baz
 617 abc@bar@@baz@baz
 618 abc@bar@@baz@baz@
 619 abc@bar @baz@baz
 620 abc@bar @baz@baz@
 621 abc@bar @baz@@baz@
 622 @file@
 623          @file@
 624 X@file@
 625 @file@X
 626 ])
 627
 628 AT_DATA([File],
 629 [@foo@@bar@
 630 ])
 631
 632 AT_CONFIGURE_AC(
 633 [[foo="AS@&t@_ESCAPE([[X*'[]+ ",& &`\($foo \& \\& \\\& \\\\& \ \\ \\\ !]])"
 634 bar="@foo@ @baz@"
 635 baz=bla
 636 AC_SUBST([foo])
 637 AC_SUBST([bar])
 638 AC_SUBST([baz])
 639 file=File
 640 AC_SUBST_FILE([file])
 641 AC_DEFINE([foo], [[X*'[]+ ",& &`\($foo !]], [Awful value.])
 642 AC_PROG_AWK
 643 AC_CONFIG_FILES([Foo])]])
 644
 645 AT_CHECK_AUTOCONF
 646 AT_CHECK_AUTOHEADER
 647 # Check both awk and the result of AC_PROG_AWK
 648 for awk_arg in FOO= AWK=awk; do
 649   AT_CHECK_CONFIGURE([$awk_arg])
 650   AT_CHECK([cat Foo], 0, [[X*'[]+ ",& &`\($foo \& \\& \\\& \\\\& \ \\ \\\ !
 651 @foo@ @baz@@notsubsted@bla stray @ and more@@bla
 652 abc@foo@ @baz@baz@baz
 653 abc@foo@ @baz@blabaz
 654 abc@foo@ @baz@blabaz@
 655 abc@bar blabaz
 656 abc@bar blabaz@
 657 abc@bar blabla
 658 @foo@@bar@
 659 @foo@@bar@
 660 X@file@
 661 @file@X
 662 ]])
 663   AT_CHECK_DEFINES([[#define foo X*'[]+ ",& &`\($foo !
 664 ]])
 665 done
 666 AT_CLEANUP
 667
 668
 669 ## ---------------------- ##
 670 ## Substitute a newline.  ##
 671 ## ---------------------- ##
 672
 673 AT_SETUP([Substitute a newline])
 674
 675 AT_DATA([Foo.in],
 676 [@foo@
 677 ])
 678
 679 AT_DATA([configure.ac],
 680 [[AC_INIT
 681 AC_CONFIG_AUX_DIR($top_srcdir/build-aux)
 682 foo='one
 683 two'
 684 AC_SUBST([foo])
 685 AC_CONFIG_FILES([Foo])
 686 AC_PROG_AWK
 687 AC_OUTPUT
 688 ]])
 689
 690 AT_CHECK_AUTOCONF
 691 # Check both awk and the result of AC_PROG_AWK
 692 for awk_arg in FOO= AWK=awk; do
 693   AT_CHECK_CONFIGURE([$awk_arg])
 694   AT_CHECK([cat Foo], 0, [one
 695 two
 696 ])
 697 done
 698 AT_CLEANUP
 699
 700
 701 ## ------------------ ##
 702 ## Define a newline.  ##
 703 ## ------------------ ##
 704
 705 AT_SETUP([Define a newline])
 706 AT_XFAIL_IF(:)
 707 AT_CONFIGURE_AC([[AC_DEFINE([foo], [one
 708 two], [This spans two lines.])
 709 ]])
 710 AT_CHECK_AUTOCONF
 711 AT_CHECK_AUTOHEADER
 712 AT_CHECK_CONFIGURE
 713 AT_CHECK_DEFINES([[#define foo one
 714 two
 715 ]])
 716 AT_CLEANUP
 717
 718
 719 ## ------------------------ ##
 720 ## datarootdir workaround.  ##
 721 ## ------------------------ ##
 722
 723 AT_SETUP([datarootdir workaround])
 724
 725 AT_DATA([Foo.in],
 726 [@datadir@
 727 @docdir@
 728 @infodir@
 729 @localedir@
 730 @mandir@
 731 ])
 732
 733 AT_DATA([Bar.in],
 734 [@mydatadir@
 735 ])
 736
 737 AT_DATA([configure.ac],
 738 [[AC_INIT
 739 d@&t@nl The following line silences the warnings, if uncommented:
 740 d@&t@nl AC_DEFUN([AC_DATAROOTDIR_CHECKED])
 741 AC_CONFIG_AUX_DIR($top_srcdir/build-aux)
 742
 743 # This substitution is wrong and bogus!  Don't use it in your own code!
 744 # Read `info Autoconf "Defining Directories"'!
 745 AC_SUBST([mydatadir], [${datadir}/my])
 746
 747 AC_CONFIG_FILES([Foo Bar])
 748 AC_OUTPUT
 749 ]])
 750
 751 AT_CHECK_AUTOCONF
 752 AT_CHECK_CONFIGURE([], [], [],
 753   [config.status: WARNING:  Foo.in seems to ignore the --datarootdir setting
 754 config.status: WARNING: Bar contains a reference to the variable `datarootdir'
 755 which seems to be undefined.  Please make sure it is defined.
 756 ])
 757 AT_CHECK([grep datarootdir Foo], 1, [])
 758
 759 rm configure
 760 sed '/AC_DEFUN/s/^d@&t@nl //' configure.ac >t
 761 mv t configure.ac
 762
 763 AT_CHECK_AUTOCONF
 764 AT_CHECK_CONFIGURE
 765
 766 AT_CLEANUP
 767
 768
 769 ## -------- ##
 770 ## srcdir.  ##
 771 ## -------- ##
 772
 773 AT_SETUP([srcdir])
 774
 775 rm -f -r at-dir
 776 mkdir at-dir
 777 : >at-dir/bar.in
 778 : >foo.in
 779
 780 AT_DATA([configure.ac],
 781 [[AC_INIT
 782
 783 AC_CONFIG_FILES([foo at-dir/bar])
 784
 785 AC_CONFIG_COMMANDS([report],
 786 [test -f $srcdir/configure.ac ||
 787    AC_MSG_ERROR([cannot find $srcdir/configure.ac])],
 788                    [srcdir=$srcdir])
 789
 790 AC_OUTPUT
 791 rm -f -r foo at-dir/bar
 792 ]])
 793
 794 AT_CHECK_AUTOCONF
 795
 796 # In place.
 797 AT_CHECK([./configure], [], [ignore])
 798
 799 # Relative name.
 800 AT_CHECK([cd at-dir && ../configure], [], [ignore])
 801
 802 # Absolute name.
 803 at_here=`pwd`
 804 AT_CHECK([cd at-dir && "$at_here/configure"], [], [ignore])
 805
 806 AT_CLEANUP
 807
 808
 809 ## ----------------- ##
 810 ## Signal handling.  ##
 811 ## ----------------- ##
 812
 813 AT_SETUP([Signal handling])
 814
 815 AT_DATA([configure.ac],
 816 [[AC_INIT
 817 kill -2 $$
 818 exit 77
 819 ]])
 820
 821 AT_CHECK_AUTOCONF
 822 AT_CHECK_CONFIGURE([], 1, ignore, ignore)
 823
 824 AT_CLEANUP
 825
 826
 827
 828 AT_BANNER([autoreconf.])
 829
 830 ## ---------------------------- ##
 831 ## Configuring subdirectories.  ##
 832 ## ---------------------------- ##
 833
 834 # .
 835 # |-- builddir
 836 # |   |-- config.log
 837 # |   |-- config.status
 838 # |   `-- inner
 839 # |       |-- config.log
 840 # |       |-- config.status
 841 # |       `-- innermost
 842 # |           `-- config
 843 # |-- configure
 844 # |-- configure.ac
 845 # |-- inner
 846 # |   |-- configure
 847 # |   |-- configure.ac
 848 # |   `-- innermost
 849 # |       `-- config.in
 850 # `-- install-sh
 851 #
 852 AT_SETUP([Configuring subdirectories])
 853 AT_KEYWORDS(autoreconf)
 854
 855 # We use aclocal (via autoreconf).
 856 AT_CHECK([aclocal --version || exit 77], [], [stdout], [ignore])
 857 # It should understand configure.ac.
 858 AT_CHECK([[grep '[^0-9]1.[01234][^0-9]' stdout && exit 77]], [1], [ignore])
 859
 860 # Set CONFIG_SITE to a nonexistent file, so that there are
 861 # no worries about nonstandard values for 'prefix'.
 862 CONFIG_SITE=no-such-file
 863 export CONFIG_SITE
 864
 865 # The contents of `inner/', and `inner/innermost/'.
 866 AS_MKDIR_P([inner/innermost])
 867
 868 # We have to use configure.in, not configure.ac, if we still want to
 869 # be compatible with Automake 1.4: aclocal (run by autoreconf) would
 870 # die because it can't find configure.in.
 871 AT_DATA([inner/configure.in],
 872 [[AC_INIT(GNU Inner, 1.0)
 873 AC_CONFIG_SRCDIR([innermost/config.in])
 874 AC_ARG_VAR([INNER], [an inner variable])
 875 AC_SUBST([INNER])
 876 if test "x$INNER" = x; then
 877   INNER=inner
 878 fi
 879 AC_CONFIG_FILES([innermost/config])
 880 AC_OUTPUT
 881 ]])
 882
 883 AT_DATA([inner/innermost/config.in],
 884 [INNER=@INNER@
 885 srcdir=@srcdir@
 886 top_srcdir=@top_srcdir@
 887 prefix=@prefix@
 888 ])
 889
 890 # The contents of `.'
 891 AT_DATA([install-sh], [])
 892
 893 # nonexistent is allowed not to exist.
 894 AT_DATA([configure.in],
 895 [[AC_INIT(GNU Outer, 1.0)
 896 AC_ARG_VAR([OUTER], [an outer variable])
 897 if false; then
 898   AC_CONFIG_SUBDIRS([nonexistent])
 899 fi
 900 AC_CONFIG_SUBDIRS([inner])
 901 AC_OUTPUT
 902 ]])
 903
 904 # If there are improperly quoted AC_DEFUN installed in share/aclocal,
 905 # they trigger warnings from aclocal 1.8, so ignore stderr.
 906 AT_CHECK([autoreconf], [], [], [ignore])
 907 AT_CHECK([test -f inner/configure])
 908
 909 # Running the outer configure recursively should provide the innermost
 910 # help strings.
 911 AT_CHECK([./configure --help=recursive | grep INNER], 0, [ignore])
 912
 913 # Running the outer configure should trigger the inner.
 914 AT_CHECK_CONFIGURE
 915 AT_CHECK([cat inner/innermost/config], 0,
 916 [INNER=inner
 917 srcdir=.
 918 top_srcdir=..
 919 prefix=/usr/local
 920 ])
 921
 922 # The same, but from a builddir.
 923 AS_MKDIR_P([builddir])
 924 AT_CHECK([cd builddir && ../configure], 0, [ignore])
 925 AT_CHECK([cat builddir/inner/innermost/config], 0,
 926 [INNER=inner
 927 srcdir=../../../inner/innermost
 928 top_srcdir=../../../inner
 929 prefix=/usr/local
 930 ])
 931
 932 # Make sure precious variables and command line options are properly
 933 # passed, even when there are duplicates.
 934 AT_CHECK([cd builddir && ../configure --prefix /bad --prefix /good INNER=bad INNER=good], 0, [ignore])
 935 AT_CHECK([cat builddir/inner/innermost/config], 0,
 936 [INNER=good
 937 srcdir=../../../inner/innermost
 938 top_srcdir=../../../inner
 939 prefix=/good
 940 ])
 941
 942 # Make sure --prefix is properly quoted
 943 AT_CHECK([cd builddir && ../configure --prefix "/a  b c$ 'd"], 0, [ignore])
 944 AT_CHECK([cat builddir/inner/innermost/config], 0,
 945 [INNER=inner
 946 srcdir=../../../inner/innermost
 947 top_srcdir=../../../inner
 948 prefix=/a  b c$ 'd
 949 ])
 950
 951 # Make sure --silent is properly passed...
 952 AT_CHECK([cd builddir && ../configure --silent], 0, [])
 953 # ...but not stored in config.status.
 954 AT_CHECK([cd builddir && ./config.status --recheck], 0, [stdout])
 955 AT_CHECK([grep 'creating \./config.status' stdout], 0, [ignore])
 956
 957 # Make sure we can run autoreconf on a subdirectory
 958 rm -f configure configure.in
 959 AT_CHECK([autoreconf inner], [], [], [ignore])
 960
 961 # Make sure we can pass a configure.ac name
 962 AT_CHECK([cd inner && autoreconf configure.in], [], [], [ignore])
 963 AT_CHECK([autoreconf inner/configure.in], [], [], [ignore])
 964
 965 AT_CLEANUP
 966
 967
 968
 969 ## -------------- ##
 970 ## Deep Package.  ##
 971 ## -------------- ##
 972
 973 AT_SETUP([Deep Package])
 974 AT_KEYWORDS(autoreconf)
 975
 976 # We use aclocal (via autoreconf).
 977 AT_CHECK([aclocal --version || exit 77], [], [ignore], [ignore])
 978
 979 # The contents of `.'
 980 AT_DATA([install-sh], [])
 981 AT_DATA([configure.in],
 982 [[AC_INIT(GNU Outer, 1.0)
 983 AC_ARG_VAR([OUTER], [an outer variable])
 984 AC_CONFIG_SUBDIRS([inner])
 985 AC_OUTPUT
 986 ]])
 987
 988 # The contents of `inner/', and `inner/innermost/'.
 989 AS_MKDIR_P([inner/innermost])
 990
 991 AT_DATA([inner/configure.in],
 992 [[AC_INIT(GNU Inner, 1.0)
 993 AC_ARG_VAR([INNER], [an inner variable])
 994 AC_CONFIG_SUBDIRS(innermost)
 995 AC_OUTPUT
 996 ]])
 997
 998 AT_DATA([inner/innermost/configure.in],
 999 [[AC_INIT(GNU Innermost, 1.0)
1000 AC_ARG_VAR([INNERMOST], [an innermost variable])
1001 AC_CONFIG_HEADERS(config.h:config.hin)
1002 AC_DEFINE_UNQUOTED([INNERMOST], [$INNERMOST], [an innermost variable])
1003 AC_OUTPUT
1004 ]])
1005
1006 AT_CHECK([autoreconf -Wall -v], [0], [ignore], [ignore])
1007 AT_CHECK([test -f inner/configure])
1008 AT_CHECK([test -f inner/innermost/configure])
1009 AT_CHECK([test -f inner/innermost/config.hin])
1010
1011 # Running the outer configure recursively should provide the innermost
1012 # help strings.
1013 AT_CHECK([./configure --help=recursive | grep " INNER "],     0, [ignore])
1014 AT_CHECK([./configure --help=recursive | grep " INNERMOST "], 0, [ignore])
1015
1016 # Running the outer configure should trigger the inner.
1017 AT_CHECK_CONFIGURE([INNERMOST=tsomrenni])
1018 AT_CHECK([grep INNERMOST inner/innermost/config.h], 0,
1019 [[#define INNERMOST tsomrenni
1020 ]])
1021
1022 # The same, but from a builddir.
1023 AS_MKDIR_P([builddir])
1024 AT_CHECK([cd builddir && ../configure INNERMOST=build/tsomrenni], 0, [ignore])
1025 AT_CHECK([grep INNERMOST builddir/inner/innermost/config.h], 0,
1026 [[#define INNERMOST build/tsomrenni
1027 ]])
1028
1029 AT_CLEANUP
1030
1031
1032
1033 ## -------------------------------- ##
1034 ## Non-Autoconf AC_CONFIG_SUBDIRS.  ##
1035 ## -------------------------------- ##
1036
1037 AT_SETUP([Non-Autoconf AC_CONFIG_SUBDIRS])
1038 AT_KEYWORDS([autoreconf])
1039
1040 # We use aclocal (via autoreconf).
1041 AT_CHECK([aclocal --version || exit 77], [], [ignore], [ignore])
1042
1043 AT_DATA([install-sh], [])
1044 AT_DATA([configure.in],
1045 [[AC_INIT(GNU Outer, 1.0)
1046 AC_CONFIG_SUBDIRS([inner])
1047 AC_OUTPUT
1048 ]])
1049
1050 AS_MKDIR_P([inner])
1051
1052 AT_DATA([inner/configure],
1053 [[#! /bin/sh
1054 case "$*" in
1055     *--help*) echo 'No Autoconf here, folks!' ;;
1056     *)        echo got_it >myfile ;;
1057 esac
1058 exit 0
1059 ]])
1060 chmod +x inner/configure
1061
1062 AT_CHECK([autoreconf -Wall -v], 0, [ignore], [ignore])
1063
1064 # Running the outer configure recursively should provide the innermost
1065 # help strings.
1066 AT_CHECK([./configure --help=recursive | grep "folks"], 0, [ignore])
1067
1068 # Running the outer configure should trigger the inner.
1069 AT_CHECK([./configure], 0, [ignore])
1070 AT_CHECK([test -f inner/myfile], 0)
1071
1072 AT_CLEANUP
1073
1074
1075
1076 ## ----------------- ##
1077 ## Empty directory.  ##
1078 ## ----------------- ##
1079
1080 AT_SETUP([Empty directory])
1081 AT_KEYWORDS([autoreconf])
1082
1083 # We use aclocal (via autoreconf).
1084 AT_CHECK([aclocal --version || exit 77], [], [ignore], [ignore])
1085
1086 # The test group directory is not necessarily _empty_, but it does not contain
1087 # files meaningful to `autoreconf'.
1088
1089 AT_CHECK([autoreconf -Wall -v], 1, [ignore], [ignore])
1090
1091 AT_CLEANUP
1092
1093
1094
1095 ## ------------------------------ ##
1096 ## Unusual Automake input files.  ##
1097 ## ------------------------------ ##
1098
1099 # This parallels gnumake.test in Automake.
1100
1101 AT_SETUP([Unusual Automake input files])
1102 AT_KEYWORDS([autoreconf])
1103
1104 # We use aclocal and automake via autoreconf.
1105 AT_CHECK([automake --version || exit 77], [], [ignore], [ignore])
1106
1107 AT_DATA([configure.in],
1108 [[AC_INIT(GNU foo, 1.0)
1109 AM_INIT_AUTOMAKE
1110 AC_CONFIG_FILES([HeeHee])
1111 AC_OUTPUT
1112 ]])
1113
1114 AT_DATA([HeeHee.am],
1115 [[# Humans do no worse than `GNUmakefile.am'.
1116 AUTOMAKE_OPTIONS = foreign 1.8
1117 ]])
1118
1119 AT_CHECK([autoreconf -Wall -v -i], 0, [ignore], [stderr],
1120          [AT_CHECK([grep 'require.*1\.8' stderr && exit 77], [1])])
1121 AT_CHECK([test -f HeeHee.in])
1122
1123 AT_CLEANUP