| blob | 5e6245d8187252629f9ef78fa3835b4ef97542fe |
1 # This file is part of Autoconf. -*- Autoconf -*-
2 # M4 sugar for common shell constructs.
3 # Requires GNU M4 and M4sugar.
4 #
5 # Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008
6 # Free Software Foundation, Inc.
7 #
8 # This program is free software: you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 2, or (at your option)
11 # any later version.
12 #
13 # This program is distributed in the hope that it will be useful,
14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
16 # GNU General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
21 # 02110-1301, USA.
22 #
23 # As a special exception, the Free Software Foundation gives unlimited
24 # permission to copy, distribute and modify the configure scripts that
25 # are the output of Autoconf. You need not follow the terms of the GNU
26 # General Public License when using or distributing such scripts, even
27 # though portions of the text of Autoconf appear in them. The GNU
28 # General Public License (GPL) does govern all other use of the material
29 # that constitutes the Autoconf program.
30 #
31 # Certain portions of the Autoconf source text are designed to be copied
32 # (in certain cases, depending on the input) into the output of
33 # Autoconf. We call these the "data" portions. The rest of the Autoconf
34 # source text consists of comments plus executable code that decides which
35 # of the data portions to output in any given case. We call these
36 # comments and executable code the "non-data" portions. Autoconf never
37 # copies any of the non-data portions into its output.
38 #
39 # This special exception to the GPL applies to versions of Autoconf
40 # released by the Free Software Foundation. When you make and
41 # distribute a modified version of Autoconf, you may extend this special
42 # exception to the GPL to apply to your modified version as well, *unless*
43 # your modified version has the potential to copy into its output some
44 # of the text that was the non-data portion of the version that you started
45 # with. (In other words, unless your change moves or copies text from
46 # the non-data portions to the data portions.) If your modification has
47 # such potential, you must delete any notice of this special exception
48 # to the GPL from your modified version.
49 #
50 # Written by Akim Demaille, Pavel Roskin, Alexandre Oliva, Lars J. Aas
51 # and many other people.
54 # We heavily use m4's diversions both for the initializations and for
55 # required macros, because in both cases we have to issue soon in
56 # output something which is discovered late.
57 #
58 #
59 # KILL is only used to suppress output.
60 #
61 # - BINSH
62 # AC_REQUIRE'd #! /bin/sh line
63 # - HEADER-REVISION
64 # RCS keywords etc.
65 # - HEADER-COMMENT
66 # Purpose of the script etc.
67 # - HEADER-COPYRIGHT
68 # Copyright notice(s)
69 # - M4SH-SANITIZE
70 # M4sh's shell setup
71 # - M4SH-INIT-FN
72 # M4sh initialization (shell functions)
73 # - M4SH-INIT
74 # M4sh initialization (detection code)
75 # - BODY
76 # The body of the script.
79 # _m4_divert(DIVERSION-NAME)
80 # --------------------------
81 # Convert a diversion name into its number. Otherwise, return
82 # DIVERSION-NAME which is supposed to be an actual diversion number.
83 # Of course it would be nicer to use m4_case here, instead of zillions
84 # of little macros, but it then takes twice longer to run `autoconf'!
85 m4_define([_m4_divert(BINSH)], 0)
86 m4_define([_m4_divert(HEADER-REVISION)], 1)
87 m4_define([_m4_divert(HEADER-COMMENT)], 2)
88 m4_define([_m4_divert(HEADER-COPYRIGHT)], 3)
89 m4_define([_m4_divert(M4SH-SANITIZE)], 4)
90 m4_define([_m4_divert(M4SH-INIT-FN)], 5)
91 m4_define([_m4_divert(M4SH-INIT)], 6)
92 m4_define([_m4_divert(BODY)], 1000)
94 # Aaarg. Yet it starts with compatibility issues... Libtool wants to
95 # use NOTICE to insert its own LIBTOOL-INIT stuff. People should ask
96 # before diving into our internals :(
97 m4_copy([_m4_divert(M4SH-INIT)], [_m4_divert(NOTICE)])
101 ## ------------------------- ##
102 ## 1. Sanitizing the shell. ##
103 ## ------------------------- ##
104 # Please maintain lexicographic sorting of this section, ignoring leading _.
106 # AS_BOURNE_COMPATIBLE
107 # --------------------
108 # Try to be as Bourne and/or POSIX as possible.
109 #
110 # This does not set BIN_SH, due to the problems described in
111 # <http://lists.gnu.org/archive/html/autoconf-patches/2006-03/msg00081.html>.
112 # People who need BIN_SH should set it in their environment before invoking
113 # configure; apparently this would include UnixWare, as described in
114 # <http://lists.gnu.org/archive/html/bug-autoconf/2006-06/msg00025.html>.
115 m4_define([AS_BOURNE_COMPATIBLE],
116 [# Be more Bourne compatible
117 DUALCASE=1; export DUALCASE # for MKS sh
118 _$0
119 ])
121 # _AS_BOURNE_COMPATIBLE
122 # ---------------------
123 # This is the part of AS_BOURNE_COMPATIBLE which has to be repeated inside
124 # each instance.
125 m4_define([_AS_BOURNE_COMPATIBLE],
126 [AS_IF([test -n "${ZSH_VERSION+set}" && (emulate sh) >/dev/null 2>&1],
127 [emulate sh
128 NULLCMD=:
129 [#] Pre-4.2 versions of Zsh do word splitting on ${1+"$[@]"}, which
130 # is contrary to our usage. Disable this feature.
131 alias -g '${1+"$[@]"}'='"$[@]"'
132 setopt NO_GLOB_SUBST],
133 [AS_CASE([`(set -o) 2>/dev/null`], [*posix*], [set -o posix])])
134 ])
137 # _AS_CLEANUP
138 # -----------
139 # Expanded as the last thing before m4sugar cleanup begins. Macros
140 # may append m4sh cleanup hooks to this as appropriate.
141 m4_define([_AS_CLEANUP],
142 [m4_divert_text([M4SH-SANITIZE], [_AS_DETECT_BETTER_SHELL])])
145 # AS_COPYRIGHT(TEXT)
146 # ------------------
147 # Emit TEXT, a copyright notice, as a shell comment near the top of the
148 # script. TEXT is evaluated once; to accomplish that, we do not prepend
149 # `# ' but `@%:@ '.
150 m4_define([AS_COPYRIGHT],
151 [m4_divert_text([HEADER-COPYRIGHT],
152 [m4_bpatsubst([
153 $1], [^], [@%:@ ])])])
156 # _AS_DETECT_REQUIRED(TEST)
157 # -------------------------
158 # Refuse to execute under a shell that does not pass the given TEST.
159 # Does not do AS_REQUIRE for the better-shell detection code.
160 m4_defun([_AS_DETECT_REQUIRED],
161 [m4_set_add([_AS_DETECT_REQUIRED_BODY],
162 [($1) || AS_EXIT(1)
163 ])])
166 # _AS_DETECT_SUGGESTED(TEST)
167 # --------------------------
168 # Prefer to execute under a shell that passes the given TEST.
169 # Does not do AS_REQUIRE for the better-shell detection code.
170 m4_defun([_AS_DETECT_SUGGESTED],
171 [m4_set_add([_AS_DETECT_SUGGESTED_BODY],
172 [($1) || AS_EXIT(1)
173 ])])
176 # _AS_DETECT_BETTER_SHELL
177 # -----------------------
178 # The real workhorse for detecting a shell with the correct
179 # features.
180 #
181 # In previous versions, we prepended /usr/posix/bin to the path, but that
182 # caused a regression on OpenServer 6.0.0
183 # <http://lists.gnu.org/archive/html/bug-autoconf/2006-06/msg00017.html>
184 # and on HP-UX 11.11, see the failure of test 120 in
185 # <http://lists.gnu.org/archive/html/bug-autoconf/2006-10/msg00003.html>
186 #
187 # FIXME: The code should test for the OSF bug described in
188 # <http://lists.gnu.org/archive/html/autoconf-patches/2006-03/msg00081.html>.
189 #
190 m4_defun([_AS_DETECT_BETTER_SHELL],
191 [if test "x$CONFIG_SHELL" = x; then
192 dnl Remove any tests from suggested that are also required
193 m4_set_foreach([_AS_DETECT_SUGGESTED_BODY], [AS_snippet],
194 [m4_set_contains([_AS_DETECT_REQUIRED_BODY],
195 _m4_defn([AS_snippet]),
196 [m4_set_remove([_AS_DETECT_SUGGESTED_BODY],
197 _m4_defn([AS_snippet]))])])dnl
198 m4_set_empty([_AS_DETECT_REQUIRED_BODY], [as_have_required=yes],
199 [as_bourne_compatible="AS_ESCAPE(m4_expand([_AS_BOURNE_COMPATIBLE]))"
200 as_required="AS_ESCAPE(m4_expand(m4_set_contents([_AS_DETECT_REQUIRED_BODY])))"
201 as_suggested="AS_ESCAPE(m4_expand(m4_set_contents([_AS_DETECT_SUGGESTED_BODY])))"
202 AS_IF([_AS_RUN(["$as_required"])],
203 [as_have_required=yes],
204 [as_have_required=no])])
205 AS_IF([test x$as_have_required = xyes && _AS_RUN(["$as_suggested"])],
206 [],
207 [as_candidate_shells=
208 _AS_PATH_WALK([/bin$PATH_SEPARATOR/usr/bin$PATH_SEPARATOR$PATH],
209 [case $as_dir in
210 /*)
211 for as_base in sh bash ksh sh5; do
212 as_candidate_shells="$as_candidate_shells $as_dir/$as_base"
213 done;;
214 esac])
216 for as_shell in $as_candidate_shells $SHELL; do
217 # Try only shells that exist, to save several forks.
218 AS_IF([{ test -f "$as_shell" || test -f "$as_shell.exe"; } &&
219 _AS_RUN(["$as_required"], ["$as_shell"])],
220 [CONFIG_SHELL=$as_shell
221 as_have_required=yes
222 m4_set_empty([_AS_DETECT_SUGGESTED_BODY], [break],
223 [AS_IF([_AS_RUN(["$as_suggested"], ["$as_shell"])], [break])])])
224 done
226 AS_IF([test "x$CONFIG_SHELL" != x],
227 [# We cannot yet assume a decent shell, so we have to provide a
228 # neutralization value for shells without unset; and this also
229 # works around shells that cannot unset nonexistent variables.
230 BASH_ENV=/dev/null
231 ENV=/dev/null
232 (unset BASH_ENV) >/dev/null 2>&1 && unset BASH_ENV ENV
233 export CONFIG_SHELL
234 exec "$CONFIG_SHELL" "$as_myself" ${1+"$[@]"}])
236 AS_IF([test x$as_have_required = xno],
237 [echo This script requires a shell more modern than all the
238 echo shells that I found on your system. Please install a
239 echo modern shell, or manually run the script under such a
240 echo shell if you do have one.
241 AS_EXIT(1)])
242 ])
243 fi
244 ])# _AS_DETECT_BETTER_SHELL
247 # _AS_PREPARE
248 # -----------
249 # This macro has a very special status. Normal use of M4sh relies
250 # heavily on AS_REQUIRE, so that needed initializations (such as
251 # _AS_TEST_PREPARE) are performed on need, not on demand. But
252 # Autoconf is the first client of M4sh, and for two reasons: configure
253 # and config.status. Relying on AS_REQUIRE is of course fine for
254 # configure, but fails for config.status (which is created by
255 # configure). So we need a means to force the inclusion of the
256 # various _AS_PREPARE_* on top of config.status. That's basically why
257 # there are so many _AS_PREPARE_* below, and that's also why it is
258 # important not to forget some: config.status needs them.
259 m4_defun([_AS_PREPARE],
260 [m4_pushdef([AS_REQUIRE], [])dnl
261 as_func_mkdir_p ()
262 {
263 _AS_MKDIR_P
264 }
266 _AS_EXPR_PREPARE
267 _AS_BASENAME_PREPARE
268 _AS_DIRNAME_PREPARE
269 _AS_ME_PREPARE
270 _AS_LINENO_PREPARE
271 _AS_ECHO_N_PREPARE[]dnl We do not need this ourselves but user code might.
272 _AS_LN_S_PREPARE
273 _AS_MKDIR_P_PREPARE
274 _AS_TEST_PREPARE
275 _AS_TR_CPP_PREPARE
276 _AS_TR_SH_PREPARE
277 _AS_UNSET_PREPARE
278 m4_popdef([AS_REQUIRE])dnl
279 ])
281 # AS_PREPARE
282 # ----------
283 # Output all the M4sh possible initialization into the initialization
284 # diversion. We do not use _AS_PREPARE so that the m4_provide symbols for
285 # AS_REQUIRE and AS_REQUIRE_SHELL_FN are defined properly, and so that
286 # shell functions are placed in M4SH-INIT-FN.
287 m4_defun([AS_PREPARE],
288 [AS_REQUIRE([_AS_EXPR_PREPARE])
289 AS_REQUIRE([_AS_BASENAME_PREPARE])
290 AS_REQUIRE([_AS_DIRNAME_PREPARE])
291 AS_REQUIRE([_AS_ME_PREPARE])
292 AS_REQUIRE([_AS_LINENO_PREPARE])
293 AS_REQUIRE([_AS_ECHO_N_PREPARE])
294 AS_REQUIRE([_AS_LN_S_PREPARE])
295 AS_REQUIRE([_AS_MKDIR_P_PREPARE])
296 AS_REQUIRE([_AS_TEST_PREPARE])
297 AS_REQUIRE([_AS_TR_CPP_PREPARE])
298 AS_REQUIRE([_AS_TR_SH_PREPARE])
299 AS_REQUIRE([_AS_UNSET_PREPARE])
300 ])
303 # AS_REQUIRE(NAME-TO-CHECK, [BODY-TO-EXPAND = NAME-TO-CHECK],
304 # [DIVERSION = M4SH-INIT])
305 # -----------------------------------------------------------
306 # BODY-TO-EXPAND is some initialization which must be expanded in the
307 # given diversion when expanded (required or not). The expansion
308 # goes in the named diversion or an earlier one.
309 #
310 m4_defun([AS_REQUIRE],
311 [m4_define([_m4_divert_desired], [m4_default_quoted([$3], [M4SH-INIT])])dnl
312 m4_if(m4_eval(_m4_divert(_m4_divert_dump) <= _m4_divert(_m4_divert_desired)), 1,
313 [m4_require([$1], [$2])],
314 [m4_divert_require([_m4_divert_desired], [$1], [$2])])])
317 # AS_REQUIRE_SHELL_FN(NAME-TO-CHECK, BODY-TO-EXPAND,
318 # [DIVERSION = M4SH-INIT-FN])
319 # --------------------------------------------------
320 # BODY-TO-EXPAND is the body of a shell function to be emitted in the
321 # given diversion when expanded (required or not). Unlike other
322 # xx_REQUIRE macros, BODY-TO-EXPAND is mandatory.
323 #
324 m4_define([AS_REQUIRE_SHELL_FN],
325 [AS_REQUIRE([AS_SHELL_FN_$1], [m4_provide([AS_SHELL_FN_$1])$1 ()
326 {
327 $2
328 }], m4_default_quoted([$3], [M4SH-INIT-FN]))])
331 # _AS_RUN(TEST, [SHELL])
332 # ----------------------
333 # Run TEST under the current shell (if one parameter is used)
334 # or under the given SHELL, protecting it from syntax errors.
335 m4_define([_AS_RUN],
336 [m4_ifval([$2], [{ $as_echo "$as_bourne_compatible"$1 | ($2); }],
337 [(eval $1)]) 2>/dev/null])
340 # _AS_SHELL_FN_WORK
341 # -----------------
342 # This is a spy to detect "in the wild" shells that do not support shell
343 # functions correctly. It is based on the m4sh.at Autotest testcases.
344 m4_define([_AS_SHELL_FN_WORK],
345 [as_func_return ()
346 {
347 (exit [$]1)
348 }
349 as_func_success ()
350 {
351 as_func_return 0
352 }
353 as_func_failure ()
354 {
355 as_func_return 1
356 }
357 as_func_ret_success ()
358 {
359 return 0
360 }
361 as_func_ret_failure ()
362 {
363 return 1
364 }
366 exitcode=0
367 AS_IF([as_func_success], [],
368 [exitcode=1
369 echo as_func_success failed.])
370 AS_IF([as_func_failure],
371 [exitcode=1
372 echo as_func_failure succeeded.])
373 AS_IF([as_func_ret_success], [],
374 [exitcode=1
375 echo as_func_ret_success failed.])
376 AS_IF([as_func_ret_failure],
377 [exitcode=1
378 echo as_func_ret_failure succeeded.])
379 AS_IF([( set x; as_func_ret_success y && test x = "[$]1" )], [],
380 [exitcode=1
381 echo positional parameters were not saved.])
382 test x$exitcode = x0[]dnl
383 ])# _AS_SHELL_FN_WORK
386 # _AS_SHELL_SANITIZE
387 # ------------------
388 # This is the prolog that is emitted by AS_INIT and AS_INIT_GENERATED.
389 m4_defun([_AS_SHELL_SANITIZE],
390 [## --------------------- ##
391 ## M4sh Initialization. ##
392 ## --------------------- ##
394 AS_BOURNE_COMPATIBLE
396 # PATH needs CR
397 _AS_CR_PREPARE
398 _AS_ECHO_PREPARE
399 _AS_PATH_SEPARATOR_PREPARE
401 # IFS
402 # We need space, tab and new line, in precisely that order. Quoting is
403 # there to prevent editors from complaining about space-tab.
404 # (If _AS_PATH_WALK were called with IFS unset, it would disable word
405 # splitting by setting IFS to empty value.)
406 IFS=" "" $as_nl"
408 # Find who we are. Look in the path if we contain no directory separator.
409 case $[0] in
410 *[[\\/]]* ) as_myself=$[0] ;;
411 *) _AS_PATH_WALK([],
412 [test -r "$as_dir/$[0]" && as_myself=$as_dir/$[0] && break])
413 ;;
414 esac
415 # We did not find ourselves, most probably we were run as `sh COMMAND'
416 # in which case we are not to be found in the path.
417 if test "x$as_myself" = x; then
418 as_myself=$[0]
419 fi
420 if test ! -f "$as_myself"; then
421 AS_ECHO(["$as_myself: error: cannot find myself; rerun with an absolute file name"]) >&2
422 AS_EXIT
423 fi
425 # Unset variables that we do not need and which cause bugs (e.g. in
426 # pre-3.0 UWIN ksh). But do not cause bugs in bash 2.01; the "|| exit 1"
427 # suppresses any "Segmentation fault" message there. '((' could
428 # trigger a bug in pdksh 5.2.14.
429 for as_var in BASH_ENV ENV MAIL MAILPATH
430 do eval test x\${$as_var+set} = xset && dnl
431 ( (unset $as_var) || exit 1) >/dev/null 2>&1 && unset $as_var || :
432 done
433 PS1='$ '
434 PS2='> '
435 PS4='+ '
437 # NLS nuisances.
438 LC_ALL=C
439 export LC_ALL
440 LANGUAGE=C
441 export LANGUAGE
443 # CDPATH.
444 (unset CDPATH) >/dev/null 2>&1 && unset CDPATH
445 ])# _AS_SHELL_SANITIZE
448 # AS_SHELL_SANITIZE
449 # -----------------
450 # This is only needed for the sake of Libtool, which screws up royally
451 # in its usage of M4sh internals.
452 m4_define([AS_SHELL_SANITIZE],
453 [_AS_SHELL_SANITIZE
454 m4_provide_if([AS_INIT], [],
455 [m4_provide([AS_INIT])
456 _AS_DETECT_REQUIRED([_AS_SHELL_FN_WORK])
457 _AS_DETECT_BETTER_SHELL
458 _AS_UNSET_PREPARE
459 ])])
462 ## ----------------------------- ##
463 ## 2. Wrappers around builtins. ##
464 ## ----------------------------- ##
466 # This section is lexicographically sorted.
469 # AS_CASE(WORD, [PATTERN1], [IF-MATCHED1]...[DEFAULT])
470 # ----------------------------------------------------
471 # Expand into
472 # | case WORD in
473 # | PATTERN1) IF-MATCHED1 ;;
474 # | ...
475 # | *) DEFAULT ;;
476 # | esac
477 m4_define([_AS_CASE],
478 [ $1[)] m4_default([$2], [:]) ;;
479 ])
480 m4_define([_AS_CASE_DEFAULT],
481 [ *[)] $1 ;;
482 ])
483 m4_defun([AS_CASE],
484 [m4_ifval([$2$3],
485 [case $1 in
486 m4_transform_pair([_$0], [_$0_DEFAULT], m4_shift($@))dnl
487 esac
488 ])dnl
489 ])# AS_CASE
492 # AS_EXIT([EXIT-CODE = 1])
493 # ------------------------
494 # Exit and set exit code to EXIT-CODE in the way that it's seen
495 # within "trap 0".
496 #
497 # We cannot simply use "exit N" because some shells (zsh and Solaris sh)
498 # will not set $? to N while running the code set by "trap 0"
499 # So we set $? by executing "exit N" in the subshell and then exit.
500 # Other shells don't use `$?' as default for `exit', hence just repeating
501 # the exit value can only help improving portability.
502 m4_define([AS_EXIT],
503 [{ (exit m4_default([$1], 1)); exit m4_default([$1], 1); }])
506 # AS_IF(TEST1, [IF-TRUE1]...[IF-FALSE])
507 # -------------------------------------
508 # Expand into
509 # | if TEST1; then
510 # | IF-TRUE1
511 # | elif TEST2; then
512 # | IF-TRUE2
513 # [...]
514 # | else
515 # | IF-FALSE
516 # | fi
517 # with simplifications if IF-TRUE1 and/or IF-FALSE is empty.
518 #
519 m4_define([_AS_IF],
520 [elif $1; then
521 m4_default([$2], [:])
522 ])
523 m4_define([_AS_IF_ELSE],
524 [m4_ifvaln([$1],
525 [else
526 $1])])
527 m4_defun([AS_IF],
528 [m4_ifval([$2$3],
529 [if $1; then
530 m4_default([$2], [:])
531 m4_transform_pair([_$0], [_$0_ELSE], m4_shift2($@))dnl
532 fi
533 ])dnl
534 ])# AS_IF
537 # _AS_UNSET_PREPARE
538 # -----------------
539 # Define $as_unset to execute AS_UNSET, for backwards compatibility
540 # with older versions of M4sh.
541 m4_defun([_AS_UNSET_PREPARE],
542 [as_func_unset ()
543 {
544 AS_UNSET([$[1]])
545 }
546 as_unset=as_func_unset
547 ])
550 # AS_UNSET(VAR)
551 # -------------
552 # Unset the env VAR, working around shells that do not allow unsetting
553 # a variable that is not already set. You should not unset MAIL and
554 # MAILCHECK, as that triggers a bug in Bash 2.01.
555 m4_defun([AS_UNSET],
556 [{ AS_LITERAL_IF([$1], [], [eval ])$1=; unset $1;}])
563 ## ------------------------------------------ ##
564 ## 3. Error and warnings at the shell level. ##
565 ## ------------------------------------------ ##
567 # If AS_MESSAGE_LOG_FD is defined, shell messages are duplicated there
568 # too.
571 # AS_ESCAPE(STRING, [CHARS = $"`\])
572 # ---------------------------------
573 # Escape the CHARS in STRING.
574 #
575 # Avoid the m4_bpatsubst if there are no interesting characters to escape.
576 # _AS_ESCAPE bypasses argument defaulting.
577 m4_define([AS_ESCAPE],
578 [_$0([$1], m4_default([$2], [\"$`]))])
579 m4_define([_AS_ESCAPE],
580 [m4_if(m4_len([$1]),
581 m4_len(m4_translit([[$1]], [$2])),
582 [$1], [m4_bpatsubst([$1], [[$2]], [\\\&])])])
585 # _AS_QUOTE_IFELSE(STRING, IF-MODERN-QUOTATION, IF-OLD-QUOTATION)
586 # ---------------------------------------------------------------
587 # Compatibility glue between the old AS_MSG suite which did not
588 # quote anything, and the modern suite which quotes the quotes.
589 # If STRING contains `\\' or `\$', it's modern.
590 # If STRING contains `\"' or `\`', it's old.
591 # Otherwise it's modern.
592 #
593 # Profiling shows that m4_index is 5 to 8x faster than m4_bregexp. The
594 # slower implementation used:
595 # m4_bmatch([$1],
596 # [\\[\\$]], [$2],
597 # [\\[`"]], [$3],
598 # [$2])
599 # The current implementation caters to the common case of no backslashes,
600 # to minimize m4_index expansions (hence the nested if).
601 m4_define([_AS_QUOTE_IFELSE],
602 [m4_cond([m4_index([$1], [\])], [-1], [$2],
603 [m4_eval(m4_index([$1], [\\]) >= 0)], [1], [$2],
604 [m4_eval(m4_index([$1], [\$]) >= 0)], [1], [$2],
605 [m4_eval(m4_index([$1], [\`]) >= 0)], [1], [$3],
606 [m4_eval(m4_index([$1], [\"]) >= 0)], [1], [$3],
607 [$2])])
610 # _AS_QUOTE(STRING, [CHARS = `"])
611 # -------------------------------
612 # If there are quoted (via backslash) backquotes do nothing, else
613 # backslash all the quotes.
614 m4_define([_AS_QUOTE],
615 [_AS_QUOTE_IFELSE([$1],
616 [_AS_ESCAPE([$1], m4_default([$2], [`""]))],
617 [m4_warn([obsolete],
618 [back quotes and double quotes must not be escaped in: $1])dnl
619 $1])])
622 # _AS_ECHO_UNQUOTED(STRING, [FD = AS_MESSAGE_FD])
623 # -----------------------------------------------
624 # Perform shell expansions on STRING and echo the string to FD.
625 m4_define([_AS_ECHO_UNQUOTED],
626 [AS_ECHO(["$1"]) >&m4_default([$2], [AS_MESSAGE_FD])])
629 # _AS_ECHO(STRING, [FD = AS_MESSAGE_FD])
630 # --------------------------------------
631 # Protect STRING from backquote expansion, echo the result to FD.
632 m4_define([_AS_ECHO],
633 [_AS_ECHO_UNQUOTED([_AS_QUOTE([$1])], [$2])])
636 # _AS_ECHO_LOG(STRING)
637 # --------------------
638 # Log the string to AS_MESSAGE_LOG_FD.
639 m4_define([_AS_ECHO_LOG],
640 [AS_REQUIRE([_AS_LINENO_PREPARE])dnl
641 _AS_ECHO([$as_me:${as_lineno-$LINENO}: $1], [AS_MESSAGE_LOG_FD])])
644 # _AS_ECHO_N_PREPARE
645 # ------------------
646 # Check whether to use -n, \c, or newline-tab to separate
647 # checking messages from result messages.
648 # Don't try to cache, since the results of this macro are needed to
649 # display the checking message. In addition, caching something used once
650 # has little interest.
651 # Idea borrowed from dist 3.0. Use `*c*,', not `*c,' because if `\c'
652 # failed there is also a newline to match.
653 m4_defun([_AS_ECHO_N_PREPARE],
654 [ECHO_C= ECHO_N= ECHO_T=
655 case `echo -n x` in
656 -n*)
657 case `echo 'x\c'` in
658 *c*) ECHO_T=' ';; # ECHO_T is single tab character.
659 *) ECHO_C='\c';;
660 esac;;
661 *)
662 ECHO_N='-n';;
663 esac
664 ])# _AS_ECHO_N_PREPARE
667 # _AS_ECHO_N(STRING, [FD = AS_MESSAGE_FD])
668 # ----------------------------------------
669 # Same as _AS_ECHO, but echo doesn't return to a new line.
670 m4_define([_AS_ECHO_N],
671 [AS_ECHO_N(["_AS_QUOTE([$1])"]) >&m4_default([$2], [AS_MESSAGE_FD])])
674 # AS_MESSAGE(STRING, [FD = AS_MESSAGE_FD])
675 # ----------------------------------------
676 m4_define([AS_MESSAGE],
677 [AS_REQUIRE([_AS_ME_PREPARE])dnl
678 m4_ifset([AS_MESSAGE_LOG_FD],
679 [{ _AS_ECHO_LOG([$1])
680 _AS_ECHO([$as_me: $1], [$2]);}],
681 [_AS_ECHO([$as_me: $1], [$2])])[]dnl
682 ])
685 # AS_WARN(PROBLEM)
686 # ----------------
687 m4_define([AS_WARN],
688 [AS_MESSAGE([WARNING: $1], [2])])# AS_WARN
691 # AS_ERROR(ERROR, [EXIT-STATUS = 1])
692 # ----------------------------------
693 m4_define([AS_ERROR],
694 [{ AS_MESSAGE([error: $1], [2])
695 AS_EXIT([$2]); }[]dnl
696 ])# AS_ERROR
700 # AS_LINENO_PUSH([LINENO])
701 # ------------------------
702 # If this is the outermost call to AS_LINENO_PUSH, make sure that
703 # AS_MESSAGE will print LINENO as the line number.
704 m4_defun([AS_LINENO_PUSH],
705 [as_lineno=${as_lineno-"$1"} as_lineno_stack=as_lineno_stack=$as_lineno_stack])
708 # AS_LINENO_POP([LINENO])
709 # ------------------------
710 # If this is call balances the outermost call to AS_LINENO_PUSH,
711 # AS_MESSAGE will restart printing $LINENO as the line number.
712 m4_defun([AS_LINENO_POP],
713 [eval $as_lineno_stack; test "x$as_lineno_stack" = x && AS_UNSET([as_lineno])])
717 ## -------------------------------------- ##
718 ## 4. Portable versions of common tools. ##
719 ## -------------------------------------- ##
721 # This section is lexicographically sorted.
724 # AS_BASENAME(FILE-NAME)
725 # ----------------------
726 # Simulate the command 'basename FILE-NAME'. Not all systems have basename.
727 # Also see the comments for AS_DIRNAME.
729 m4_defun([_AS_BASENAME_EXPR],
730 [$as_expr X/[]$1 : '.*/\([[^/][^/]*]\)/*$' \| \
731 X[]$1 : 'X\(//\)$' \| \
732 X[]$1 : 'X\(/\)' \| .])
734 m4_defun([_AS_BASENAME_SED],
735 [AS_ECHO([X/[]$1]) |
736 sed ['/^.*\/\([^/][^/]*\)\/*$/{
737 s//\1/
738 q
739 }
740 /^X\/\(\/\/\)$/{
741 s//\1/
742 q
743 }
744 /^X\/\(\/\).*/{
745 s//\1/
746 q
747 }
748 s/.*/./; q']])
750 m4_defun([AS_BASENAME],
751 [AS_REQUIRE([_$0_PREPARE])dnl
752 $as_basename -- $1 ||
753 _AS_BASENAME_EXPR([$1]) 2>/dev/null ||
754 _AS_BASENAME_SED([$1])])
757 # _AS_BASENAME_PREPARE
758 # --------------------
759 # Avoid Solaris 9 /usr/ucb/basename, as `basename /' outputs an empty line.
760 # Also, traditional basename mishandles --. Require here _AS_EXPR_PREPARE,
761 # to avoid problems when _AS_BASENAME is called from the M4SH-INIT diversion
762 # (AS_REQUIRE is nowhere near being as sophisticated as AC_REQUIRE).
763 m4_defun([_AS_BASENAME_PREPARE],
764 [AS_REQUIRE([_AS_EXPR_PREPARE])dnl
765 if (basename -- /) >/dev/null 2>&1 && test "X`basename -- / 2>&1`" = "X/"; then
766 as_basename=basename
767 else
768 as_basename=false
769 fi
770 ])# _AS_BASENAME_PREPARE
773 # AS_DIRNAME(FILE-NAME)
774 # ---------------------
775 # Simulate the command 'dirname FILE-NAME'. Not all systems have dirname.
776 # This macro must be usable from inside ` `.
777 #
778 # Prefer expr to echo|sed, since expr is usually faster and it handles
779 # backslashes and newlines correctly. However, older expr
780 # implementations (e.g. SunOS 4 expr and Solaris 8 /usr/ucb/expr) have
781 # a silly length limit that causes expr to fail if the matched
782 # substring is longer than 120 bytes. So fall back on echo|sed if
783 # expr fails.
784 m4_defun([_AS_DIRNAME_EXPR],
785 [AS_REQUIRE([_AS_EXPR_PREPARE])dnl
786 $as_expr X[]$1 : 'X\(.*[[^/]]\)//*[[^/][^/]]*/*$' \| \
787 X[]$1 : 'X\(//\)[[^/]]' \| \
788 X[]$1 : 'X\(//\)$' \| \
789 X[]$1 : 'X\(/\)' \| .])
791 m4_defun([_AS_DIRNAME_SED],
792 [AS_ECHO([X[]$1]) |
793 sed ['/^X\(.*[^/]\)\/\/*[^/][^/]*\/*$/{
794 s//\1/
795 q
796 }
797 /^X\(\/\/\)[^/].*/{
798 s//\1/
799 q
800 }
801 /^X\(\/\/\)$/{
802 s//\1/
803 q
804 }
805 /^X\(\/\).*/{
806 s//\1/
807 q
808 }
809 s/.*/./; q']])
811 m4_defun([AS_DIRNAME],
812 [AS_REQUIRE([_$0_PREPARE])dnl
813 $as_dirname -- $1 ||
814 _AS_DIRNAME_EXPR([$1]) 2>/dev/null ||
815 _AS_DIRNAME_SED([$1])])
818 # _AS_DIRNAME_PREPARE
819 # --------------------
820 m4_defun([_AS_DIRNAME_PREPARE],
821 [AS_REQUIRE([_AS_EXPR_PREPARE])dnl
822 if (as_dir=`dirname -- /` && test "X$as_dir" = X/) >/dev/null 2>&1; then
823 as_dirname=dirname
824 else
825 as_dirname=false
826 fi
827 ])# _AS_DIRNAME_PREPARE
830 # AS_ECHO(WORD)
831 # -------------
832 # Output WORD followed by a newline. WORD must be a single shell word
833 # (typically a quoted string). The bytes of WORD are output as-is, even
834 # if it starts with "-" or contains "\".
835 m4_defun([AS_ECHO],
836 [AS_REQUIRE([_$0_PREPARE])dnl
837 $as_echo $1])
840 # AS_ECHO_N(WORD)
841 # -------------
842 # Like AS_ECHO(WORD), except do not output the trailing newline.
843 m4_defun([AS_ECHO_N],
844 [AS_REQUIRE([_AS_ECHO_PREPARE])dnl
845 $as_echo_n $1])
848 # _AS_ECHO_PREPARE
849 # -----------------
850 # Arrange for $as_echo 'FOO' to echo FOO without escape-interpretation;
851 # and similarly for $as_echo_foo, which omits the trailing newline.
852 # 'FOO' is an optional single argument; a missing FOO is treated as empty.
853 m4_defun([_AS_ECHO_PREPARE],
854 [[as_nl='
855 '
856 export as_nl
857 # Printing a long string crashes Solaris 7 /usr/bin/printf.
858 as_echo='\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\'
859 as_echo=$as_echo$as_echo$as_echo$as_echo$as_echo
860 as_echo=$as_echo$as_echo$as_echo$as_echo$as_echo$as_echo
861 if (test "X`printf %s $as_echo`" = "X$as_echo") 2>/dev/null; then
862 as_echo='printf %s\n'
863 as_echo_n='printf %s'
864 else
865 if test "X`(/usr/ucb/echo -n -n $as_echo) 2>/dev/null`" = "X-n $as_echo"; then
866 as_echo_body='eval /usr/ucb/echo -n "$][1$as_nl"'
867 as_echo_n='/usr/ucb/echo -n'
868 else
869 as_echo_body='eval expr "X$][1" : "X\\(.*\\)"'
870 as_echo_n_body='eval
871 arg=$][1;
872 case $arg in
873 *"$as_nl"*)
874 expr "X$arg" : "X\\(.*\\)$as_nl";
875 arg=`expr "X$arg" : ".*$as_nl\\(.*\\)"`;;
876 esac;
877 expr "X$arg" : "X\\(.*\\)" | tr -d "$as_nl"
878 '
879 export as_echo_n_body
880 as_echo_n='sh -c $as_echo_n_body as_echo'
881 fi
882 export as_echo_body
883 as_echo='sh -c $as_echo_body as_echo'
884 fi
885 ]])# _AS_ECHO_PREPARE
888 # AS_TEST_X
889 # ---------
890 # Check whether a file has executable or search permissions.
891 m4_defun([AS_TEST_X],
892 [AS_REQUIRE([_AS_TEST_PREPARE])dnl
893 $as_test_x $1[]dnl
894 ])# AS_TEST_X
897 # AS_EXECUTABLE_P
898 # ---------------
899 # Check whether a file is a regular file that has executable permissions.
900 m4_defun([AS_EXECUTABLE_P],
901 [AS_REQUIRE([_AS_TEST_PREPARE])dnl
902 { test -f $1 && AS_TEST_X([$1]); }dnl
903 ])# AS_EXECUTABLE_P
906 # _AS_EXPR_PREPARE
907 # ----------------
908 # QNX 4.25 expr computes and issue the right result but exits with failure.
909 # Tru64 expr mishandles leading zeros in numeric strings.
910 # Detect these flaws.
911 m4_defun([_AS_EXPR_PREPARE],
912 [if expr a : '\(a\)' >/dev/null 2>&1 &&
913 test "X`expr 00001 : '.*\(...\)'`" = X001; then
914 as_expr=expr
915 else
916 as_expr=false
917 fi
918 ])# _AS_EXPR_PREPARE
921 # _AS_ME_PREPARE
922 # --------------
923 # Define $as_me to the basename of the executable file's name.
924 m4_defun([AS_ME_PREPARE], [AS_REQUIRE([_$0])])
925 m4_defun([_AS_ME_PREPARE],
926 [AS_REQUIRE([_AS_BASENAME_PREPARE])dnl
927 as_me=`AS_BASENAME("$[0]")`
928 ])
930 # _AS_LINENO_WORKS
931 # ---------------
932 # Succeed if the currently executing shell supports LINENO.
933 # This macro does not expand to a single shell command, so be careful
934 # when using it. Surrounding the body of this macro with {} would
935 # cause "bash -c '_ASLINENO_WORKS'" to fail (with Bash 2.05, anyway),
936 # but that bug is irrelevant to our use of LINENO.
937 m4_define([_AS_LINENO_WORKS],
938 [
939 as_lineno_1=$LINENO
940 as_lineno_2=$LINENO
941 test "x$as_lineno_1" != "x$as_lineno_2" &&
942 test "x`expr $as_lineno_1 + 1`" = "x$as_lineno_2"])
945 # _AS_LINENO_PREPARE
946 # ------------------
947 # If LINENO is not supported by the shell, produce a version of this
948 # script where LINENO is hard coded.
949 # Comparing LINENO against _oline_ is not a good solution, since in
950 # the case of embedded executables (such as config.status within
951 # configure) you'd compare LINENO wrt config.status vs. _oline_ wrt
952 # configure.
953 m4_defun([AS_LINENO_PREPARE], [AS_REQUIRE([_$0])])
954 m4_defun([_AS_LINENO_PREPARE],
955 [AS_REQUIRE([_AS_CR_PREPARE])dnl
956 AS_REQUIRE([_AS_ME_PREPARE])dnl
957 _AS_DETECT_SUGGESTED([_AS_LINENO_WORKS])dnl
958 dnl Even if the logging fd is open, we don't want to use $LINENO in the
959 dnl AS_ERROR complaining that LINENO is broken.
960 m4_pushdef([AS_MESSAGE_LOG_FD])dnl
961 _AS_LINENO_WORKS || {
963 dnl Create $as_me.lineno as a copy of $as_myself, but with $LINENO
964 dnl uniformly replaced by the line number. The first 'sed' inserts a
965 dnl line-number line after each line using $LINENO; the second 'sed'
966 dnl does the real work. The second script uses 'N' to pair each
967 dnl line-number line with the line containing $LINENO, and appends
968 dnl trailing '-' during substitution so that $LINENO is not a special
969 dnl case at line end. (Raja R Harinath suggested sed '=', and Paul
970 dnl Eggert wrote the scripts with optimization help from Paolo Bonzini).
971 # Blame Lee E. McMahon (1931-1989) for sed's syntax. :-)
972 sed -n '
973 p
974 /[[$]]LINENO/=
975 ' <$as_myself |
976 sed '
977 s/[[$]]LINENO.*/&-/
978 t lineno
979 b
980 :lineno
981 N
982 :loop
983 s/[[$]]LINENO\([[^'$as_cr_alnum'_]].*\n\)\(.*\)/\2\1\2/
984 t loop
985 s/-\n.*//
986 ' >$as_me.lineno &&
987 chmod +x "$as_me.lineno" ||
988 AS_ERROR([cannot create $as_me.lineno; rerun with a POSIX shell])
990 # Don't try to exec as it changes $[0], causing all sort of problems
991 # (the dirname of $[0] is not the place where we might find the
992 # original and so on. Autoconf is especially sensitive to this).
993 . "./$as_me.lineno"
994 # Exit status is that of the last command.
995 exit
996 }
997 m4_popdef([AS_MESSAGE_LOG_FD])dnl
998 ])# _AS_LINENO_PREPARE
1001 # _AS_LN_S_PREPARE
1002 # ----------------
1003 # Don't use conftest.sym to avoid file name issues on DJGPP, where this
1004 # would yield conftest.sym.exe for DJGPP < 2.04. And don't use `conftest'
1005 # as base name to avoid prohibiting concurrency (e.g., concurrent
1006 # config.statuses). On read-only media, assume 'cp -p' and hope we
1007 # are just running --help anyway.
1008 m4_defun([_AS_LN_S_PREPARE],
1009 [rm -f conf$$ conf$$.exe conf$$.file
1010 if test -d conf$$.dir; then
1011 rm -f conf$$.dir/conf$$.file
1012 else
1013 rm -f conf$$.dir
1014 mkdir conf$$.dir 2>/dev/null
1015 fi
1016 if (echo >conf$$.file) 2>/dev/null; then
1017 if ln -s conf$$.file conf$$ 2>/dev/null; then
1018 as_ln_s='ln -s'
1019 # ... but there are two gotchas:
1020 # 1) On MSYS, both `ln -s file dir' and `ln file dir' fail.
1021 # 2) DJGPP < 2.04 has no symlinks; `ln -s' creates a wrapper executable.
1022 # In both cases, we have to default to `cp -p'.
1023 ln -s conf$$.file conf$$.dir 2>/dev/null && test ! -f conf$$.exe ||
1024 as_ln_s='cp -p'
1025 elif ln conf$$.file conf$$ 2>/dev/null; then
1026 as_ln_s=ln
1027 else
1028 as_ln_s='cp -p'
1029 fi
1030 else
1031 as_ln_s='cp -p'
1032 fi
1033 rm -f conf$$ conf$$.exe conf$$.dir/conf$$.file conf$$.file
1034 rmdir conf$$.dir 2>/dev/null
1035 ])# _AS_LN_S_PREPARE
1038 # AS_LN_S(FILE, LINK)
1039 # -------------------
1040 # FIXME: Should we add the glue code to handle properly relative symlinks
1041 # simulated with `ln' or `cp'?
1042 m4_defun([AS_LN_S],
1043 [AS_REQUIRE([_AS_LN_S_PREPARE])dnl
1044 $as_ln_s $1 $2
1045 ])
1048 # _AS_MKDIR_P
1049 # -----------
1050 # Emit code that can be used to emulate `mkdir -p` with plain `mkdir';
1051 # the code assumes that "$as_dir" contains the directory to create.
1052 # $as_dir is normalized, so there is no need to worry about using --.
1053 m4_define([_AS_MKDIR_P],
1054 [case $as_dir in #(
1055 -*) as_dir=./$as_dir;;
1056 esac
1057 test -d "$as_dir" || eval $as_mkdir_p || {
1058 as_dirs=
1059 while :; do
1060 case $as_dir in #(
1061 *\'*) as_qdir=`AS_ECHO(["$as_dir"]) | sed "s/'/'\\\\\\\\''/g"`;; #'(
1062 *) as_qdir=$as_dir;;
1063 esac
1064 as_dirs="'$as_qdir' $as_dirs"
1065 as_dir=`AS_DIRNAME("$as_dir")`
1066 test -d "$as_dir" && break
1067 done
1068 test -z "$as_dirs" || eval "mkdir $as_dirs"
1069 } || test -d "$as_dir" || AS_ERROR([cannot create directory $as_dir])
1070 ])
1072 # AS_MKDIR_P(DIR)
1073 # ---------------
1074 # Emulate `mkdir -p' with plain `mkdir' if needed.
1075 m4_define([AS_MKDIR_P],
1076 [AS_REQUIRE([_$0_PREPARE])dnl
1077 as_dir=$1; as_func_mkdir_p])# AS_MKDIR_P
1080 # _AS_MKDIR_P_PREPARE
1081 # -------------------
1082 m4_defun([_AS_MKDIR_P_PREPARE],
1083 [AS_REQUIRE_SHELL_FN([as_func_mkdir_p], [
1084 _AS_MKDIR_P
1085 ])
1086 if mkdir -p . 2>/dev/null; then
1087 as_mkdir_p='mkdir -p "$as_dir"'
1088 else
1089 test -d ./-p && rmdir ./-p
1090 as_mkdir_p=false
1091 fi
1092 ])# _AS_MKDIR_P_PREPARE
1095 # _AS_PATH_SEPARATOR_PREPARE
1096 # --------------------------
1097 # Compute the path separator.
1098 m4_defun([_AS_PATH_SEPARATOR_PREPARE],
1099 [# The user is always right.
1100 if test "${PATH_SEPARATOR+set}" != set; then
1101 PATH_SEPARATOR=:
1102 (PATH='/bin;/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 && {
1103 (PATH='/bin:/bin'; FPATH=$PATH; sh -c :) >/dev/null 2>&1 ||
1104 PATH_SEPARATOR=';'
1105 }
1106 fi
1107 ])# _AS_PATH_SEPARATOR_PREPARE
1110 # _AS_PATH_WALK([PATH = $PATH], BODY)
1111 # -----------------------------------
1112 # Walk through PATH running BODY for each `as_dir'.
1113 #
1114 # Still very private as its interface looks quite bad.
1115 #
1116 # `$as_dummy' forces splitting on constant user-supplied paths.
1117 # POSIX.2 field splitting is done only on the result of word
1118 # expansions, not on literal text. This closes a longstanding sh security
1119 # hole. Optimize it away when not needed, i.e., if there are no literal
1120 # path separators.
1121 m4_define([_AS_PATH_WALK],
1122 [AS_REQUIRE([_AS_PATH_SEPARATOR_PREPARE])dnl
1123 as_save_IFS=$IFS; IFS=$PATH_SEPARATOR
1124 m4_bmatch([$1], [[:;]],
1125 [as_dummy="$1"
1126 for as_dir in $as_dummy],
1127 [for as_dir in m4_default([$1], [$PATH])])
1128 do
1129 IFS=$as_save_IFS
1130 test -z "$as_dir" && as_dir=.
1131 $2
1132 done
1133 IFS=$as_save_IFS
1134 ])
1137 # AS_SET_CATFILE(VAR, DIR-NAME, FILE-NAME)
1138 # ----------------------------------------
1139 # Set VAR to DIR-NAME/FILE-NAME.
1140 # Optimize the common case where $2 or $3 is '.'.
1141 m4_define([AS_SET_CATFILE],
1142 [case $2 in
1143 .) $1=$3;;
1144 *)
1145 case $3 in
1146 .) $1=$2;;
1147 [[\\/]]* | ?:[[\\/]]* ) $1=$3;;
1148 *) $1=$2/$3;;
1149 esac;;
1150 esac[]dnl
1151 ])# AS_SET_CATFILE
1154 # _AS_TEST_PREPARE
1155 # ----------------
1156 # Find out whether `test -x' works. If not, prepare a substitute
1157 # that should work well enough for most scripts.
1158 #
1159 # Here are some of the problems with the substitute.
1160 # The 'ls' tests whether the owner, not the current user, can execute/search.
1161 # The eval means '*', '?', and '[' cause inadvertent file name globbing
1162 # after the 'eval', so jam together as many tokens as we can to minimize
1163 # the likelihood that the inadvertent globbing will actually do anything.
1164 # Luckily, this gorp is needed only on really ancient hosts.
1165 #
1166 m4_defun([_AS_TEST_PREPARE],
1167 [if test -x / >/dev/null 2>&1; then
1168 as_test_x='test -x'
1169 else
1170 if ls -dL / >/dev/null 2>&1; then
1171 as_ls_L_option=L
1172 else
1173 as_ls_L_option=
1174 fi
1175 as_test_x='
1176 eval sh -c '\''
1177 if test -d "$[]1"; then
1178 test -d "$[]1/.";
1179 else
1180 case $[]1 in
1181 -*)set "./$[]1";;
1182 esac;
1183 case `ls -ld'$as_ls_L_option' "$[]1" 2>/dev/null` in
1184 ???[[sx]]*):;;*)false;;esac;fi
1185 '\'' sh
1186 '
1187 fi
1188 dnl as_executable_p is present for backward compatibility with Libtool
1189 dnl 1.5.22, but it should go away at some point.
1190 as_executable_p=$as_test_x
1191 ])# _AS_TEST_PREPARE
1196 ## ------------------ ##
1197 ## 5. Common idioms. ##
1198 ## ------------------ ##
1200 # This section is lexicographically sorted.
1203 # AS_BOX(MESSAGE, [FRAME-CHARACTER = `-'])
1204 # ----------------------------------------
1205 # Output MESSAGE, a single line text, framed with FRAME-CHARACTER (which
1206 # must not be `/').
1207 m4_define([AS_BOX],
1208 [AS_LITERAL_IF([$1],
1209 [_AS_BOX_LITERAL($@)],
1210 [_AS_BOX_INDIR($@)])])
1213 # _AS_BOX_LITERAL(MESSAGE, [FRAME-CHARACTER = `-'])
1214 # -------------------------------------------------
1215 m4_define([_AS_BOX_LITERAL],
1216 [cat <<\_ASBOX
1217 m4_text_box($@)
1218 _ASBOX])
1221 # _AS_BOX_INDIR(MESSAGE, [FRAME-CHARACTER = `-'])
1222 # -----------------------------------------------
1223 m4_define([_AS_BOX_INDIR],
1224 [sed 'h;s/./m4_default([$2], [-])/g;s/^.../@%:@@%:@ /;s/...$/ @%:@@%:@/;p;x;p;x' <<_ASBOX
1225 @%:@@%:@ $1 @%:@@%:@
1226 _ASBOX])
1229 # AS_HELP_STRING(LHS, RHS, [INDENT-COLUMN = 26], [WRAP-COLUMN = 79])
1230 # ------------------------------------------------------------------
1231 #
1232 # Format a help string so that it looks pretty when the user executes
1233 # "script --help". This macro takes up to four arguments, a
1234 # "left hand side" (LHS), a "right hand side" (RHS), a decimal
1235 # INDENT-COLUMN which is the column where wrapped lines should begin
1236 # (the default of 26 is recommended), and a decimal WRAP-COLUMN which is
1237 # the column where lines should wrap (the default of 79 is recommended).
1238 # LHS is expanded, RHS is not.
1239 #
1240 # For backwards compatibility not documented in the manual, INDENT-COLUMN
1241 # can also be specified as a string of white spaces, whose width
1242 # determines the indentation column. Using TABs in INDENT-COLUMN is not
1243 # recommended, since screen width of TAB is not computed.
1244 #
1245 # The resulting string is suitable for use in other macros that require
1246 # a help string (e.g. AC_ARG_WITH).
1247 #
1248 # Here is the sample string from the Autoconf manual (Node: External
1249 # Software) which shows the proper spacing for help strings.
1250 #
1251 # --with-readline support fancy command line editing
1252 # ^ ^ ^
1253 # | | |
1254 # | column 2 column 26
1255 # |
1256 # column 0
1257 #
1258 # A help string is made up of a "left hand side" (LHS) and a "right
1259 # hand side" (RHS). In the example above, the LHS is
1260 # "--with-readline", while the RHS is "support fancy command line
1261 # editing".
1262 #
1263 # If the LHS contains more than (INDENT-COLUMN - 3) characters, then the
1264 # LHS is terminated with a newline so that the RHS starts on a line of its
1265 # own beginning at INDENT-COLUMN. In the default case, this corresponds to an
1266 # LHS with more than 23 characters.
1267 #
1268 # Therefore, in the example, if the LHS were instead
1269 # "--with-readline-blah-blah-blah", then the AS_HELP_STRING macro would
1270 # expand into:
1271 #
1272 #
1273 # --with-readline-blah-blah-blah
1274 # ^ ^ support fancy command line editing
1275 # | | ^
1276 # | column 2 |
1277 # column 0 column 26
1278 #
1279 #
1280 # m4_text_wrap hacks^Wworks around the fact that m4_format does not
1281 # know quadrigraphs.
1282 #
1283 m4_define([AS_HELP_STRING],
1284 [m4_text_wrap([$2], m4_cond([[$3]], [], [ ],
1285 [m4_eval([$3]+0)], [0], [[$3]],
1286 [m4_format([[%*s]], [$3], [])]),
1287 m4_expand([ $1 ]), [$4])dnl
1288 ])# AS_HELP_STRING
1291 # AS_IDENTIFIER_IF(EXPRESSION, IF-IDENT, IF-NOT-IDENT)
1292 # ----------------------------------------------------
1293 # If EXPRESSION serves as an identifier (ie, after removal of @&t@, it
1294 # matches the regex `^[a-zA-Z_][a-zA-Z_0-9]*$'), execute IF-IDENT,
1295 # otherwise IF-NOT-IDENT.
1296 #
1297 # This is generally faster than the alternative:
1298 # m4_bmatch(m4_bpatsubst([[$1]], [@&t@]), ^m4_defn([m4_re_word])$,
1299 # [$2], [$3])
1300 #
1301 # Rather than expand m4_defn every time AS_IDENTIFIER_IF is expanded, we
1302 # inline its expansion up front. Only use a regular expression if we
1303 # detect a potential quadrigraph.
1304 #
1305 # First, check if the entire string matches m4_cr_symbol2. Only then do
1306 # we worry if the first character also matches m4_cr_symbol1 (ie. does not
1307 # match m4_cr_digit).
1308 m4_define([AS_IDENTIFIER_IF],
1309 [m4_if(m4_index([$1], [@]), [-1],
1310 [_$0($@)],
1311 [_$0(m4_bpatsubst([[$1]], [@&t@]), [$2], [$3])])])
1312 m4_define([_AS_IDENTIFIER_IF],
1313 [m4_cond([[$1]], [], [$3],
1314 [m4_eval(m4_len(m4_translit([[$1]], ]]dnl
1315 m4_dquote(m4_dquote(m4_defn([m4_cr_symbols2])))[[)) > 0)], [1], [$3],
1316 [m4_len(m4_translit(m4_format([[%.1s]], [$1]), ]]dnl
1317 m4_dquote(m4_dquote(m4_defn([m4_cr_symbols1])))[[))], [0], [$2], [$3])])
1320 # AS_LITERAL_IF(EXPRESSION, IF-LITERAL, IF-NOT-LITERAL)
1321 # -----------------------------------------------------
1322 # If EXPRESSION has shell indirections ($var or `expr`), expand
1323 # IF-INDIR, else IF-NOT-INDIR.
1324 # This is an *approximation*: for instance EXPRESSION = `\$' is
1325 # definitely a literal, but will not be recognized as such.
1326 #
1327 # Why do we reject EXPRESSION expanding with `[' or `]' as a literal?
1328 # Because AS_TR_SH is MUCH faster if it can use m4_translit on literals
1329 # instead of m4_bpatsubst; but m4_translit is much tougher to do safely
1330 # if `[' is translated.
1331 #
1332 # Note that the quadrigraph @S|@ can result in non-literals, but outright
1333 # rejecting all @ would make AC_INIT complain on its bug report address.
1334 #
1335 # We used to use m4_bmatch(m4_quote($1), [[`$]], [$3], [$2]), but
1336 # profiling shows that it is faster to use m4_translit.
1337 #
1338 # Because the translit is stripping quotes, it must also neutralize anything
1339 # that might be in a macro name, as well as comments and commas. All the
1340 # problem characters are unified so that a single m4_index can scan the
1341 # result.
1342 #
1343 # Rather than expand m4_defn every time AS_LITERAL_IF is expanded, we
1344 # inline its expansion up front.
1345 m4_define([AS_LITERAL_IF],
1346 [m4_cond([m4_eval(m4_index(m4_quote($1), [@S|@]) == -1)], [0], [$3],
1347 [m4_index(m4_translit(m4_quote($1),
1348 [[]`,#]]]dnl
1349 m4_dquote(m4_dquote(m4_defn([m4_cr_symbols2])))[[,
1350 [$$$]),
1351 [$])], [-1], [$2],
1352 [$3])])
1355 # AS_TMPDIR(PREFIX, [DIRECTORY = $TMPDIR [= /tmp]])
1356 # -------------------------------------------------
1357 # Create as safely as possible a temporary directory in DIRECTORY
1358 # which name is inspired by PREFIX (should be 2-4 chars max).
1359 m4_define([AS_TMPDIR],
1360 [AS_REQUIRE([_AS_ME_PREPARE])dnl
1361 # Create a (secure) tmp directory for tmp files.
1362 m4_if([$2], [], [: ${TMPDIR=/tmp}])
1363 {
1364 tmp=`(umask 077 && mktemp -d "m4_default([$2], [$TMPDIR])/$1XXXXXX") 2>/dev/null` &&
1365 test -n "$tmp" && test -d "$tmp"
1366 } ||
1367 {
1368 tmp=m4_default([$2], [$TMPDIR])/$1$$-$RANDOM
1369 (umask 077 && mkdir "$tmp")
1370 } || AS_ERROR([cannot create a temporary directory in m4_default([$2], [$TMPDIR])])dnl
1371 ])# AS_TMPDIR
1374 # AS_UNAME
1375 # --------
1376 # Try to describe this machine. Meant for logs.
1377 m4_define([AS_UNAME],
1378 [{
1379 cat <<_ASUNAME
1380 m4_text_box([Platform.])
1382 hostname = `(hostname || uname -n) 2>/dev/null | sed 1q`
1383 uname -m = `(uname -m) 2>/dev/null || echo unknown`
1384 uname -r = `(uname -r) 2>/dev/null || echo unknown`
1385 uname -s = `(uname -s) 2>/dev/null || echo unknown`
1386 uname -v = `(uname -v) 2>/dev/null || echo unknown`
1388 /usr/bin/uname -p = `(/usr/bin/uname -p) 2>/dev/null || echo unknown`
1389 /bin/uname -X = `(/bin/uname -X) 2>/dev/null || echo unknown`
1391 /bin/arch = `(/bin/arch) 2>/dev/null || echo unknown`
1392 /usr/bin/arch -k = `(/usr/bin/arch -k) 2>/dev/null || echo unknown`
1393 /usr/convex/getsysinfo = `(/usr/convex/getsysinfo) 2>/dev/null || echo unknown`
1394 /usr/bin/hostinfo = `(/usr/bin/hostinfo) 2>/dev/null || echo unknown`
1395 /bin/machine = `(/bin/machine) 2>/dev/null || echo unknown`
1396 /usr/bin/oslevel = `(/usr/bin/oslevel) 2>/dev/null || echo unknown`
1397 /bin/universe = `(/bin/universe) 2>/dev/null || echo unknown`
1399 _ASUNAME
1401 _AS_PATH_WALK([$PATH], [AS_ECHO(["PATH: $as_dir"])])
1402 }])
1405 # _AS_VERSION_COMPARE_PREPARE
1406 # ---------------------------
1407 # Output variables for comparing version numbers.
1408 m4_defun([_AS_VERSION_COMPARE_PREPARE],
1409 [[as_awk_strverscmp='
1410 # Use only awk features that work with 7th edition Unix awk (1978).
1411 # My, what an old awk you have, Mr. Solaris!
1412 END {
1413 while (length(v1) && length(v2)) {
1414 # Set d1 to be the next thing to compare from v1, and likewise for d2.
1415 # Normally this is a single character, but if v1 and v2 contain digits,
1416 # compare them as integers and fractions as strverscmp does.
1417 if (v1 ~ /^[0-9]/ && v2 ~ /^[0-9]/) {
1418 # Split v1 and v2 into their leading digit string components d1 and d2,
1419 # and advance v1 and v2 past the leading digit strings.
1420 for (len1 = 1; substr(v1, len1 + 1) ~ /^[0-9]/; len1++) continue
1421 for (len2 = 1; substr(v2, len2 + 1) ~ /^[0-9]/; len2++) continue
1422 d1 = substr(v1, 1, len1); v1 = substr(v1, len1 + 1)
1423 d2 = substr(v2, 1, len2); v2 = substr(v2, len2 + 1)
1424 if (d1 ~ /^0/) {
1425 if (d2 ~ /^0/) {
1426 # Compare two fractions.
1427 while (d1 ~ /^0/ && d2 ~ /^0/) {
1428 d1 = substr(d1, 2); len1--
1429 d2 = substr(d2, 2); len2--
1430 }
1431 if (len1 != len2 && ! (len1 && len2 && substr(d1, 1, 1) == substr(d2, 1, 1))) {
1432 # The two components differ in length, and the common prefix
1433 # contains only leading zeros. Consider the longer to be less.
1434 d1 = -len1
1435 d2 = -len2
1436 } else {
1437 # Otherwise, compare as strings.
1438 d1 = "x" d1
1439 d2 = "x" d2
1440 }
1441 } else {
1442 # A fraction is less than an integer.
1443 exit 1
1444 }
1445 } else {
1446 if (d2 ~ /^0/) {
1447 # An integer is greater than a fraction.
1448 exit 2
1449 } else {
1450 # Compare two integers.
1451 d1 += 0
1452 d2 += 0
1453 }
1454 }
1455 } else {
1456 # The normal case, without worrying about digits.
1457 d1 = substr(v1, 1, 1); v1 = substr(v1, 2)
1458 d2 = substr(v2, 1, 1); v2 = substr(v2, 2)
1459 }
1460 if (d1 < d2) exit 1
1461 if (d1 > d2) exit 2
1462 }
1463 # Beware Solaris /usr/xgp4/bin/awk (at least through Solaris 10),
1464 # which mishandles some comparisons of empty strings to integers.
1465 if (length(v2)) exit 1
1466 if (length(v1)) exit 2
1467 }
1468 ']])# _AS_VERSION_COMPARE_PREPARE
1471 # AS_VERSION_COMPARE(VERSION-1, VERSION-2,
1472 # [ACTION-IF-LESS], [ACTION-IF-EQUAL], [ACTION-IF-GREATER])
1473 # -----------------------------------------------------------------------------
1474 # Compare two strings possibly containing shell variables as version strings.
1475 m4_defun([AS_VERSION_COMPARE],
1476 [AS_REQUIRE([_$0_PREPARE])dnl
1477 as_arg_v1=$1
1478 as_arg_v2=$2
1479 dnl This usage is portable even to ancient awk,
1480 dnl so don't worry about finding a "nice" awk version.
1481 awk "$as_awk_strverscmp" v1="$as_arg_v1" v2="$as_arg_v2" /dev/null
1482 case $? in
1483 1) $3;;
1484 0) $4;;
1485 2) $5;;
1486 esac[]dnl
1487 ])# _AS_VERSION_COMPARE
1491 ## ------------------------------------ ##
1492 ## Common m4/sh character translation. ##
1493 ## ------------------------------------ ##
1495 # The point of this section is to provide high level macros comparable
1496 # to m4's `translit' primitive, but m4/sh polymorphic.
1497 # Transliteration of literal strings should be handled by m4, while
1498 # shell variables' content will be translated at runtime (tr or sed).
1501 # _AS_CR_PREPARE
1502 # --------------
1503 # Output variables defining common character ranges.
1504 # See m4_cr_letters etc.
1505 m4_defun([_AS_CR_PREPARE],
1506 [# Avoid depending upon Character Ranges.
1507 as_cr_letters='abcdefghijklmnopqrstuvwxyz'
1508 as_cr_LETTERS='ABCDEFGHIJKLMNOPQRSTUVWXYZ'
1509 as_cr_Letters=$as_cr_letters$as_cr_LETTERS
1510 as_cr_digits='0123456789'
1511 as_cr_alnum=$as_cr_Letters$as_cr_digits
1512 ])
1515 # _AS_TR_SH_PREPARE
1516 # -----------------
1517 m4_defun([_AS_TR_SH_PREPARE],
1518 [AS_REQUIRE([_AS_CR_PREPARE])dnl
1519 # Sed expression to map a string onto a valid variable name.
1520 as_tr_sh="eval sed 'y%*+%pp%;s%[[^_$as_cr_alnum]]%_%g'"
1521 ])
1524 # AS_TR_SH(EXPRESSION)
1525 # --------------------
1526 # Transform EXPRESSION into a valid shell variable name.
1527 # sh/m4 polymorphic.
1528 # Be sure to update the definition of `$as_tr_sh' if you change this.
1529 #
1530 # AS_LITERAL_IF guarantees that a literal does not have any nested quotes,
1531 # once $1 is expanded. m4_translit silently uses only the first occurrence
1532 # of a character that appears multiple times in argument 2, since we know
1533 # that m4_cr_not_symbols2 also contains [ and ]. m4_translit also silently
1534 # ignores characters in argument 3 that do not match argument 2; we use this
1535 # fact to skip worrying about the length of m4_cr_not_symbols2.
1536 #
1537 # For speed, we inline the literal definitions that can be computed up front.
1538 m4_defun([AS_TR_SH],
1539 [AS_REQUIRE([_$0_PREPARE])dnl
1540 AS_LITERAL_IF([$1],
1541 [m4_translit([$1], [*+[]]]]dnl
1542 m4_dquote(m4_dquote(m4_defn([m4_cr_not_symbols2])))[[,
1543 [pp[]]]]dnl
1544 m4_dquote(m4_dquote(m4_for(,1,255,,[[_]])))[[)],
1545 [`AS_ECHO(["$1"]) | $as_tr_sh`])])
1548 # _AS_TR_CPP_PREPARE
1549 # ------------------
1550 m4_defun([_AS_TR_CPP_PREPARE],
1551 [AS_REQUIRE([_AS_CR_PREPARE])dnl
1552 # Sed expression to map a string onto a valid CPP name.
1553 as_tr_cpp="eval sed 'y%*$as_cr_letters%P$as_cr_LETTERS%;s%[[^_$as_cr_alnum]]%_%g'"
1554 ])
1557 # AS_TR_CPP(EXPRESSION)
1558 # ---------------------
1559 # Map EXPRESSION to an upper case string which is valid as rhs for a
1560 # `#define'. sh/m4 polymorphic. Be sure to update the definition
1561 # of `$as_tr_cpp' if you change this.
1562 #
1563 # See implementation comments in AS_TR_SH.
1564 m4_defun([AS_TR_CPP],
1565 [AS_REQUIRE([_$0_PREPARE])dnl
1566 AS_LITERAL_IF([$1],
1567 [m4_translit([$1], [*[]]]]dnl
1568 m4_dquote(m4_dquote(m4_defn([m4_cr_letters])m4_defn([m4_cr_not_symbols2])))[[,
1569 [P[]]]]dnl
1570 m4_dquote(m4_dquote(m4_defn([m4_cr_LETTERS])m4_for(,1,255,,[[_]])))[[)],
1571 [`AS_ECHO(["$1"]) | $as_tr_cpp`])])
1574 # _AS_TR_PREPARE
1575 # --------------
1576 m4_defun([_AS_TR_PREPARE],
1577 [AS_REQUIRE([_AS_TR_SH_PREPARE])dnl
1578 AS_REQUIRE([_AS_TR_CPP_PREPARE])dnl
1579 ])
1584 ## --------------------------------------------------- ##
1585 ## Common m4/sh handling of variables (indirections). ##
1586 ## --------------------------------------------------- ##
1589 # The purpose of this section is to provide a uniform API for
1590 # reading/setting sh variables with or without indirection.
1591 # Typically, one can write
1592 # AS_VAR_SET(var, val)
1593 # or
1594 # AS_VAR_SET(as_$var, val)
1595 # and expect the right thing to happen.
1598 # AS_VAR_SET(VARIABLE, VALUE)
1599 # ---------------------------
1600 # Set the VALUE of the shell VARIABLE.
1601 # If the variable contains indirections (e.g. `ac_cv_func_$ac_func')
1602 # perform whenever possible at m4 level, otherwise sh level.
1603 m4_define([AS_VAR_SET],
1604 [AS_LITERAL_IF([$1],
1605 [$1=$2],
1606 [eval "$1=AS_ESCAPE([$2])"])])
1609 # AS_VAR_GET(VARIABLE)
1610 # --------------------
1611 # Get the value of the shell VARIABLE.
1612 # Evaluates to $VARIABLE if there are no indirection in VARIABLE,
1613 # else into the appropriate `eval' sequence.
1614 # FIXME: This mishandles values that end in newlines.
1615 # Fixing this will require changing the API.
1616 m4_define([AS_VAR_GET],
1617 [AS_LITERAL_IF([$1],
1618 [$$1],
1619 [`eval 'as_val=${'m4_bpatsubst([$1], [[\\`]], [\\\&])'}
1620 AS_ECHO(["$as_val"])'`])])
1623 # AS_VAR_TEST_SET(VARIABLE)
1624 # -------------------------
1625 # Expands into the `test' expression which is true if VARIABLE
1626 # is set. Polymorphic. Should be dnl'ed.
1627 m4_define([AS_VAR_TEST_SET],
1628 [AS_LITERAL_IF([$1],
1629 [test "${$1+set}" = set],
1630 [{ as_var=$1; eval "test \"\${$as_var+set}\" = set"; }])])
1633 # AS_VAR_SET_IF(VARIABLE, IF-TRUE, IF-FALSE)
1634 # ------------------------------------------
1635 # Implement a shell `if-then-else' depending whether VARIABLE is set
1636 # or not. Polymorphic.
1637 m4_define([AS_VAR_SET_IF],
1638 [AS_IF([AS_VAR_TEST_SET([$1])], [$2], [$3])])
1641 # AS_VAR_IF(VARIABLE, VALUE, IF-TRUE, IF-FALSE)
1642 # ---------------------------------------------
1643 # Implement a shell `if test $VARIABLE = VALUE; then-else'.
1644 # Polymorphic, and avoids sh expansion error upon interrupt or term signal.
1645 m4_define([AS_VAR_IF],
1646 [AS_LITERAL_IF([$1],
1647 [AS_IF([test "x$$1" = x""$2], [$3], [$4])],
1648 [as_val=AS_VAR_GET([$1])
1649 AS_IF([test "x$as_val" = x""$2], [$3], [$4])])])
1652 # AS_VAR_PUSHDEF and AS_VAR_POPDEF
1653 # --------------------------------
1654 #
1656 # Sometimes we may have to handle literals (e.g. `stdlib.h'), while at
1657 # other moments, the same code may have to get the value from a
1658 # variable (e.g., `ac_header'). To have a uniform handling of both
1659 # cases, when a new value is about to be processed, declare a local
1660 # variable, e.g.:
1661 #
1662 # AS_VAR_PUSHDEF([header], [ac_cv_header_$1])
1663 #
1664 # and then in the body of the macro, use `header' as is. It is of
1665 # first importance to use `AS_VAR_*' to access this variable. Don't
1666 # quote its name: it must be used right away by m4.
1667 #
1668 # If the value `$1' was a literal (e.g. `stdlib.h'), then `header' is
1669 # in fact the value `ac_cv_header_stdlib_h'. If `$1' was indirect,
1670 # then `header's value in m4 is in fact `$as_header', the shell
1671 # variable that holds all of the magic to get the expansion right.
1672 #
1673 # At the end of the block, free the variable with
1674 #
1675 # AS_VAR_POPDEF([header])
1678 # AS_VAR_PUSHDEF(VARNAME, VALUE)
1679 # ------------------------------
1680 # Define the m4 macro VARNAME to an accessor to the shell variable
1681 # named VALUE. VALUE does not need to be a valid shell variable name:
1682 # the transliteration is handled here. To be dnl'ed.
1683 m4_define([AS_VAR_PUSHDEF],
1684 [AS_LITERAL_IF([$2],
1685 [m4_pushdef([$1], [AS_TR_SH($2)])],
1686 [as_$1=AS_TR_SH($2)
1687 m4_pushdef([$1], [$as_[$1]])])])
1690 # AS_VAR_POPDEF(VARNAME)
1691 # ----------------------
1692 # Free the shell variable accessor VARNAME. To be dnl'ed.
1693 m4_define([AS_VAR_POPDEF],
1694 [m4_popdef([$1])])
1697 ## ----------------- ##
1698 ## Setting M4sh up. ##
1699 ## ----------------- ##
1702 # AS_INIT_GENERATED
1703 # -----------------
1704 # Emit m4sh initialization code in a suitable form for a quoted
1705 # here document. Does not emit the `#!' sequence, which should be
1706 # generated with `#! $SHELL'; see the manual or autoconf/status.m4
1707 # for more detail.
1708 m4_defun([AS_INIT_GENERATED],
1709 [m4_require([AS_PREPARE])dnl
1710 _AS_SHELL_SANITIZE
1711 _AS_PREPARE])
1713 # AS_INIT
1714 # -------
1715 # Initialize m4sh.
1716 m4_define([AS_INIT],
1717 [# Wrap our cleanup prior to m4sugar's cleanup.
1718 m4_wrap([_AS_CLEANUP])
1719 m4_init
1720 m4_provide([AS_INIT])
1722 # Forbidden tokens and exceptions.
1723 m4_pattern_forbid([^_?AS_])
1725 # Bangshe and minimal initialization.
1726 m4_divert_text([BINSH], [@%:@! /bin/sh])
1727 m4_divert_text([HEADER-COMMENT],
1728 [@%:@ Generated from __file__ by m4_PACKAGE_STRING.])
1729 m4_divert_text([M4SH-SANITIZE], [_AS_SHELL_SANITIZE])
1731 # Let's go!
1732 m4_divert_pop([KILL])[]dnl
1733 m4_divert_push([BODY])[]dnl
1734 _AS_DETECT_REQUIRED([_AS_SHELL_FN_WORK])dnl
1735 AS_REQUIRE([_AS_UNSET_PREPARE])dnl For backwards compatibility.
1736 ])