tests/compile.at

   1 #                                                       -*- Autotest -*-
   2
   3 AT_BANNER([Low level compiling/preprocessing macros.])
   4
   5 # Copyright (C) 2000, 2001, 2003, 2005, 2006, 2007, 2008, 2009, 2010
   6 # Free Software Foundation, Inc.
   7 #
   8 # This program is free software: you can redistribute it and/or modify
   9 # it under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation, either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # This program is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  20
  21
  22 # Since the macros which compile are required by most tests, check
  23 # them first.  But remember that looking for a compiler is even more
  24 # primitive, so check those first.
  25
  26
  27 ## ------------------------------------- ##
  28 ## AC_LANG, AC_LANG_PUSH & AC_LANG_POP.  ##
  29 ## ------------------------------------- ##
  30
  31 AT_SETUP([[AC_LANG, AC_LANG_PUSH & AC_LANG_POP]])
  32
  33 AT_DATA([configure.ac],
  34 [[AC_INIT
  35 # C
  36 AC_LANG([C])
  37 # C
  38 AC_LANG_PUSH([C])
  39 # C C
  40 AC_LANG_PUSH([C++])
  41 # C++ C C
  42 AC_LANG([C++])
  43 # C++ C C
  44 AC_LANG_PUSH([Erlang])
  45 # Erlang C++ C C
  46 AC_LANG_PUSH([Fortran 77])
  47 # F77 Erlang C++ C C
  48 AC_LANG_POP([Fortran 77])
  49 # Erlang C++ C C
  50 AC_LANG_POP([Erlang])
  51 # C++ C C
  52 AC_LANG([C++])
  53 # C++ C C
  54 AC_LANG_POP([C++])
  55 # C C
  56 AC_LANG_POP([C])
  57 # C
  58 ]])
  59
  60 AT_CHECK_AUTOCONF
  61 AT_CHECK([sed -n 's/^ac_ext=//p' configure], 0,
  62 [c
  63 c
  64 c
  65 cpp
  66 cpp
  67 erl
  68 f
  69 erl
  70 cpp
  71 cpp
  72 c
  73 c
  74 ])
  75
  76 AT_CLEANUP
  77
  78
  79 ## ---------------------- ##
  80 ## AC_REQUIRE & AC_LANG.  ##
  81 ## ---------------------- ##
  82
  83 AT_SETUP([AC_REQUIRE & AC_LANG])
  84
  85 AT_DATA([configure.ac],
  86 [[AC_DEFUN([AC_F77_1],
  87 [AC_LANG_PUSH([Fortran 77])
  88 if test $ac_ext != f; then
  89   AC_MSG_ERROR([F77_1: current shell language is $ac_ext, expected Fortran])
  90 fi
  91 AC_LANG_POP
  92 ])
  93
  94
  95 AC_DEFUN([AC_F77_2],
  96 [AC_LANG_PUSH([Fortran 77])
  97 AC_REQUIRE([AC_F77_1])
  98 if test $ac_ext != f; then
  99   AC_MSG_ERROR([F77_2: current shell language is $ac_ext, expected Fortran])
 100 fi
 101 AC_LANG_POP
 102 ])
 103
 104 AC_INIT
 105 AC_F77_2
 106 AS_EXIT(0)
 107 ]])
 108
 109 AT_CHECK_AUTOCONF
 110 AT_CHECK_CONFIGURE
 111
 112 AT_CLEANUP
 113
 114
 115 ## ---------------- ##
 116 ## AC_LANG_SOURCE.  ##
 117 ## ---------------- ##
 118
 119 AT_SETUP([AC_LANG_SOURCE])
 120
 121 AT_DATA([configure.ac],
 122 [[AC_INIT([pkg], [1.0])
 123 AC_PROG_CC
 124 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#ifndef PACKAGE_NAME
 125 choke me
 126 #endif
 127 int main ()
 128 {
 129   return 0;
 130 }
 131 ]], [], [AC_MSG_FAILURE([confdefs not included])])])
 132 ]])
 133
 134 AT_CHECK_AUTOCONF
 135 AT_CHECK_CONFIGURE
 136
 137 AT_CLEANUP
 138
 139
 140 ## --------------------- ##
 141 ## AC_LANG_SOURCE(C++).  ##
 142 ## --------------------- ##
 143
 144 AT_SETUP([AC_LANG_SOURCE(C++)])
 145
 146 AT_DATA([configure.ac],
 147 [[AC_INIT([pkg], [1.0])
 148 AC_PROG_CXX
 149 AC_LANG([C++])
 150 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[#ifndef PACKAGE_NAME
 151 choke me
 152 #endif
 153 int main ()
 154 {
 155   return 0;
 156 }
 157 ]], [], [AC_MSG_FAILURE([confdefs not included])])])
 158 ]])
 159
 160 AT_CHECK_AUTOCONF
 161 AT_CHECK_CONFIGURE
 162
 163 AT_CLEANUP
 164
 165
 166 ## ------------------------ ##
 167 ## AC_LANG_SOURCE example.  ##
 168 ## ------------------------ ##
 169
 170 AT_SETUP([AC_LANG_SOURCE example])
 171
 172 # Set CONFIG_SITE to a nonexistent file, so that there are
 173 # no worries about configure output caused by sourcing a config.site.
 174 CONFIG_SITE=no-such-file
 175 export CONFIG_SITE
 176
 177 AT_DATA([configure.ac],
 178 [[# Taken from autoconf.texi:Generating Sources.
 179 # The only change is to not fail if gcc doesn't work.
 180 AC_INIT([Hello], [1.0], [bug-hello@example.org], [],
 181         [http://www.example.org/])
 182 AC_DEFINE([HELLO_WORLD], ["Hello, World\n"],
 183   [Greetings string.])
 184 AC_LANG([C])
 185 AC_LANG_CONFTEST(
 186    [AC_LANG_SOURCE([[const char hw[] = "Hello, World\n";]])])
 187 gcc -E -dD conftest.c || AS_EXIT([77])
 188 ]])
 189
 190 AT_CHECK_AUTOCONF
 191 AT_CHECK_CONFIGURE([], [], [stdout])
 192 # Taken from autoconf.texi:Generating Sources.
 193 # Note that the output may contain more than one line matching
 194 #   # 1 "conftest.c"
 195 # so delete everything until the last one.
 196 AT_CHECK([sed  '1,/# 1 "conftest\.c"/d' stdout], [],
 197 [[
 198 #define PACKAGE_NAME "Hello"
 199 #define PACKAGE_TARNAME "hello"
 200 #define PACKAGE_VERSION "1.0"
 201 #define PACKAGE_STRING "Hello 1.0"
 202 #define PACKAGE_BUGREPORT "bug-hello@example.org"
 203 #define PACKAGE_URL "http://www.example.org/"
 204 #define HELLO_WORLD "Hello, World\n"
 205
 206 const char hw[] = "Hello, World\n";
 207 ]])
 208
 209 AT_CLEANUP
 210
 211
 212 ## ------------------------- ##
 213 ## AC_LANG_PROGRAM example.  ##
 214 ## ------------------------- ##
 215
 216 AT_SETUP([AC_LANG_PROGRAM example])
 217
 218 # Set CONFIG_SITE to a nonexistent file, so that there are
 219 # no worries about configure output caused by sourcing a config.site.
 220 CONFIG_SITE=no-such-file
 221 export CONFIG_SITE
 222
 223 AT_DATA([configure.ac],
 224 [[# Taken from autoconf.texi:Generating Sources.
 225 # The only change is to not fail if gcc doesn't work.
 226 AC_INIT([Hello], [1.0], [bug-hello@example.org], [],
 227         [http://www.example.org/])
 228 AC_DEFINE([HELLO_WORLD], ["Hello, World\n"],
 229   [Greetings string.])
 230 AC_LANG_CONFTEST(
 231 [AC_LANG_PROGRAM([[const char hw[] = "Hello, World\n";]],
 232                  [[fputs (hw, stdout);]])])
 233 gcc -E -dD conftest.c || AS_EXIT([77])
 234 ]])
 235
 236 AT_CHECK_AUTOCONF
 237 AT_CHECK_CONFIGURE([], [], [stdout])
 238 # Taken from autoconf.texi:Generating Sources.
 239 # Note that the output may contain more than one line matching
 240 #   # 1 "conftest.c"
 241 # so delete everything until the last one.
 242 AT_CHECK([sed  '1,/# 1 "conftest\.c"/d' stdout], [],
 243 [[
 244 #define PACKAGE_NAME "Hello"
 245 #define PACKAGE_TARNAME "hello"
 246 #define PACKAGE_VERSION "1.0"
 247 #define PACKAGE_STRING "Hello 1.0"
 248 #define PACKAGE_BUGREPORT "bug-hello@example.org"
 249 #define PACKAGE_URL "http://www.example.org/"
 250 #define HELLO_WORLD "Hello, World\n"
 251
 252 const char hw[] = "Hello, World\n";
 253 int
 254 main ()
 255 {
 256 fputs (hw, stdout);
 257   ;
 258   return 0;
 259 }
 260 ]])
 261
 262 AT_CLEANUP
 263
 264
 265 ## --------------- ##
 266 ## AC_RUN_IFELSE.  ##
 267 ## --------------- ##
 268
 269 AT_SETUP([AC_RUN_IFELSE])
 270
 271 AT_DATA([configure.ac],
 272 [[AC_INIT
 273
 274 AC_RUN_IFELSE([AC_LANG_PROGRAM([], [return 0])],
 275               [],
 276               [AC_MSG_ERROR([saw `return 0' as a failure])])
 277
 278 AC_RUN_IFELSE([AC_LANG_PROGRAM([], [return 2])],
 279               [AC_MSG_ERROR([saw `return 2' as a success])],
 280               [estatus=$?
 281 test $estatus != 2 &&
 282   AC_MSG_ERROR([did not get as 2 exit status: $estatus])])
 283
 284 # The old stinky one.
 285 AC_TRY_RUN([int main () { return 3; }],
 286            [AC_MSG_ERROR([saw `return 3' as a success])],
 287            [estatus=$?
 288 test $estatus != 3 &&
 289   AC_MSG_ERROR([did not get 3 as exit status: $estatus])])
 290
 291 ]])
 292
 293 AT_CHECK_AUTOCONF
 294 AT_CHECK_CONFIGURE([-q])
 295
 296 AT_CLEANUP
 297
 298 ## --------------------------  ##
 299 ## Order of `rm' and actions.  ##
 300 ## --------------------------  ##
 301
 302 AT_SETUP([Order of user actions and cleanup])
 303 AT_DATA([configure.ac],
 304 [[AC_INIT
 305 AC_PROG_CC
 306
 307 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([int grepme;], [])],
 308                   [{ test -f conftest.err && grep grepme conftest.i; } || AS_EXIT([1])],
 309                   [AS_EXIT([1])])
 310 AC_PREPROC_IFELSE([AC_LANG_PROGRAM([#define 12 34 /*], [])],
 311                   [AS_EXIT([1])],
 312                   [test -f conftest.err || AS_EXIT([1])])
 313
 314 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int ok;], [])],
 315                   [test -f conftest.$ac_objext || AS_EXIT([1])],
 316                   [AS_EXIT([1])])
 317 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([int bad bad;], [])],
 318                   [AS_EXIT([1])],
 319                   [test -f conftest.err || AS_EXIT([1])])
 320
 321 AC_LINK_IFELSE([AC_LANG_PROGRAM([int ok;], [])],
 322                [test -f conftest$ac_exeext || AS_EXIT([1])],
 323                [AS_EXIT([1])])
 324 AC_LINK_IFELSE([AC_LANG_PROGRAM([int bad bad;], [])],
 325                [AS_EXIT([1])],
 326                [test -f conftest.err || AS_EXIT([1])])
 327
 328 AC_RUN_IFELSE([AC_LANG_PROGRAM([int ok;], [])],
 329               [./conftest$ac_exeext || AS_EXIT([1])],
 330               [AS_EXIT([1])])
 331
 332 d@&t@nl conftest.err not generated by AC_RUN_IFELSE?
 333 AC_RUN_IFELSE([AC_LANG_PROGRAM([int bad bad;], [])],
 334               [AS_EXIT([1])],
 335               [])
 336 ]])
 337
 338 AT_CHECK_AUTOCONF
 339 AT_CHECK_CONFIGURE([-q])
 340
 341 AT_CLEANUP
 342
 343
 344 ## ------------------ ##
 345 ## AC_TRY_LINK_FUNC.  ##
 346 ## ------------------ ##
 347
 348 AT_CHECK_MACRO([AC_TRY_LINK_FUNC],
 349 [AC_TRY_LINK_FUNC(printf,,
 350                   [AC_MSG_ERROR([cannot find `printf'])])
 351 AC_TRY_LINK_FUNC(Be_doomed_if_your_libc_has_a_function_named_like_this,
 352                  [AC_MSG_ERROR([found a nonexistent function])])])
 353
 354 ## -------------------- ##
 355 ## Multiple languages.  ##
 356 ## -------------------- ##
 357
 358 AT_SETUP([Multiple languages])
 359
 360 # This test should be skipped if the C compiler is a C++ compiler.
 361 AT_DATA([configure.ac],
 362 [[AC_INIT
 363
 364 AC_PROG_CC
 365 AC_COMPILE_IFELSE([
 366   AC_LANG_PROGRAM([[
 367     #ifdef __cplusplus
 368     choke me
 369     #endif
 370   ]])], [], AS_EXIT([77]))
 371 ]])
 372
 373 AT_CHECK_AUTOCONF
 374 AT_CHECK_CONFIGURE
 375
 376 # This test should be skipped on systems without a C++ compiler.
 377 AT_DATA([configure.ac],
 378 [[AC_INIT
 379
 380 AC_PROG_CXX
 381 AC_LANG_PUSH([C++])
 382 AC_COMPILE_IFELSE([
 383   AC_LANG_PROGRAM([[
 384     #ifndef __cplusplus
 385     choke me
 386     #endif
 387   ]])], [], AS_EXIT([77]))
 388 AC_LANG_POP([C++])
 389 ]])
 390
 391 AT_CHECK_AUTOCONF
 392 AT_CHECK_CONFIGURE
 393
 394 AT_DATA([configure.ac],
 395 [[AC_INIT
 396
 397 AC_PROG_CC
 398 AC_PROG_CXX
 399
 400 AC_LANG_PUSH([C])
 401 AC_MSG_CHECKING([a simple C program that is not valid C++])
 402 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([enum a { A, B, C };
 403                                     enum a f(enum a in) { return in++; }], [])],
 404                   [AC_MSG_RESULT([ok])],
 405                   [AC_MSG_RESULT([failed])
 406                    AC_MSG_ERROR([could not compile test program])])
 407 AC_LANG_POP([C])
 408
 409 AC_LANG_PUSH([C++])
 410 AC_MSG_CHECKING([a simple C++ program that is not valid C])
 411 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([class A {};], [])],
 412                   [AC_MSG_RESULT([ok])],
 413                   [AC_MSG_RESULT([failed])
 414                    AC_MSG_ERROR([could not compile test program])])
 415
 416 AC_CHECK_HEADER([cstring])
 417 AC_LANG_POP([C++])
 418 ]])
 419
 420 AT_CHECK_AUTOCONF
 421 AT_CHECK_CONFIGURE([-q])
 422
 423 AT_CLEANUP
 424