lib/autoconf/specific.m4

   1 # This file is part of Autoconf.                        -*- Autoconf -*-
   2 # Macros that test for specific, unclassified, features.
   3 #
   4 # Copyright (C) 1992, 1993, 1994, 1995, 1996, 1998, 1999, 2000, 2001,
   5 # 2002, 2003, 2004, 2005, 2006 Free Software Foundation, Inc.
   6 #
   7 # This program is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2, or (at your option)
  10 # any later version.
  11 #
  12 # This program is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA
  20 # 02110-1301, USA.
  21 #
  22 # As a special exception, the Free Software Foundation gives unlimited
  23 # permission to copy, distribute and modify the configure scripts that
  24 # are the output of Autoconf.  You need not follow the terms of the GNU
  25 # General Public License when using or distributing such scripts, even
  26 # though portions of the text of Autoconf appear in them.  The GNU
  27 # General Public License (GPL) does govern all other use of the material
  28 # that constitutes the Autoconf program.
  29 #
  30 # Certain portions of the Autoconf source text are designed to be copied
  31 # (in certain cases, depending on the input) into the output of
  32 # Autoconf.  We call these the "data" portions.  The rest of the Autoconf
  33 # source text consists of comments plus executable code that decides which
  34 # of the data portions to output in any given case.  We call these
  35 # comments and executable code the "non-data" portions.  Autoconf never
  36 # copies any of the non-data portions into its output.
  37 #
  38 # This special exception to the GPL applies to versions of Autoconf
  39 # released by the Free Software Foundation.  When you make and
  40 # distribute a modified version of Autoconf, you may extend this special
  41 # exception to the GPL to apply to your modified version as well, *unless*
  42 # your modified version has the potential to copy into its output some
  43 # of the text that was the non-data portion of the version that you started
  44 # with.  (In other words, unless your change moves or copies text from
  45 # the non-data portions to the data portions.)  If your modification has
  46 # such potential, you must delete any notice of this special exception
  47 # to the GPL from your modified version.
  48 #
  49 # Written by David MacKenzie, with help from
  50 # Franc,ois Pinard, Karl Berry, Richard Pixley, Ian Lance Taylor,
  51 # Roland McGrath, Noah Friedman, david d zuhn, and many others.
  52
  53
  54 ## ------------------------- ##
  55 ## Checks for declarations.  ##
  56 ## ------------------------- ##
  57
  58
  59 # AC_DECL_SYS_SIGLIST
  60 # -------------------
  61 AN_IDENTIFIER([sys_siglist],     [AC_CHECK_DECLS([sys_siglist])])
  62 AU_DEFUN([AC_DECL_SYS_SIGLIST],
  63 [AC_CHECK_DECLS([sys_siglist],,,
  64 [#include <signal.h>
  65 /* NetBSD declares sys_siglist in unistd.h.  */
  66 #ifdef HAVE_UNISTD_H
  67 # include <unistd.h>
  68 #endif
  69 ])
  70 ])# AC_DECL_SYS_SIGLIST
  71
  72
  73
  74
  75 ## -------------------------------------- ##
  76 ## Checks for operating system services.  ##
  77 ## -------------------------------------- ##
  78
  79
  80 # AC_SYS_INTERPRETER
  81 # ------------------
  82 AC_DEFUN([AC_SYS_INTERPRETER],
  83 [AC_CACHE_CHECK(whether @%:@! works in shell scripts, ac_cv_sys_interpreter,
  84 [echo '#! /bin/cat
  85 exit 69
  86 ' >conftest
  87 chmod u+x conftest
  88 (SHELL=/bin/sh; export SHELL; ./conftest >/dev/null 2>&1)
  89 if test $? -ne 69; then
  90    ac_cv_sys_interpreter=yes
  91 else
  92    ac_cv_sys_interpreter=no
  93 fi
  94 rm -f conftest])
  95 interpval=$ac_cv_sys_interpreter
  96 ])
  97
  98
  99 AU_DEFUN([AC_HAVE_POUNDBANG],
 100 [AC_SYS_INTERPRETER],
 101 [Remove this warning when you adjust your code to use
 102 `AC_SYS_INTERPRETER'.])
 103
 104
 105 AU_DEFUN([AC_ARG_ARRAY], [],
 106 [$0 is no longer implemented: don't do unportable things
 107 with arguments. Remove this warning when you adjust your code.])
 108
 109
 110 # _AC_SYS_LARGEFILE_TEST_INCLUDES
 111 # -------------------------------
 112 m4_define([_AC_SYS_LARGEFILE_TEST_INCLUDES],
 113 [@%:@include <sys/types.h>
 114  /* Check that off_t can represent 2**63 - 1 correctly.
 115     We can't simply define LARGE_OFF_T to be 9223372036854775807,
 116     since some C++ compilers masquerading as C compilers
 117     incorrectly reject 9223372036854775807.  */
 118 @%:@define LARGE_OFF_T (((off_t) 1 << 62) - 1 + ((off_t) 1 << 62))
 119   int off_t_is_large[[(LARGE_OFF_T % 2147483629 == 721
 120                        && LARGE_OFF_T % 2147483647 == 1)
 121                       ? 1 : -1]];[]dnl
 122 ])
 123
 124
 125 # _AC_SYS_LARGEFILE_MACRO_VALUE(C-MACRO, VALUE,
 126 #                               CACHE-VAR,
 127 #                               DESCRIPTION,
 128 #                               PROLOGUE, [FUNCTION-BODY])
 129 # ----------------------------------------------------------
 130 m4_define([_AC_SYS_LARGEFILE_MACRO_VALUE],
 131 [AC_CACHE_CHECK([for $1 value needed for large files], [$3],
 132 [while :; do
 133   $3=no
 134   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([$5], [$6])],
 135                     [break])
 136   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([@%:@define $1 $2
 137 $5], [$6])],
 138                     [$3=$2; break])
 139   break
 140 done])
 141 if test "$$3" != no; then
 142   AC_DEFINE_UNQUOTED([$1], [$$3], [$4])
 143 fi
 144 rm -f conftest*[]dnl
 145 ])# _AC_SYS_LARGEFILE_MACRO_VALUE
 146
 147
 148 # AC_SYS_LARGEFILE
 149 # ----------------
 150 # By default, many hosts won't let programs access large files;
 151 # one must use special compiler options to get large-file access to work.
 152 # For more details about this brain damage please see:
 153 # http://www.unix-systems.org/version2/whatsnew/lfs20mar.html
 154 AC_DEFUN([AC_SYS_LARGEFILE],
 155 [AC_ARG_ENABLE(largefile,
 156                [  --disable-largefile     omit support for large files])
 157 if test "$enable_largefile" != no; then
 158
 159   AC_CACHE_CHECK([for special C compiler options needed for large files],
 160     ac_cv_sys_largefile_CC,
 161     [ac_cv_sys_largefile_CC=no
 162      if test "$GCC" != yes; then
 163        ac_save_CC=$CC
 164        while :; do
 165          # IRIX 6.2 and later do not support large files by default,
 166          # so use the C compiler's -n32 option if that helps.
 167          AC_LANG_CONFTEST([AC_LANG_PROGRAM([_AC_SYS_LARGEFILE_TEST_INCLUDES])])
 168          AC_COMPILE_IFELSE([], [break])
 169          CC="$CC -n32"
 170          AC_COMPILE_IFELSE([], [ac_cv_sys_largefile_CC=' -n32'; break])
 171          break
 172        done
 173        CC=$ac_save_CC
 174        rm -f conftest.$ac_ext
 175     fi])
 176   if test "$ac_cv_sys_largefile_CC" != no; then
 177     CC=$CC$ac_cv_sys_largefile_CC
 178   fi
 179
 180   _AC_SYS_LARGEFILE_MACRO_VALUE(_FILE_OFFSET_BITS, 64,
 181     ac_cv_sys_file_offset_bits,
 182     [Number of bits in a file offset, on hosts where this is settable.],
 183     [_AC_SYS_LARGEFILE_TEST_INCLUDES])
 184   _AC_SYS_LARGEFILE_MACRO_VALUE(_LARGE_FILES, 1,
 185     ac_cv_sys_large_files,
 186     [Define for large files, on AIX-style hosts.],
 187     [_AC_SYS_LARGEFILE_TEST_INCLUDES])
 188 fi
 189 ])# AC_SYS_LARGEFILE
 190
 191
 192 # AC_SYS_LONG_FILE_NAMES
 193 # ----------------------
 194 # Security: use a temporary directory as the most portable way of
 195 # creating files in /tmp securely.  Removing them leaves a race
 196 # condition, set -C is not portably guaranteed to use O_EXCL, so still
 197 # leaves a race, and not all systems have the `mktemp' utility.  We
 198 # still test for existence first in case of broken systems where the
 199 # mkdir succeeds even when the directory exists.  Broken systems may
 200 # retain a race, but they probably have other security problems
 201 # anyway; this should be secure on well-behaved systems.  In any case,
 202 # use of `mktemp' is probably inappropriate here since it would fail in
 203 # attempting to create different file names differing after the 14th
 204 # character on file systems without long file names.
 205 AC_DEFUN([AC_SYS_LONG_FILE_NAMES],
 206 [AC_CACHE_CHECK(for long file names, ac_cv_sys_long_file_names,
 207 [ac_cv_sys_long_file_names=yes
 208 # Test for long file names in all the places we know might matter:
 209 #      .                the current directory, where building will happen
 210 #      $prefix/lib      where we will be installing things
 211 #      $exec_prefix/lib likewise
 212 #      $TMPDIR          if set, where it might want to write temporary files
 213 #      /tmp             where it might want to write temporary files
 214 #      /var/tmp         likewise
 215 #      /usr/tmp         likewise
 216 for ac_dir in . "$TMPDIR" /tmp /var/tmp /usr/tmp "$prefix/lib" "$exec_prefix/lib"; do
 217   # Skip $TMPDIR if it is empty or bogus, and skip $exec_prefix/lib
 218   # in the usual case where exec_prefix is '${prefix}'.
 219   case $ac_dir in #(
 220     . | /* | ?:[[\\/]]*) ;; #(
 221     *) continue;;
 222   esac
 223   test -w "$ac_dir/." || continue # It is less confusing to not echo anything here.
 224   ac_xdir=$ac_dir/cf$$
 225   (umask 077 && mkdir "$ac_xdir" 2>/dev/null) || continue
 226   ac_tf1=$ac_xdir/conftest9012345
 227   ac_tf2=$ac_xdir/conftest9012346
 228   touch "$ac_tf1" 2>/dev/null && test -f "$ac_tf1" && test ! -f "$ac_tf2" ||
 229     ac_cv_sys_long_file_names=no
 230   rm -f -r "$ac_xdir" 2>/dev/null
 231   test $ac_cv_sys_long_file_names = no && break
 232 done])
 233 if test $ac_cv_sys_long_file_names = yes; then
 234   AC_DEFINE(HAVE_LONG_FILE_NAMES, 1,
 235             [Define to 1 if you support file names longer than 14 characters.])
 236 fi
 237 ])
 238
 239
 240 # AC_SYS_RESTARTABLE_SYSCALLS
 241 # ---------------------------
 242 # If the system automatically restarts a system call that is
 243 # interrupted by a signal, define `HAVE_RESTARTABLE_SYSCALLS'.
 244 AC_DEFUN([AC_SYS_RESTARTABLE_SYSCALLS],
 245 [AC_DIAGNOSE([obsolete],
 246 [$0: AC_SYS_RESTARTABLE_SYSCALLS is useful only when supporting very
 247 old systems that lack `sigaction' and `SA_RESTART'.  Don't bother with
 248 this macro unless you need to support very old systems like 4.2BSD and
 249 SVR3.])dnl
 250 AC_REQUIRE([AC_HEADER_SYS_WAIT])dnl
 251 AC_CACHE_CHECK(for restartable system calls, ac_cv_sys_restartable_syscalls,
 252 [AC_RUN_IFELSE([AC_LANG_SOURCE(
 253 [/* Exit 0 (true) if wait returns something other than -1,
 254    i.e. the pid of the child, which means that wait was restarted
 255    after getting the signal.  */
 256
 257 AC_INCLUDES_DEFAULT
 258 #include <signal.h>
 259 #ifdef HAVE_SYS_WAIT_H
 260 # include <sys/wait.h>
 261 #endif
 262
 263 /* Some platforms explicitly require an extern "C" signal handler
 264    when using C++. */
 265 #ifdef __cplusplus
 266 extern "C" void ucatch (int dummy) { }
 267 #else
 268 void ucatch (dummy) int dummy; { }
 269 #endif
 270
 271 int
 272 main ()
 273 {
 274   int i = fork (), status;
 275
 276   if (i == 0)
 277     {
 278       sleep (3);
 279       kill (getppid (), SIGINT);
 280       sleep (3);
 281       return 0;
 282     }
 283
 284   signal (SIGINT, ucatch);
 285
 286   status = wait (&i);
 287   if (status == -1)
 288     wait (&i);
 289
 290   return status == -1;
 291 }])],
 292                [ac_cv_sys_restartable_syscalls=yes],
 293                [ac_cv_sys_restartable_syscalls=no])])
 294 if test $ac_cv_sys_restartable_syscalls = yes; then
 295   AC_DEFINE(HAVE_RESTARTABLE_SYSCALLS, 1,
 296             [Define to 1 if system calls automatically restart after
 297              interruption by a signal.])
 298 fi
 299 ])# AC_SYS_RESTARTABLE_SYSCALLS
 300
 301
 302 # AC_SYS_POSIX_TERMIOS
 303 # --------------------
 304 AC_DEFUN([AC_SYS_POSIX_TERMIOS],
 305 [AC_CACHE_CHECK([POSIX termios], ac_cv_sys_posix_termios,
 306 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
 307 #include <unistd.h>
 308 #include <termios.h>
 309 ]],
 310              [/* SunOS 4.0.3 has termios.h but not the library calls.  */
 311    tcgetattr(0, 0);])],
 312              ac_cv_sys_posix_termios=yes,
 313              ac_cv_sys_posix_termios=no)])
 314 ])# AC_SYS_POSIX_TERMIOS
 315
 316
 317
 318
 319 ## ------------------------------------ ##
 320 ## Checks for not-quite-Unix variants.  ##
 321 ## ------------------------------------ ##
 322
 323
 324 # AC_GNU_SOURCE
 325 # --------------
 326 AC_DEFUN([AC_GNU_SOURCE],
 327 [AH_VERBATIM([_GNU_SOURCE],
 328 [/* Enable GNU extensions on systems that have them.  */
 329 #ifndef _GNU_SOURCE
 330 # undef _GNU_SOURCE
 331 #endif])dnl
 332 AC_BEFORE([$0], [AC_COMPILE_IFELSE])dnl
 333 AC_BEFORE([$0], [AC_RUN_IFELSE])dnl
 334 AC_DEFINE([_GNU_SOURCE])
 335 ])
 336
 337
 338 # AC_CYGWIN
 339 # ---------
 340 # Check for Cygwin.  This is a way to set the right value for
 341 # EXEEXT.
 342 AU_DEFUN([AC_CYGWIN],
 343 [AC_CANONICAL_HOST
 344 case $host_os in
 345   *cygwin* ) CYGWIN=yes;;
 346          * ) CYGWIN=no;;
 347 esac
 348 ], [$0 is obsolete: use AC_CANONICAL_HOST and check if $host_os
 349 matches *cygwin*])# AC_CYGWIN
 350
 351
 352 # AC_EMXOS2
 353 # ---------
 354 # Check for EMX on OS/2.  This is another way to set the right value
 355 # for EXEEXT.
 356 AU_DEFUN([AC_EMXOS2],
 357 [AC_CANONICAL_HOST
 358 case $host_os in
 359   *emx* ) EMXOS2=yes;;
 360       * ) EMXOS2=no;;
 361 esac
 362 ], [$0 is obsolete: use AC_CANONICAL_HOST and check if $host_os
 363 matches *emx*])# AC_EMXOS2
 364
 365
 366 # AC_MINGW32
 367 # ----------
 368 # Check for mingw32.  This is another way to set the right value for
 369 # EXEEXT.
 370 AU_DEFUN([AC_MINGW32],
 371 [AC_CANONICAL_HOST
 372 case $host_os in
 373   *mingw32* ) MINGW32=yes;;
 374           * ) MINGW32=no;;
 375 esac
 376 ], [$0 is obsolete: use AC_CANONICAL_HOST and check if $host_os
 377 matches *mingw32*])# AC_MINGW32
 378
 379
 380 # AC_USE_SYSTEM_EXTENSIONS
 381 # ------------------------
 382 # Enable extensions on systems that normally disable them,
 383 # typically due to standards-conformance issues.
 384 AC_DEFUN([AC_USE_SYSTEM_EXTENSIONS],
 385 [
 386   AC_BEFORE([$0], [AC_COMPILE_IFELSE])
 387   AC_BEFORE([$0], [AC_RUN_IFELSE])
 388
 389   AC_REQUIRE([AC_GNU_SOURCE])
 390   AC_REQUIRE([AC_AIX])
 391   AC_REQUIRE([AC_MINIX])
 392
 393   AH_VERBATIM([__EXTENSIONS__],
 394 [/* Enable extensions on Solaris.  */
 395 #ifndef __EXTENSIONS__
 396 # undef __EXTENSIONS__
 397 #endif
 398 #ifndef _POSIX_PTHREAD_SEMANTICS
 399 # undef _POSIX_PTHREAD_SEMANTICS
 400 #endif])
 401   AC_CACHE_CHECK([whether it is safe to define __EXTENSIONS__],
 402     [ac_cv_safe_to_define___extensions__],
 403     [AC_COMPILE_IFELSE(
 404        [AC_LANG_PROGRAM([
 405 #         define __EXTENSIONS__ 1
 406           AC_INCLUDES_DEFAULT])],
 407        [ac_cv_safe_to_define___extensions__=yes],
 408        [ac_cv_safe_to_define___extensions__=no])])
 409   test $ac_cv_safe_to_define___extensions__ = yes &&
 410     AC_DEFINE([__EXTENSIONS__])
 411   AC_DEFINE([_POSIX_PTHREAD_SEMANTICS])
 412 ])
 413
 414
 415
 416
 417 ## -------------------------- ##
 418 ## Checks for UNIX variants.  ##
 419 ## -------------------------- ##
 420
 421
 422 # These are kludges which should be replaced by a single POSIX check.
 423 # They aren't cached, to discourage their use.
 424
 425 # AC_AIX
 426 # ------
 427 AC_DEFUN([AC_AIX],
 428 [AH_VERBATIM([_ALL_SOURCE],
 429 [/* Define to 1 if on AIX 3.
 430    System headers sometimes define this.
 431    We just want to avoid a redefinition error message.  */
 432 @%:@ifndef _ALL_SOURCE
 433 @%:@ undef _ALL_SOURCE
 434 @%:@endif])dnl
 435 AC_BEFORE([$0], [AC_COMPILE_IFELSE])dnl
 436 AC_BEFORE([$0], [AC_RUN_IFELSE])dnl
 437 AC_MSG_CHECKING([for AIX])
 438 AC_EGREP_CPP(yes,
 439 [#ifdef _AIX
 440   yes
 441 #endif
 442 ],
 443 [AC_MSG_RESULT([yes])
 444 AC_DEFINE(_ALL_SOURCE)],
 445 [AC_MSG_RESULT([no])])
 446 ])# AC_AIX
 447
 448
 449 # AC_MINIX
 450 # --------
 451 AC_DEFUN([AC_MINIX],
 452 [AC_BEFORE([$0], [AC_COMPILE_IFELSE])dnl
 453 AC_BEFORE([$0], [AC_RUN_IFELSE])dnl
 454 AC_CHECK_HEADER(minix/config.h, MINIX=yes, MINIX=)
 455 if test "$MINIX" = yes; then
 456   AC_DEFINE(_POSIX_SOURCE, 1,
 457             [Define to 1 if you need to in order for `stat' and other things to
 458              work.])
 459   AC_DEFINE(_POSIX_1_SOURCE, 2,
 460             [Define to 2 if the system does not provide POSIX.1 features except
 461              with this defined.])
 462   AC_DEFINE(_MINIX, 1,
 463             [Define to 1 if on MINIX.])
 464 fi
 465 ])# AC_MINIX
 466
 467
 468 # AC_ISC_POSIX
 469 # ------------
 470 AC_DEFUN([AC_ISC_POSIX], [AC_SEARCH_LIBS(strerror, cposix)])
 471
 472
 473 # AC_XENIX_DIR
 474 # ------------
 475 AU_DEFUN([AC_XENIX_DIR],
 476 [AC_MSG_CHECKING([for Xenix])
 477 AC_EGREP_CPP(yes,
 478 [#if defined M_XENIX && ! defined M_UNIX
 479   yes
 480 @%:@endif],
 481              [AC_MSG_RESULT([yes]); XENIX=yes],
 482              [AC_MSG_RESULT([no]); XENIX=])
 483
 484 AC_HEADER_DIRENT[]dnl
 485 ],
 486 [You shouldn't need to depend upon XENIX.  Remove the
 487 `AC_MSG_CHECKING', `AC_EGREP_CPP', and this warning if this part
 488 of the test is useless.])
 489
 490
 491 # AC_DYNIX_SEQ
 492 # ------------
 493 AU_DEFUN([AC_DYNIX_SEQ], [AC_FUNC_GETMNTENT])
 494
 495
 496 # AC_IRIX_SUN
 497 # -----------
 498 AU_DEFUN([AC_IRIX_SUN],
 499 [AC_FUNC_GETMNTENT
 500 AC_CHECK_LIB(sun, getpwnam)])
 501
 502
 503 # AC_SCO_INTL
 504 # -----------
 505 AU_DEFUN([AC_SCO_INTL], [AC_FUNC_STRFTIME])