tests/foreign.at

   1 #                                                       -*- Autotest -*-
   2
   3 AT_BANNER([Compatibility with other tools.])
   4
   5 # Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005, 2006 Free Software
   6 # Foundation, Inc.
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 ## --------- ##
  23 ## Libtool.  ##
  24 ## --------- ##
  25
  26 AT_SETUP([Libtool])
  27
  28 # Skip this test if there is no libtoolize.
  29 AT_CHECK([libtoolize --version || exit 77],
  30          ignore, ignore, ignore)
  31 # CVS Autoconf probably does not work with too old Libtools.
  32 AT_CHECK([[
  33 case `libtoolize --version |
  34       sed -n '/^.* \([0-9][0-9.a-z]*\)$/{
  35                 s//\1/
  36                 p
  37                 q
  38         }'` in
  39   0.*          ) exit 77;;
  40   1.[0123]*    ) exit 77;;
  41 esac]],
  42          ignore, ignore, ignore)
  43
  44 # FIXME: Once Libtool `configure.ac' aware, change this.
  45 # Using a configure.in, have libtoolize confess where libtool.m4 is.
  46 AT_DATA([configure.in],
  47 [[AC_INIT
  48 # The other tests are relying on Autoconf's own copy of install-sh
  49 # etc. via AC_CONFIG_AUX_DIR(..).  Don't do that here, since we don't
  50 # want libtoolize to pollute Autoconf's srcdir.
  51 AC_CONFIG_AUX_DIR(.)
  52 AC_PROG_LIBTOOL
  53 ]])
  54 # Some libtoolize complain if you don't have an aclocal.m4.
  55 AT_CHECK([touch aclocal.m4])
  56 AT_CHECK([libtoolize], 0, [stdout], ignore)
  57
  58 # Some broken libtoolize fail to install a functional config.guess.
  59 AT_CHECK([./config.guess || exit 77], [], [ignore], [ignore])
  60
  61 # Make sure at-path contains something valid, and let the test suite
  62 # display it when verbose.  And fail, skipping would too easily hide
  63 # problems.
  64 AT_CHECK([sed -n ["s,^.*\`\\(/[^']*\\)'.*,\\1,p"] stdout], 0, [stdout])
  65 AT_CHECK([test -f "`cat stdout`"])
  66
  67 # libtoolize installed everything but install-sh...
  68 touch install-sh
  69
  70 # Build the concatenation of libtool.m4 and configure.ac.
  71 cp `cat stdout` configure.in
  72 cat >>configure.in <<_EOF
  73 AC_INIT
  74 AC_CONFIG_AUX_DIR(.)
  75 AC_CANONICAL_SYSTEM
  76 AC_PROG_LIBTOOL
  77 _EOF
  78
  79 # FIXME: Once Libtool really fixed, stop ignoring stderr.
  80 AT_CHECK_AUTOCONF([], [], [], [ignore])
  81
  82 # Ignore stderr, because ltconfig always loads the cache, which is
  83 # /dev/null, and some shells choke on this.  For instance with Bash
  84 # 2.05, you get:
  85 #
  86 #   loading cache /dev/null within ltconfig
  87 #   ./ltconfig: .: /dev/null: not a regular file
  88 #
  89 # But the script executes properly.
  90 AT_CHECK_CONFIGURE([], [], [], [ignore])
  91
  92 AT_CLEANUP