vdr-epgsearch/PKGBUILD

   1 # Maintainer: David Spicer <azleifel at googlemail dot com>
   2 # Contributor: Leszek Czurylo <leniu_user@wp.pl>
   3
   4 pkgname=vdr-epgsearch
   5 _pluginname=epgsearch
   6 pkgver=1.0.0
   7 pkgrel=1
   8 arch=('i686' 'x86_64')
   9 pkgdesc="A VDR plugin providing a replacement schedule with extended functionality"
  10 url="http://winni.vdr-developer.org/epgsearch/"
  11 license=('GPL2')
  12 depends=('vdr>=1.6' 'perl' 'pcre')
  13 backup=('etc/vdr/plugins/epgsearch/epgsearchcats.conf'
  14         'etc/vdr/plugins/epgsearch/epgsearchcmds.conf'
  15         'etc/vdr/plugins/epgsearch/epgsearchmenu.conf')
  16 install=${pkgname}.install
  17 source=(http://winni.vdr-developer.org/epgsearch/downloads/${pkgname}-${pkgver}.tgz)
  18 md5sums=('c18d93ceeb4ae5d23b03e786d12c571b')
  19
  20 build() {
  21   cd "${srcdir}/${_pluginname}-${pkgver}"
  22
  23   # Assumed VDR directory environment (VDRDIR/Make.config):
  24   # MANDIR       = /usr/share/man
  25   # BINDIR       = /usr/bin
  26   # LOCDIR       = /usr/share/locale
  27   # PLUGINLIBDIR = /usr/lib/vdr
  28   # VIDEODIR     = /var/spool/video
  29   # CONFDIR      = /etc/vdr
  30
  31   install -d -m755 "${pkgdir}/etc/vdr/plugins/${_pluginname}"
  32   install -d -m755 "${pkgdir}/usr/bin"
  33   install -d -m755 "${pkgdir}/usr/lib/vdr"
  34   install -d -m755 "${pkgdir}/usr/share/doc/${pkgname}"
  35   install -d -m755 "${pkgdir}/usr/share/locale"
  36   install -d -m755 "${pkgdir}/usr/share/man"
  37
  38   make VDRDIR=/usr/include/vdr \
  39        LIBDIR="${pkgdir}/usr/lib/vdr" \
  40        LOCALEDIR="${pkgdir}/usr/share/locale" \
  41        MANDIR="${pkgdir}/usr/share/man" all install-doc
  42
  43   # Install scripts
  44   install -m755 scripts/*.{pl,sh} "${pkgdir}/usr/bin"
  45
  46   # Install configuration files
  47   install -m644 conf/* "${pkgdir}/etc/vdr/plugins/${_pluginname}"
  48   install -m644 conf/epgsearchcats.conf-epgdata "${pkgdir}/etc/vdr/plugins/${_pluginname}/epgsearchcats.conf"
  49   install -m644 scripts/*.conf "${pkgdir}/etc/vdr/plugins/${_pluginname}"
  50
  51   # Install documents
  52   for _file in README README.DE HISTORY HISTORY.DE MANUAL; do
  53     install -m644 ${_file} "${pkgdir}/usr/share/doc/${pkgname}"
  54   done
  55 }