tests/foreign.at

   1 #                                                       -*- Autotest -*-
   2
   3 AT_BANNER([Compatibility with other tools.])
   4
   5 # Copyright (C) 2000, 2001, 2002, 2003, 2004, 2005 Free Software
   6 # Foundation, Inc.
   7 #
   8 # This program is free software; you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 2, or (at your option)
  11 # any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program; if not, write to the Free Software
  20 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA
  21 # 02111-1307, USA.
  22
  23
  24 ## --------- ##
  25 ## Libtool.  ##
  26 ## --------- ##
  27
  28 AT_SETUP([Libtool])
  29
  30 # Skip this test if there is no libtoolize.
  31 AT_CHECK([libtoolize --version || exit 77],
  32          ignore, ignore, ignore)
  33 # CVS Autoconf probably does not work with too old Libtools.
  34 AT_CHECK([[
  35 case `libtoolize --version |
  36       sed -n '/^.* \([0-9][0-9.a-z]*\)$/{s//\1/;p;q;}'` in
  37   0.*          ) exit 77;;
  38   1.[0123]*    ) exit 77;;
  39 esac]],
  40          ignore, ignore, ignore)
  41
  42 # FIXME: Once Libtool `configure.ac' aware, change this.
  43 # Using a configure.in, have libtoolize confess where libtool.m4 is.
  44 AT_DATA([configure.in],
  45 [[AC_INIT
  46 # The other tests are relying on Autoconf's own copy of install-sh
  47 # etc. via AC_CONFIG_AUX_DIR(..).  Don't do that here, since we don't
  48 # want libtoolize to pollute Autoconf's srcdir.
  49 AC_CONFIG_AUX_DIR(.)
  50 AC_PROG_LIBTOOL
  51 ]])
  52 # Some libtoolize complain if you don't have an aclocal.m4.
  53 AT_CHECK([touch aclocal.m4])
  54 AT_CHECK([libtoolize], 0, [stdout], ignore)
  55
  56 # Some broken libtoolize fail to install a functional config.guess.
  57 AT_CHECK([./config.guess || exit 77], [], [ignore], [ignore])
  58
  59 # Make sure at-path contains something valid, and let the test suite
  60 # display it when verbose.  And fail, skipping would too easily hide
  61 # problems.
  62 AT_CHECK([sed -n ["s,^.*\`\\(/[^']*\\)'.*,\\1,p"] stdout], 0, [stdout])
  63 AT_CHECK([test -f "`cat stdout`"])
  64
  65 # libtoolize installed everything but install-sh...
  66 touch install-sh
  67
  68 # Build the concatenation of libtool.m4 and configure.ac.
  69 cp `cat stdout` configure.in
  70 cat >>configure.in <<_EOF
  71 AC_INIT
  72 AC_CONFIG_AUX_DIR(.)
  73 AC_CANONICAL_SYSTEM
  74 AC_PROG_LIBTOOL
  75 _EOF
  76
  77 # FIXME: Once Libtool really fixed, stop ignoring stderr.
  78 AT_CHECK_AUTOCONF([], [], [], [ignore])
  79
  80 # Ignore stderr, because ltconfig always loads the cache, which is
  81 # /dev/null, and some shells choke on this.  For instance with Bash
  82 # 2.05, you get:
  83 #
  84 #   loading cache /dev/null within ltconfig
  85 #   ./ltconfig: .: /dev/null: not a regular file
  86 #
  87 # But the script executes properly.
  88 AT_CHECK_CONFIGURE([], [], [], [ignore])
  89
  90 AT_CLEANUP(install-sh ltconfig libtool at-path ltmain.sh config.guess config.sub)