tests/compile.at

   1 #                                                       -*- Autotest -*-
   2
   3 AT_BANNER([Low level compiling/preprocessing macros.])
   4
   5 # Copyright (C) 2000, 2001, 2003, 2005, 2006 Free Software Foundation, Inc.
   6 #
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20
  21 # Since the macros which compile are required by most tests, check
  22 # them first.  But remember that looking for a compiler is even more
  23 # primitive, so check those first.
  24
  25
  26 ## ------------------------------------- ##
  27 ## AC_LANG, AC_LANG_PUSH & AC_LANG_POP.  ##
  28 ## ------------------------------------- ##
  29
  30 AT_SETUP([AC_LANG, AC_LANG_PUSH & AC_LANG_POP])
  31
  32 AT_DATA([configure.ac],
  33 [[AC_INIT
  34 # C
  35 AC_LANG(C)
  36 # C
  37 AC_LANG_PUSH(C)
  38 # C C
  39 AC_LANG_PUSH(C++)
  40 # C++ C C
  41 AC_LANG(C++)
  42 # C++ C C
  43 AC_LANG_PUSH(Fortran 77)
  44 # F77 C++ C C
  45 AC_LANG_POP(Fortran 77)
  46 # C++ C C
  47 AC_LANG(C++)
  48 # C++ C C
  49 AC_LANG_POP(C++)
  50 # C C
  51 AC_LANG_POP(C)
  52 # C
  53 ]])
  54
  55 AT_CHECK_AUTOCONF
  56 AT_CHECK([sed -n 's/^ac_ext=//p' configure], 0,
  57 [c
  58 c
  59 c
  60 cpp
  61 cpp
  62 f
  63 cpp
  64 cpp
  65 c
  66 c
  67 ])
  68
  69 AT_CLEANUP
  70
  71
  72 ## ---------------------- ##
  73 ## AC_REQUIRE & AC_LANG.  ##
  74 ## ---------------------- ##
  75
  76 AT_SETUP([AC_REQUIRE & AC_LANG])
  77
  78 AT_DATA([configure.ac],
  79 [[AC_DEFUN([AC_F77_1],
  80 [AC_LANG_PUSH([Fortran 77])
  81 if test $ac_ext != f; then
  82   AC_MSG_ERROR([F77_1: current shell language is $ac_ext, expected Fortran])
  83 fi
  84 AC_LANG_POP
  85 ])
  86
  87
  88 AC_DEFUN([AC_F77_2],
  89 [AC_LANG_PUSH([Fortran 77])
  90 AC_REQUIRE([AC_F77_1])
  91 if test $ac_ext != f; then
  92   AC_MSG_ERROR([F77_2: current shell language is $ac_ext, expected Fortran])
  93 fi
  94 AC_LANG_POP
  95 ])
  96
  97 AC_INIT
  98 AC_F77_2
  99 AS_EXIT(0)
 100 ]])
 101
 102 AT_CHECK_AUTOCONF
 103 AT_CHECK_CONFIGURE
 104
 105 AT_CLEANUP
 106
 107
 108 ## --------------- ##
 109 ## AC_RUN_IFELSE.  ##
 110 ## --------------- ##
 111
 112 AT_SETUP([AC_RUN_IFELSE])
 113
 114 AT_DATA([configure.ac],
 115 [[AC_INIT
 116
 117 AC_RUN_IFELSE([AC_LANG_PROGRAM([], [return 0])],
 118               [],
 119               [AC_MSG_ERROR([saw `return 0' as a failure])])
 120
 121 AC_RUN_IFELSE([AC_LANG_PROGRAM([], [return 2])],
 122               [AC_MSG_ERROR([saw `return 2' as a success])],
 123               [status=$?
 124 test $status != 2 &&
 125   AC_MSG_ERROR([did not get as 2 exit status: $status])])
 126
 127 # The old stinky one.
 128 AC_TRY_RUN([int main () { return 3; }],
 129            [AC_MSG_ERROR([saw `return 3' as a success])],
 130            [status=$?
 131 test $status != 3 &&
 132   AC_MSG_ERROR([did not get 3 as exit status: $status])])
 133
 134 ]])
 135
 136 AT_CHECK_AUTOCONF
 137 AT_CHECK_CONFIGURE([-q])
 138
 139 AT_CLEANUP
 140
 141 ## ------------------ ##
 142 ## AC_TRY_LINK_FUNC.  ##
 143 ## ------------------ ##
 144
 145 AT_CHECK_MACRO([AC_TRY_LINK_FUNC],
 146 [AC_TRY_LINK_FUNC(printf,,
 147                   [AC_MSG_ERROR([cannot find `printf'])])
 148 AC_TRY_LINK_FUNC(Be_doomed_if_your_libc_has_a_function_named_like_this,
 149                  [AC_MSG_ERROR([found a nonexistent function])])])