tests/semantics.at

   1 #                                                       -*- Autotest -*-
   2
   3 AT_BANNER([Semantics.])
   4
   5 # Copyright (C) 2000, 2001, 2002 Free Software Foundation, Inc.
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 # 02111-1307, USA.
  21
  22
  23 ## -------------------------------- ##
  24 ## Members of the AC_CHECK family.  ##
  25 ## -------------------------------- ##
  26
  27
  28 # AC_CHECK_LIB
  29 # ------------
  30 # Well, I can't imagine a system where `cos' is neither in libc, nor
  31 # in libm.  Nor can I imagine a lib more likely to exists than libm.
  32 # But there are systems without libm, on which we don't want to have
  33 # this test fail, so exit successfully if `cos' is in libc.
  34 AT_CHECK_MACRO([AC_CHECK_LIB],
  35 [AC_TRY_LINK_FUNC(cos,
  36                   [AC_MSG_ERROR([`cos' is in `libc'], 77)])
  37
  38 AC_CHECK_LIB(m, cos,,
  39              [AC_MSG_ERROR([cannot find `cos' in `libm'])])
  40
  41 # No kidding, using variables was broken in 2.50 :(
  42 ac_sin=sin
  43 AC_CHECK_LIB(m, $ac_sin,,
  44       [AC_MSG_ERROR([cannot find `\$ac_sin' (= `$ac_sin') in `libm'])])
  45
  46 ac_m=m
  47 AC_CHECK_LIB($ac_m, acos,,
  48       [AC_MSG_ERROR([cannot find `acos' in `\$ac_m' (= `$ac_m')])])
  49
  50 ac_asin=asin
  51 AC_CHECK_LIB($ac_m, $ac_asin,,
  52       [AC_MSG_ERROR([cannot find `\$ac_asin' (= `$ac_asin') in `\$ac_m' (= `$at_m')])])
  53
  54 # But if the bug is in the caching mechanism, then be sure we
  55 # correctly detect failures.
  56
  57 AC_CHECK_LIB(m, cossack,
  58              [AC_MSG_ERROR([found `cossack' in `libm'])])
  59
  60 # No kidding, using variables was broken in 2.50 :(
  61 ac_sinner=sinner
  62 AC_CHECK_LIB(m, $ac_sinner,
  63       [AC_MSG_ERROR([found `\$ac_sinner' (= `$ac_sinner') in `libm'])])
  64
  65 ac_m=m
  66 AC_CHECK_LIB($ac_m, acossack,
  67       [AC_MSG_ERROR([found `acossack' in `\$ac_m' (= `$ac_m')])])
  68
  69 ac_asinner=asinner
  70 AC_CHECK_LIB($ac_m, $ac_asinner,
  71       [AC_MSG_ERROR([found `\$ac_asinner' (= `$ac_asinner') in `\$ac_m' (= `$at_m')])])
  72
  73 ])
  74
  75
  76 # AC_SEARCH_LIBS
  77 # --------------
  78 AT_CHECK_MACRO([AC_SEARCH_LIBS],
  79 [
  80 AC_SEARCH_LIBS(cos, oser m ust,,
  81              [AC_MSG_ERROR([cannot find `cos'])])
  82
  83 case "$ac_cv_search_cos" in
  84   -loser|-lust) AC_MSG_ERROR([jeez, $ac_cv_search_cos must be a cool library!]) ;;
  85 esac
  86
  87 AC_SEARCH_LIBS(printf, oser c ust,,
  88              [AC_MSG_ERROR([cannot find `printf'])])
  89
  90 case "$ac_cv_search_printf" in
  91   -loser|-lust) AC_MSG_ERROR([jeez, $ac_cv_search_printf must be a cool library!]) ;;
  92   -lc) AC_MSG_ERROR([huh, you need to give -lc?])
  93 esac
  94
  95 ])
  96
  97
  98 # AC_CHECK_DECLS
  99 # --------------
 100 # Check that it performs the correct actions:
 101 # Must define NEED_NO_DECL, but not NEED_YES_DECL.
 102 AT_CHECK_MACRO([AC_CHECK_DECLS],
 103 [[AC_CHECK_DECLS([yes, no],,,
 104                  [int yes = 1;])]],
 105 [AT_CHECK_DEFINES(
 106 [#define HAVE_DECL_NO 0
 107 #define HAVE_DECL_YES 1
 108 ])])
 109
 110
 111 # AC_CHECK_FUNCS
 112 # --------------
 113 # Check that it performs the correct actions:
 114 # Must define HAVE_PRINTF, but not HAVE_AUTOCONF_FTNIRP
 115 AT_CHECK_MACRO([AC_CHECK_FUNCS],
 116 [AC_CHECK_FUNCS(printf autoconf_ftnirp)],
 117 [AT_CHECK_DEFINES(
 118 [/* #undef HAVE_AUTOCONF_FTNIRP */
 119 #define HAVE_PRINTF 1
 120 ])])
 121
 122
 123 # AC_REPLACE_FUNCS
 124 # ----------------
 125 # Check that it performs the correct actions: autoconf_ftnirp.c must
 126 # be compiled, and must define HAVE_PRINTF, but not HAVE_AUTOCONF_FTNIRP
 127 # FIXME: Maybe check the traces?
 128 AT_SETUP([AC_REPLACE_FUNCS])
 129
 130 AT_DATA([config.in],
 131 [@LIBOBJS@
 132 ])
 133
 134 AT_CONFIGURE_AC(
 135 [AC_CONFIG_FILES(config.libobjs:config.in)
 136 AC_REPLACE_FUNCS(printf autoconf_ftnirp)])
 137
 138 AT_CHECK_AUTOCONF([-W obsolete])
 139 AT_CHECK_AUTOHEADER
 140 AT_CHECK_CONFIGURE
 141 AT_CHECK_ENV
 142 AT_CHECK_DEFINES(
 143 [/* #undef HAVE_AUTOCONF_FTNIRP */
 144 #define HAVE_PRINTF 1
 145 ])
 146
 147 AT_CHECK([sed 's/  */ /g;s/^ //;s/ $//' config.libobjs], [],
 148          [autoconf_ftnirp$U.o
 149 ])
 150
 151 AT_CLEANUP([config.libobjs])
 152
 153
 154 # AC_CHECK_HEADERS
 155 # ----------------
 156 # Check that it performs the correct actions:
 157 # Must define HAVE_STDIO_H, but not HAVE_AUTOCONF_IO_H.
 158 AT_CHECK_MACRO([AC_CHECK_HEADERS],
 159 [AC_CHECK_HEADERS(stdio.h autoconf_io.h)],
 160 [AT_CHECK_DEFINES(
 161 [/* #undef HAVE_AUTOCONF_IO_H */
 162 #define HAVE_STDIO_H 1
 163 ])])
 164
 165
 166 # AC_CHECK_HEADERS_OLD
 167 # --------------------
 168 # Check that it performs the correct actions:
 169 # Must not check prerequisites, hence define header2.h
 170 AT_SETUP([AC_CHECK_HEADERS_OLD])
 171
 172 AT_DATA([header1.h],
 173 [typedef int foo;
 174 ])
 175
 176 AT_DATA([header2.h],
 177 [typedef foo bar;
 178 ])
 179
 180 AT_CONFIGURE_AC(
 181 [CPPFLAGS="$CPPFLAGS -I."
 182 AC_CHECK_HEADERS(header2.h, [], [], -)])
 183
 184 AT_CHECK_AUTOCONF([-W obsolete])
 185 AT_CHECK_AUTOHEADER
 186 AT_CHECK_CONFIGURE
 187 AT_CHECK_ENV
 188 AT_CHECK_DEFINES(
 189 [#define HAVE_HEADER2_H 1
 190 ])
 191
 192 AT_CLEANUP([header1.h header2.h])
 193
 194
 195 # AC_CHECK_HEADERS_NEW
 196 # --------------------
 197 # Check that it performs the correct actions:
 198 # Must check prerequisites, hence define header2.h but not header3.h
 199 AT_SETUP([AC_CHECK_HEADERS_NEW])
 200
 201 AT_DATA([header1.h],
 202 [typedef int foo;
 203 ])
 204
 205 AT_DATA([header2.h],
 206 [typedef foo bar;
 207 ])
 208
 209 AT_DATA([header3.h],
 210 [typedef bar wow;
 211 ])
 212
 213 AT_CONFIGURE_AC(
 214 [CPPFLAGS="$CPPFLAGS -I."
 215 AC_CHECK_HEADERS(header2.h header3.h, [], [], [[@%:@include "header1.h"]])])
 216
 217 AT_CHECK_AUTOCONF([-W obsolete])
 218 AT_CHECK_AUTOHEADER
 219 AT_CHECK_CONFIGURE
 220 AT_CHECK_ENV
 221 AT_CHECK_DEFINES(
 222 [#define HAVE_HEADER2_H 1
 223 /* #undef HAVE_HEADER3_H */
 224 ])
 225
 226 AT_CLEANUP([header1.h header2.h header3.h])
 227
 228
 229 # AC_CHECK_MEMBERS
 230 # ----------------
 231 # Check that it performs the correct actions.
 232 # Must define HAVE_STRUCT_YES_S_YES, but not HAVE_STRUCT_YES_S_NO.
 233 AT_CHECK_MACRO([AC_CHECK_MEMBERS],
 234 [[AC_CHECK_MEMBERS([struct yes_s.yes, struct yes_s.no],,,
 235                    [struct yes_s { int yes ;} ;])]],
 236 [AT_CHECK_DEFINES(
 237 [/* #undef HAVE_STRUCT_YES_S_NO */
 238 #define HAVE_STRUCT_YES_S_YES 1
 239 ])])
 240
 241
 242 # AC_CHECK_SIZEOF
 243 # ---------------
 244 # Not cross-compiling.
 245 AT_CHECK_MACRO([AC_CHECK_SIZEOF],
 246 [[AC_CHECK_SIZEOF(char)
 247 AC_CHECK_SIZEOF(charchar,,
 248 [[#include <stdio.h>
 249 typedef char charchar[2];]])
 250 AC_CHECK_SIZEOF(charcharchar)
 251 ]],
 252 [AT_CHECK_DEFINES(
 253 [#define SIZEOF_CHAR 1
 254 #define SIZEOF_CHARCHAR 2
 255 #define SIZEOF_CHARCHARCHAR 0
 256 ])])
 257
 258
 259 # AC_CHECK_SIZEOF
 260 # ---------------
 261 AT_CHECK_MACRO([AC_CHECK_SIZEOF],
 262 [[# Exercise the code used when cross-compiling
 263 cross_compiling=yes
 264 AC_CHECK_SIZEOF(char)
 265 AC_CHECK_SIZEOF(charchar,,
 266 [[#include <stdio.h>
 267 typedef char charchar[2];]])
 268 AC_CHECK_SIZEOF(charcharchar)
 269 ]],
 270 [AT_CHECK_DEFINES(
 271 [#define SIZEOF_CHAR 1
 272 #define SIZEOF_CHARCHAR 2
 273 #define SIZEOF_CHARCHARCHAR 0
 274 ])])
 275
 276
 277 # AC_CHECK_TYPES
 278 # --------------
 279 # Check that it performs the correct actions.
 280 # Must define HAVE_STRUCT_YES_S, HAVE_INT, but not HAVE_STRUCT_NO_S.
 281 # `int' and `struct yes_s' are both checked to test both the compiler
 282 # builtin types, and defined types.
 283 AT_CHECK_MACRO([AC_CHECK_TYPES],
 284 [[AC_CHECK_TYPES([int, struct yes_s, struct no_s],,,
 285                  [struct yes_s { int yes ;} ;])]],
 286 [AT_CHECK_DEFINES(
 287 [#define HAVE_INT 1
 288 /* #undef HAVE_STRUCT_NO_S */
 289 #define HAVE_STRUCT_YES_S 1
 290 ])])
 291
 292
 293 # AC_CHECK_TYPES
 294 # --------------
 295 # Check that we properly dispatch properly to the old implementation
 296 # or to the new one.
 297 AT_SETUP([AC_CHECK_TYPES: backward compatibility])
 298
 299 AT_DATA([configure.ac],
 300 [[AC_INIT
 301 define([_AC_CHECK_TYPE_NEW], [NEW])
 302 define([_AC_CHECK_TYPE_OLD], [OLD])
 303 #(cut-from-here
 304 AC_CHECK_TYPE(ptrdiff_t)
 305 AC_CHECK_TYPE(ptrdiff_t, int)
 306 AC_CHECK_TYPE(quad, long long)
 307 AC_CHECK_TYPE(table_42, [int[42]])
 308 # Nice machine!
 309 AC_CHECK_TYPE(uint8_t, uint65536_t)
 310 AC_CHECK_TYPE(a,b,c,d)
 311 #to-here)
 312 AC_OUTPUT
 313 ]])
 314
 315 AT_CHECK_AUTOCONF
 316 AT_CHECK([[sed -e '/^#(cut-from-here/,/^#to-here)/!d' -e '/^#/d' configure]],
 317          0,
 318          [NEW
 319 OLD
 320 OLD
 321 OLD
 322 OLD
 323 NEW
 324 ])
 325
 326 AT_CLEANUP
 327
 328
 329 # AC_CHECK_FILES
 330 # --------------
 331 # FIXME: To really test HAVE_AC_EXISTS2 and HAVE_AC_MISSING2 we need to
 332 # open AH_TEMPLATE to `configure.ac', which is not yet the case.
 333 AT_CHECK_MACRO([AC_CHECK_FILES],
 334 [touch at-exists1 at-exists2
 335 ac_exists2=at-exists2
 336 ac_missing2=at-missing2
 337 AC_CHECK_FILES(at-exists1 at-missing1 $ac_exists2 $ac_missing2)
 338 rm at-exists1 at-exists2],
 339 [AT_CHECK_DEFINES(
 340 [#define HAVE_AT_EXISTS1 1
 341 /* #undef HAVE_AT_MISSING1 */
 342 ])])
 343
 344
 345
 346 ## ------------------------------ ##
 347 ## AC_CHECK_PROG & AC_PATH_PROG.  ##
 348 ## ------------------------------ ##
 349
 350
 351 # AT_CHECK_PROGS_PREPARE
 352 # ----------------------
 353 # Create a sub directory `path' with 6 subdirs which all 7 contain
 354 # an executable `tool'. `6' contains a `better' tool.
 355 m4_define([AT_CHECK_PROGS_PREPARE],
 356 [mkdir path
 357
 358 cat >path/tool <<\EOF
 359 #! /bin/sh
 360 exit 0
 361 EOF
 362 chmod +x path/tool
 363
 364 for i in 1 2 3 4 5 6
 365 do
 366   mkdir path/$i
 367   cp path/tool path/$i
 368 done
 369 cp path/tool path/6/better])
 370
 371
 372 # -------------------------------- #
 373 # AC_CHECK_PROG & AC_CHECK_PROGS.  #
 374 # -------------------------------- #
 375
 376 AT_SETUP([AC_CHECK_PROG & AC_CHECK_PROGS])
 377
 378 AT_CHECK_PROGS_PREPARE
 379
 380 AT_DATA([configure.ac],
 381 [[AC_INIT
 382 pwd=`pwd`
 383 p="1${PATH_SEPARATOR}2${PATH_SEPARATOR}3${PATH_SEPARATOR}4${PATH_SEPARATOR}5${PATH_SEPARATOR}6"
 384 path=`echo $p | sed -e 's,\([[0-9]]\),'"$pwd"'/path/\1,g'`
 385 fail=false
 386
 387 AC_CHECK_PROG(TOOL1, tool, found, not-found, $path)
 388 test "$TOOL1" = found || fail=:
 389
 390 # Yes, the semantics of this macro is weird.
 391 AC_CHECK_PROG(TOOL2, tool,, not-found, $path)
 392 test "$TOOL2" = not-found || fail=:
 393
 394 AC_CHECK_PROG(TOOL3, tool, tool, not-found, $path, $pwd/path/1/tool)
 395 test "$TOOL3" = $pwd/path/2/tool || fail=:
 396
 397 AC_CHECK_PROG(TOOL4, better, better, not-found, $path, $pwd/path/1/tool)
 398 test "$TOOL4" = better || fail=:
 399
 400 # When a tool is not found, and no value is given for not-found,
 401 # the variable is left empty.
 402 AC_CHECK_PROGS(TOOL5, missing,, $path)
 403 test -z "$TOOL5" || fail=:
 404
 405 AC_CHECK_PROGS(TOOL6, missing tool better,, $path)
 406 test "$TOOL6" = tool || fail=:
 407
 408 # No AC-OUTPUT, we don't need config.status.
 409 $fail &&
 410   AC_MSG_ERROR([[CHECK_PROG failed]])
 411 AS_EXIT(0)
 412 ]])
 413
 414 AT_CHECK_AUTOCONF
 415 AT_CHECK_CONFIGURE
 416
 417 AT_CLEANUP(path)
 418
 419
 420
 421 ## ---------------- ##
 422 ## AC_C_BIGENDIAN.  ##
 423 ## ---------------- ##
 424
 425 AT_SETUP([[AC_C_BIGENDIAN]])
 426 AT_KEYWORDS([cross])
 427
 428 # Make sure that AC_C_BIGENDIAN behave the same whether we are
 429 # cross-compiling or not.
 430
 431 _AT_CHECK_AC_MACRO(
 432   [AC_C_BIGENDIAN([ac_endian=big],[ac_endian=little],[ac_endian=unknown])
 433    echo $ac_endian > at-endian
 434 ])
 435
 436 rm -f config.hin  # So that next run of autoheader is quiet.
 437 _AT_CHECK_AC_MACRO(
 438   [cross_compiling=yes
 439    AC_C_BIGENDIAN([ac_endian=big],[ac_endian=little],[ac_endian=unknown])
 440    ac_prevendian=`cat at-endian`
 441    # Check that we have found the same result as in the previous run
 442    # or unknown (because the cross-compiling check is allowed to fail;
 443    # although it might be interesting to suppress this comparison, just
 444    # to know on which system it fails if it ever does).
 445    if test $ac_endian != $ac_prevendian && test $ac_endian != unknown; then
 446      AC_MSG_ERROR([unexpected endianness: first run found '$ac_prevendian' but second run found '$ac_endian'])
 447    fi
 448 ])
 449
 450 # Make sure AC_C_BIGENDIAN with no argument will define WORDS_BIGENDIAN
 451 AT_CONFIGURE_AC([AC_C_BIGENDIAN])
 452 AT_CHECK_AUTOHEADER
 453 AT_CHECK([grep WORDS_BIGENDIAN config.hin], [], [ignore])
 454
 455 AT_CLEANUP(at-endian)
 456
 457
 458 # ------------------------------ #
 459 # AC_PATH_PROG & AC_PATH_PROGS.  #
 460 # ------------------------------ #
 461
 462 AT_SETUP([[AC_PATH_PROG & AC_PATH_PROGS]])
 463
 464 AT_CHECK_PROGS_PREPARE
 465
 466 AT_DATA([configure.ac],
 467 [[AC_INIT
 468 pwd=`pwd`
 469 p="1${PATH_SEPARATOR}2${PATH_SEPARATOR}3${PATH_SEPARATOR}4${PATH_SEPARATOR}5${PATH_SEPARATOR}6"
 470 path=`echo $p | sed -e 's,\([[0-9]]\),'"$pwd"'/path/\1,g'`
 471 fail=false
 472
 473 AC_PATH_PROG(TOOL1, tool, not-found, $path)
 474 test "$TOOL1" = $pwd/path/1/tool || fail=:
 475
 476 AC_PATH_PROG(TOOL2, better, not-found, $path)
 477 test "$TOOL2" = $pwd/path/6/better || fail=:
 478
 479 # When a tool is not found, and no value is given for not-found,
 480 # the variable is left empty.
 481 AC_PATH_PROGS(TOOL3, missing,, $path)
 482 test -z "$TOOL3" || fail=:
 483
 484 AC_PATH_PROGS(TOOL4, missing tool better,, $path)
 485 test "$TOOL4" = $pwd/path/1/tool || fail=:
 486
 487 # No AC-OUTPUT, we don't need config.status.
 488 $fail &&
 489   AC_MSG_ERROR([[PATH_PROG failed]])
 490 AS_EXIT(0)
 491 ]])
 492
 493 AT_CHECK_AUTOCONF
 494 AT_CHECK_CONFIGURE
 495
 496 AT_CLEANUP(path)
 497
 498
 499
 500
 501 ## -------------- ##
 502 ## AC_PATH_XTRA.  ##
 503 ## -------------- ##
 504
 505
 506 AT_SETUP([AC_PATH_XTRA])
 507
 508 _AT_CHECK_AC_MACRO([AC_PATH_XTRA])
 509
 510 # Check X_DISPLAY_MISSING.
 511 AT_CHECK_CONFIGURE([--without-x])
 512 AT_CHECK_DEFINES(
 513 [#define X_DISPLAY_MISSING 1
 514 ])
 515
 516 AT_CLEANUP
 517
 518
 519 ## ------------------------------- ##
 520 ## Obsolete non-updatable macros.  ##
 521 ## ------------------------------- ##
 522
 523
 524 AT_CHECK_MACRO([AC_SYS_RESTARTABLE_SYSCALLS], , ,[-W no-obsolete])
 525 AT_CHECK_MACRO([AC_FUNC_WAIT3], , ,[-W no-obsolete])