icecat/PKGBUILD

   1 # Maintainer: Figue <ffigue at gmail>
   2 # Contributor: Figue <ffigue at gmail>
   3 # Contributor (Parabola): fauno <fauno@kiwwwi.com.ar>
   4 # Thank you very much to the older contributors:
   5 # Contributor: evr <evanroman at gmail>
   6 # Contributor: Muhammad 'MJ' Jassim <UnbreakableMJ@gmail.com>
   7
   8 pkgname=icecat
   9 pkgver=9.0.1
  10 pkgrel=1
  11 pkgdesc="GNU version of the Firefox browser"
  12 arch=(i686 x86_64)
  13 url="http://www.gnu.org/software/gnuzilla/"
  14 license=('GPL' 'MPL' 'LGPL')
  15 depends=('gtk2' 'gcc-libs' 'libidl2' 'mozilla-common' 'nss>=3.12.10' 'libxt'
  16          'libxrender' 'hunspell' 'startup-notification' 'mime-types' 'dbus-glib'
  17          'alsa-lib' 'libevent' 'sqlite3>=3.7.4' 'libnotify' 'desktop-file-utils'
  18          'libvpx' 'lcms' 'nspr>=4.8.8' 'libevent' 'libpng' 'cairo')
  19 makedepends=('zip' 'pkg-config' 'diffutils' 'python2' 'wireless_tools'
  20              'yasm' 'mesa' 'autoconf2.13' 'gconf' 'xorg-server-xvfb')
  21 install=icecat.install
  22 source=(http://ftp.gnu.org/gnu/gnuzilla/${pkgver}/${pkgname}-${pkgver}.tar.xz
  23         mozconfig
  24         icecat.desktop
  25         icecat-safe.desktop
  26         mozilla-firefox-1.0-lang.patch)
  27
  28 build() {
  29
  30   ICECATDIR="/usr/lib/${pkgname}-${pkgver}" && export ICECATDIR
  31
  32   msg2 "Patching some files..."
  33   cd "${srcdir}/${pkgname}-${pkgver}/"
  34   patch -Np1 -i "${srcdir}/mozilla-firefox-1.0-lang.patch"
  35
  36   msg2 "Starting build..."
  37   cp "${srcdir}/mozconfig" .mozconfig
  38
  39   # Kill @PRE_RELEASE_SUFFIX@ from browser.xul because it
  40   # gets set to \177 for an unknown reason
  41   sed -i 's/@PRE_RELEASE_SUFFIX@//g' \
  42       browser/base/content/browser.xul
  43
  44   export LDFLAGS="-Wl,-rpath,${ICECATDIR} -Wl,-O1,--sort-common,--hash-style=gnu,--as-needed"
  45   export PYTHON="/usr/bin/python2"
  46
  47   # PGO
  48   sed -i '/^NO_PROFILE_GUIDED_OPTIMIZE = 1$/d' \
  49     memory/jemalloc/Makefile.in
  50   echo 'LDFLAGS += -lX11 -lXrender' \
  51     >> layout/build/Makefile.in
  52
  53   LD_PRELOAD="" /usr/bin/Xvfb -nolisten tcp -extension GLX -screen 0 1280x1024x24 :99 &
  54   LD_PRELOAD="" DISPLAY=:99 make -j1 -f client.mk profiledbuild MOZ_MAKE_FLAGS="$MAKEFLAGS"
  55   kill $! || true
  56 }
  57
  58 package () {
  59
  60   cd "${srcdir}/${pkgname}-${pkgver}/"
  61   make -j1 -f client.mk DESTDIR="$pkgdir" install
  62
  63   msg2 "Finishing..."
  64   install -m755 -d ${pkgdir}/usr/share/applications
  65   install -m755 -d ${pkgdir}/usr/share/pixmaps
  66   install -m644 ${srcdir}/${pkgname}-${pkgver}/browser/branding/unofficial/default48.png ${pkgdir}/usr/share/pixmaps/icecat.png
  67   install -m644 ${srcdir}/icecat.desktop ${pkgdir}/usr/share/applications/
  68   install -m644 ${srcdir}/icecat-safe.desktop ${pkgdir}/usr/share/applications/
  69
  70   cd ${pkgdir}/usr/lib
  71   ln -s ${ICECATDIR} icecat
  72
  73   # Remove included dictionaries, add symlink to system myspell path
  74   # Note: this will cause file conflicts when users have installed dictionaries in the old location
  75   #rm -rf "${pkgdir}/usr/lib/firefox-$pkgver/dictionaries"
  76   #ln -sf /usr/share/myspell/dicts \
  77   #  "${pkgdir}/usr/lib/firefox-$pkgver/dictionaries"
  78
  79   # We don't want the development stuff
  80   rm -r "$pkgdir"/usr/{include,lib/icecat-devel-$pkgver,share/idl}
  81 }
  82
  83 md5sums=('a135581da2fd2845f268d7ca91054c06'
  84          'ebfc16ffcf5f7c5c11d6d5c7c3ef73e8'
  85          'e81ad01dbc16ba28bf92ba4b7c309ca7'
  86          'd93fe402b87cd000a869e1fd6badc6c9'
  87          'bd5db57c23c72a02a489592644f18995')