exaile/PKGBUILD

   1 # $Id: PKGBUILD 54170 2011-08-14 09:26:12Z jelle $
   2 # Contributor: Roman Kyrylych <Roman.Kyrylych@gmail.com>
   3 # Contributor: Benjamin Wild <benwild@gmx.de>
   4 # Maintainer: Daniel J Griffiths <ghost1227@archlinux.us>
   5
   6 pkgname=exaile
   7 pkgver=0.3.2.2
   8 pkgrel=3
   9 pkgdesc="A full-featured media player for GTK+"
  10 arch=('any')
  11 url="http://www.exaile.org"
  12 license=('GPL')
  13 depends=('python2'
  14          'gstreamer0.10-python'
  15          'gstreamer0.10-good-plugins'
  16          'mutagen'
  17          'dbus-python'
  18          'pygtk>=2.10'
  19          'librsvg')
  20 makedepends=('make' 'help2man')
  21 optdepends=('pycddb: CD metadata retrieval'
  22             'python2-bsddb: music collection support'
  23             'gstreamer0.10-bad-plugins: support for more formats'
  24             'gstreamer0.10-ugly-plugins: support for more formats'
  25             'gstreamer0.10-ffmpeg: support for more formats' )
  26 source=(https://www.launchpad.net/exaile/${pkgver%.*}/${pkgver}/+download/exaile-${pkgver}.tar.gz)
  27 install=$pkgname.install
  28
  29 build() {
  30   cd "${srcdir}/${pkgname}-${pkgver}"
  31
  32     # python2 fix
  33     for file in $(find . -name Makefile -print) tools/generate-launcher; do
  34         sed -i 's_python_python2_' $file
  35     done
  36     for file in plugins/*/*.py exaile.py; do
  37         sed -i 's_#!/usr/bin/env python_#!/usr/bin/env python2_' $file
  38         sed -i 's_#!/usr/bin/python_#!/usr/bin/python2_' $file
  39     done
  40
  41         make
  42 }
  43
  44 package() {
  45         cd "${srcdir}/${pkgname}-${pkgver}"
  46         make PREFIX=/usr DESTDIR="${pkgdir}" install
  47
  48         # fix for clicking files with spaces in names from nautilus
  49         sed -i "s#%u#%f#" "${pkgdir}/usr/share/applications/exaile.desktop"
  50 }
  51 md5sums=('b3fd87e40af6592df0b511183ca49408')