m4/m4.m4

   1 # m4.m4 serial 11
   2
   3 # Copyright (C) 2000, 2006, 2007, 2008, 2009, 2010 Free Software
   4 # Foundation, Inc.
   5
   6 # Copying and distribution of this file, with or without modification,
   7 # are permitted in any medium without royalty provided the copyright
   8 # notice and this notice are preserved.  This file is offered as-is,
   9 # without warranty of any kind.
  10
  11 # AC_PROG_GNU_M4
  12 # --------------
  13 # Check for GNU M4, at least 1.4.6 (all earlier versions had bugs in
  14 # trace support and regexp support):
  15 # http://lists.gnu.org/archive/html/bug-gnu-utils/2006-11/msg00096.html
  16 # http://lists.gnu.org/archive/html/bug-autoconf/2009-07/msg00023.html
  17 # Also, check whether --error-output (through 1.4.x) or --debugfile (2.0)
  18 # is supported, and AC_SUBST M4_DEBUGFILE accordingly.
  19 AC_DEFUN([AC_PROG_GNU_M4],
  20   [AC_ARG_VAR([M4], [Location of GNU M4 1.4.6 or later.  Defaults to the first
  21     program of `m4', `gm4', or `gnum4' on PATH that meets Autoconf needs.])
  22   AC_CACHE_CHECK([for GNU M4 that supports accurate traces], [ac_cv_path_M4],
  23     [rm -f conftest.m4f
  24 ac_had_posixly_correct=${POSIXLY_CORRECT:+yes}
  25 AS_UNSET([POSIXLY_CORRECT])
  26 AC_PATH_PROGS_FEATURE_CHECK([M4], [m4 gm4 gnum4],
  27       [dnl Creative quoting here to avoid raw dnl and ifdef in configure.
  28       # Root out GNU M4 1.4.5, as well as non-GNU m4 that ignore -t, -F.
  29       ac_snippet=change'quote(<,>)in''dir(<if''def>,mac,bug)'
  30       ac_snippet=${ac_snippet}pat'subst(a,\(b\)\|\(a\),\1)d'nl
  31       test -z "`$ac_path_M4 -F conftest.m4f </dev/null 2>&1`" \
  32       && test -z "`AS_ECHO([$ac_snippet]) | $ac_path_M4 --trace=mac 2>&1`" \
  33       && test -f conftest.m4f \
  34       && ac_cv_path_M4=$ac_path_M4 ac_path_M4_found=:
  35       rm -f conftest.m4f],
  36       [AC_MSG_ERROR([no acceptable m4 could be found in \$PATH.
  37 GNU M4 1.4.6 or later is required; 1.4.14 is recommended])])])
  38   M4=$ac_cv_path_M4
  39   AC_CACHE_CHECK([whether $ac_cv_path_M4 accepts --gnu],
  40     [ac_cv_prog_gnu_m4_gnu],
  41     [case `$M4 --help < /dev/null 2>&1` in
  42       *--gnu*) ac_cv_prog_gnu_m4_gnu=yes ;;
  43       *) ac_cv_prog_gnu_m4_gnu=no ;;
  44     esac])
  45   if test "$ac_cv_prog_gnu_m4_gnu" = yes; then
  46     M4_GNU=--gnu
  47   else
  48     M4_GNU=
  49   fi
  50   AC_SUBST([M4_GNU])
  51   if test x$ac_had_posixly_correct = xyes; then
  52     POSIXLY_CORRECT=:
  53     if test $ac_cv_prog_gnu_m4_gnu = no; then
  54       AC_MSG_WARN([the version of M4 that was found does not support -g])
  55       AC_MSG_WARN([using it with POSIXLY_CORRECT set may cause problems])
  56     fi
  57   fi
  58   AC_CACHE_CHECK([how m4 supports trace files], [ac_cv_prog_gnu_m4_debugfile],
  59     [case `$M4 --help < /dev/null 2>&1` in
  60       *debugfile*) ac_cv_prog_gnu_m4_debugfile=--debugfile ;;
  61       *) ac_cv_prog_gnu_m4_debugfile=--error-output ;;
  62     esac])
  63   AC_SUBST([M4_DEBUGFILE], [$ac_cv_prog_gnu_m4_debugfile])
  64 ])
  65
  66 # Compatibility for bootstrapping with Autoconf 2.61.
  67 dnl FIXME - replace this with AC_PREREQ([2.62]) after the release.
  68 # AC_PATH_PROGS_FEATURE_CHECK was added the same time the slightly broken,
  69 # undocumented _AC_PATH_PROG_FEATURE_CHECK was deleted.
  70 m4_ifndef([AC_PATH_PROGS_FEATURE_CHECK],
  71   [m4_define([AC_PATH_PROGS_FEATURE_CHECK],
  72     [_AC_PATH_PROG_FEATURE_CHECK([$1], [$2], [$3], [$5])
  73 ])])