gwaei/PKGBUILD

   1 # Maintainer:  TDY <tdy@gmx.com>
   2 # Contributor: lswest <lswest34 : gmail>
   3 # Contributor: Christoph Zeiler <rabyte : gmail>
   4
   5 pkgname=gwaei
   6 pkgver=1.5.2
   7 pkgrel=1
   8 pkgdesc="A Japanese-English dictionary program"
   9 arch=('i686' 'x86_64')
  10 url="http://gwaei.sourceforge.net/"
  11 license=('GPL3')
  12 depends=('curl>=7.19.6' 'gconf>=2.24.0' 'hicolor-icon-theme' 'libsexy>=0.1.11'
  13          'libunique>=1.0.0')
  14 makedepends=('gnome-doc-utils>=0.14.0' 'pkg-config>=0.9.0')
  15 optdepends=('rsync: provide incremental dictionary updates'
  16             'ttf-arphic-ukai'
  17             'ttf-kanjistrokeorders: show stroke order diagrams')
  18 install=gwaei.install
  19 source=(http://downloads.sourceforge.net/$pkgname/$pkgname-$pkgver.tar.gz)
  20 md5sums=('f51ae472828f077170ae88f69a14d775')
  21
  22 build() {
  23   cd "$srcdir/$pkgname-$pkgver"
  24   ./configure --prefix=/usr --disable-scrollkeeper  --disable-schemas-install \
  25       --with-gconf-schema-file-dir=/usr/share/gconf/schemas
  26   make
  27 }
  28
  29 package() {
  30   cd "$srcdir/$pkgname-$pkgver"
  31   make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="$pkgdir" install
  32   glib-compile-schemas "$pkgdir/usr/share/glib-2.0/schemas"
  33   ln -sf $pkgname "$pkgdir/usr/bin/waei"
  34 }