tests/local.at

   1 # M4 macros used in building Autoconf test suites.        -*- Autotest -*-
   2
   3 # Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
   4 # 2009, 2010 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation, either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 m4_version_prereq([2.57])
  20
  21 # Used in many tests.
  22 m4_pattern_allow([^AS_EXIT$])
  23 m4_pattern_allow([^m4_(define|shift)$])
  24
  25 # Programs this package provides
  26 AT_TESTED([autom4te autoconf autoheader autoupdate autoreconf ifnames])
  27
  28
  29 ## ---------------- ##
  30 ## Utility macros.  ##
  31 ## ---------------- ##
  32
  33 # AT_CMP(FILE-1, FILE-2)
  34 # ----------------------
  35 # Check FILE-1 and FILE-2 for equality, like `cmp FILE-1 FILE-2'.
  36 m4_define([AT_CMP],
  37 [m4_ifval([$2],, [m4_fatal([AT_CMP takes two arguments.])])[]dnl
  38 AT_CHECK([$at_diff "$1" "$2"])
  39 ])# AT_CMP
  40
  41
  42 ## ---------------- ##
  43 ## Testing syntax.  ##
  44 ## ---------------- ##
  45
  46 # AT_CHECK_SHELL_SYNTAX(PROGRAM)
  47 # ------------------------------
  48 # If the shell handles `-n' well, use it to check the syntax of PROGRAM;
  49 # otherwise, do nothing.
  50 m4_define([AT_CHECK_SHELL_SYNTAX],
  51 [AT_SKIP_IF([test "$ac_cv_sh_n_works" != yes])
  52 AT_CHECK([/bin/sh -n $1])])
  53
  54 m4_define([AT_CHECK_PERL_SYNTAX],
  55 [AT_CHECK([autom4te_perllibdir=$abs_top_srcdir/lib $PERL -c "$abs_top_builddir"/bin/$1],
  56           0, [], [ignore])])
  57
  58 ## ------------------ ##
  59 ## Testing autom4te.  ##
  60 ## ------------------ ##
  61
  62
  63 # AT_CHECK_M4(COMMAND, [EXIT-STATUS = 0], STDOUT, STDERR)
  64 # -------------------------------------------------------
  65 # If stderr is specified, normalize the observed stderr.
  66 # This (using GNU M4 1.4.6)
  67 #
  68 #  /usr/local/bin/m4:script.4s:1: cannot open `foo': No such file or directory
  69 #  autom4te: /usr/local/bin/m4 failed with exit status: 1
  70 #
  71 # or this (GNU M4 1.4.11)
  72 #
  73 #  /usr/local/bin/m4:script.4s:1: include: cannot open `foo': No such file or directory
  74 #  autom4te: /usr/local/bin/m4 failed with exit status: 1
  75 #
  76 # or this (GNU M4 1.4 installed as gm4)
  77 #
  78 #  script.4s:1: /usr/local/bin/gm4: Cannot open foo: No such file or directory
  79 #  autom4te: /usr/local/bin/gm4 failed with exit status: 1
  80 #
  81 # becomes
  82 #
  83 #  m4:script.4s:1: cannot open `foo': No such file or directory
  84 #  autom4te: m4 failed with exit status: 1
  85 #
  86 # We use the following sed patterns:
  87 #
  88 #     (m4): ?(file): ?(line):
  89 # or  (file): ?(line): ?(m4):
  90 # to  m4:(file):(line):
  91 #
  92 # and
  93 #     m4:(file):(line): Cannot open foo:
  94 # or  m4:(file):(line): include: cannot open `foo':
  95 # to  m4:(file):(line): cannot open `foo':
  96 #
  97 # and
  98 #     autom4te: [^ ]m4
  99 # or  autom4te: [^ ]m4.exe
 100 # to  autom4te: m4
 101 #
 102 # Moreover, DJGPP error messages include the error code in brackets;
 103 # remove the error code during normalization.
 104 #
 105 m4_define([AT_CHECK_M4],
 106 [AT_CHECK([$1], [$2], [$3],
 107           m4_case([$4], [], [], [ignore], [ignore], [stderr]))
 108 m4_case([$4], [], [], [ignore], [],
 109 [AT_CHECK([[sed 's/^[^:]*m4[.ex]*: *\([^:]*:\) *\([0-9][0-9]*: \)/m4:\1\2/
 110         s/^\([^:]*:\) *\([0-9][0-9]*:\)[^:]*m4[.ex]*: /m4:\1\2 /
 111         s/: C\(annot open \)\([^`:]*\):/: c\1`\2'\'':/
 112         s/: include:\( cannot open\)/:\1/
 113         s/^autom4te: [^ ]*m4[.ex]* /autom4te: m4 /
 114         s/ (E[A-Z]*)$//
 115     ' stderr >&2]], [0], [], [$4])])
 116 ])
 117
 118 # AT_CHECK_AUTOM4TE(FLAGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 119 # -----------------------------------------------------------
 120 m4_define([AT_CHECK_AUTOM4TE],
 121 [AT_CHECK_M4([autom4te $1], [$2], [$3], [$4])])
 122
 123
 124
 125 ## ----------------- ##
 126 ## Testing M4sugar.  ##
 127 ## ----------------- ##
 128
 129
 130 # AT_DATA_M4SUGAR(FILE-NAME, CONTENTS)
 131 # ------------------------------------
 132 # Escape the invalid tokens with @&t@.
 133 m4_define([AT_DATA_M4SUGAR],
 134 [AT_DATA([$1],
 135 [m4_bpatsubst([$2], [\(@.\)\(.@\)\|\(m4\)\(_\)\|\(d\)\(nl\)],
 136               [\1\3\5@&t@\2\4\6])])])
 137
 138
 139 # AT_CHECK_M4SUGAR(FLAGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 140 # ----------------------------------------------------------
 141 m4_define([AT_CHECK_M4SUGAR],
 142 [AT_KEYWORDS([m4sugar])
 143 AT_CHECK_AUTOM4TE([--language=m4sugar script.4s -o script $1],
 144                    [$2], [$3], [$4])])
 145
 146
 147
 148 ## -------------- ##
 149 ## Testing M4sh.  ##
 150 ## -------------- ##
 151
 152
 153 # AT_DATA_M4SH(FILE-NAME, CONTENTS)
 154 # ---------------------------------
 155 # Escape the invalid tokens with @&t@.
 156 m4_define([AT_DATA_M4SH],
 157 [AT_DATA([$1],
 158 [m4_bpatsubst([$2], [\(@.\)\(.@\)\|\(m4\|AS\)\(_\)\|\(d\)\(nl\)],
 159               [\1\3\5@&t@\2\4\6])])])
 160
 161
 162 # AT_CHECK_M4SH(FLAGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 163 # -------------------------------------------------------
 164 m4_define([AT_CHECK_M4SH],
 165 [AT_CHECK_AUTOM4TE([--language=m4sh script.as -o script $1],
 166                    [$2], [$3], [$4])])
 167
 168
 169
 170 ## ------------------ ##
 171 ## Testing Autoconf.  ##
 172 ## ------------------ ##
 173
 174
 175 # AT_DATA_AUTOCONF(FILE-NAME, CONTENTS)
 176 # -------------------------------------
 177 # Escape the invalid tokens with @&t@.
 178 m4_define([AT_DATA_AUTOCONF],
 179 [AT_DATA([$1],
 180 [m4_bpatsubst([$2], [\(@.\)\(.@\)\|\(m4\|AS\|AC\)\(_\)\|\(d\)\(nl\)],
 181               [\1\3\5@&t@\2\4\6])])])
 182
 183
 184
 185 # AT_CONFIGURE_AC(BODY)
 186 # ---------------------
 187 # Create a full configure.ac running BODY, with a config header set up,
 188 # AC_OUTPUT, and environment checking hooks.
 189 m4_define([AT_CONFIGURE_AC],
 190 [AT_DATA([configure.ac],
 191 [[AC_INIT
 192 AC_CONFIG_HEADERS(config.h:config.hin)
 193 AC_STATE_SAVE(before)]
 194 $1
 195 [AC_OUTPUT
 196 AC_STATE_SAVE(after)
 197 ]])
 198 cp "$abs_top_srcdir/build-aux/install-sh" \
 199    "$abs_top_srcdir/build-aux/config.guess" \
 200    "$abs_top_srcdir/build-aux/config.sub" .
 201 cp "$abs_top_srcdir/tests/statesave.m4" aclocal.m4
 202 ])# AT_CONFIGURE_AC
 203
 204
 205 # AT_CHECK_AUTOCONF(ARGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 206 # ----------------------------------------------------------
 207 # We always use "--force", to prevent problems with timestamps if the testsuite
 208 # were running too fast.
 209 m4_define([AT_CHECK_AUTOCONF],
 210 [AT_CHECK_M4([autoconf --force $1], [$2], [$3], [$4])
 211 if test -s configure && test "$ac_cv_sh_n_works" = yes; then
 212   AT_CHECK_SHELL_SYNTAX([configure])
 213 fi
 214 ])
 215
 216
 217 # AT_CHECK_AUTOHEADER(ARGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 218 # ------------------------------------------------------------
 219 m4_define([AT_CHECK_AUTOHEADER],
 220 [AT_CHECK([autoheader $1], [$2], [$3], [$4])
 221 ])
 222
 223
 224 # AT_CHECK_CONFIGURE(END-COMMAND,
 225 #                    [EXIT-STATUS = 0],
 226 #                    [STDOUT = IGNORE], STDERR)
 227 # ---------------------------------------------
 228 # `abs_top_srcdir' is needed so that `./configure' finds install-sh.
 229 # Using --srcdir is more expensive.
 230 m4_define([AT_CHECK_CONFIGURE],
 231 [AT_CAPTURE_FILE([config.log])[]dnl
 232  AT_CHECK([./configure $configure_options $1],
 233           [$2],
 234           m4_default([$3], [ignore]), [$4])])
 235
 236
 237 # AT_CHECK_ENV
 238 # ------------
 239 # Check that the full configure run remained in its variable name space,
 240 # and cleaned up tmp files.
 241 #
 242 # Perhaps grep -E is not supported, or perhaps it chokes on such a big regex.
 243 # In this case just don't pay attention to the env.  It would be great
 244 # to keep the error message but we can't: that would break AT_CHECK.
 245 #
 246 # FreeBSD sh may intermingle the trace output from the egrep and grep
 247 # commands in the pipe, so turn off tracing for these.
 248 #
 249 # Some tests might exit prematurely when they find a problem, in
 250 # which case `env-after' is probably missing.  Don't check it then.
 251 #
 252 # Here are the variables `configure' may modify during execution:
 253 # - ^as_
 254 #   M4sh's shell name space.
 255 # - ^ac_
 256 #   Autoconf's shell name space.
 257 # - prefix and exec_prefix
 258 #   are kept undefined (NONE) until AC_OUTPUT which then sets them to
 259 #   `/usr/local' and `${prefix}' for make.
 260 # - (host|build|target)(_(alias|cpu|vendor|os))?
 261 #   Set by AC_CANONICAL_(HOST|BUILD|TARGET).
 262 # - cross_compiling
 263 #   Set by AC_INIT.
 264 # - interpval
 265 #   Set by AC_SYS_INTERPRETER.
 266 # - CONFIG_STATUS and DEFS
 267 #   Set by AC_OUTPUT.
 268 # - AC_SUBST'ed variables
 269 #   (FIXME: Generate a list of these automatically.)
 270 # - _|@|.[*#?$].|argv|ARGC|LINENO|OLDPWD|PIPESTATUS|RANDOM|SECONDS
 271 #   Some variables some shells use and change.
 272 #   `.[*#?$].' catches `$#' etc. which are displayed like this:
 273 #      | '!'=18186
 274 #      | '#'=0
 275 #      | '$'=6908
 276 #
 277 m4_define([AT_CHECK_ENV],
 278 [m4_divert_once([PREPARE_TESTS], [_AT_CHECK_ENV])dnl
 279 AT_CHECK([at_check_env])])
 280 m4_define([_AT_CHECK_ENV],
 281 [AS_FUNCTION_DESCRIBE([at_check_env], [],
 282 [Compare the directory and environment state both before and after a run,
 283 and return non-zero status if they differ inappropriately.])
 284 at_check_env ()
 285 {
 286 # Compare directory listings.
 287 test -f state-ls.before ||
 288   AS_ERROR([state-ls.before not present])
 289 test -f state-ls.after \
 290   && { $at_diff state-ls.before state-ls.after || return 1; }
 291 # Compare variable space dumps.
 292 if test -f state-env.before && test -f state-env.after; then
 293   set +x
 294   for act_file in state-env.before state-env.after
 295   do
 296     $EGREP -v '^(m4_join([|],
 297       [a[cs]_.*],
 298       [(exec_)?prefix|DEFS|CONFIG_STATUS],
 299       [CC|CFLAGS|CPP|GCC|CXX|CXXFLAGS|CXXCPP|GXX|F77|FFLAGS|FLIBS|G77],
 300       [ERL|ERLC|ERLCFLAGS|ERLANG_PATH_ERL|ERLANG_ROOT_DIR|ERLANG_LIB_DIR],
 301       [ERLANG_LIB_DIR_.*|ERLANG_LIB_VER_.*|ERLANG_INSTALL_LIB_DIR],
 302       [ERLANG_INSTALL_LIB_DIR_.*|ERLANG_ERTS_VER|OBJC|OBJCPP|OBJCFLAGS],
 303       [OBJCXX|OBJCXXCPP|OBJCXXFLAGS],
 304       [OPENMP_CFLAGS],
 305       [LIBS|LIB@&t@OBJS|LTLIBOBJS|LDFLAGS],
 306       [INSTALL(_(DATA|PROGRAM|SCRIPT))?],
 307       [CYGWIN|ISC|MINGW32|MINIX|EMXOS2|XENIX|EXEEXT|OBJEXT],
 308       [X_(CFLAGS|(EXTRA_|PRE_)?LIBS)|x_(includes|libraries)|(have|no)_x],
 309       [(host|build|target)(_(alias|cpu|vendor|os))?],
 310       [cross_compiling|U],
 311       [interpval|PATH_SEPARATOR],
 312       [F77_DUMMY_MAIN|f77_(case|underscore)],
 313       [FC(_DUMMY_MAIN|FLAGS|LIBS|FLAGS_f)?],
 314       [ALLOCA|GETLOADAVG_LIBS|KMEM_GROUP|NEED_SETGID|POW_LIB],
 315       [AWK|LEX|LEXLIB|LEX_OUTPUT_ROOT|LN_S|M4|MKDIR_P|RANLIB|SET_MAKE|YACC],
 316       [GREP|[EF]GREP|SED],
 317       [[_@]|.[*#?$].],
 318       [argv|ARGC|LINENO|OLDPWD|PIPESTATUS|RANDOM|SECONDS]))=' \
 319      $act_file 2>/dev/null |
 320       # There may be variables spread on several lines; remove latter lines.
 321       $GREP '^m4_defn([m4_re_word])=' >clean-$act_file
 322   done
 323   $at_traceon
 324   $at_diff clean-state-env.before clean-state-env.after
 325 fi
 326 } [#]at_check_env])
 327
 328
 329 # AT_CONFIG_CMP(VAR-FILE-A, VAR-FILE-B)
 330 # -------------------------------------
 331 # Check the outcomes of two configure runs for equality by comparing dumps of
 332 # their shell variables.  VAR-FILE-A and VAR-FILE-B are two `set'-style shell
 333 # variable space dumps.
 334 #
 335 # We permit variance between runs in the following shell variables:
 336 # - ^as_
 337 #   M4sh's shell name space.
 338 # - ^ac_, excluding ^ac_cv_
 339 #   Autoconf's private shell name space.
 340 # - PPID [bash, zsh]
 341 # - RANDOM [zsh]
 342 # - SECONDS [zsh]
 343 # - '$' [zsh]
 344 # - argv [zsh]
 345 # - ARGC [zsh]
 346 #
 347 # Furthermore, it is okay for a non-cache variable initialized to empty in one
 348 # run to be unset in another run.  This happens when, for example, cache update
 349 # code tries a number of values in LIBS and eventually restores LIBS to its
 350 # original value. If LIBS was previously unset, it will have become set and
 351 # empty.  (OTOH, cache variables indicate the result of the test even if they
 352 # are empty, so we have to be strict about them.)
 353 #
 354 # Lines that do not look like `foo=bar' are probably latter lines of
 355 # multiline values; trim them.
 356 #
 357 m4_define([AT_CONFIG_CMP],
 358 [for act_file in $1 $2
 359 do
 360   $SED '/^ac_cv_/ b
 361         /^m4_defn([m4_re_word])=./ !d
 362         /^[[^=]]*='\'''\''$/ d
 363         /^a[[cs]]_/ d
 364         /^PPID=/ d
 365         /^RANDOM=/ d
 366         /^SECONDS=/ d
 367         /'\'\\\$\''=/ d
 368         /^argv=/ d
 369         /^ARGC=/ d
 370         ' $act_file >at_config_vars-$act_file
 371 done
 372 AT_CMP([at_config_vars-$1], [at_config_vars-$2])[]dnl
 373 ])# AT_CONFIG_CMP
 374
 375
 376 # AT_CHECK_DEFINES(CONTENT)
 377 # -------------------------
 378 # Verify that config.h, once stripped, is CONTENT.
 379 # Stripping consists of keeping CPP lines (i.e. containing a hash),
 380 # but those of automatically checked features (STDC_HEADERS etc.)
 381 # and symbols (PACKAGE_...).
 382 # AT_CHECK_HEADER is a better name, but too close from AC_CHECK_HEADER.
 383 m4_define([AT_CHECK_DEFINES],
 384 [AT_CHECK([[sed '/#/!d
 385 /INTTYPES/d
 386 /MEMORY/d
 387 /PACKAGE_/d
 388 /STDC_HEADERS/d
 389 /STDINT/d
 390 /STDLIB/d
 391 /STRING/d
 392 /SYS_STAT/d
 393 /SYS_TYPES/d
 394 /UNISTD/d' config.h]],,
 395           [$1])])
 396
 397
 398 # AT_CHECK_AUTOUPDATE
 399 # -------------------
 400 m4_define([AT_CHECK_AUTOUPDATE],
 401 [AT_CHECK([autoupdate $1], [$2], [$3], [$4])
 402 ])
 403
 404
 405 # _AT_CHECK_AC_MACRO(AC-BODY, PRE-TESTS)
 406 # --------------------------------------
 407 # Create a minimalist configure.ac running the macro named
 408 # NAME-OF-THE-MACRO, check that autoconf runs on that script,
 409 # and that the shell runs correctly the configure.
 410 m4_define([_AT_CHECK_AC_MACRO],
 411 [AT_CONFIGURE_AC([$1])
 412 $2
 413 AT_CHECK_AUTOCONF
 414 AT_CHECK_AUTOHEADER
 415 AT_CHECK_CONFIGURE
 416 AT_CHECK_ENV
 417 ])# _AT_CHECK_AC_MACRO
 418
 419
 420 # AT_CHECK_MACRO(MACRO, [MACRO-USE], [ADDITIONAL-CMDS],
 421 #                [AUTOCONF-FLAGS = -W obsolete])
 422 # -----------------------------------------------------
 423 # Create a minimalist configure.ac running the macro named
 424 # NAME-OF-THE-MACRO, check that autoconf runs on that script,
 425 # and that the shell runs correctly the configure.
 426 #
 427 # We run `configure' twice, both times with a cache, and compare
 428 # the environment after each run to detect inconsistencies.
 429 #
 430 # New macros are not expected to depend upon obsolete macros.
 431 m4_define([AT_CHECK_MACRO],
 432 [AT_SETUP([$1])
 433
 434 AT_CONFIGURE_AC([m4_default([$2], [$1])])
 435
 436 AT_CHECK_AUTOCONF([m4_default([$4], [-W obsolete])])
 437 AT_CHECK_AUTOHEADER
 438
 439 for at_run in r1 r2
 440 do
 441     AT_CHECK_CONFIGURE([-C])
 442     cp -f state-env.after state-env.$at_run
 443     cp -f config.h config-h.$at_run
 444     AT_CHECK_ENV
 445 done
 446
 447 AT_CMP([config-h.r1], [config-h.r2])
 448 AT_CONFIG_CMP([state-env.r1], [state-env.r2])
 449
 450 $3
 451
 452 AT_CLEANUP[]dnl
 453 ])# AT_CHECK_MACRO
 454
 455
 456 # AT_CHECK_MACRO_CROSS(MACRO, [MACRO-USE], [ADDITIONAL-CMDS],
 457 #                      [AUTOCONF-FLAGS = -W obsolete])
 458 # -----------------------------------------------------------
 459 # Like the previous one, but creates two checks: for native
 460 # compile and for cross-compile.
 461 m4_define([AT_CHECK_MACRO_CROSS],
 462 [AT_CHECK_MACRO($@)
 463 AT_CHECK_MACRO([$1 (cross compile)],
 464   [AT_KEYWORDS([cross])
 465   # Exercise the code used when cross-compiling.
 466   cross_compiling=yes
 467   ac_tool_warned=yes
 468   m4_default([$2], [$1])],
 469   [$3], [$4])
 470 ])
 471
 472
 473 # AT_CHECK_AU_MACRO(MACRO)
 474 # ------------------------
 475 # Create a minimalist configure.ac running the macro named
 476 # NAME-OF-THE-MACRO, autoupdate this script, check that autoconf runs
 477 # on that script, and that the shell runs correctly the configure.
 478 #
 479 # Updated configure.ac shall not depend upon obsolete macros, which votes
 480 # in favor of `-W obsolete', but since many of these macros leave a message
 481 # to be removed by the user once her code is adjusted, let's not check.
 482 #
 483 # Remove config.hin to avoid `autoheader: config.hin is unchanged'.
 484 m4_define([AT_CHECK_AU_MACRO],
 485 [AT_SETUP([$1])
 486 AT_KEYWORDS([autoupdate])
 487
 488 AT_CONFIGURE_AC([$1])
 489
 490 AT_CHECK_AUTOCONF
 491 AT_CHECK_AUTOHEADER
 492 AT_CHECK_CONFIGURE
 493 AT_CHECK_ENV
 494
 495 rm config.hin
 496 AT_CHECK_AUTOUPDATE([], 0, [], ignore)
 497 AT_CHECK([grep '^$1$' configure.ac], 1)
 498
 499 AT_CHECK_AUTOCONF
 500 AT_CHECK_AUTOHEADER
 501 AT_CHECK_CONFIGURE
 502 AT_CHECK_ENV
 503
 504 AT_CLEANUP[]dnl
 505 ])# AT_CHECK_AU_MACRO
 506
 507
 508
 509 ## ----------------------- ##
 510 ## Launch the test suite.  ##
 511 ## ----------------------- ##
 512
 513 AT_INIT