configure.ac

   1 #                                                       -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1992, 1993, 1994, 1995, 1999, 2000, 2001, 2002, 2003,
   5 # 2004 Free Software Foundation, Inc.
   6
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 # 02111-1307, USA.
  21
  22 # We need AC_CONFIG_TESTDIR.
  23 AC_PREREQ([2.59])
  24
  25 AC_INIT([GNU Autoconf], [2.59c], [bug-autoconf@gnu.org])
  26 AC_SUBST([PACKAGE_NAME])dnl
  27 AC_CONFIG_SRCDIR([ChangeLog])
  28
  29 AC_CONFIG_AUX_DIR([config])
  30 AC_CONFIG_FILES([config/Makefile])
  31
  32 AM_INIT_AUTOMAKE([check-news 1.7.9 dist-bzip2 readme-alpha])
  33
  34 # We use `/bin/sh -n script' to check that there are no syntax errors
  35 # in the scripts.  Although incredible, there are /bin/sh that go into
  36 # endless loops with `-n', e.g., SunOS's:
  37 #
  38 #   $ uname -a
  39 #   SunOS ondine 4.1.3 2 sun4m unknown
  40 #   $ cat endless.sh
  41 #   while false
  42 #   do
  43 #     :
  44 #   done
  45 #   exit 0
  46 #   $ time sh endless.sh
  47 #   sh endless.sh  0,02s user 0,03s system 78% cpu 0,064 total
  48 #   $ time sh -nx endless.sh
  49 #   ^Csh -nx endless.sh  3,67s user 0,03s system 63% cpu 5,868 total
  50 #
  51 # So before using `/bin/sh -n' to check our scripts, we first check
  52 # that `/bin/sh -n' is not broken to death.
  53
  54 # A script that never returns.  We don't care that it never returns,
  55 # broken /bin/sh loop equally with `false', but it makes it easier to
  56 # test the robustness in a good environment: just remove the `-n'.
  57 AC_CACHE_CHECK([whether sh -n works], ac_cv_sh_n_works,
  58 [cat > conftest.sh <<_CONFEOF_
  59 while :
  60 do
  61   :
  62 done
  63 _CONFEOF_
  64
  65 (/bin/sh -n conftest.sh) &
  66 sleep 2
  67 if kill $! >/dev/null 2>&1; then
  68   # We managed to kill the child, which means that we probably
  69   # can't trust `/bin/sh -n', hence the test failed.
  70   ac_cv_sh_n_works=no
  71 else
  72   ac_cv_sh_n_works=yes
  73 fi
  74 rm conftest.sh
  75 ])
  76 AC_SUBST(ac_cv_sh_n_works)
  77
  78 # Initialize the test suite.
  79 AC_CONFIG_TESTDIR([tests])
  80 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
  81 AC_PATH_PROG([EXPR], [expr])
  82
  83
  84 ## ---- ##
  85 ## M4.  ##
  86 ## ---- ##
  87
  88 # We use an absolute name for GNU m4 so even if users have another m4 first in
  89 # their path, the installer can configure with a path that has GNU m4
  90 # first and get that path embedded in the installed autoconf and
  91 # autoheader scripts.
  92 AC_PROG_GNU_M4
  93 if test x"$ac_cv_prog_gnu_m4" != xyes; then
  94   AC_MSG_ERROR([GNU M4 1.4 is required])
  95 fi
  96
  97 ## ----------- ##
  98 ## Man pages.  ##
  99 ## ----------- ##
 100
 101 AC_CONFIG_FILES(man/Makefile)
 102 AM_MISSING_PROG(HELP2MAN, help2man)
 103
 104
 105 ## ------ ##
 106 ## Perl.  ##
 107 ## ------ ##
 108
 109 # We use an absolute name for perl so the #! line in autoscan will work.
 110 AC_PATH_PROG([PERL], perl, no)
 111 AC_SUBST([PERL])dnl
 112 if test "$PERL" = no; then
 113   AC_MSG_ERROR([perl is not found])
 114 fi
 115 $PERL -e 'require 5.005_03;' || {
 116    AC_MSG_ERROR([Perl 5.005_03 or better is required])
 117 }
 118
 119
 120 ## ------- ##
 121 ## Emacs.  ##
 122 ## ------- ##
 123
 124 AC_CONFIG_FILES([lib/emacs/Makefile])
 125 TEST_EMACS=$EMACS
 126 test x"$TEST_EMACS" = xt && TEST_EMACS=
 127 AC_CHECK_PROGS([TEST_EMACS], [emacs xemacs], [no])
 128
 129 # autoconf-mode.el and autotest-mode.el do not work with older version of
 130 # Emacs (i.e. 18.x.x).  During byte-compilation, Emacs complains:
 131 # "Variable (broken nil) seen on pass 2 of byte compiler but not pass 1"
 132 # We detect this problem here.
 133 AS_IF([test "$TEST_EMACS" != no],
 134   [AC_CACHE_CHECK([whether $TEST_EMACS is sufficiently recent],
 135     [ac_cv_prog_emacs_ok],
 136     [# Note: The quoted "EOF" is intentional.  It protects the ` in the text.
 137     cat >conftest.el << "EOF"
 138       (defvar broken)
 139       (defun broken-mode () (setq broken-defaults `(broken nil)))
 140 EOF
 141     AS_IF([AC_RUN_LOG(
 142       [$TEST_EMACS -batch -q -f batch-byte-compile conftest.el 1>&2])],
 143       [ac_cv_prog_emacs_ok=yes], [ac_cv_prog_emacs_ok=no])
 144     rm -f conftest.el conftest.elc])
 145   AS_IF([test $ac_cv_prog_emacs_ok = no], [TEST_EMACS=no])])
 146
 147 AC_SUBST([EMACS], [$TEST_EMACS])
 148
 149 AM_PATH_LISPDIR
 150
 151
 152 ## ------ ##
 153 ## Grep.  ##
 154 ## ------ ##
 155 AC_PROG_GREP
 156
 157
 158 ## ------------ ##
 159 ## Conclusion.  ##
 160 ## ------------ ##
 161
 162 AC_CONFIG_FILES([Makefile doc/Makefile
 163                  lib/Makefile lib/Autom4te/Makefile lib/autoscan/Makefile
 164                  lib/m4sugar/Makefile
 165                  lib/autoconf/Makefile lib/autotest/Makefile
 166                  bin/Makefile])
 167
 168 AC_OUTPUT
 169 # Report the state of this version of Autoconf if this is a beta.
 170 m4_bmatch(m4_defn([AC_PACKAGE_VERSION]),  [[a-z]],
 171 [    cat <<EOF
 172
 173 You are about to use an experimental version of Autoconf.  Be sure to
 174 read the relevant mailing lists, most importantly <autoconf@gnu.org>.
 175
 176 Below you will find information on the status of this version of Autoconf.
 177
 178
 179 EOF
 180     sed -n '/^\* Status/,$p' $srcdir/BUGS
 181 ])