tests/local.at

   1 # M4 macros used in building Autoconf test suites.        -*- Autotest -*-
   2
   3 # Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008,
   4 # 2009 Free Software Foundation, Inc.
   5
   6 # This program is free software: you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; if not, write to the Free Software
  18 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  19 # 02110-1301, USA.
  20
  21 m4_version_prereq([2.57])
  22
  23 # Used in many tests.
  24 m4_pattern_allow([^AS_EXIT$])
  25 m4_pattern_allow([^m4_(define|shift)$])
  26
  27 # Programs this package provides
  28 AT_TESTED([autom4te autoconf autoheader autoupdate autoreconf ifnames])
  29
  30
  31 ## ---------------- ##
  32 ## Utility macros.  ##
  33 ## ---------------- ##
  34
  35 # AT_CMP(FILE-1, FILE-2)
  36 # ----------------------
  37 # Check FILE-1 and FILE-2 for equality, like `cmp FILE-1 FILE-2'.
  38 m4_define([AT_CMP],
  39 [m4_ifval([$2],, [m4_fatal([AT_CMP takes two arguments.])])[]dnl
  40 AT_CHECK([$at_diff "$1" "$2"])
  41 ])# AT_CMP
  42
  43
  44 ## ---------------- ##
  45 ## Testing syntax.  ##
  46 ## ---------------- ##
  47
  48 # AT_CHECK_SHELL_SYNTAX(PROGRAM)
  49 # ------------------------------
  50 # If the shell handles `-n' well, use it to check the syntax of PROGRAM;
  51 # otherwise, do nothing.
  52 m4_define([AT_CHECK_SHELL_SYNTAX],
  53 [AS_IF([test "$ac_cv_sh_n_works" = yes],
  54   [AT_CHECK([/bin/sh -n $1])])])
  55
  56 m4_define([AT_CHECK_PERL_SYNTAX],
  57 [AT_CHECK([autom4te_perllibdir=$abs_top_srcdir/lib $PERL -c "$abs_top_builddir"/bin/$1],
  58           0, [], [ignore])])
  59
  60 ## ------------------ ##
  61 ## Testing autom4te.  ##
  62 ## ------------------ ##
  63
  64
  65 # AT_CHECK_M4(COMMAND, [EXIT-STATUS = 0], STDOUT, STDERR)
  66 # -------------------------------------------------------
  67 # If stderr is specified, normalize the observed stderr.
  68 # This (using GNU M4 1.4.6)
  69 #
  70 #  /usr/local/bin/m4:script.4s:1: cannot open `foo': No such file or directory
  71 #  autom4te: /usr/local/bin/m4 failed with exit status: 1
  72 #
  73 # or this (GNU M4 1.4.11)
  74 #
  75 #  /usr/local/bin/m4:script.4s:1: include: cannot open `foo': No such file or directory
  76 #  autom4te: /usr/local/bin/m4 failed with exit status: 1
  77 #
  78 # or this (GNU M4 1.4 installed as gm4)
  79 #
  80 #  script.4s:1: /usr/local/bin/gm4: Cannot open foo: No such file or directory
  81 #  autom4te: /usr/local/bin/gm4 failed with exit status: 1
  82 #
  83 # becomes
  84 #
  85 #  m4:script.4s:1: cannot open `foo': No such file or directory
  86 #  autom4te: m4 failed with exit status: 1
  87 #
  88 # We use the following sed patterns:
  89 #
  90 #     (m4): ?(file): ?(line):
  91 # or  (file): ?(line): ?(m4):
  92 # to  m4:(file):(line):
  93 #
  94 # and
  95 #     m4:(file):(line): Cannot open foo:
  96 # or  m4:(file):(line): include: cannot open `foo':
  97 # to  m4:(file):(line): cannot open `foo':
  98 #
  99 # and
 100 #     autom4te: [^ ]m4
 101 # or  autom4te: [^ ]m4.exe
 102 # to  autom4te: m4
 103 #
 104 # Moreover, DJGPP error messages include the error code in brackets;
 105 # remove the error code during normalization.
 106 #
 107 m4_define([AT_CHECK_M4],
 108 [AT_CHECK([$1], [$2], [$3],
 109           m4_case([$4], [], [], [ignore], [ignore], [stderr]))
 110 m4_case([$4], [], [], [ignore], [],
 111 [AT_CHECK([[sed 's/^[^:]*m4[.ex]*: *\([^:]*:\) *\([0-9][0-9]*: \)/m4:\1\2/
 112         s/^\([^:]*:\) *\([0-9][0-9]*:\)[^:]*m4[.ex]*: /m4:\1\2 /
 113         s/: C\(annot open \)\([^`:]*\):/: c\1`\2'\'':/
 114         s/: include:\( cannot open\)/:\1/
 115         s/^autom4te: [^ ]*m4[.ex]* /autom4te: m4 /
 116         s/ (E[A-Z]*)$//
 117     ' stderr >&2]], [0], [], [$4])])
 118 ])
 119
 120 # AT_CHECK_AUTOM4TE(FLAGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 121 # -----------------------------------------------------------
 122 m4_define([AT_CHECK_AUTOM4TE],
 123 [AT_CHECK_M4([autom4te $1], [$2], [$3], [$4])])
 124
 125
 126
 127 ## ----------------- ##
 128 ## Testing M4sugar.  ##
 129 ## ----------------- ##
 130
 131
 132 # AT_DATA_M4SUGAR(FILE-NAME, CONTENTS)
 133 # ------------------------------------
 134 # Escape the invalid tokens with @&t@.
 135 m4_define([AT_DATA_M4SUGAR],
 136 [AT_DATA([$1],
 137 [m4_bpatsubst([$2], [\(@.\)\(.@\)\|\(m4\)\(_\)\|\(d\)\(nl\)],
 138               [\1\3\5@&t@\2\4\6])])])
 139
 140
 141 # AT_CHECK_M4SUGAR(FLAGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 142 # ----------------------------------------------------------
 143 m4_define([AT_CHECK_M4SUGAR],
 144 [AT_KEYWORDS([m4sugar])
 145 AT_CHECK_AUTOM4TE([--language=m4sugar script.4s -o script $1],
 146                    [$2], [$3], [$4])])
 147
 148
 149
 150 ## -------------- ##
 151 ## Testing M4sh.  ##
 152 ## -------------- ##
 153
 154
 155 # AT_DATA_M4SH(FILE-NAME, CONTENTS)
 156 # ---------------------------------
 157 # Escape the invalid tokens with @&t@.
 158 m4_define([AT_DATA_M4SH],
 159 [AT_DATA([$1],
 160 [m4_bpatsubst([$2], [\(@.\)\(.@\)\|\(m4\|AS\)\(_\)\|\(d\)\(nl\)],
 161               [\1\3\5@&t@\2\4\6])])])
 162
 163
 164 # AT_CHECK_M4SH(FLAGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 165 # -------------------------------------------------------
 166 m4_define([AT_CHECK_M4SH],
 167 [AT_CHECK_AUTOM4TE([--language=m4sh script.as -o script $1],
 168                    [$2], [$3], [$4])])
 169
 170
 171
 172 ## ------------------ ##
 173 ## Testing Autoconf.  ##
 174 ## ------------------ ##
 175
 176
 177 # AT_DATA_AUTOCONF(FILE-NAME, CONTENTS)
 178 # -------------------------------------
 179 # Escape the invalid tokens with @&t@.
 180 m4_define([AT_DATA_AUTOCONF],
 181 [AT_DATA([$1],
 182 [m4_bpatsubst([$2], [\(@.\)\(.@\)\|\(m4\|AS\|AC\)\(_\)\|\(d\)\(nl\)],
 183               [\1\3\5@&t@\2\4\6])])])
 184
 185
 186
 187 # AT_CONFIGURE_AC(BODY)
 188 # ---------------------
 189 # Create a full configure.ac running BODY, with a config header set up,
 190 # AC_OUTPUT, and environment checking hooks.
 191 m4_define([AT_CONFIGURE_AC],
 192 [AT_DATA([configure.ac],
 193 [[AC_INIT
 194 AC_CONFIG_HEADERS(config.h:config.hin)
 195 AC_STATE_SAVE(before)]
 196 $1
 197 [AC_OUTPUT
 198 AC_STATE_SAVE(after)
 199 ]])
 200 cp "$abs_top_srcdir/build-aux/install-sh" \
 201    "$abs_top_srcdir/build-aux/config.guess" \
 202    "$abs_top_srcdir/build-aux/config.sub" .
 203 cp "$abs_top_srcdir/tests/statesave.m4" aclocal.m4
 204 ])# AT_CONFIGURE_AC
 205
 206
 207 # AT_CHECK_AUTOCONF(ARGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 208 # ----------------------------------------------------------
 209 # We always use "--force", to prevent problems with timestamps if the testsuite
 210 # were running too fast.
 211 m4_define([AT_CHECK_AUTOCONF],
 212 [AT_CHECK_M4([autoconf --force $1], [$2], [$3], [$4])
 213 if test -s configure; then
 214   AT_CHECK_SHELL_SYNTAX(configure)
 215 fi
 216 ])
 217
 218
 219 # AT_CHECK_AUTOHEADER(ARGS, [EXIT-STATUS = 0], STDOUT, STDERR)
 220 # ------------------------------------------------------------
 221 m4_define([AT_CHECK_AUTOHEADER],
 222 [AT_CHECK([autoheader $1], [$2], [$3], [$4])
 223 ])
 224
 225
 226 # AT_CHECK_CONFIGURE(END-COMMAND,
 227 #                    [EXIT-STATUS = 0],
 228 #                    [STDOUT = IGNORE], STDERR)
 229 # --------------------------------------------
 230 # `abs_top_srcdir' is needed so that `./configure' finds install-sh.
 231 # Using --srcdir is more expensive.
 232 m4_define([AT_CHECK_CONFIGURE],
 233 [AT_CAPTURE_FILE([config.log])[]dnl
 234  AT_CHECK([./configure $1],
 235           [$2],
 236           m4_default([$3], [ignore]), [$4])])
 237
 238
 239 # AT_CHECK_ENV
 240 # ------------
 241 # Check that the full configure run remained in its variable name space,
 242 # and cleaned up tmp files.
 243 #
 244 # Perhaps grep -E is not supported, or perhaps it chokes on such a big regex.
 245 # In this case just don't pay attention to the env.  It would be great
 246 # to keep the error message but we can't: that would break AT_CHECK.
 247 #
 248 # Some tests might exit prematurely when they find a problem, in
 249 # which case `env-after' is probably missing.  Don't check it then.
 250 #
 251 # Here are the variables `configure' may modify during execution:
 252 # - ^as_
 253 #   M4sh's shell name space.
 254 # - ^ac_
 255 #   Autoconf's shell name space.
 256 # - prefix and exec_prefix
 257 #   are kept undefined (NONE) until AC_OUTPUT which then sets them to
 258 #   `/usr/local' and `${prefix}' for make.
 259 # - (host|build|target)(_(alias|cpu|vendor|os))?
 260 #   Set by AC_CANONICAL_(HOST|BUILD|TARGET).
 261 # - cross_compiling
 262 #   Set by AC_INIT.
 263 # - interpval
 264 #   Set by AC_SYS_INTERPRETER.
 265 # - CONFIG_STATUS and DEFS
 266 #   Set by AC_OUTPUT.
 267 # - AC_SUBST'ed variables
 268 #   (FIXME: Generate a list of these automatically.)
 269 # - _|@|.[*#?$].|argv|ARGC|LINENO|OLDPWD|PIPESTATUS|RANDOM|SECONDS
 270 #   Some variables some shells use and change.
 271 #   `.[*#?$].' catches `$#' etc. which are displayed like this:
 272 #      | '!'=18186
 273 #      | '#'=0
 274 #      | '$'=6908
 275 #
 276 m4_define([AT_CHECK_ENV],
 277 [m4_divert_once([PREPARE_TESTS], [_AT_CHECK_ENV])dnl
 278 AT_CHECK([at_check_env])])
 279 m4_define([_AT_CHECK_ENV],
 280 [AS_FUNCTION_DESCRIBE([at_check_env], [],
 281 [Compare the directory and environment state both before and after a run,
 282 and return non-zero status if they differ inappropriately.])
 283 at_check_env ()
 284 {
 285 # Compare directory listings.
 286 test -f state-ls.before ||
 287   AS_ERROR([state-ls.before not present])
 288 test -f state-ls.after \
 289   && { $at_diff state-ls.before state-ls.after || return 1; }
 290 # Compare variable space dumps.
 291 if test -f state-env.before && test -f state-env.after; then
 292   for act_file in state-env.before state-env.after
 293   do
 294     $EGREP -v '^(m4_join([|],
 295       [a[cs]_.*],
 296       [(exec_)?prefix|DEFS|CONFIG_STATUS],
 297       [CC|CFLAGS|CPP|GCC|CXX|CXXFLAGS|CXXCPP|GXX|F77|FFLAGS|FLIBS|G77],
 298       [ERL|ERLC|ERLCFLAGS|ERLANG_PATH_ERL|ERLANG_ROOT_DIR|ERLANG_LIB_DIR],
 299       [ERLANG_INSTALL_LIB_DIR|OBJC|OBJCPP|OBJCFLAGS],
 300       [OPENMP_CFLAGS],
 301       [LIBS|LIB@&t@OBJS|LTLIBOBJS|LDFLAGS],
 302       [INSTALL(_(DATA|PROGRAM|SCRIPT))?],
 303       [CYGWIN|ISC|MINGW32|MINIX|EMXOS2|XENIX|EXEEXT|OBJEXT],
 304       [X_(CFLAGS|(EXTRA_|PRE_)?LIBS)|x_(includes|libraries)|(have|no)_x],
 305       [(host|build|target)(_(alias|cpu|vendor|os))?],
 306       [cross_compiling],
 307       [interpval|PATH_SEPARATOR],
 308       [F77_DUMMY_MAIN|f77_(case|underscore)],
 309       [FC(_DUMMY_MAIN|FLAGS|LIBS|FLAGS_f)?],
 310       [ALLOCA|GETLOADAVG_LIBS|KMEM_GROUP|NEED_SETGID|POW_LIB],
 311       [AWK|LEX|LEXLIB|LEX_OUTPUT_ROOT|LN_S|M4|MKDIR_P|RANLIB|SET_MAKE|YACC],
 312       [GREP|[EF]GREP|SED],
 313       [[_@]|.[*#?$].],
 314       [argv|ARGC|LINENO|OLDPWD|PIPESTATUS|RANDOM|SECONDS]))=' \
 315      $act_file 2>/dev/null |
 316       # There may be variables spread on several lines; remove latter lines.
 317       $GREP '^m4_defn([m4_re_word])=' >clean-$act_file
 318   done
 319   $at_diff clean-state-env.before clean-state-env.after
 320 fi
 321 } [#]at_check_env])
 322
 323
 324 # AT_CONFIG_CMP(VAR-FILE-A, VAR-FILE-B)
 325 # -------------------------------------
 326 # Check the outcomes of two configure runs for equality by comparing dumps of
 327 # their shell variables.  VAR-FILE-A and VAR-FILE-B are two `set'-style shell
 328 # variable space dumps.
 329 #
 330 # We permit variance between runs in the following shell variables:
 331 # - ^as_
 332 #   M4sh's shell name space.
 333 # - ^ac_, excluding ^ac_cv_
 334 #   Autoconf's private shell name space.
 335 # - PPID [bash, zsh]
 336 # - RANDOM [zsh]
 337 # - SECONDS [zsh]
 338 # - '$' [zsh]
 339 #
 340 # Furthermore, it is okay for a non-cache variable initialized to empty in one
 341 # run to be unset in another run.  This happens when, for example, cache update
 342 # code tries a number of values in LIBS and eventually restores LIBS to its
 343 # original value. If LIBS was previously unset, it will have become set and
 344 # empty.  (OTOH, cache variables indicate the result of the test even if they
 345 # are empty, so we have to be strict about them.)
 346 #
 347 # Lines that do not look like `foo=bar' are probably latter lines of
 348 # multiline values; trim them.
 349 #
 350 m4_define([AT_CONFIG_CMP],
 351 [for act_file in $1 $2
 352 do
 353   $SED '/^ac_cv_/ b
 354         /^m4_defn([m4_re_word])=./ !d
 355         /^[[^=]]*='\'''\''$/ d
 356         /^a[[cs]]_/ d
 357         /^PPID=/ d
 358         /^RANDOM=/ d
 359         /^SECONDS=/ d
 360         /'\'\\\$\''=/ d
 361         ' $act_file >at_config_vars-$act_file
 362 done
 363 AT_CMP([at_config_vars-$1], [at_config_vars-$2])[]dnl
 364 ])# AT_CONFIG_CMP
 365
 366
 367 # AT_CHECK_DEFINES(CONTENT)
 368 # -------------------------
 369 # Verify that config.h, once stripped, is CONTENT.
 370 # Stripping consists of keeping CPP lines (i.e. containing a hash),
 371 # but those of automatically checked features (STDC_HEADERS etc.)
 372 # and symbols (PACKAGE_...).
 373 # AT_CHECK_HEADER is a better name, but too close from AC_CHECK_HEADER.
 374 m4_define([AT_CHECK_DEFINES],
 375 [AT_CHECK([[sed '/#/!d
 376 /INTTYPES/d
 377 /MEMORY/d
 378 /PACKAGE_/d
 379 /STDC_HEADERS/d
 380 /STDINT/d
 381 /STDLIB/d
 382 /STRING/d
 383 /SYS_STAT/d
 384 /SYS_TYPES/d
 385 /UNISTD/d' config.h]],,
 386           [$1])])
 387
 388
 389 # AT_CHECK_AUTOUPDATE
 390 # -------------------
 391 m4_define([AT_CHECK_AUTOUPDATE],
 392 [AT_CHECK([autoupdate $1], [$2], [$3], [$4])
 393 ])
 394
 395
 396 # _AT_CHECK_AC_MACRO(AC-BODY, PRE-TESTS)
 397 # --------------------------------------
 398 # Create a minimalist configure.ac running the macro named
 399 # NAME-OF-THE-MACRO, check that autoconf runs on that script,
 400 # and that the shell runs correctly the configure.
 401 m4_define([_AT_CHECK_AC_MACRO],
 402 [AT_CONFIGURE_AC([$1])
 403 $2
 404 AT_CHECK_AUTOCONF
 405 AT_CHECK_AUTOHEADER
 406 AT_CHECK_CONFIGURE
 407 AT_CHECK_ENV
 408 ])# _AT_CHECK_AC_MACRO
 409
 410
 411 # AT_CHECK_MACRO(MACRO, [MACRO-USE], [ADDITIONAL-CMDS],
 412 #                [AUTOCONF-FLAGS = -W obsolete])
 413 # -----------------------------------------------------
 414 # Create a minimalist configure.ac running the macro named
 415 # NAME-OF-THE-MACRO, check that autoconf runs on that script,
 416 # and that the shell runs correctly the configure.
 417 #
 418 # We run `configure' twice, both times with a cache, and compare
 419 # the environment after each run to detect inconsistencies.
 420 #
 421 # New macros are not expected to depend upon obsolete macros.
 422 m4_define([AT_CHECK_MACRO],
 423 [AT_SETUP([$1])
 424
 425 AT_CONFIGURE_AC([m4_default([$2], [$1])])
 426
 427 AT_CHECK_AUTOCONF([m4_default([$4], [-W obsolete])])
 428 AT_CHECK_AUTOHEADER
 429
 430 for at_run in r1 r2
 431 do
 432     AT_CHECK_CONFIGURE([-C])
 433     cp -f state-env.after state-env.$at_run
 434     cp -f config.h config-h.$at_run
 435     AT_CHECK_ENV
 436 done
 437
 438 AT_CMP([config-h.r1], [config-h.r2])
 439 AT_CONFIG_CMP([state-env.r1], [state-env.r2])
 440
 441 $3
 442
 443 AT_CLEANUP[]dnl
 444 ])# AT_CHECK_MACRO
 445
 446
 447 # AT_CHECK_MACRO_CROSS(MACRO, [MACRO-USE], [ADDITIONAL-CMDS],
 448 #                      [AUTOCONF-FLAGS = -W obsolete])
 449 # -----------------------------------------------------------
 450 # Like the previous one, but creates two checks: for native
 451 # compile and for cross-compile.
 452 m4_define([AT_CHECK_MACRO_CROSS],
 453 [AT_CHECK_MACRO($@)
 454 AT_CHECK_MACRO([$1 (cross compile)],
 455   [AT_KEYWORDS([cross])
 456   # Exercise the code used when cross-compiling.
 457   cross_compiling=yes
 458   ac_tool_warned=yes
 459   m4_default([$2], [$1])],
 460   [$3], [$4])
 461 ])
 462
 463
 464 # AT_CHECK_AU_MACRO(MACRO)
 465 # ------------------------
 466 # Create a minimalist configure.ac running the macro named
 467 # NAME-OF-THE-MACRO, autoupdate this script, check that autoconf runs
 468 # on that script, and that the shell runs correctly the configure.
 469 #
 470 # Updated configure.ac shall not depend upon obsolete macros, which votes
 471 # in favor of `-W obsolete', but since many of these macros leave a message
 472 # to be removed by the user once her code is adjusted, let's not check.
 473 #
 474 # Remove config.hin to avoid `autoheader: config.hin is unchanged'.
 475 m4_define([AT_CHECK_AU_MACRO],
 476 [AT_SETUP([$1])
 477 AT_KEYWORDS([autoupdate])
 478
 479 AT_CONFIGURE_AC([$1])
 480
 481 AT_CHECK_AUTOCONF
 482 AT_CHECK_AUTOHEADER
 483 AT_CHECK_CONFIGURE
 484 AT_CHECK_ENV
 485
 486 rm config.hin
 487 AT_CHECK_AUTOUPDATE([], 0, [], ignore)
 488 AT_CHECK([grep '^$1$' configure.ac], 1)
 489
 490 AT_CHECK_AUTOCONF
 491 AT_CHECK_AUTOHEADER
 492 AT_CHECK_CONFIGURE
 493 AT_CHECK_ENV
 494
 495 AT_CLEANUP[]dnl
 496 ])# AT_CHECK_AU_MACRO
 497
 498
 499
 500 ## ----------------------- ##
 501 ## Launch the test suite.  ##
 502 ## ----------------------- ##
 503
 504 AT_INIT