configure.ac

   1 #                                                       -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 # Copyright (C) 1992, 1993, 1994, 1995, 1999, 2000, 2001, 2002, 2003,
   5 # 2004, 2005, 2006, 2007, 2008 Free Software Foundation, Inc.
   6
   7 # This program is free software: you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation, either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 # We need AC_CONFIG_TESTDIR, AC_PROG_SED, AC_PROG_GREP.
  21 AC_PREREQ([2.60])
  22
  23 AC_INIT([GNU Autoconf],
  24         m4_esyscmd([build-aux/git-version-gen .tarball-version]),
  25         [bug-autoconf@gnu.org])
  26 AC_CONFIG_SRCDIR([ChangeLog])
  27
  28 AC_CONFIG_AUX_DIR([build-aux])
  29
  30 AM_INIT_AUTOMAKE([1.10 dist-bzip2 readme-alpha no-texinfo.tex std-options])
  31
  32 # We use `/bin/sh -n script' to check that there are no syntax errors
  33 # in the scripts.  Although incredible, there are /bin/sh that go into
  34 # endless loops with `-n', e.g., SunOS's:
  35 #
  36 #   $ uname -a
  37 #   SunOS ondine 4.1.3 2 sun4m unknown
  38 #   $ cat endless.sh
  39 #   while false
  40 #   do
  41 #     :
  42 #   done
  43 #   exit 0
  44 #   $ time sh endless.sh
  45 #   sh endless.sh  0,02s user 0,03s system 78% cpu 0,064 total
  46 #   $ time sh -nx endless.sh
  47 #   ^Csh -nx endless.sh  3,67s user 0,03s system 63% cpu 5,868 total
  48 #
  49 # Also, some implementations of /bin/sh (e.g., Solaris 8) are soooo slow
  50 # that they are unusable on large scripts like our testsuite.
  51
  52 # So before using `/bin/sh -n' to check our scripts, we first check
  53 # that `/bin/sh -n' is known to not have these problems.
  54
  55 AC_CACHE_CHECK([whether /bin/sh -n is known to work], [ac_cv_sh_n_works],
  56 [if (
  57     unset BASH_VERSION ZSH_VERSION
  58     /bin/sh -c '
  59       test -n "${BASH_VERSION+set}" || # Bash
  60       test -n "${KSH_VERSION+set}" || # pdksh
  61       test -n "${ZSH_VERSION+set}" || # zsh
  62       test -n "${.sh.version}" # ksh93; put this last since its syntax is dodgy
  63     '
  64   ) 2>/dev/null
  65 then ac_cv_sh_n_works=yes
  66 else ac_cv_sh_n_works=no
  67 fi
  68 ])
  69 AC_SUBST([ac_cv_sh_n_works])
  70
  71 # Initialize the test suite.
  72 AC_CONFIG_TESTDIR([tests])
  73 AC_CONFIG_FILES([tests/Makefile tests/atlocal])
  74 AC_PATH_PROG([EXPR], [expr])
  75
  76
  77 ## ---- ##
  78 ## M4.  ##
  79 ## ---- ##
  80
  81 # We use an absolute name for GNU m4 so even if users have another m4 first in
  82 # their path, the installer can configure with a path that has GNU m4
  83 # on it and get that path embedded in the installed autoconf and
  84 # autoheader scripts.
  85 AC_PROG_GNU_M4
  86
  87 ## ----------- ##
  88 ## Man pages.  ##
  89 ## ----------- ##
  90
  91 AC_CONFIG_FILES([man/Makefile])
  92 AM_MISSING_PROG([HELP2MAN], [help2man])
  93
  94
  95 ## ------ ##
  96 ## Perl.  ##
  97 ## ------ ##
  98
  99 # We use an absolute name for perl so the #! line in autoscan will work.
 100 AC_PATH_PROG([PERL], [perl], [no])
 101 AC_SUBST([PERL])dnl
 102 if test "$PERL" = no; then
 103   AC_MSG_ERROR([perl is not found])
 104 fi
 105 $PERL -e 'require 5.005_03;' || {
 106    AC_MSG_ERROR([Perl 5.005_03 or better is required])
 107 }
 108
 109
 110 ## ------- ##
 111 ## Emacs.  ##
 112 ## ------- ##
 113
 114 AC_CONFIG_FILES([lib/emacs/Makefile])
 115 TEST_EMACS=$EMACS
 116 test x"$TEST_EMACS" = xt && TEST_EMACS=
 117 AC_CHECK_PROGS([TEST_EMACS], [emacs xemacs], [no])
 118
 119 # autoconf-mode.el and autotest-mode.el do not work with older version of
 120 # Emacs (i.e. 18.x.x).  During byte-compilation, Emacs complains:
 121 # "Variable (broken nil) seen on pass 2 of byte compiler but not pass 1"
 122 # We detect this problem here.
 123 AS_IF([test "$TEST_EMACS" != no],
 124   [AC_CACHE_CHECK([whether $TEST_EMACS is sufficiently recent],
 125     [ac_cv_prog_emacs_ok],
 126     [# Note: The quoted "EOF" is intentional.  It protects the ` in the text.
 127     cat >conftest.el << "EOF"
 128       (defvar broken)
 129       (defun broken-mode () (setq broken-defaults `(broken nil)))
 130 EOF
 131     AS_IF([AC_RUN_LOG(
 132       [$TEST_EMACS -batch -q -f batch-byte-compile conftest.el 1>&2])],
 133       [ac_cv_prog_emacs_ok=yes], [ac_cv_prog_emacs_ok=no])
 134     rm -f conftest.el conftest.elc])
 135   AS_IF([test $ac_cv_prog_emacs_ok = no], [TEST_EMACS=no])])
 136
 137 AC_SUBST([EMACS], [$TEST_EMACS])
 138
 139 AM_PATH_LISPDIR
 140
 141
 142 ## ------------ ##
 143 ## Grep & sed.  ##
 144 ## ------------ ##
 145 AC_PROG_GREP
 146 AC_PROG_EGREP
 147 AC_PROG_SED
 148
 149
 150 ## ----- ##
 151 ## Make. ##
 152 ## ----- ##
 153 AC_PROG_MAKE_CASE_SENSITIVE
 154
 155
 156 ## ------------ ##
 157 ## Conclusion.  ##
 158 ## ------------ ##
 159
 160 dnl Allow maintainer rules under GNU make even in VPATH builds.  This does
 161 dnl not work in autoconf 2.61 or earlier, but we don't want to require
 162 dnl unreleased autoconf during bootstrap, hence the version test.
 163 dnl TODO remove the version check once we depend on autoconf 2.62.
 164 dnl Meanwhile, we must use a shell variable so that we bypass automake's
 165 dnl attempts to remove the sole copy of GNUmakefile in a non-VPATH build
 166 dnl during 'make distclean'.
 167 dnl TODO avoid the shell variable once automake is fixed.
 168 GNUmakefile=GNUmakefile
 169 m4_if(m4_version_compare([2.61a.100],
 170         m4_defn([m4_PACKAGE_VERSION])), [1], [],
 171       [AC_CONFIG_LINKS([$GNUmakefile:$GNUmakefile], [],
 172         [GNUmakefile=$GNUmakefile])])
 173
 174 AC_CONFIG_FILES([Makefile doc/Makefile
 175                  lib/Makefile lib/Autom4te/Makefile lib/autoscan/Makefile
 176                  lib/m4sugar/Makefile
 177                  lib/autoconf/Makefile lib/autotest/Makefile
 178                  bin/Makefile])
 179
 180 AC_OUTPUT
 181 # Report the state of this version of Autoconf if this is a beta.
 182 m4_bmatch(m4_defn([AC_PACKAGE_VERSION]),  [[a-z]],
 183 [    cat <<EOF
 184
 185 You are about to use an experimental version of Autoconf.  Be sure to
 186 read the relevant mailing lists, most importantly <autoconf@gnu.org>.
 187
 188 Below you will find information on the status of this version of Autoconf.
 189
 190
 191 EOF
 192     sed -n '/^\* Status/,$p' $srcdir/BUGS
 193 ])dnl