tests/base.at

   1 #                                                       -*- Autotest -*-
   2
   3 AT_BANNER([Autoconf base layer.])
   4
   5 # Copyright (C) 2000, 2001, 2003 Free Software Foundation, Inc.
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  20 # 02111-1307, USA.
  21
  22
  23 ## ------------------------------- ##
  24 ## AC_REQUIRE: topological sort..  ##
  25 ## ------------------------------- ##
  26
  27 # Check that dependencies are always properly honored.
  28
  29 AT_SETUP([AC_REQUIRE: topological sort])
  30
  31 AT_DATA([configure.ac],
  32 [[define([REQUIRE_AND_CHECK],
  33 [AC_REQUIRE([$1])
  34 test -z "$m4@&t@_translit([$1], [A-Z], [a-z])" && AS_EXIT(1)])
  35
  36 AC_DEFUN([TEST1],
  37 [REQUIRE_AND_CHECK([TEST2a])
  38 REQUIRE_AND_CHECK([TEST2b])
  39 test1=set])
  40
  41 AC_DEFUN([TEST2a],
  42 [test2a=set])
  43
  44 AC_DEFUN([TEST2b],
  45 [REQUIRE_AND_CHECK([TEST3])
  46 test2b=set])
  47
  48 AC_DEFUN([TEST3],
  49 [REQUIRE_AND_CHECK([TEST2a])
  50 test3=set])
  51
  52 AS@&t@_INIT
  53
  54 TEST1
  55 test -z "$test1" &&
  56   AC_MSG_ERROR([\$test1 is empty])
  57 AS_EXIT(0)
  58 ]])
  59
  60 AT_CHECK_AUTOCONF
  61 AT_CHECK_CONFIGURE
  62
  63 AT_CLEANUP
  64
  65
  66
  67 ## ----------------------------------------------- ##
  68 ## AC_REQUIRE and AC_DEFUN_ONCE: Require, expand.  ##
  69 ## ----------------------------------------------- ##
  70
  71 AT_SETUP([AC_REQUIRE & AC_DEFUN_ONCE: Require, expand])
  72
  73 AT_DATA([configure.ac],
  74 [[AC_DEFUN([TEST],
  75 [AC_REQUIRE([MULTI_TEST])
  76 AC_REQUIRE([SINGLE_TEST])])
  77
  78 AC_DEFUN([MULTI_TEST],
  79 [multi_test=".$multi_test"])
  80
  81 AC_DEFUN_ONCE([SINGLE_TEST],
  82 [single_test=".$single_test"])
  83
  84 AS@&t@_INIT
  85
  86 TEST
  87 TEST
  88 MULTI_TEST
  89 MULTI_TEST
  90 SINGLE_TEST
  91 SINGLE_TEST
  92
  93 case $multi_test:$single_test in
  94   ...:. ) AS_EXIT(0);;
  95   ...:* ) AC_MSG_ERROR([DEFUN_ONCE is broken]);;
  96   *:.   ) AC_MSG_ERROR([DEFUN is broken (Wow, congrats!)]);;
  97 esac
  98 ]])
  99
 100 AT_CHECK_AUTOCONF([], 0, [],
 101 [configure.ac:17: warning: SINGLE_TEST invoked multiple times
 102 configure.ac:18: warning: SINGLE_TEST invoked multiple times
 103 ])
 104
 105 AT_CHECK_CONFIGURE
 106
 107 AT_CLEANUP
 108
 109
 110
 111 ## ----------------------------------------------- ##
 112 ## AC_REQUIRE and AC_DEFUN_ONCE: Expand, require.  ##
 113 ## ----------------------------------------------- ##
 114
 115 AT_SETUP([AC_REQUIRE & AC_DEFUN_ONCE: Expand, require])
 116
 117 AT_DATA([configure.ac],
 118 [[AC_DEFUN([TEST],
 119 [AC_REQUIRE([MULTI_TEST])
 120 AC_REQUIRE([SINGLE_TEST])])
 121
 122 AC_DEFUN([MULTI_TEST],
 123 [multi_test=".$multi_test"])
 124
 125 AC_DEFUN_ONCE([SINGLE_TEST],
 126 [single_test=".$single_test"])
 127
 128 AS@&t@_INIT
 129
 130 MULTI_TEST
 131 MULTI_TEST
 132 SINGLE_TEST
 133 SINGLE_TEST
 134 TEST
 135 TEST
 136
 137 case $multi_test:$single_test in
 138   ..:. ) AS_EXIT(0);;
 139   ..:* ) AC_MSG_ERROR([DEFUN_ONCE is broken]);;
 140   *:.  ) AC_MSG_ERROR([DEFUN is broken (Wow, congrats!)]);;
 141      * ) AC_MSG_ERROR([received `$multi_test:$single_test']);;
 142 esac
 143 ]])
 144
 145 AT_CHECK_AUTOCONF([], 0, [],
 146 [configure.ac:16: warning: SINGLE_TEST invoked multiple times
 147 ])
 148 AT_CHECK_CONFIGURE
 149
 150 AT_CLEANUP
 151
 152
 153
 154 ## ------------------------- ##
 155 ## AC_REQUIRE & AC_PROVIDE.  ##
 156 ## ------------------------- ##
 157
 158 AT_SETUP([AC_REQUIRE & AC_PROVIDE])
 159
 160 AT_DATA([configure.ac],
 161 [[AC_DEFUN([TEST],
 162 [AC_REQUIRE([INNER_TEST])])
 163
 164 AC_DEFUN([INNER_TEST],
 165 [inner_test=".$inner_test"])
 166
 167 AS@&t@_INIT
 168
 169 AC_PROVIDE([INNER_TEST])
 170 TEST
 171
 172 case $inner_test in
 173   "" ) AS_EXIT(0);;
 174   *  ) AC_MSG_ERROR([received `$inner_test']);;
 175 esac
 176 ]])
 177
 178 AT_CHECK_AUTOCONF
 179 AT_CHECK_CONFIGURE
 180
 181 AT_CLEANUP
 182
 183
 184 ## ---------------- ##
 185 ## AC_CACHE_CHECK.  ##
 186 ## ---------------- ##
 187
 188 # Make sure AC_CACHE_CHECK is silent with -q.
 189
 190 AT_SETUP([AC_CACHE_CHECK])
 191
 192 AT_DATA([configure.ac],
 193 [[AC_INIT
 194 AC_CACHE_CHECK([for nothing],
 195                [ac_nothing],
 196                [ac_nothing=found])
 197 ]])
 198
 199 AT_CHECK_AUTOCONF
 200 AT_CHECK_CONFIGURE([-q])
 201
 202 AT_CLEANUP
 203
 204
 205 ## ---------------- ##
 206 ## AC_TRY_COMMAND.  ##
 207 ## ---------------- ##
 208
 209 AT_SETUP([AC_TRY_COMMAND])
 210
 211 AT_DATA([configure.ac],
 212 [[AC_INIT
 213
 214 if AC_TRY_COMMAND([(echo "The Cat in the Hat";
 215                     echo "The Hat in the Cat" >&2)
 216                   | grep \^The\ Cat\ in\ the\ Hat\$ >/dev/null]); then
 217   :
 218 else
 219   AC_MSG_ERROR([Didn't see the Cat in the Hat!])
 220 fi
 221
 222 if AC_TRY_COMMAND([(echo "The Cat in the Hat";
 223                     echo "The Hat in the Cat" >&2)
 224                   | grep \^The\ Hat\ in\ the\ Cat\$ >/dev/null]); then
 225   AC_MSG_ERROR([Saw the Hat in the Cat!])
 226 fi
 227 ]])
 228
 229 AT_CHECK_AUTOCONF
 230 AT_CHECK_CONFIGURE([-q])
 231
 232 AT_CLEANUP