bin/autoscan.in

   1 #! @PERL@ -w
   2 # -*- perl -*-
   3 # @configure_input@
   4
   5 # autoscan - Create configure.scan (a preliminary configure.ac) for a package.
   6 # Copyright (C) 1994, 1999, 2000, 2001, 2002, 2003, 2004
   7 #  Free Software Foundation, Inc.
   8
   9 # This program is free software; you can redistribute it and/or modify
  10 # it under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 2, or (at your option)
  12 # any later version.
  13
  14 # This program is distributed in the hope that it will be useful,
  15 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  17 # GNU General Public License for more details.
  18
  19 # You should have received a copy of the GNU General Public License
  20 # along with this program; if not, write to the Free Software
  21 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  22 # 02111-1307, USA.
  23
  24 # Written by David MacKenzie <djm@gnu.ai.mit.edu>.
  25
  26 eval 'case $# in 0) exec @PERL@ -S "$0";; *) exec @PERL@ -S "$0" "$@";; esac'
  27     if 0;
  28
  29 BEGIN
  30 {
  31   my $datadir = $ENV{'autom4te_perllibdir'} || '@datadir@';
  32   unshift @INC, $datadir;
  33
  34   # Override SHELL.  On DJGPP SHELL may not be set to a shell
  35   # that can handle redirection and quote arguments correctly,
  36   # e.g.: COMMAND.COM.  For DJGPP always use the shell that configure
  37   # has detected.
  38   $ENV{'SHELL'} = '@SHELL@' if ($^O eq 'dos');
  39 }
  40
  41 use Autom4te::ChannelDefs;
  42 use Autom4te::Configure_ac;
  43 use Autom4te::General;
  44 use Autom4te::FileUtils;
  45 use Autom4te::XFile;
  46 use File::Basename;
  47 use File::Find;
  48 use strict;
  49
  50 use vars qw(@cfiles @makefiles @shfiles %printed);
  51
  52 # The kind of the words we are looking for.
  53 my @kinds = qw (function header identifier program
  54                 makevar librarie);
  55
  56 # For each kind, the default macro.
  57 my %generic_macro =
  58   (
  59    'function'   => 'AC_CHECK_FUNCS',
  60    'header'     => 'AC_CHECK_HEADERS',
  61    'identifier' => 'AC_CHECK_TYPES',
  62    'program'    => 'AC_CHECK_PROGS',
  63    'library'    => 'AC_CHECK_LIB'
  64   );
  65
  66 my %kind_comment =
  67   (
  68    'function'   => 'Checks for library functions.',
  69    'header'     => 'Checks for header files.',
  70    'identifier' => 'Checks for typedefs, structures, and compiler characteristics.',
  71    'program'    => 'Checks for programs.',
  72   );
  73
  74 # $USED{KIND}{ITEM} is the list of locations where the ITEM (of KIND) was used
  75 # in the user package.
  76 # For instance $USED{function}{alloca} is the list of `file:line' where
  77 # `alloca (...)' appears.
  78 my %used = ();
  79
  80 # $MACRO{KIND}{ITEM} is the list of macros to use to test ITEM.
  81 # Initialized from lib/autoscan/*.  E.g., $MACRO{function}{alloca} contains
  82 # the singleton AC_FUNC_ALLOCA.  Some require several checks.
  83 my %macro = ();
  84
  85 # $NEEDED_MACROS{MACRO} is an array of locations requiring MACRO.
  86 # E.g., $NEEDED_MACROS{AC_FUNC_ALLOC} the list of `file:line' containing
  87 # `alloca (...)'.
  88 my %needed_macros =
  89   (
  90    'AC_PREREQ' => [$me],
  91   );
  92
  93 my $configure_scan = 'configure.scan';
  94 my $log;
  95
  96 # Autoconf and lib files.
  97 my $autom4te = $ENV{'AUTOM4TE'} || '@bindir@/@autom4te-name@';
  98 my $autoconf = "$autom4te --language=autoconf";
  99 my @prepend_include;
 100 my @include = ('@datadir@');
 101
 102 # $help
 103 # -----
 104 $help = "Usage: $0 [OPTION] ... [SRCDIR]
 105
 106 Examine source files in the directory tree rooted at SRCDIR, or the
 107 current directory if none is given.  Search the source files for
 108 common portability problems, check for incompleteness of
 109 `configure.ac', and create a file `$configure_scan' which is a
 110 preliminary `configure.ac' for that package.
 111
 112   -h, --help          print this help, then exit
 113   -V, --version       print version number, then exit
 114   -v, --verbose       verbosely report processing
 115   -d, --debug         don't remove temporary files
 116
 117 Library directories:
 118   -B, --prepend-include=DIR  prepend directory DIR to search path
 119   -I, --include=DIR          append directory DIR to search path
 120
 121 Report bugs to <bug-autoconf\@gnu.org>.\n";
 122
 123 # $version
 124 # --------
 125 $version = "autoscan (@PACKAGE_NAME@) @VERSION@
 126 Written by David J. MacKenzie and Akim Demaille.
 127
 128 Copyright (C) 2004 Free Software Foundation, Inc.
 129 This is free software; see the source for copying conditions.  There is NO
 130 warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.\n";
 131
 132
 133
 134
 135 ## ------------------------ ##
 136 ## Command line interface.  ##
 137 ## ------------------------ ##
 138
 139 # parse_args ()
 140 # -------------
 141 # Process any command line arguments.
 142 sub parse_args ()
 143 {
 144   getopt ('I|include=s' => \@include,
 145           'B|prepend-include=s' => \@prepend_include);
 146
 147   die "$me: too many arguments
 148 Try `$me --help' for more information.\n"
 149     if @ARGV > 1;
 150
 151   my $srcdir = $ARGV[0] || ".";
 152
 153   verb "srcdir = $srcdir";
 154   chdir $srcdir || error "cannot cd to $srcdir: $!";
 155 }
 156
 157
 158 # init_tables ()
 159 # --------------
 160 # Put values in the tables of what to do with each token.
 161 sub init_tables ()
 162 {
 163   # The data file format supports only one line of macros per function.
 164   # If more than that is required for a common portability problem,
 165   # a new Autoconf macro should probably be written for that case,
 166   # instead of duplicating the code in lots of configure.ac files.
 167   my $file = find_file ("autoscan/autoscan.list",
 168                         reverse (@prepend_include), @include);
 169   my $table = new Autom4te::XFile $file;
 170   my $tables_are_consistent = 1;
 171
 172   while ($_ = $table->getline)
 173     {
 174       # Ignore blank lines and comments.
 175       next
 176         if /^\s*$/ || /^\s*\#/;
 177
 178       # '<kind>: <word> <macro invocation>' or...
 179       # '<kind>: <word> warn: <message>'.
 180       if (/^(\S+):\s+(\S+)\s+(\S.*)$/)
 181         {
 182           my ($kind, $word, $macro) = ($1, $2, $3);
 183           error "$file:$.: invalid kind: $_"
 184             unless grep { $_ eq $kind } @kinds;
 185           push @{$macro{$kind}{$word}}, $macro;
 186         }
 187       else
 188         {
 189           error "$file:$.: invalid definition: $_";
 190         }
 191     }
 192
 193   if ($debug)
 194     {
 195       foreach my $kind (@kinds)
 196         {
 197           foreach my $word (sort keys %{$macro{$kind}})
 198             {
 199               print "$kind: $word: @{$macro{$kind}{$word}}\n";
 200             }
 201         }
 202
 203     }
 204 }
 205
 206
 207 # used ($KIND, $WORD, [$WHERE])
 208 # -----------------------------
 209 # $WORD is used as a $KIND.
 210 sub used ($$;$)
 211 {
 212   my ($kind, $word, $where) = @_;
 213   $where ||= "$File::Find::name:$.";
 214   if (
 215       # Check for all the libraries.  But `-links' is certainly a
 216       # `find' argument, and `-le', a `test' argument.
 217       ($kind eq 'library' && $word !~ /^(e|inks)$/)
 218       # Other than libraries are to be checked only if listed in
 219       # the Autoscan library files.
 220       || defined $macro{$kind}{$word}
 221      )
 222     {
 223       push (@{$used{$kind}{$word}}, $where);
 224     }
 225 }
 226
 227
 228
 229 ## ----------------------- ##
 230 ## Scanning source files.  ##
 231 ## ----------------------- ##
 232
 233
 234 # scan_c_file ($FILE-NAME)
 235 # ------------------------
 236 sub scan_c_file ($)
 237 {
 238   my ($file_name) = @_;
 239   push @cfiles, $File::Find::name;
 240
 241   # Nonzero if in a multiline comment.
 242   my $in_comment = 0;
 243
 244   my $file = new Autom4te::XFile "<$file_name";
 245
 246   while ($_ = $file->getline)
 247     {
 248       # Strip out comments.
 249       if ($in_comment && s,^.*?\*/,,)
 250         {
 251           $in_comment = 0;
 252         }
 253       # The whole line is inside a commment.
 254       next if $in_comment;
 255       # All on one line.
 256       s,/\*.*?\*/,,g;
 257
 258       # Starting on this line.
 259       if (s,/\*.*$,,)
 260         {
 261           $in_comment = 1;
 262         }
 263
 264       # Preprocessor directives.
 265       if (s/^\s*\#\s*//)
 266         {
 267           if (/^include\s*<([^>]*)>/)
 268             {
 269               used ('header', $1);
 270             }
 271           if (s/^(if|ifdef|ifndef|elif)\s+//)
 272             {
 273               foreach my $word (split (/\W+/))
 274                 {
 275                   used ('identifier', $word)
 276                     unless $word eq 'defined' || $word !~ /^[a-zA-Z_]/;
 277                 }
 278             }
 279           # Ignore other preprocessor directives.
 280           next;
 281         }
 282
 283       # Remove string and character constants.
 284       s,\"[^\"]*\",,g;
 285       s,\'[^\']*\',,g;
 286
 287       # Tokens in the code.
 288       # Maybe we should ignore function definitions (in column 0)?
 289       while (s/\b([a-zA-Z_]\w*)\s*\(/ /)
 290         {
 291           used ('function', $1);
 292         }
 293       while (s/\b([a-zA-Z_]\w*)\b/ /)
 294         {
 295           used ('identifier', $1);
 296         }
 297     }
 298
 299   $file->close;
 300 }
 301
 302
 303 # scan_makefile($MAKEFILE-NAME)
 304 # -----------------------------
 305 sub scan_makefile ($)
 306 {
 307   my ($file_name) = @_;
 308   push @makefiles, $File::Find::name;
 309
 310   my $file = new Autom4te::XFile "<$file_name";
 311
 312   while ($_ = $file->getline)
 313     {
 314       # Strip out comments.
 315       s/#.*//;
 316
 317       # Variable assignments.
 318       while (s/\b([a-zA-Z_]\w*)\s*=/ /)
 319         {
 320           used ('makevar', $1);
 321         }
 322       # Be sure to catch a whole word.  For instance `lex$U.$(OBJEXT)'
 323       # is a single token.  Otherwise we might believe `lex' is needed.
 324       foreach my $word (split (/\s+/))
 325         {
 326           # Libraries.
 327           if ($word =~ /^-l([a-zA-Z_]\w*)$/)
 328             {
 329               used ('library', $1);
 330             }
 331           # Tokens in the code.
 332           # We allow some additional characters, e.g., `+', since
 333           # autoscan/programs includes `c++'.
 334           if ($word =~ /^[a-zA-Z_][\w+]*$/)
 335             {
 336               used ('program', $word);
 337             }
 338         }
 339     }
 340
 341   $file->close;
 342 }
 343
 344
 345 # scan_sh_file($SHELL-SCRIPT-NAME)
 346 # --------------------------------
 347 sub scan_sh_file ($)
 348 {
 349   my ($file_name) = @_;
 350   push @shfiles, $File::Find::name;
 351
 352   my $file = new Autom4te::XFile "<$file_name";
 353
 354   while ($_ = $file->getline)
 355     {
 356       # Strip out comments and variable references.
 357       s/#.*//;
 358       s/\${[^\}]*}//g;
 359       s/@[^@]*@//g;
 360
 361       # Tokens in the code.
 362       while (s/\b([a-zA-Z_]\w*)\b/ /)
 363         {
 364           used ('program', $1);
 365         }
 366     }
 367
 368   $file->close;
 369 }
 370
 371
 372 # scan_file ()
 373 # ------------
 374 # Called by &find on each file.  $_ contains the current file name with
 375 # the current directory of the walk through.
 376 sub scan_file ()
 377 {
 378   # Wanted only if there is no corresponding FILE.in.
 379   return
 380     if -f "$_.in";
 381
 382   # Save $_ as Find::File requires it to be preserved.
 383   local $_ = $_;
 384
 385   # Strip a useless leading `./'.
 386   $File::Find::name =~ s,^\./,,;
 387
 388   if (/\.[chlym](\.in)?$/)
 389     {
 390       used 'program', 'cc', $File::Find::name;
 391       scan_c_file ($_);
 392     }
 393   elsif (/\.(cc|cpp|cxx|CC|C|hh|hpp|hxx|HH|H|yy|ypp|ll|lpp)(\.in)?$/)
 394     {
 395       used 'program', 'c++', $File::Find::name;
 396       scan_c_file ($_);
 397     }
 398   elsif ((/^((?:GNUm|M|m)akefile)(\.in)?$/ && ! -f "$1.am")
 399          || /^(?:GNUm|M|m)akefile(\.am)?$/)
 400     {
 401       scan_makefile ($_);
 402     }
 403   elsif (/\.sh(\.in)?$/)
 404     {
 405       scan_sh_file ($_);
 406     }
 407 }
 408
 409
 410 # scan_files ()
 411 # -------------
 412 # Read through the files and collect lists of tokens in them
 413 # that might create nonportabilities.
 414 sub scan_files ()
 415 {
 416   find (\&scan_file, '.');
 417
 418   if ($verbose)
 419     {
 420       print "cfiles: @cfiles\n";
 421       print "makefiles: @makefiles\n";
 422       print "shfiles: @shfiles\n";
 423
 424       foreach my $kind (@kinds)
 425         {
 426           print "\n$kind:\n";
 427           foreach my $word (sort keys %{$used{$kind}})
 428             {
 429               print "$word: @{$used{$kind}{$word}}\n";
 430             }
 431         }
 432     }
 433 }
 434
 435
 436 ## ----------------------- ##
 437 ## Output configure.scan.  ##
 438 ## ----------------------- ##
 439
 440
 441 # output_kind ($FILE, $KIND)
 442 # --------------------------
 443 sub output_kind ($$)
 444 {
 445   my ($file, $kind) = @_;
 446   # Lists of words to be checked with the generic macro.
 447   my @have;
 448
 449   print $file "\n# $kind_comment{$kind}\n"
 450     if exists $kind_comment{$kind};
 451   foreach my $word (sort keys %{$used{$kind}})
 452     {
 453       # Output the needed macro invocations in $configure_scan if not
 454       # already printed, and remember these macros are needed.
 455       foreach my $macro (@{$macro{$kind}{$word}})
 456         {
 457           if ($macro =~ /^warn:\s+(.*)/)
 458             {
 459               my $message = $1;
 460               foreach my $location (@{$used{$kind}{$word}})
 461                 {
 462                   warn "$location: warning: $message\n";
 463                 }
 464             }
 465           elsif (exists $generic_macro{$kind}
 466               && $macro eq $generic_macro{$kind})
 467             {
 468               push (@have, $word);
 469               push (@{$needed_macros{"$generic_macro{$kind}([$word])"}},
 470                     @{$used{$kind}{$word}});
 471             }
 472           else
 473             {
 474               if (! $printed{$macro})
 475                 {
 476                   print $file "$macro\n";
 477                   $printed{$macro} = 1;
 478                 }
 479               push (@{$needed_macros{$macro}},
 480                     @{$used{$kind}{$word}});
 481             }
 482         }
 483     }
 484   print $file "$generic_macro{$kind}([" . join(' ', sort(@have)) . "])\n"
 485     if @have;
 486 }
 487
 488
 489 # output_libraries ($FILE)
 490 # ------------------------
 491 sub output_libraries ($)
 492 {
 493   my ($file) = @_;
 494
 495   print $file "\n# Checks for libraries.\n";
 496   foreach my $word (sort keys %{$used{'library'}})
 497     {
 498       print $file "# FIXME: Replace `main' with a function in `-l$word':\n";
 499       print $file "AC_CHECK_LIB([$word], [main])\n";
 500     }
 501 }
 502
 503
 504 # output ($CONFIGURE_SCAN)
 505 # ------------------------
 506 # Print a proto configure.ac.
 507 sub output ($)
 508 {
 509   my $configure_scan = shift;
 510   my %unique_makefiles;
 511
 512   my $file = new Autom4te::XFile ">$configure_scan";
 513
 514   print $file
 515     ("#                                               -*- Autoconf -*-\n" .
 516      "# Process this file with autoconf to produce a configure script.\n" .
 517      "\n" .
 518      "AC_PREREQ(@VERSION@)\n" .
 519      "AC_INIT(FULL-PACKAGE-NAME, VERSION, BUG-REPORT-ADDRESS)\n");
 520   if (defined $cfiles[0])
 521     {
 522       print $file "AC_CONFIG_SRCDIR([$cfiles[0]])\n";
 523       print $file "AC_CONFIG_HEADER([config.h])\n";
 524     }
 525
 526   output_kind ($file, 'program');
 527   output_kind ($file, 'makevar');
 528   output_libraries ($file);
 529   output_kind ($file, 'header');
 530   output_kind ($file, 'identifier');
 531   output_kind ($file, 'function');
 532
 533   if (@makefiles)
 534     {
 535       # Change DIR/Makefile.in to DIR/Makefile.
 536       foreach my $m (@makefiles)
 537         {
 538           $m =~ s/\.(?:in|am)$//;
 539           $unique_makefiles{$m}++;
 540         }
 541       print $file ("\nAC_CONFIG_FILES([",
 542                    join ("\n                 ",
 543                          sort keys %unique_makefiles), "])\n");
 544     }
 545   print $file "AC_OUTPUT\n";
 546
 547   $file->close;
 548 }
 549
 550
 551
 552 ## --------------------------------------- ##
 553 ## Checking the accuracy of configure.ac.  ##
 554 ## --------------------------------------- ##
 555
 556
 557 # &check_configure_ac ($CONFIGURE_AC)
 558 # -----------------------------------
 559 # Use autoconf to check if all the suggested macros are included
 560 # in CONFIGURE_AC.
 561 sub check_configure_ac ($)
 562 {
 563   my ($configure_ac) = @_;
 564
 565   # Find what needed macros are invoked in CONFIGURE_AC.
 566   # I'd be very happy if someone could explain to me why sort (uniq ...)
 567   # doesn't work properly: I need `uniq (sort ...)'.  --akim
 568   my $trace_option =
 569     join (' --trace=', '',
 570           uniq (sort (map { s/\(.*//; $_ } keys %needed_macros)));
 571
 572   verb "running: $autoconf $trace_option $configure_ac";
 573   my $traces =
 574     new Autom4te::XFile "$autoconf $trace_option $configure_ac|";
 575
 576   while ($_ = $traces->getline)
 577     {
 578       chomp;
 579       my ($file, $line, $macro, @args) = split (/:/, $_);
 580       if ($macro =~ /^AC_CHECK_(HEADER|FUNC|TYPE|MEMBER)S$/)
 581         {
 582           # To be rigorous, we should distinguish between space and comma
 583           # separated macros.  But there is no point.
 584           foreach my $word (split (/\s|,/, $args[0]))
 585             {
 586               # AC_CHECK_MEMBERS wants `struct' or `union'.
 587               if ($macro eq "AC_CHECK_MEMBERS"
 588                   && $word =~ /^stat.st_/)
 589                 {
 590                   $word = "struct " . $word;
 591                 }
 592               delete $needed_macros{"$macro([$word])"};
 593             }
 594         }
 595       else
 596         {
 597           delete $needed_macros{$macro};
 598         }
 599     }
 600
 601   $traces->close;
 602
 603   # Report the missing macros.
 604   foreach my $macro (sort keys %needed_macros)
 605     {
 606       warn ("$configure_ac: warning: missing $macro wanted by: "
 607             . (${$needed_macros{$macro}}[0])
 608             . "\n");
 609       print $log "$me: warning: missing $macro wanted by: \n";
 610       foreach my $need (@{$needed_macros{$macro}})
 611         {
 612           print $log "\t$need\n";
 613         }
 614     }
 615 }
 616
 617
 618 ## -------------- ##
 619 ## Main program.  ##
 620 ## -------------- ##
 621
 622 parse_args;
 623 $log = new Autom4te::XFile ">$me.log";
 624
 625 $autoconf .= " --debug" if $debug;
 626 $autoconf .= " --verbose" if $verbose;
 627 $autoconf .= join (' --include=', '', @include);
 628 $autoconf .= join (' --prepend-include=', '', @prepend_include);
 629
 630 my $configure_ac = find_configure_ac;
 631 init_tables;
 632 scan_files;
 633 output ('configure.scan');
 634 if ($configure_ac)
 635   {
 636     check_configure_ac ($configure_ac);
 637   }
 638 # This close is really needed.  For some reason, probably best named
 639 # a bug, it seems that the dtor of $LOG is not called automatically
 640 # at END.  It results in a truncated file.
 641 $log->close;
 642 exit 0;
 643
 644 ### Setup "GNU" style for perl-mode and cperl-mode.
 645 ## Local Variables:
 646 ## perl-indent-level: 2
 647 ## perl-continued-statement-offset: 2
 648 ## perl-continued-brace-offset: 0
 649 ## perl-brace-offset: 0
 650 ## perl-brace-imaginary-offset: 0
 651 ## perl-label-offset: -2
 652 ## cperl-indent-level: 2
 653 ## cperl-brace-offset: 0
 654 ## cperl-continued-brace-offset: 0
 655 ## cperl-label-offset: -2
 656 ## cperl-extra-newline-before-brace: t
 657 ## cperl-merge-trailing-else: nil
 658 ## cperl-continued-statement-offset: 2
 659 ## End: